ox-texinfo.el 61 KB

123456789101112131415161718192021222324252627282930313233343536373839404142434445464748495051525354555657585960616263646566676869707172737475767778798081828384858687888990919293949596979899100101102103104105106107108109110111112113114115116117118119120121122123124125126127128129130131132133134135136137138139140141142143144145146147148149150151152153154155156157158159160161162163164165166167168169170171172173174175176177178179180181182183184185186187188189190191192193194195196197198199200201202203204205206207208209210211212213214215216217218219220221222223224225226227228229230231232233234235236237238239240241242243244245246247248249250251252253254255256257258259260261262263264265266267268269270271272273274275276277278279280281282283284285286287288289290291292293294295296297298299300301302303304305306307308309310311312313314315316317318319320321322323324325326327328329330331332333334335336337338339340341342343344345346347348349350351352353354355356357358359360361362363364365366367368369370371372373374375376377378379380381382383384385386387388389390391392393394395396397398399400401402403404405406407408409410411412413414415416417418419420421422423424425426427428429430431432433434435436437438439440441442443444445446447448449450451452453454455456457458459460461462463464465466467468469470471472473474475476477478479480481482483484485486487488489490491492493494495496497498499500501502503504505506507508509510511512513514515516517518519520521522523524525526527528529530531532533534535536537538539540541542543544545546547548549550551552553554555556557558559560561562563564565566567568569570571572573574575576577578579580581582583584585586587588589590591592593594595596597598599600601602603604605606607608609610611612613614615616617618619620621622623624625626627628629630631632633634635636637638639640641642643644645646647648649650651652653654655656657658659660661662663664665666667668669670671672673674675676677678679680681682683684685686687688689690691692693694695696697698699700701702703704705706707708709710711712713714715716717718719720721722723724725726727728729730731732733734735736737738739740741742743744745746747748749750751752753754755756757758759760761762763764765766767768769770771772773774775776777778779780781782783784785786787788789790791792793794795796797798799800801802803804805806807808809810811812813814815816817818819820821822823824825826827828829830831832833834835836837838839840841842843844845846847848849850851852853854855856857858859860861862863864865866867868869870871872873874875876877878879880881882883884885886887888889890891892893894895896897898899900901902903904905906907908909910911912913914915916917918919920921922923924925926927928929930931932933934935936937938939940941942943944945946947948949950951952953954955956957958959960961962963964965966967968969970971972973974975976977978979980981982983984985986987988989990991992993994995996997998999100010011002100310041005100610071008100910101011101210131014101510161017101810191020102110221023102410251026102710281029103010311032103310341035103610371038103910401041104210431044104510461047104810491050105110521053105410551056105710581059106010611062106310641065106610671068106910701071107210731074107510761077107810791080108110821083108410851086108710881089109010911092109310941095109610971098109911001101110211031104110511061107110811091110111111121113111411151116111711181119112011211122112311241125112611271128112911301131113211331134113511361137113811391140114111421143114411451146114711481149115011511152115311541155115611571158115911601161116211631164116511661167116811691170117111721173117411751176117711781179118011811182118311841185118611871188118911901191119211931194119511961197119811991200120112021203120412051206120712081209121012111212121312141215121612171218121912201221122212231224122512261227122812291230123112321233123412351236123712381239124012411242124312441245124612471248124912501251125212531254125512561257125812591260126112621263126412651266126712681269127012711272127312741275127612771278127912801281128212831284128512861287128812891290129112921293129412951296129712981299130013011302130313041305130613071308130913101311131213131314131513161317131813191320132113221323132413251326132713281329133013311332133313341335133613371338133913401341134213431344134513461347134813491350135113521353135413551356135713581359136013611362136313641365136613671368136913701371137213731374137513761377137813791380138113821383138413851386138713881389139013911392139313941395139613971398139914001401140214031404140514061407140814091410141114121413141414151416141714181419142014211422142314241425142614271428142914301431143214331434143514361437143814391440144114421443144414451446144714481449145014511452145314541455145614571458145914601461146214631464146514661467146814691470147114721473147414751476147714781479148014811482148314841485148614871488148914901491149214931494149514961497149814991500150115021503150415051506150715081509151015111512151315141515151615171518151915201521152215231524152515261527152815291530153115321533153415351536153715381539154015411542154315441545154615471548154915501551155215531554155515561557155815591560156115621563156415651566156715681569157015711572157315741575157615771578157915801581158215831584158515861587158815891590159115921593159415951596159715981599160016011602160316041605160616071608160916101611161216131614161516161617161816191620162116221623162416251626162716281629163016311632163316341635163616371638163916401641164216431644164516461647164816491650165116521653165416551656165716581659166016611662166316641665166616671668166916701671167216731674167516761677167816791680168116821683168416851686168716881689169016911692169316941695169616971698169917001701170217031704170517061707170817091710
  1. ;;; ox-texinfo.el --- Texinfo Back-End for Org Export Engine -*- lexical-binding: t; -*-
  2. ;; Copyright (C) 2012-2018 Free Software Foundation, Inc.
  3. ;; Author: Jonathan Leech-Pepin <jonathan.leechpepin at gmail dot com>
  4. ;; Keywords: outlines, hypermedia, calendar, wp
  5. ;; This file is part of GNU Emacs.
  6. ;; GNU Emacs is free software: you can redistribute it and/or modify
  7. ;; it under the terms of the GNU General Public License as published by
  8. ;; the Free Software Foundation, either version 3 of the License, or
  9. ;; (at your option) any later version.
  10. ;; GNU Emacs is distributed in the hope that it will be useful,
  11. ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  12. ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  13. ;; GNU General Public License for more details.
  14. ;; You should have received a copy of the GNU General Public License
  15. ;; along with GNU Emacs. If not, see <https://www.gnu.org/licenses/>.
  16. ;;; Commentary:
  17. ;;
  18. ;; See Org manual for details.
  19. ;;; Code:
  20. (require 'cl-lib)
  21. (require 'ox)
  22. (defvar orgtbl-exp-regexp)
  23. ;;; Define Back-End
  24. (org-export-define-backend 'texinfo
  25. '((bold . org-texinfo-bold)
  26. (center-block . org-texinfo-center-block)
  27. (clock . org-texinfo-clock)
  28. (code . org-texinfo-code)
  29. (drawer . org-texinfo-drawer)
  30. (dynamic-block . org-texinfo-dynamic-block)
  31. (entity . org-texinfo-entity)
  32. (example-block . org-texinfo-example-block)
  33. (export-block . org-texinfo-export-block)
  34. (export-snippet . org-texinfo-export-snippet)
  35. (fixed-width . org-texinfo-fixed-width)
  36. (footnote-definition . org-texinfo-footnote-definition)
  37. (footnote-reference . org-texinfo-footnote-reference)
  38. (headline . org-texinfo-headline)
  39. (inline-src-block . org-texinfo-inline-src-block)
  40. (inlinetask . org-texinfo-inlinetask)
  41. (italic . org-texinfo-italic)
  42. (item . org-texinfo-item)
  43. (keyword . org-texinfo-keyword)
  44. (line-break . org-texinfo-line-break)
  45. (link . org-texinfo-link)
  46. (node-property . org-texinfo-node-property)
  47. (paragraph . org-texinfo-paragraph)
  48. (plain-list . org-texinfo-plain-list)
  49. (plain-text . org-texinfo-plain-text)
  50. (planning . org-texinfo-planning)
  51. (property-drawer . org-texinfo-property-drawer)
  52. (quote-block . org-texinfo-quote-block)
  53. (radio-target . org-texinfo-radio-target)
  54. (section . org-texinfo-section)
  55. (special-block . org-texinfo-special-block)
  56. (src-block . org-texinfo-src-block)
  57. (statistics-cookie . org-texinfo-statistics-cookie)
  58. (strike-through . org-texinfo-strike-through)
  59. (subscript . org-texinfo-subscript)
  60. (superscript . org-texinfo-superscript)
  61. (table . org-texinfo-table)
  62. (table-cell . org-texinfo-table-cell)
  63. (table-row . org-texinfo-table-row)
  64. (target . org-texinfo-target)
  65. (template . org-texinfo-template)
  66. (timestamp . org-texinfo-timestamp)
  67. (underline . org-texinfo-underline)
  68. (verbatim . org-texinfo-verbatim)
  69. (verse-block . org-texinfo-verse-block))
  70. :filters-alist
  71. '((:filter-headline . org-texinfo--filter-section-blank-lines)
  72. (:filter-parse-tree . org-texinfo--normalize-headlines)
  73. (:filter-section . org-texinfo--filter-section-blank-lines)
  74. (:filter-final-output . org-texinfo--untabify))
  75. :menu-entry
  76. '(?i "Export to Texinfo"
  77. ((?t "As TEXI file" org-texinfo-export-to-texinfo)
  78. (?i "As INFO file" org-texinfo-export-to-info)
  79. (?o "As INFO file and open"
  80. (lambda (a s v b)
  81. (if a (org-texinfo-export-to-info t s v b)
  82. (org-open-file (org-texinfo-export-to-info nil s v b)))))))
  83. :options-alist
  84. '((:texinfo-filename "TEXINFO_FILENAME" nil nil t)
  85. (:texinfo-class "TEXINFO_CLASS" nil org-texinfo-default-class t)
  86. (:texinfo-header "TEXINFO_HEADER" nil nil newline)
  87. (:texinfo-post-header "TEXINFO_POST_HEADER" nil nil newline)
  88. (:subtitle "SUBTITLE" nil nil parse)
  89. (:subauthor "SUBAUTHOR" nil nil newline)
  90. (:texinfo-dircat "TEXINFO_DIR_CATEGORY" nil nil t)
  91. (:texinfo-dirtitle "TEXINFO_DIR_TITLE" nil nil t)
  92. (:texinfo-dirdesc "TEXINFO_DIR_DESC" nil nil t)
  93. (:texinfo-printed-title "TEXINFO_PRINTED_TITLE" nil nil t)
  94. ;; Other variables.
  95. (:texinfo-classes nil nil org-texinfo-classes)
  96. (:texinfo-format-headline-function nil nil org-texinfo-format-headline-function)
  97. (:texinfo-node-description-column nil nil org-texinfo-node-description-column)
  98. (:texinfo-active-timestamp-format nil nil org-texinfo-active-timestamp-format)
  99. (:texinfo-inactive-timestamp-format nil nil org-texinfo-inactive-timestamp-format)
  100. (:texinfo-diary-timestamp-format nil nil org-texinfo-diary-timestamp-format)
  101. (:texinfo-link-with-unknown-path-format nil nil org-texinfo-link-with-unknown-path-format)
  102. (:texinfo-tables-verbatim nil nil org-texinfo-tables-verbatim)
  103. (:texinfo-table-scientific-notation nil nil org-texinfo-table-scientific-notation)
  104. (:texinfo-table-default-markup nil nil org-texinfo-table-default-markup)
  105. (:texinfo-text-markup-alist nil nil org-texinfo-text-markup-alist)
  106. (:texinfo-format-drawer-function nil nil org-texinfo-format-drawer-function)
  107. (:texinfo-format-inlinetask-function nil nil org-texinfo-format-inlinetask-function)))
  108. ;;; User Configurable Variables
  109. (defgroup org-export-texinfo nil
  110. "Options for exporting Org mode files to Texinfo."
  111. :tag "Org Export Texinfo"
  112. :version "24.4"
  113. :package-version '(Org . "8.0")
  114. :group 'org-export)
  115. ;;;; Preamble
  116. (defcustom org-texinfo-coding-system nil
  117. "Default document encoding for Texinfo output.
  118. If nil it will default to `buffer-file-coding-system'."
  119. :group 'org-export-texinfo
  120. :type 'coding-system)
  121. (defcustom org-texinfo-default-class "info"
  122. "The default Texinfo class."
  123. :group 'org-export-texinfo
  124. :type '(string :tag "Texinfo class"))
  125. (defcustom org-texinfo-classes
  126. '(("info"
  127. "@documentencoding AUTO\n@documentlanguage AUTO"
  128. ("@chapter %s" "@unnumbered %s" "@chapheading %s" "@appendix %s")
  129. ("@section %s" "@unnumberedsec %s" "@heading %s" "@appendixsec %s")
  130. ("@subsection %s" "@unnumberedsubsec %s" "@subheading %s"
  131. "@appendixsubsec %s")
  132. ("@subsubsection %s" "@unnumberedsubsubsec %s" "@subsubheading %s"
  133. "@appendixsubsubsec %s")))
  134. "Alist of Texinfo classes and associated header and structure.
  135. If #+TEXINFO_CLASS is set in the buffer, use its value and the
  136. associated information. Here is the structure of a class
  137. definition:
  138. (class-name
  139. header-string
  140. (numbered-1 unnumbered-1 unnumbered-no-toc-1 appendix-1)
  141. (numbered-2 unnumbered-2 unnumbered-no-toc-2 appendix-2)
  142. ...)
  143. The header string
  144. -----------------
  145. The header string is inserted in the header of the generated
  146. document, right after \"@setfilename\" and \"@settitle\"
  147. commands.
  148. If it contains the special string
  149. \"@documentencoding AUTO\"
  150. \"AUTO\" will be replaced with an appropriate coding system. See
  151. `org-texinfo-coding-system' for more information. Likewise, if
  152. the string contains the special string
  153. \"@documentlanguage AUTO\"
  154. \"AUTO\" will be replaced with the language defined in the
  155. buffer, through #+LANGUAGE keyword, or globally, with
  156. `org-export-default-language', which see.
  157. The sectioning structure
  158. ------------------------
  159. The sectioning structure of the class is given by the elements
  160. following the header string. For each sectioning level, a number
  161. of strings is specified. A %s formatter is mandatory in each
  162. section string and will be replaced by the title of the section."
  163. :group 'org-export-texinfo
  164. :version "27.1"
  165. :package-version '(Org . "9.2")
  166. :type '(repeat
  167. (list (string :tag "Texinfo class")
  168. (string :tag "Texinfo header")
  169. (repeat :tag "Levels" :inline t
  170. (choice
  171. (list :tag "Heading"
  172. (string :tag " numbered")
  173. (string :tag " unnumbered")
  174. (string :tag "unnumbered-no-toc")
  175. (string :tag " appendix")))))))
  176. ;;;; Headline
  177. (defcustom org-texinfo-format-headline-function
  178. 'org-texinfo-format-headline-default-function
  179. "Function to format headline text.
  180. This function will be called with 5 arguments:
  181. TODO the todo keyword (string or nil).
  182. TODO-TYPE the type of todo (symbol: `todo', `done', nil)
  183. PRIORITY the priority of the headline (integer or nil)
  184. TEXT the main headline text (string).
  185. TAGS the tags as a list of strings (list of strings or nil).
  186. The function result will be used in the section format string."
  187. :group 'org-export-texinfo
  188. :type 'function
  189. :version "26.1"
  190. :package-version '(Org . "8.3"))
  191. ;;;; Node listing (menu)
  192. (defcustom org-texinfo-node-description-column 32
  193. "Column at which to start the description in the node listings.
  194. If a node title is greater than this length, the description will
  195. be placed after the end of the title."
  196. :group 'org-export-texinfo
  197. :type 'integer)
  198. ;;;; Timestamps
  199. (defcustom org-texinfo-active-timestamp-format "@emph{%s}"
  200. "A printf format string to be applied to active timestamps."
  201. :group 'org-export-texinfo
  202. :type 'string)
  203. (defcustom org-texinfo-inactive-timestamp-format "@emph{%s}"
  204. "A printf format string to be applied to inactive timestamps."
  205. :group 'org-export-texinfo
  206. :type 'string)
  207. (defcustom org-texinfo-diary-timestamp-format "@emph{%s}"
  208. "A printf format string to be applied to diary timestamps."
  209. :group 'org-export-texinfo
  210. :type 'string)
  211. ;;;; Links
  212. (defcustom org-texinfo-link-with-unknown-path-format "@indicateurl{%s}"
  213. "Format string for links with unknown path type."
  214. :group 'org-export-texinfo
  215. :type 'string)
  216. ;;;; Tables
  217. (defcustom org-texinfo-tables-verbatim nil
  218. "When non-nil, tables are exported verbatim."
  219. :group 'org-export-texinfo
  220. :type 'boolean)
  221. (defcustom org-texinfo-table-scientific-notation nil
  222. "Format string to display numbers in scientific notation.
  223. The format should have \"%s\" twice, for mantissa and exponent
  224. \(i.e. \"%s\\\\times10^{%s}\").
  225. When nil, no transformation is made."
  226. :group 'org-export-texinfo
  227. :type '(choice
  228. (string :tag "Format string")
  229. (const :tag "No formatting" nil)))
  230. (defcustom org-texinfo-table-default-markup "@asis"
  231. "Default markup for first column in two-column tables.
  232. This should an indicating command, e.g., \"@code\", \"@kbd\" or
  233. \"@samp\".
  234. It can be overridden locally using the \":indic\" attribute."
  235. :group 'org-export-texinfo
  236. :type 'string
  237. :version "26.1"
  238. :package-version '(Org . "9.1")
  239. :safe #'stringp)
  240. ;;;; Text markup
  241. (defcustom org-texinfo-text-markup-alist '((bold . "@strong{%s}")
  242. (code . code)
  243. (italic . "@emph{%s}")
  244. (verbatim . samp))
  245. "Alist of Texinfo expressions to convert text markup.
  246. The key must be a symbol among `bold', `code', `italic',
  247. `strike-through', `underscore' and `verbatim'. The value is
  248. a formatting string to wrap fontified text with.
  249. Value can also be set to the following symbols: `verb', `samp'
  250. and `code'. With the first one, Org uses \"@verb\" to create
  251. a format string and selects a delimiter character that isn't in
  252. the string. For the other two, Org uses \"@samp\" or \"@code\"
  253. to typeset and protects special characters.
  254. When no association is found for a given markup, text is returned
  255. as-is."
  256. :group 'org-export-texinfo
  257. :version "26.1"
  258. :package-version '(Org . "9.1")
  259. :type 'alist
  260. :options '(bold code italic strike-through underscore verbatim))
  261. ;;;; Drawers
  262. (defcustom org-texinfo-format-drawer-function (lambda (_name contents) contents)
  263. "Function called to format a drawer in Texinfo code.
  264. The function must accept two parameters:
  265. NAME the drawer name, like \"LOGBOOK\"
  266. CONTENTS the contents of the drawer.
  267. The function should return the string to be exported.
  268. The default function simply returns the value of CONTENTS."
  269. :group 'org-export-texinfo
  270. :version "24.4"
  271. :package-version '(Org . "8.2")
  272. :type 'function)
  273. ;;;; Inlinetasks
  274. (defcustom org-texinfo-format-inlinetask-function
  275. 'org-texinfo-format-inlinetask-default-function
  276. "Function called to format an inlinetask in Texinfo code.
  277. The function must accept six parameters:
  278. TODO the todo keyword, as a string
  279. TODO-TYPE the todo type, a symbol among `todo', `done' and nil.
  280. PRIORITY the inlinetask priority, as a string
  281. NAME the inlinetask name, as a string.
  282. TAGS the inlinetask tags, as a list of strings.
  283. CONTENTS the contents of the inlinetask, as a string.
  284. The function should return the string to be exported."
  285. :group 'org-export-texinfo
  286. :type 'function)
  287. ;;;; Compilation
  288. (defcustom org-texinfo-info-process '("makeinfo --no-split %f")
  289. "Commands to process a Texinfo file to an INFO file.
  290. This is a list of strings, each of them will be given to the
  291. shell as a command. %f in the command will be replaced by the
  292. relative file name, %F by the absolute file name, %b by the file
  293. base name (i.e. without directory and extension parts), %o by the
  294. base directory of the file and %O by the absolute file name of
  295. the output file."
  296. :group 'org-export-texinfo
  297. :version "26.1"
  298. :package-version '(Org . "9.1")
  299. :type '(repeat :tag "Shell command sequence"
  300. (string :tag "Shell command")))
  301. (defcustom org-texinfo-logfiles-extensions
  302. '("aux" "toc" "cp" "fn" "ky" "pg" "tp" "vr")
  303. "The list of file extensions to consider as Texinfo logfiles.
  304. The logfiles will be remove if `org-texinfo-remove-logfiles' is
  305. non-nil."
  306. :group 'org-export-texinfo
  307. :type '(repeat (string :tag "Extension")))
  308. (defcustom org-texinfo-remove-logfiles t
  309. "Non-nil means remove the logfiles produced by compiling a Texinfo file.
  310. By default, logfiles are files with these extensions: .aux, .toc,
  311. .cp, .fn, .ky, .pg and .tp. To define the set of logfiles to remove,
  312. set `org-texinfo-logfiles-extensions'."
  313. :group 'org-export-latex
  314. :type 'boolean)
  315. ;;; Constants
  316. (defconst org-texinfo-max-toc-depth 4
  317. "Maximum depth for creation of detailed menu listings.
  318. Beyond this depth, Texinfo will not recognize the nodes and will
  319. cause errors. Left as a constant in case this value ever
  320. changes.")
  321. (defconst org-texinfo-supported-coding-systems
  322. '("US-ASCII" "UTF-8" "ISO-8859-15" "ISO-8859-1" "ISO-8859-2" "koi8-r" "koi8-u")
  323. "List of coding systems supported by Texinfo, as strings.
  324. Specified coding system will be matched against these strings.
  325. If two strings share the same prefix (e.g. \"ISO-8859-1\" and
  326. \"ISO-8859-15\"), the most specific one has to be listed first.")
  327. (defconst org-texinfo-inline-image-rules
  328. (list (cons "file"
  329. (regexp-opt '("eps" "pdf" "png" "jpg" "jpeg" "gif" "svg"))))
  330. "Rules characterizing image files that can be inlined.")
  331. ;;; Internal Functions
  332. (defun org-texinfo--untabify (s _backend _info)
  333. "Remove TAB characters in string S."
  334. (replace-regexp-in-string "\t" (make-string tab-width ?\s) s))
  335. (defun org-texinfo--filter-section-blank-lines (headline _backend _info)
  336. "Filter controlling number of blank lines after a section."
  337. (replace-regexp-in-string "\n\\(?:\n[ \t]*\\)*\\'" "\n\n" headline))
  338. (defun org-texinfo--normalize-headlines (tree _backend info)
  339. "Normalize headlines in TREE.
  340. BACK-END is the symbol specifying back-end used for export. INFO
  341. is a plist used as a communication channel.
  342. Make sure every headline in TREE contains a section, since those
  343. are required to install a menu. Also put exactly one blank line
  344. at the end of each section.
  345. Return new tree."
  346. (org-element-map tree 'headline
  347. (lambda (hl)
  348. (org-element-put-property hl :post-blank 1)
  349. (let ((contents (org-element-contents hl)))
  350. (when contents
  351. (let ((first (org-element-map contents '(headline section)
  352. #'identity info t)))
  353. (unless (eq (org-element-type first) 'section)
  354. (apply #'org-element-set-contents
  355. hl
  356. (cons `(section (:parent ,hl)) contents)))))))
  357. info)
  358. tree)
  359. (defun org-texinfo--find-verb-separator (s)
  360. "Return a character not used in string S.
  361. This is used to choose a separator for constructs like \\verb."
  362. (let ((ll "~,./?;':\"|!@#%^&-_=+abcdefghijklmnopqrstuvwxyzABCDEFGHIJKLMNOPQRSTUVWXYZ<>()[]{}"))
  363. (cl-loop for c across ll
  364. when (not (string-match (regexp-quote (char-to-string c)) s))
  365. return (char-to-string c))))
  366. (defun org-texinfo--text-markup (text markup _info)
  367. "Format TEXT depending on MARKUP text markup.
  368. INFO is a plist used as a communication channel. See
  369. `org-texinfo-text-markup-alist' for details."
  370. (pcase (cdr (assq markup org-texinfo-text-markup-alist))
  371. (`nil text) ;no markup: return raw text
  372. (`code (format "@code{%s}" (org-texinfo--sanitize-content text)))
  373. (`samp (format "@samp{%s}" (org-texinfo--sanitize-content text)))
  374. (`verb
  375. (let ((separator (org-texinfo--find-verb-separator text)))
  376. (format "@verb{%s%s%s}" separator text separator)))
  377. ;; Else use format string.
  378. (fmt (format fmt text))))
  379. (defun org-texinfo--get-node (datum info)
  380. "Return node or anchor associated to DATUM.
  381. DATUM is a headline, a radio-target or a target. INFO is a plist
  382. used as a communication channel. The function guarantees the
  383. node or anchor name is unique."
  384. (let ((cache (plist-get info :texinfo-node-cache)))
  385. (or (cdr (assq datum cache))
  386. (let* ((salt 0)
  387. (basename
  388. (org-texinfo--sanitize-node
  389. (pcase (org-element-type datum)
  390. (`headline
  391. (org-texinfo--sanitize-title
  392. (org-export-get-alt-title datum info) info))
  393. (`radio-target
  394. (org-texinfo--sanitize-title
  395. (org-element-contents datum) info))
  396. (`target
  397. (org-export-data (org-element-property :value datum) info))
  398. (type
  399. (error "Cannot generate node name for type: %S" type)))))
  400. (name basename))
  401. ;; Org exports deeper elements before their parents. If two
  402. ;; node names collide -- e.g., they have the same title --
  403. ;; within the same hierarchy, the second one would get the
  404. ;; shorter node name. This is counter-intuitive.
  405. ;; Consequently, we ensure that every parent headline get
  406. ;; its node beforehand. As a recursive operation, this
  407. ;; achieves the desired effect.
  408. (let ((parent (org-element-lineage datum '(headline))))
  409. (when (and parent (not (assq parent cache)))
  410. (org-texinfo--get-node parent info)
  411. (setq cache (plist-get info :texinfo-node-cache))))
  412. ;; Ensure NAME is unique and not reserved node name "Top".
  413. (while (or (equal name "Top") (rassoc name cache))
  414. (setq name (concat basename (format " (%d)" (cl-incf salt)))))
  415. (plist-put info :texinfo-node-cache (cons (cons datum name) cache))
  416. name))))
  417. (defun org-texinfo--sanitize-node (title)
  418. "Bend string TITLE to node line requirements.
  419. Trim string and collapse multiple whitespace characters as they
  420. are not significant. Replace leading left parenthesis, when
  421. followed by a right parenthesis, with a square bracket. Remove
  422. periods, commas and colons."
  423. (org-trim
  424. (replace-regexp-in-string
  425. "[ \t]+" " "
  426. (replace-regexp-in-string
  427. "[:,.]" ""
  428. (replace-regexp-in-string "\\`(\\(.*?)\\)" "[\\1" title)))))
  429. (defun org-texinfo--sanitize-title (title info)
  430. "Make TITLE suitable as a section name.
  431. TITLE is a string or a secondary string. INFO is the current
  432. export state, as a plist."
  433. (org-export-data-with-backend
  434. title (org-export-toc-entry-backend 'texinfo) info))
  435. (defun org-texinfo--sanitize-content (text)
  436. "Escape special characters in string TEXT.
  437. Special characters are: @ { }"
  438. (replace-regexp-in-string "[@{}]" "@\\&" text))
  439. (defun org-texinfo--wrap-float (value info &optional type label caption short)
  440. "Wrap string VALUE within a @float command.
  441. INFO is the current export state, as a plist. TYPE is float
  442. type, as a string. LABEL is the cross reference label for the
  443. float, as a string. CAPTION and SHORT are, respectively, the
  444. caption and shortcaption used for the float, as secondary
  445. strings (e.g., returned by `org-export-get-caption')."
  446. (let* ((backend
  447. (org-export-toc-entry-backend 'texinfo
  448. (cons 'footnote-reference
  449. (lambda (f c i) (org-export-with-backend 'texinfo f c i)))))
  450. (short-backend
  451. (org-export-toc-entry-backend 'texinfo
  452. '(inline-src-block . ignore)
  453. '(verbatim . ignore)))
  454. (short-str
  455. (if (and short caption)
  456. (format "@shortcaption{%s}\n"
  457. (org-export-data-with-backend short short-backend info))
  458. ""))
  459. (caption-str
  460. (if (or short caption)
  461. (format "@caption{%s}\n"
  462. (org-export-data-with-backend
  463. (or caption short)
  464. (if (equal short-str "") short-backend backend)
  465. info))
  466. "")))
  467. (format "@float %s%s\n%s\n%s%s@end float"
  468. type (if label (concat "," label) "") value caption-str short-str)))
  469. ;;; Template
  470. (defun org-texinfo-template (contents info)
  471. "Return complete document string after Texinfo conversion.
  472. CONTENTS is the transcoded contents string. INFO is a plist
  473. holding export options."
  474. (let ((title (org-export-data (plist-get info :title) info))
  475. ;; Copying data is the contents of the first headline in
  476. ;; parse tree with a non-nil copying property.
  477. (copying (org-element-map (plist-get info :parse-tree) 'headline
  478. (lambda (hl)
  479. (and (org-not-nil (org-element-property :COPYING hl))
  480. (org-element-contents hl)))
  481. info t)))
  482. (concat
  483. "\\input texinfo @c -*- texinfo -*-\n"
  484. "@c %**start of header\n"
  485. (let ((file (or (org-strip-quotes (plist-get info :texinfo-filename))
  486. (let ((f (plist-get info :output-file)))
  487. (and f (concat (file-name-sans-extension f) ".info"))))))
  488. (and file (format "@setfilename %s\n" file)))
  489. (format "@settitle %s\n" title)
  490. ;; Insert class-defined header.
  491. (org-element-normalize-string
  492. (let ((header (nth 1 (assoc (plist-get info :texinfo-class)
  493. org-texinfo-classes)))
  494. (coding
  495. (catch 'coding-system
  496. (let ((case-fold-search t)
  497. (name (symbol-name (or org-texinfo-coding-system
  498. buffer-file-coding-system))))
  499. (dolist (system org-texinfo-supported-coding-systems "UTF-8")
  500. (when (string-match-p (regexp-quote system) name)
  501. (throw 'coding-system system))))))
  502. (language (plist-get info :language))
  503. (case-fold-search nil))
  504. ;; Auto coding system.
  505. (replace-regexp-in-string
  506. "^@documentencoding \\(AUTO\\)$"
  507. coding
  508. (replace-regexp-in-string
  509. "^@documentlanguage \\(AUTO\\)$" language header t nil 1) t nil 1)))
  510. ;; Additional header options set by #+TEXINFO_HEADER.
  511. (let ((texinfo-header (plist-get info :texinfo-header)))
  512. (and texinfo-header (org-element-normalize-string texinfo-header)))
  513. "@c %**end of header\n\n"
  514. ;; Additional options set by #+TEXINFO_POST_HEADER.
  515. (let ((texinfo-post-header (plist-get info :texinfo-post-header)))
  516. (and texinfo-post-header
  517. (org-element-normalize-string texinfo-post-header)))
  518. ;; Copying.
  519. (and copying
  520. (format "@copying\n%s@end copying\n\n"
  521. (org-element-normalize-string
  522. (org-export-data copying info))))
  523. ;; Info directory information. Only supply if both title and
  524. ;; category are provided.
  525. (let ((dircat (plist-get info :texinfo-dircat))
  526. (dirtitle
  527. (let ((title (plist-get info :texinfo-dirtitle)))
  528. (and title
  529. (string-match "^\\(?:\\* \\)?\\(.*?\\)\\(\\.\\)?$" title)
  530. (format "* %s." (match-string 1 title))))))
  531. (when (and dircat dirtitle)
  532. (concat "@dircategory " dircat "\n"
  533. "@direntry\n"
  534. (let ((dirdesc
  535. (let ((desc (plist-get info :texinfo-dirdesc)))
  536. (cond ((not desc) nil)
  537. ((string-suffix-p "." desc) desc)
  538. (t (concat desc "."))))))
  539. (if dirdesc (format "%-23s %s" dirtitle dirdesc) dirtitle))
  540. "\n"
  541. "@end direntry\n\n")))
  542. ;; Title
  543. "@finalout\n"
  544. "@titlepage\n"
  545. (when (plist-get info :with-title)
  546. (concat
  547. (format "@title %s\n"
  548. (or (plist-get info :texinfo-printed-title) title ""))
  549. (let ((subtitle (plist-get info :subtitle)))
  550. (when subtitle
  551. (format "@subtitle %s\n"
  552. (org-export-data subtitle info))))))
  553. (when (plist-get info :with-author)
  554. (concat
  555. ;; Primary author.
  556. (let ((author (org-string-nw-p
  557. (org-export-data (plist-get info :author) info)))
  558. (email (and (plist-get info :with-email)
  559. (org-string-nw-p
  560. (org-export-data (plist-get info :email) info)))))
  561. (cond ((and author email)
  562. (format "@author %s (@email{%s})\n" author email))
  563. (author (format "@author %s\n" author))
  564. (email (format "@author @email{%s}\n" email))))
  565. ;; Other authors.
  566. (let ((subauthor (plist-get info :subauthor)))
  567. (and subauthor
  568. (org-element-normalize-string
  569. (replace-regexp-in-string "^" "@author " subauthor))))))
  570. (and copying "@page\n@vskip 0pt plus 1filll\n@insertcopying\n")
  571. "@end titlepage\n\n"
  572. ;; Table of contents.
  573. (and (plist-get info :with-toc) "@contents\n\n")
  574. ;; Configure Top Node when not for TeX. Also include contents
  575. ;; from the first section of the document.
  576. "@ifnottex\n"
  577. "@node Top\n"
  578. (format "@top %s\n" title)
  579. (let* ((first-section
  580. (org-element-map (plist-get info :parse-tree) 'section
  581. #'identity info t '(headline)))
  582. (top-contents
  583. (org-export-data (org-element-contents first-section) info)))
  584. (and (org-string-nw-p top-contents) (concat "\n" top-contents)))
  585. "@end ifnottex\n\n"
  586. ;; Menu.
  587. (org-texinfo-make-menu (plist-get info :parse-tree) info 'master)
  588. "\n"
  589. ;; Document's body.
  590. contents "\n"
  591. ;; Creator.
  592. (and (plist-get info :with-creator)
  593. (concat (plist-get info :creator) "\n"))
  594. ;; Document end.
  595. "@bye")))
  596. ;;; Transcode Functions
  597. ;;;; Bold
  598. (defun org-texinfo-bold (_bold contents info)
  599. "Transcode BOLD from Org to Texinfo.
  600. CONTENTS is the text with bold markup. INFO is a plist holding
  601. contextual information."
  602. (org-texinfo--text-markup contents 'bold info))
  603. ;;;; Center Block
  604. (defun org-texinfo-center-block (_center-block contents _info)
  605. "Transcode a CENTER-BLOCK element from Org to Texinfo.
  606. CONTENTS holds the contents of the block. INFO is a plist used
  607. as a communication channel."
  608. contents)
  609. ;;;; Clock
  610. (defun org-texinfo-clock (clock _contents info)
  611. "Transcode a CLOCK element from Org to Texinfo.
  612. CONTENTS is nil. INFO is a plist holding contextual
  613. information."
  614. (concat
  615. "@noindent"
  616. (format "@strong{%s} " org-clock-string)
  617. (format (plist-get info :texinfo-inactive-timestamp-format)
  618. (concat (org-timestamp-translate (org-element-property :value clock))
  619. (let ((time (org-element-property :duration clock)))
  620. (and time (format " (%s)" time)))))
  621. "@*"))
  622. ;;;; Code
  623. (defun org-texinfo-code (code _contents info)
  624. "Transcode a CODE object from Org to Texinfo.
  625. CONTENTS is nil. INFO is a plist used as a communication
  626. channel."
  627. (org-texinfo--text-markup (org-element-property :value code) 'code info))
  628. ;;;; Drawer
  629. (defun org-texinfo-drawer (drawer contents info)
  630. "Transcode a DRAWER element from Org to Texinfo.
  631. CONTENTS holds the contents of the block. INFO is a plist
  632. holding contextual information."
  633. (let* ((name (org-element-property :drawer-name drawer))
  634. (output (funcall (plist-get info :texinfo-format-drawer-function)
  635. name contents)))
  636. output))
  637. ;;;; Dynamic Block
  638. (defun org-texinfo-dynamic-block (_dynamic-block contents _info)
  639. "Transcode a DYNAMIC-BLOCK element from Org to Texinfo.
  640. CONTENTS holds the contents of the block. INFO is a plist
  641. holding contextual information."
  642. contents)
  643. ;;;; Entity
  644. (defun org-texinfo-entity (entity _contents _info)
  645. "Transcode an ENTITY object from Org to Texinfo."
  646. ;; Since there is not specific Texinfo entry in entities, use
  647. ;; Texinfo-specific commands whenever possible, and fallback to
  648. ;; UTF-8 otherwise.
  649. (pcase (org-element-property :name entity)
  650. ("AElig" "@AE{}")
  651. ("aelig" "@ae{}")
  652. ((or "bull" "bullet") "@bullet{}")
  653. ("copy" "@copyright{}")
  654. ("deg" "@textdegree{}")
  655. ((or "dots" "hellip") "@dots{}")
  656. ("equiv" "@equiv{}")
  657. ((or "euro" "EUR") "@euro{}")
  658. ((or "ge" "geq") "@geq{}")
  659. ("laquo" "@guillemetleft{}")
  660. ("iexcl" "@exclamdown{}")
  661. ("imath" "@dotless{i}")
  662. ("iquest" "@questiondown{}")
  663. ("jmath" "@dotless{j}")
  664. ((or "le" "leq") "@leq{}")
  665. ("lsaquo" "@guilsinglleft{}")
  666. ("mdash" "---")
  667. ("minus" "@minus{}")
  668. ("nbsp" "@tie{}")
  669. ("ndash" "--")
  670. ("OElig" "@OE{}")
  671. ("oelig" "@oe{}")
  672. ("ordf" "@ordf{}")
  673. ("ordm" "@ordm{}")
  674. ("pound" "@pound{}")
  675. ("raquo" "@guillemetright{}")
  676. ((or "rArr" "Rightarrow") "@result{}")
  677. ("reg" "@registeredsymbol{}")
  678. ((or "rightarrow" "to" "rarr") "@arrow{}")
  679. ("rsaquo" "@guilsinglright{}")
  680. ("thorn" "@th{}")
  681. ("THORN" "@TH{}")
  682. ((and (pred (string-prefix-p "_")) name) ;spacing entities
  683. (format "@w{%s}" (substring name 1)))
  684. (_ (org-element-property :utf-8 entity))))
  685. ;;;; Example Block
  686. (defun org-texinfo-example-block (example-block _contents info)
  687. "Transcode an EXAMPLE-BLOCK element from Org to Texinfo.
  688. CONTENTS is nil. INFO is a plist holding contextual
  689. information."
  690. (format "@example\n%s@end example"
  691. (org-texinfo--sanitize-content
  692. (org-export-format-code-default example-block info))))
  693. ;;; Export Block
  694. (defun org-texinfo-export-block (export-block _contents _info)
  695. "Transcode a EXPORT-BLOCK element from Org to Texinfo.
  696. CONTENTS is nil. INFO is a plist holding contextual information."
  697. (when (string= (org-element-property :type export-block) "TEXINFO")
  698. (org-remove-indentation (org-element-property :value export-block))))
  699. ;;; Export Snippet
  700. (defun org-texinfo-export-snippet (export-snippet _contents _info)
  701. "Transcode a EXPORT-SNIPPET object from Org to Texinfo.
  702. CONTENTS is nil. INFO is a plist holding contextual information."
  703. (when (eq (org-export-snippet-backend export-snippet) 'texinfo)
  704. (org-element-property :value export-snippet)))
  705. ;;;; Fixed Width
  706. (defun org-texinfo-fixed-width (fixed-width _contents _info)
  707. "Transcode a FIXED-WIDTH element from Org to Texinfo.
  708. CONTENTS is nil. INFO is a plist holding contextual information."
  709. (format "@example\n%s\n@end example"
  710. (org-remove-indentation
  711. (org-texinfo--sanitize-content
  712. (org-element-property :value fixed-width)))))
  713. ;;;; Footnote Reference
  714. (defun org-texinfo-footnote-reference (footnote _contents info)
  715. "Create a footnote reference for FOOTNOTE.
  716. FOOTNOTE is the footnote to define. CONTENTS is nil. INFO is a
  717. plist holding contextual information."
  718. (let ((def (org-export-get-footnote-definition footnote info)))
  719. (format "@footnote{%s}"
  720. (org-trim (org-export-data def info)))))
  721. ;;;; Headline
  722. (defun org-texinfo-headline (headline contents info)
  723. "Transcode a HEADLINE element from Org to Texinfo.
  724. CONTENTS holds the contents of the headline. INFO is a plist
  725. holding contextual information."
  726. (cond
  727. ((org-element-property :footnote-section-p headline) nil)
  728. ((org-not-nil (org-export-get-node-property :COPYING headline t)) nil)
  729. (t
  730. (let* ((index (let ((i (org-export-get-node-property :INDEX headline t)))
  731. (and (member i '("cp" "fn" "ky" "pg" "tp" "vr")) i)))
  732. (numbered? (org-export-numbered-headline-p headline info))
  733. (notoc? (org-export-excluded-from-toc-p headline info))
  734. (command
  735. (and
  736. (not (org-export-low-level-p headline info))
  737. (let ((class (plist-get info :texinfo-class)))
  738. (pcase (assoc class (plist-get info :texinfo-classes))
  739. (`(,_ ,_ . ,sections)
  740. (pcase (nth (1- (org-export-get-relative-level headline info))
  741. sections)
  742. (`(,numbered ,unnumbered ,unnumbered-no-toc ,appendix)
  743. (cond
  744. ((org-not-nil
  745. (org-export-get-node-property :APPENDIX headline t))
  746. appendix)
  747. (numbered? numbered)
  748. (index unnumbered)
  749. (notoc? unnumbered-no-toc)
  750. (t unnumbered)))
  751. (`nil nil)
  752. (_ (user-error "Invalid Texinfo class specification: %S"
  753. class))))
  754. (_ (user-error "Unknown Texinfo class: %S" class))))))
  755. (todo
  756. (and (plist-get info :with-todo-keywords)
  757. (let ((todo (org-element-property :todo-keyword headline)))
  758. (and todo (org-export-data todo info)))))
  759. (todo-type (and todo (org-element-property :todo-type headline)))
  760. (tags (and (plist-get info :with-tags)
  761. (org-export-get-tags headline info)))
  762. (priority (and (plist-get info :with-priority)
  763. (org-element-property :priority headline)))
  764. (text (org-texinfo--sanitize-title
  765. (org-element-property :title headline) info))
  766. (full-text
  767. (funcall (plist-get info :texinfo-format-headline-function)
  768. todo todo-type priority text tags))
  769. (contents
  770. (concat "\n"
  771. (if (org-string-nw-p contents) (concat "\n" contents) "")
  772. (and index (format "\n@printindex %s\n" index)))))
  773. (if (not command)
  774. (concat (and (org-export-first-sibling-p headline info)
  775. (format "@%s\n" (if numbered? 'enumerate 'itemize)))
  776. "@item\n" full-text "\n"
  777. contents
  778. (if (org-export-last-sibling-p headline info)
  779. (format "@end %s" (if numbered? 'enumerate 'itemize))
  780. "\n"))
  781. (concat
  782. ;; Even if HEADLINE is using @subheading and al., leave an
  783. ;; anchor so cross-references in the Org document still work.
  784. (format (if notoc? "@anchor{%s}\n" "@node %s\n")
  785. (org-texinfo--get-node headline info))
  786. (format command full-text)
  787. contents))))))
  788. (defun org-texinfo-format-headline-default-function
  789. (todo _todo-type priority text tags)
  790. "Default format function for a headline.
  791. See `org-texinfo-format-headline-function' for details."
  792. (concat (and todo (format "@strong{%s} " todo))
  793. (and priority (format "@emph{#%s} " priority))
  794. text
  795. (and tags (concat " " (org-make-tag-string tags)))))
  796. ;;;; Inline Src Block
  797. (defun org-texinfo-inline-src-block (inline-src-block _contents _info)
  798. "Transcode an INLINE-SRC-BLOCK element from Org to Texinfo.
  799. CONTENTS holds the contents of the item. INFO is a plist holding
  800. contextual information."
  801. (format "@code{%s}"
  802. (org-texinfo--sanitize-content
  803. (org-element-property :value inline-src-block))))
  804. ;;;; Inlinetask
  805. (defun org-texinfo-inlinetask (inlinetask contents info)
  806. "Transcode an INLINETASK element from Org to Texinfo.
  807. CONTENTS holds the contents of the block. INFO is a plist
  808. holding contextual information."
  809. (let ((title (org-export-data (org-element-property :title inlinetask) info))
  810. (todo (and (plist-get info :with-todo-keywords)
  811. (let ((todo (org-element-property :todo-keyword inlinetask)))
  812. (and todo (org-export-data todo info)))))
  813. (todo-type (org-element-property :todo-type inlinetask))
  814. (tags (and (plist-get info :with-tags)
  815. (org-export-get-tags inlinetask info)))
  816. (priority (and (plist-get info :with-priority)
  817. (org-element-property :priority inlinetask))))
  818. (funcall (plist-get info :texinfo-format-inlinetask-function)
  819. todo todo-type priority title tags contents)))
  820. (defun org-texinfo-format-inlinetask-default-function
  821. (todo _todo-type priority title tags contents)
  822. "Default format function for inlinetasks.
  823. See `org-texinfo-format-inlinetask-function' for details."
  824. (let ((full-title
  825. (concat (when todo (format "@strong{%s} " todo))
  826. (when priority (format "#%c " priority))
  827. title
  828. (when tags (org-make-tag-string tags)))))
  829. (format "@center %s\n\n%s\n" full-title contents)))
  830. ;;;; Italic
  831. (defun org-texinfo-italic (_italic contents info)
  832. "Transcode ITALIC from Org to Texinfo.
  833. CONTENTS is the text with italic markup. INFO is a plist holding
  834. contextual information."
  835. (org-texinfo--text-markup contents 'italic info))
  836. ;;;; Item
  837. (defun org-texinfo-item (item contents info)
  838. "Transcode an ITEM element from Org to Texinfo.
  839. CONTENTS holds the contents of the item. INFO is a plist holding
  840. contextual information."
  841. (let* ((tag (org-element-property :tag item))
  842. (split (org-string-nw-p
  843. (org-export-read-attribute :attr_texinfo
  844. (org-element-property :parent item)
  845. :sep)))
  846. (items (and tag
  847. (let ((tag (org-export-data tag info)))
  848. (if split
  849. (split-string tag (regexp-quote split) t "[ \t\n]+")
  850. (list tag))))))
  851. (format "%s\n%s"
  852. (pcase items
  853. (`nil "@item")
  854. (`(,item) (concat "@item " item))
  855. (`(,item . ,items)
  856. (concat "@item " item "\n"
  857. (mapconcat (lambda (i) (concat "@itemx " i))
  858. items
  859. "\n"))))
  860. (or contents ""))))
  861. ;;;; Keyword
  862. (defun org-texinfo-keyword (keyword _contents info)
  863. "Transcode a KEYWORD element from Org to Texinfo.
  864. CONTENTS is nil. INFO is a plist holding contextual information."
  865. (let ((value (org-element-property :value keyword)))
  866. (pcase (org-element-property :key keyword)
  867. ("TEXINFO" value)
  868. ("CINDEX" (format "@cindex %s" value))
  869. ("FINDEX" (format "@findex %s" value))
  870. ("KINDEX" (format "@kindex %s" value))
  871. ("PINDEX" (format "@pindex %s" value))
  872. ("TINDEX" (format "@tindex %s" value))
  873. ("VINDEX" (format "@vindex %s" value))
  874. ("TOC"
  875. (cond ((string-match-p "\\<tables\\>" value)
  876. (concat "@listoffloats "
  877. (org-export-translate "Table" :utf-8 info)))
  878. ((string-match-p "\\<listings\\>" value)
  879. (concat "@listoffloats "
  880. (org-export-translate "Listing" :utf-8 info))))))))
  881. ;;;; Line Break
  882. (defun org-texinfo-line-break (_line-break _contents _info)
  883. "Transcode a LINE-BREAK object from Org to Texinfo.
  884. CONTENTS is nil. INFO is a plist holding contextual information."
  885. "@*\n")
  886. ;;;; Link
  887. (defun org-texinfo--@ref (datum description info)
  888. "Return @ref command for element or object DATUM.
  889. DESCRIPTION is the printed name of the section, as a string, or
  890. nil."
  891. (let ((node-name (org-texinfo--get-node datum info))
  892. ;; Sanitize DESCRIPTION for cross-reference use. In
  893. ;; particular, remove colons as they seem to cause pain (even
  894. ;; within @asis{...}) to the Texinfo reader.
  895. (title (and description
  896. (replace-regexp-in-string
  897. "[ \t]*:+" ""
  898. (replace-regexp-in-string "," "@comma{}" description)))))
  899. (if (or (not title) (equal title node-name))
  900. (format "@ref{%s}" node-name)
  901. (format "@ref{%s, , %s}" node-name title))))
  902. (defun org-texinfo-link (link desc info)
  903. "Transcode a LINK object from Org to Texinfo.
  904. DESC is the description part of the link, or the empty string.
  905. INFO is a plist holding contextual information. See
  906. `org-export-data'."
  907. (let* ((type (org-element-property :type link))
  908. (raw-path (org-element-property :path link))
  909. ;; Ensure DESC really exists, or set it to nil.
  910. (desc (and (not (string= desc "")) desc))
  911. (path (cond
  912. ((member type '("http" "https" "ftp"))
  913. (concat type ":" raw-path))
  914. ((string= type "file") (org-export-file-uri raw-path))
  915. (t raw-path))))
  916. (cond
  917. ((org-export-custom-protocol-maybe link desc 'texinfo))
  918. ((org-export-inline-image-p link org-texinfo-inline-image-rules)
  919. (org-texinfo--inline-image link info))
  920. ((equal type "radio")
  921. (let ((destination (org-export-resolve-radio-link link info)))
  922. (if (not destination) desc
  923. (org-texinfo--@ref destination desc info))))
  924. ((member type '("custom-id" "id" "fuzzy"))
  925. (let ((destination
  926. (if (equal type "fuzzy")
  927. (org-export-resolve-fuzzy-link link info)
  928. (org-export-resolve-id-link link info))))
  929. (pcase (org-element-type destination)
  930. (`nil
  931. (format org-texinfo-link-with-unknown-path-format
  932. (org-texinfo--sanitize-content path)))
  933. ;; Id link points to an external file.
  934. (`plain-text
  935. (if desc (format "@uref{file://%s,%s}" destination desc)
  936. (format "@uref{file://%s}" destination)))
  937. ((or `headline
  938. ;; Targets within headlines cannot be turned into
  939. ;; @anchor{}, so we refer to the headline parent
  940. ;; directly.
  941. (and `target
  942. (guard (eq 'headline
  943. (org-element-type
  944. (org-element-property :parent destination))))))
  945. (let ((headline (org-element-lineage destination '(headline) t)))
  946. (org-texinfo--@ref headline desc info)))
  947. (_ (org-texinfo--@ref destination desc info)))))
  948. ((string= type "mailto")
  949. (format "@email{%s}"
  950. (concat (org-texinfo--sanitize-content path)
  951. (and desc (concat ", " desc)))))
  952. ;; External link with a description part.
  953. ((and path desc) (format "@uref{%s, %s}" path desc))
  954. ;; External link without a description part.
  955. (path (format "@uref{%s}" path))
  956. ;; No path, only description. Try to do something useful.
  957. (t
  958. (format (plist-get info :texinfo-link-with-unknown-path-format) desc)))))
  959. (defun org-texinfo--inline-image (link info)
  960. "Return Texinfo code for an inline image.
  961. LINK is the link pointing to the inline image. INFO is the
  962. current state of the export, as a plist."
  963. (let* ((parent (org-export-get-parent-element link))
  964. (label (and (org-element-property :name parent)
  965. (org-texinfo--get-node parent info)))
  966. (caption (org-export-get-caption parent))
  967. (shortcaption (org-export-get-caption parent t))
  968. (path (org-element-property :path link))
  969. (filename
  970. (file-name-sans-extension
  971. (if (file-name-absolute-p path) (expand-file-name path) path)))
  972. (extension (file-name-extension path))
  973. (attributes (org-export-read-attribute :attr_texinfo parent))
  974. (height (or (plist-get attributes :height) ""))
  975. (width (or (plist-get attributes :width) ""))
  976. (alt (or (plist-get attributes :alt) ""))
  977. (image (format "@image{%s,%s,%s,%s,%s}"
  978. filename width height alt extension)))
  979. (cond ((or caption shortcaption)
  980. (org-texinfo--wrap-float image
  981. info
  982. (org-export-translate "Figure" :utf-8 info)
  983. label
  984. caption
  985. shortcaption))
  986. (label (concat "@anchor{" label "}\n" image))
  987. (t image))))
  988. ;;;; Menu
  989. (defun org-texinfo-make-menu (scope info &optional master)
  990. "Create the menu for inclusion in the Texinfo document.
  991. SCOPE is a headline or a full parse tree. INFO is the
  992. communication channel, as a plist.
  993. When optional argument MASTER is non-nil, generate a master menu,
  994. including detailed node listing."
  995. (let ((menu (org-texinfo--build-menu scope info)))
  996. (when (org-string-nw-p menu)
  997. (org-element-normalize-string
  998. (format
  999. "@menu\n%s@end menu"
  1000. (concat menu
  1001. (when master
  1002. (let ((detailmenu
  1003. (org-texinfo--build-menu
  1004. scope info
  1005. (let ((toc-depth (plist-get info :with-toc)))
  1006. (if (wholenump toc-depth) toc-depth
  1007. org-texinfo-max-toc-depth)))))
  1008. (when (org-string-nw-p detailmenu)
  1009. (concat "\n@detailmenu\n"
  1010. "--- The Detailed Node Listing ---\n\n"
  1011. detailmenu
  1012. "@end detailmenu\n"))))))))))
  1013. (defun org-texinfo--build-menu (scope info &optional level)
  1014. "Build menu for entries within SCOPE.
  1015. SCOPE is a headline or a full parse tree. INFO is a plist
  1016. containing contextual information. When optional argument LEVEL
  1017. is an integer, build the menu recursively, down to this depth."
  1018. (cond
  1019. ((not level)
  1020. (org-texinfo--format-entries (org-texinfo--menu-entries scope info) info))
  1021. ((zerop level) "\n")
  1022. (t
  1023. (mapconcat
  1024. (lambda (h)
  1025. (let ((entries (org-texinfo--menu-entries h info)))
  1026. (when entries
  1027. (concat
  1028. (format "%s\n\n%s\n"
  1029. (org-export-data (org-export-get-alt-title h info) info)
  1030. (org-texinfo--format-entries entries info))
  1031. (org-texinfo--build-menu h info (1- level))))))
  1032. (org-texinfo--menu-entries scope info)
  1033. ""))))
  1034. (defun org-texinfo--format-entries (entries info)
  1035. "Format all direct menu entries in SCOPE, as a string.
  1036. SCOPE is either a headline or a full Org document. INFO is
  1037. a plist containing contextual information."
  1038. (org-element-normalize-string
  1039. (mapconcat
  1040. (lambda (h)
  1041. (let* ((title
  1042. ;; Colons are used as a separator between title and node
  1043. ;; name. Remove them.
  1044. (replace-regexp-in-string
  1045. "[ \t]+:+" ""
  1046. (org-texinfo--sanitize-title
  1047. (org-export-get-alt-title h info) info)))
  1048. (node (org-texinfo--get-node h info))
  1049. (entry (concat "* " title ":"
  1050. (if (string= title node) ":"
  1051. (concat " " node ". "))))
  1052. (desc (org-element-property :DESCRIPTION h)))
  1053. (if (not desc) entry
  1054. (format (format "%%-%ds %%s" org-texinfo-node-description-column)
  1055. entry desc))))
  1056. entries "\n")))
  1057. (defun org-texinfo--menu-entries (scope info)
  1058. "List direct children in SCOPE needing a menu entry.
  1059. SCOPE is a headline or a full parse tree. INFO is a plist
  1060. holding contextual information."
  1061. (let* ((cache (or (plist-get info :texinfo-entries-cache)
  1062. (plist-get (plist-put info :texinfo-entries-cache
  1063. (make-hash-table :test #'eq))
  1064. :texinfo-entries-cache)))
  1065. (cached-entries (gethash scope cache 'no-cache)))
  1066. (if (not (eq cached-entries 'no-cache)) cached-entries
  1067. (puthash scope
  1068. (cl-remove-if
  1069. (lambda (h)
  1070. (org-not-nil (org-export-get-node-property :COPYING h t)))
  1071. (org-export-collect-headlines info 1 scope))
  1072. cache))))
  1073. ;;;; Node Property
  1074. (defun org-texinfo-node-property (node-property _contents _info)
  1075. "Transcode a NODE-PROPERTY element from Org to Texinfo.
  1076. CONTENTS is nil. INFO is a plist holding contextual
  1077. information."
  1078. (format "%s:%s"
  1079. (org-element-property :key node-property)
  1080. (let ((value (org-element-property :value node-property)))
  1081. (if value (concat " " value) ""))))
  1082. ;;;; Paragraph
  1083. (defun org-texinfo-paragraph (_paragraph contents _info)
  1084. "Transcode a PARAGRAPH element from Org to Texinfo.
  1085. CONTENTS is the contents of the paragraph, as a string. INFO is
  1086. the plist used as a communication channel."
  1087. contents)
  1088. ;;;; Plain List
  1089. (defun org-texinfo-plain-list (plain-list contents info)
  1090. "Transcode a PLAIN-LIST element from Org to Texinfo.
  1091. CONTENTS is the contents of the list. INFO is a plist holding
  1092. contextual information."
  1093. (let* ((attr (org-export-read-attribute :attr_texinfo plain-list))
  1094. (indic (let ((i (or (plist-get attr :indic)
  1095. (plist-get info :texinfo-table-default-markup))))
  1096. ;; Allow indicating commands with missing @ sign.
  1097. (if (string-prefix-p "@" i) i (concat "@" i))))
  1098. (table-type (plist-get attr :table-type))
  1099. (type (org-element-property :type plain-list))
  1100. (list-type (cond
  1101. ((eq type 'ordered) "enumerate")
  1102. ((eq type 'unordered) "itemize")
  1103. ((member table-type '("ftable" "vtable")) table-type)
  1104. (t "table"))))
  1105. (format "@%s\n%s@end %s"
  1106. (if (eq type 'descriptive) (concat list-type " " indic) list-type)
  1107. contents
  1108. list-type)))
  1109. ;;;; Plain Text
  1110. (defun org-texinfo-plain-text (text info)
  1111. "Transcode a TEXT string from Org to Texinfo.
  1112. TEXT is the string to transcode. INFO is a plist holding
  1113. contextual information."
  1114. ;; First protect @, { and }.
  1115. (let ((output (org-texinfo--sanitize-content text)))
  1116. ;; Activate smart quotes. Be sure to provide original TEXT string
  1117. ;; since OUTPUT may have been modified.
  1118. (when (plist-get info :with-smart-quotes)
  1119. (setq output
  1120. (org-export-activate-smart-quotes output :texinfo info text)))
  1121. ;; LaTeX into @LaTeX{} and TeX into @TeX{}
  1122. (let ((case-fold-search nil))
  1123. (setq output (replace-regexp-in-string "\\(?:La\\)?TeX" "@\\&{}" output)))
  1124. ;; Convert special strings.
  1125. (when (plist-get info :with-special-strings)
  1126. (setq output
  1127. (replace-regexp-in-string
  1128. "\\.\\.\\." "@dots{}"
  1129. (replace-regexp-in-string "\\\\-" "@-" output))))
  1130. ;; Handle break preservation if required.
  1131. (when (plist-get info :preserve-breaks)
  1132. (setq output (replace-regexp-in-string
  1133. "\\(\\\\\\\\\\)?[ \t]*\n" " @*\n" output)))
  1134. ;; Reverse sentence ending. A sentence can end with a capital
  1135. ;; letter. Use non-breaking space if it shouldn't.
  1136. (let ((case-fold-search nil))
  1137. (replace-regexp-in-string
  1138. "[A-Z]\\([.?!]\\)\\(?:[])]\\|'\\{1,2\\}\\)?\\(?: \\|$\\)"
  1139. "@\\1"
  1140. output nil nil 1))))
  1141. ;;;; Planning
  1142. (defun org-texinfo-planning (planning _contents info)
  1143. "Transcode a PLANNING element from Org to Texinfo.
  1144. CONTENTS is nil. INFO is a plist holding contextual
  1145. information."
  1146. (concat
  1147. "@noindent"
  1148. (mapconcat
  1149. 'identity
  1150. (delq nil
  1151. (list
  1152. (let ((closed (org-element-property :closed planning)))
  1153. (when closed
  1154. (concat
  1155. (format "@strong{%s} " org-closed-string)
  1156. (format (plist-get info :texinfo-inactive-timestamp-format)
  1157. (org-timestamp-translate closed)))))
  1158. (let ((deadline (org-element-property :deadline planning)))
  1159. (when deadline
  1160. (concat
  1161. (format "@strong{%s} " org-deadline-string)
  1162. (format (plist-get info :texinfo-active-timestamp-format)
  1163. (org-timestamp-translate deadline)))))
  1164. (let ((scheduled (org-element-property :scheduled planning)))
  1165. (when scheduled
  1166. (concat
  1167. (format "@strong{%s} " org-scheduled-string)
  1168. (format (plist-get info :texinfo-active-timestamp-format)
  1169. (org-timestamp-translate scheduled)))))))
  1170. " ")
  1171. "@*"))
  1172. ;;;; Property Drawer
  1173. (defun org-texinfo-property-drawer (_property-drawer contents _info)
  1174. "Transcode a PROPERTY-DRAWER element from Org to Texinfo.
  1175. CONTENTS holds the contents of the drawer. INFO is a plist
  1176. holding contextual information."
  1177. (and (org-string-nw-p contents)
  1178. (format "@verbatim\n%s@end verbatim" contents)))
  1179. ;;;; Quote Block
  1180. (defun org-texinfo-quote-block (quote-block contents _info)
  1181. "Transcode a QUOTE-BLOCK element from Org to Texinfo.
  1182. CONTENTS holds the contents of the block. INFO is a plist
  1183. holding contextual information."
  1184. (let ((tag (org-export-read-attribute :attr_texinfo quote-block :tag))
  1185. (author (org-export-read-attribute :attr_texinfo quote-block :author)))
  1186. (format "@quotation%s\n%s%s\n@end quotation"
  1187. (if tag (concat " " tag) "")
  1188. contents
  1189. (if author (concat "\n@author " author) ""))))
  1190. ;;;; Radio Target
  1191. (defun org-texinfo-radio-target (radio-target text info)
  1192. "Transcode a RADIO-TARGET object from Org to Texinfo.
  1193. TEXT is the text of the target. INFO is a plist holding
  1194. contextual information."
  1195. (format "@anchor{%s}%s"
  1196. (org-texinfo--get-node radio-target info)
  1197. text))
  1198. ;;;; Section
  1199. (defun org-texinfo-section (section contents info)
  1200. "Transcode a SECTION element from Org to Texinfo.
  1201. CONTENTS holds the contents of the section. INFO is a plist
  1202. holding contextual information."
  1203. (let ((parent (org-export-get-parent-headline section)))
  1204. (when parent ;first section is handled in `org-texinfo-template'
  1205. (org-trim
  1206. (concat contents
  1207. "\n"
  1208. (and (not (org-export-excluded-from-toc-p parent info))
  1209. (org-texinfo-make-menu parent info)))))))
  1210. ;;;; Special Block
  1211. (defun org-texinfo-special-block (special-block contents _info)
  1212. "Transcode a SPECIAL-BLOCK element from Org to Texinfo.
  1213. CONTENTS holds the contents of the block. INFO is a plist used
  1214. as a communication channel."
  1215. (let ((opt (org-export-read-attribute :attr_texinfo special-block :options))
  1216. (type (org-element-property :type special-block)))
  1217. (format "@%s%s\n%s@end %s"
  1218. type
  1219. (if opt (concat " " opt) "")
  1220. (or contents "")
  1221. type)))
  1222. ;;;; Src Block
  1223. (defun org-texinfo-src-block (src-block _contents info)
  1224. "Transcode a SRC-BLOCK element from Org to Texinfo.
  1225. CONTENTS holds the contents of the item. INFO is a plist holding
  1226. contextual information."
  1227. (let* ((lisp (string-match-p "lisp"
  1228. (org-element-property :language src-block)))
  1229. (code (org-texinfo--sanitize-content
  1230. (org-export-format-code-default src-block info)))
  1231. (value (format
  1232. (if lisp "@lisp\n%s@end lisp" "@example\n%s@end example")
  1233. code))
  1234. (caption (org-export-get-caption src-block))
  1235. (shortcaption (org-export-get-caption src-block t)))
  1236. (if (not (or caption shortcaption)) value
  1237. (org-texinfo--wrap-float value
  1238. info
  1239. (org-export-translate "Listing" :utf-8 info)
  1240. (org-texinfo--get-node src-block info)
  1241. caption
  1242. shortcaption))))
  1243. ;;;; Statistics Cookie
  1244. (defun org-texinfo-statistics-cookie (statistics-cookie _contents _info)
  1245. "Transcode a STATISTICS-COOKIE object from Org to Texinfo.
  1246. CONTENTS is nil. INFO is a plist holding contextual information."
  1247. (org-element-property :value statistics-cookie))
  1248. ;;;; Strike-through
  1249. (defun org-texinfo-strike-through (_strike-through contents info)
  1250. "Transcode STRIKE-THROUGH from Org to Texinfo.
  1251. CONTENTS is the text with strike-through markup. INFO is a plist
  1252. holding contextual information."
  1253. (org-texinfo--text-markup contents 'strike-through info))
  1254. ;;;; Subscript
  1255. (defun org-texinfo-subscript (_subscript contents _info)
  1256. "Transcode a SUBSCRIPT object from Org to Texinfo.
  1257. CONTENTS is the contents of the object. INFO is a plist holding
  1258. contextual information."
  1259. (format "@math{_%s}" contents))
  1260. ;;;; Superscript
  1261. (defun org-texinfo-superscript (_superscript contents _info)
  1262. "Transcode a SUPERSCRIPT object from Org to Texinfo.
  1263. CONTENTS is the contents of the object. INFO is a plist holding
  1264. contextual information."
  1265. (format "@math{^%s}" contents))
  1266. ;;;; Table
  1267. (defun org-texinfo-table (table contents info)
  1268. "Transcode a TABLE element from Org to Texinfo.
  1269. CONTENTS is the contents of the table. INFO is a plist holding
  1270. contextual information."
  1271. (if (eq (org-element-property :type table) 'table.el)
  1272. (format "@verbatim\n%s@end verbatim"
  1273. (org-element-normalize-string
  1274. (org-element-property :value table)))
  1275. (let* ((col-width (org-export-read-attribute :attr_texinfo table :columns))
  1276. (columns
  1277. (if col-width (format "@columnfractions %s" col-width)
  1278. (org-texinfo-table-column-widths table info)))
  1279. (caption (org-export-get-caption table))
  1280. (shortcaption (org-export-get-caption table t))
  1281. (table-str (format "@multitable %s\n%s@end multitable"
  1282. columns
  1283. contents)))
  1284. (if (not (or caption shortcaption)) table-str
  1285. (org-texinfo--wrap-float table-str
  1286. info
  1287. (org-export-translate "Table" :utf-8 info)
  1288. (org-texinfo--get-node table info)
  1289. caption
  1290. shortcaption)))))
  1291. (defun org-texinfo-table-column-widths (table info)
  1292. "Determine the largest table cell in each column to process alignment.
  1293. TABLE is the table element to transcode. INFO is a plist used as
  1294. a communication channel."
  1295. (let ((widths (make-vector (cdr (org-export-table-dimensions table info)) 0)))
  1296. (org-element-map table 'table-row
  1297. (lambda (row)
  1298. (let ((idx 0))
  1299. (org-element-map row 'table-cell
  1300. (lambda (cell)
  1301. ;; Length of the cell in the original buffer is only an
  1302. ;; approximation of the length of the cell in the
  1303. ;; output. It can sometimes fail (e.g. it considers
  1304. ;; "/a/" being larger than "ab").
  1305. (let ((w (- (org-element-property :contents-end cell)
  1306. (org-element-property :contents-begin cell))))
  1307. (aset widths idx (max w (aref widths idx))))
  1308. (cl-incf idx))
  1309. info)))
  1310. info)
  1311. (format "{%s}" (mapconcat (lambda (w) (make-string w ?a)) widths "} {"))))
  1312. ;;;; Table Cell
  1313. (defun org-texinfo-table-cell (table-cell contents info)
  1314. "Transcode a TABLE-CELL element from Org to Texinfo.
  1315. CONTENTS is the cell contents. INFO is a plist used as
  1316. a communication channel."
  1317. (concat
  1318. (let ((scientific-notation
  1319. (plist-get info :texinfo-table-scientific-notation)))
  1320. (if (and contents
  1321. scientific-notation
  1322. (string-match orgtbl-exp-regexp contents))
  1323. ;; Use appropriate format string for scientific notation.
  1324. (format scientific-notation
  1325. (match-string 1 contents)
  1326. (match-string 2 contents))
  1327. contents))
  1328. (when (org-export-get-next-element table-cell info) "\n@tab ")))
  1329. ;;;; Table Row
  1330. (defun org-texinfo-table-row (table-row contents info)
  1331. "Transcode a TABLE-ROW element from Org to Texinfo.
  1332. CONTENTS is the contents of the row. INFO is a plist used as
  1333. a communication channel."
  1334. ;; Rules are ignored since table separators are deduced from
  1335. ;; borders of the current row.
  1336. (when (eq (org-element-property :type table-row) 'standard)
  1337. (let ((rowgroup-tag
  1338. (if (and (= 1 (org-export-table-row-group table-row info))
  1339. (org-export-table-has-header-p
  1340. (org-export-get-parent-table table-row) info))
  1341. "@headitem "
  1342. "@item ")))
  1343. (concat rowgroup-tag contents "\n"))))
  1344. ;;;; Target
  1345. (defun org-texinfo-target (target _contents info)
  1346. "Transcode a TARGET object from Org to Texinfo.
  1347. CONTENTS is nil. INFO is a plist holding contextual
  1348. information."
  1349. (format "@anchor{%s}" (org-texinfo--get-node target info)))
  1350. ;;;; Timestamp
  1351. (defun org-texinfo-timestamp (timestamp _contents info)
  1352. "Transcode a TIMESTAMP object from Org to Texinfo.
  1353. CONTENTS is nil. INFO is a plist holding contextual
  1354. information."
  1355. (let ((value (org-texinfo-plain-text
  1356. (org-timestamp-translate timestamp) info)))
  1357. (pcase (org-element-property :type timestamp)
  1358. ((or `active `active-range)
  1359. (format (plist-get info :texinfo-active-timestamp-format) value))
  1360. ((or `inactive `inactive-range)
  1361. (format (plist-get info :texinfo-inactive-timestamp-format) value))
  1362. (_ (format (plist-get info :texinfo-diary-timestamp-format) value)))))
  1363. ;;;; Underline
  1364. (defun org-texinfo-underline (_underline contents info)
  1365. "Transcode UNDERLINE from Org to Texinfo.
  1366. CONTENTS is the text with underline markup. INFO is a plist
  1367. holding contextual information."
  1368. (org-texinfo--text-markup contents 'underline info))
  1369. ;;;; Verbatim
  1370. (defun org-texinfo-verbatim (verbatim _contents info)
  1371. "Transcode a VERBATIM object from Org to Texinfo.
  1372. CONTENTS is nil. INFO is a plist used as a communication
  1373. channel."
  1374. (org-texinfo--text-markup
  1375. (org-element-property :value verbatim) 'verbatim info))
  1376. ;;;; Verse Block
  1377. (defun org-texinfo-verse-block (_verse-block contents _info)
  1378. "Transcode a VERSE-BLOCK element from Org to Texinfo.
  1379. CONTENTS is verse block contents. INFO is a plist holding
  1380. contextual information."
  1381. (format "@display\n%s@end display" contents))
  1382. ;;; Interactive functions
  1383. ;;;###autoload
  1384. (defun org-texinfo-export-to-texinfo
  1385. (&optional async subtreep visible-only body-only ext-plist)
  1386. "Export current buffer to a Texinfo file.
  1387. If narrowing is active in the current buffer, only export its
  1388. narrowed part.
  1389. If a region is active, export that region.
  1390. A non-nil optional argument ASYNC means the process should happen
  1391. asynchronously. The resulting file should be accessible through
  1392. the `org-export-stack' interface.
  1393. When optional argument SUBTREEP is non-nil, export the sub-tree
  1394. at point, extracting information from the headline properties
  1395. first.
  1396. When optional argument VISIBLE-ONLY is non-nil, don't export
  1397. contents of hidden elements.
  1398. When optional argument BODY-ONLY is non-nil, only write code
  1399. between \"\\begin{document}\" and \"\\end{document}\".
  1400. EXT-PLIST, when provided, is a property list with external
  1401. parameters overriding Org default settings, but still inferior to
  1402. file-local settings.
  1403. Return output file's name."
  1404. (interactive)
  1405. (let ((outfile (org-export-output-file-name ".texi" subtreep))
  1406. (org-export-coding-system org-texinfo-coding-system))
  1407. (org-export-to-file 'texinfo outfile
  1408. async subtreep visible-only body-only ext-plist)))
  1409. ;;;###autoload
  1410. (defun org-texinfo-export-to-info
  1411. (&optional async subtreep visible-only body-only ext-plist)
  1412. "Export current buffer to Texinfo then process through to INFO.
  1413. If narrowing is active in the current buffer, only export its
  1414. narrowed part.
  1415. If a region is active, export that region.
  1416. A non-nil optional argument ASYNC means the process should happen
  1417. asynchronously. The resulting file should be accessible through
  1418. the `org-export-stack' interface.
  1419. When optional argument SUBTREEP is non-nil, export the sub-tree
  1420. at point, extracting information from the headline properties
  1421. first.
  1422. When optional argument VISIBLE-ONLY is non-nil, don't export
  1423. contents of hidden elements.
  1424. When optional argument BODY-ONLY is non-nil, only write code
  1425. between \"\\begin{document}\" and \"\\end{document}\".
  1426. EXT-PLIST, when provided, is a property list with external
  1427. parameters overriding Org default settings, but still inferior to
  1428. file-local settings.
  1429. When optional argument PUB-DIR is set, use it as the publishing
  1430. directory.
  1431. Return INFO file's name."
  1432. (interactive)
  1433. (let ((outfile (org-export-output-file-name ".texi" subtreep))
  1434. (org-export-coding-system org-texinfo-coding-system))
  1435. (org-export-to-file 'texinfo outfile
  1436. async subtreep visible-only body-only ext-plist
  1437. (lambda (file) (org-texinfo-compile file)))))
  1438. ;;;###autoload
  1439. (defun org-texinfo-publish-to-texinfo (plist filename pub-dir)
  1440. "Publish an org file to Texinfo.
  1441. FILENAME is the filename of the Org file to be published. PLIST
  1442. is the property list for the given project. PUB-DIR is the
  1443. publishing directory.
  1444. Return output file name."
  1445. (org-publish-org-to 'texinfo filename ".texi" plist pub-dir))
  1446. ;;;###autoload
  1447. (defun org-texinfo-convert-region-to-texinfo ()
  1448. "Assume the current region has Org syntax, and convert it to Texinfo.
  1449. This can be used in any buffer. For example, you can write an
  1450. itemized list in Org syntax in an Texinfo buffer and use this
  1451. command to convert it."
  1452. (interactive)
  1453. (org-export-replace-region-by 'texinfo))
  1454. (defun org-texinfo-compile (file)
  1455. "Compile a texinfo file.
  1456. FILE is the name of the file being compiled. Processing is done
  1457. through the command specified in `org-texinfo-info-process',
  1458. which see. Output is redirected to \"*Org INFO Texinfo Output*\"
  1459. buffer.
  1460. Return INFO file name or an error if it couldn't be produced."
  1461. (message "Processing Texinfo file %s..." file)
  1462. (let* ((log-name "*Org INFO Texinfo Output*")
  1463. (log (get-buffer-create log-name))
  1464. (output
  1465. (org-compile-file file org-texinfo-info-process "info"
  1466. (format "See %S for details" log-name)
  1467. log)))
  1468. (when org-texinfo-remove-logfiles
  1469. (let ((base (file-name-sans-extension output)))
  1470. (dolist (ext org-texinfo-logfiles-extensions)
  1471. (let ((file (concat base "." ext)))
  1472. (when (file-exists-p file) (delete-file file))))))
  1473. (message "Process completed.")
  1474. output))
  1475. (provide 'ox-texinfo)
  1476. ;; Local variables:
  1477. ;; generated-autoload-file: "org-loaddefs.el"
  1478. ;; End:
  1479. ;;; ox-texinfo.el ends here