ox-md.el 25 KB

123456789101112131415161718192021222324252627282930313233343536373839404142434445464748495051525354555657585960616263646566676869707172737475767778798081828384858687888990919293949596979899100101102103104105106107108109110111112113114115116117118119120121122123124125126127128129130131132133134135136137138139140141142143144145146147148149150151152153154155156157158159160161162163164165166167168169170171172173174175176177178179180181182183184185186187188189190191192193194195196197198199200201202203204205206207208209210211212213214215216217218219220221222223224225226227228229230231232233234235236237238239240241242243244245246247248249250251252253254255256257258259260261262263264265266267268269270271272273274275276277278279280281282283284285286287288289290291292293294295296297298299300301302303304305306307308309310311312313314315316317318319320321322323324325326327328329330331332333334335336337338339340341342343344345346347348349350351352353354355356357358359360361362363364365366367368369370371372373374375376377378379380381382383384385386387388389390391392393394395396397398399400401402403404405406407408409410411412413414415416417418419420421422423424425426427428429430431432433434435436437438439440441442443444445446447448449450451452453454455456457458459460461462463464465466467468469470471472473474475476477478479480481482483484485486487488489490491492493494495496497498499500501502503504505506507508509510511512513514515516517518519520521522523524525526527528529530531532533534535536537538539540541542543544545546547548549550551552553554555556557558559560561562563564565566567568569570571572573574575576577578579580581582583584585586587588589590591592593594595596597598599600601602603604605606607608609610611612613614615616617618619620621622623624625626627628629630631632633634635636637638639640641642643644645646647648649650651652653654655656657658659660661662663664665666667668669670671672673674675676677678679680681682683684685686687688689690691692693694695696697698699700701702703704705706707708709710711712713714715716717718719720721722723724725726727728729730731732733734
  1. ;;; ox-md.el --- Markdown Back-End for Org Export Engine -*- lexical-binding: t; -*-
  2. ;; Copyright (C) 2012-2018 Free Software Foundation, Inc.
  3. ;; Author: Nicolas Goaziou <n.goaziou@gmail.com>
  4. ;; Keywords: org, wp, markdown
  5. ;; This file is part of GNU Emacs.
  6. ;; GNU Emacs is free software: you can redistribute it and/or modify
  7. ;; it under the terms of the GNU General Public License as published by
  8. ;; the Free Software Foundation, either version 3 of the License, or
  9. ;; (at your option) any later version.
  10. ;; GNU Emacs is distributed in the hope that it will be useful,
  11. ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  12. ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  13. ;; GNU General Public License for more details.
  14. ;; You should have received a copy of the GNU General Public License
  15. ;; along with GNU Emacs. If not, see <https://www.gnu.org/licenses/>.
  16. ;;; Commentary:
  17. ;; This library implements a Markdown back-end (vanilla flavor) for
  18. ;; Org exporter, based on `html' back-end. See Org manual for more
  19. ;; information.
  20. ;;; Code:
  21. (require 'cl-lib)
  22. (require 'ox-html)
  23. (require 'ox-publish)
  24. ;;; User-Configurable Variables
  25. (defgroup org-export-md nil
  26. "Options specific to Markdown export back-end."
  27. :tag "Org Markdown"
  28. :group 'org-export
  29. :version "24.4"
  30. :package-version '(Org . "8.0"))
  31. (defcustom org-md-headline-style 'atx
  32. "Style used to format headlines.
  33. This variable can be set to either `atx' or `setext'."
  34. :group 'org-export-md
  35. :type '(choice
  36. (const :tag "Use \"atx\" style" atx)
  37. (const :tag "Use \"Setext\" style" setext)))
  38. ;;;; Footnotes
  39. (defcustom org-md-footnotes-section "%s%s"
  40. "Format string for the footnotes section.
  41. The first %s placeholder will be replaced with the localized Footnotes section
  42. heading, the second with the contents of the Footnotes section."
  43. :group 'org-export-md
  44. :type 'string
  45. :version "26.1"
  46. :package-version '(Org . "9.0"))
  47. (defcustom org-md-footnote-format "<sup>%s</sup>"
  48. "Format string for the footnote reference.
  49. The %s will be replaced by the footnote reference itself."
  50. :group 'org-export-md
  51. :type 'string
  52. :version "26.1"
  53. :package-version '(Org . "9.0"))
  54. ;;; Define Back-End
  55. (org-export-define-derived-backend 'md 'html
  56. :filters-alist '((:filter-parse-tree . org-md-separate-elements))
  57. :menu-entry
  58. '(?m "Export to Markdown"
  59. ((?M "To temporary buffer"
  60. (lambda (a s v b) (org-md-export-as-markdown a s v)))
  61. (?m "To file" (lambda (a s v b) (org-md-export-to-markdown a s v)))
  62. (?o "To file and open"
  63. (lambda (a s v b)
  64. (if a (org-md-export-to-markdown t s v)
  65. (org-open-file (org-md-export-to-markdown nil s v)))))))
  66. :translate-alist '((bold . org-md-bold)
  67. (code . org-md-verbatim)
  68. (example-block . org-md-example-block)
  69. (export-block . org-md-export-block)
  70. (fixed-width . org-md-example-block)
  71. (headline . org-md-headline)
  72. (horizontal-rule . org-md-horizontal-rule)
  73. (inline-src-block . org-md-verbatim)
  74. (inner-template . org-md-inner-template)
  75. (italic . org-md-italic)
  76. (item . org-md-item)
  77. (keyword . org-md-keyword)
  78. (line-break . org-md-line-break)
  79. (link . org-md-link)
  80. (node-property . org-md-node-property)
  81. (paragraph . org-md-paragraph)
  82. (plain-list . org-md-plain-list)
  83. (plain-text . org-md-plain-text)
  84. (property-drawer . org-md-property-drawer)
  85. (quote-block . org-md-quote-block)
  86. (section . org-md-section)
  87. (src-block . org-md-example-block)
  88. (template . org-md-template)
  89. (verbatim . org-md-verbatim))
  90. :options-alist
  91. '((:md-footnote-format nil nil org-md-footnote-format)
  92. (:md-footnotes-section nil nil org-md-footnotes-section)
  93. (:md-headline-style nil nil org-md-headline-style)))
  94. ;;; Filters
  95. (defun org-md-separate-elements (tree _backend info)
  96. "Fix blank lines between elements.
  97. TREE is the parse tree being exported. BACKEND is the export
  98. back-end used. INFO is a plist used as a communication channel.
  99. Enforce a blank line between elements. There are two exceptions
  100. to this rule:
  101. 1. Preserve blank lines between sibling items in a plain list,
  102. 2. In an item, remove any blank line before the very first
  103. paragraph and the next sub-list when the latter ends the
  104. current item.
  105. Assume BACKEND is `md'."
  106. (org-element-map tree (remq 'item org-element-all-elements)
  107. (lambda (e)
  108. (org-element-put-property
  109. e :post-blank
  110. (if (and (eq (org-element-type e) 'paragraph)
  111. (eq (org-element-type (org-element-property :parent e)) 'item)
  112. (org-export-first-sibling-p e info)
  113. (let ((next (org-export-get-next-element e info)))
  114. (and (eq (org-element-type next) 'plain-list)
  115. (not (org-export-get-next-element next info)))))
  116. 0
  117. 1))))
  118. ;; Return updated tree.
  119. tree)
  120. ;;; Transcode Functions
  121. ;;;; Bold
  122. (defun org-md-bold (_bold contents _info)
  123. "Transcode BOLD object into Markdown format.
  124. CONTENTS is the text within bold markup. INFO is a plist used as
  125. a communication channel."
  126. (format "**%s**" contents))
  127. ;;;; Code and Verbatim
  128. (defun org-md-verbatim (verbatim _contents _info)
  129. "Transcode VERBATIM object into Markdown format.
  130. CONTENTS is nil. INFO is a plist used as a communication
  131. channel."
  132. (let ((value (org-element-property :value verbatim)))
  133. (format (cond ((not (string-match "`" value)) "`%s`")
  134. ((or (string-prefix-p "`" value)
  135. (string-suffix-p "`" value))
  136. "`` %s ``")
  137. (t "``%s``"))
  138. value)))
  139. ;;;; Example Block, Src Block and Export Block
  140. (defun org-md-example-block (example-block _contents info)
  141. "Transcode EXAMPLE-BLOCK element into Markdown format.
  142. CONTENTS is nil. INFO is a plist used as a communication
  143. channel."
  144. (replace-regexp-in-string
  145. "^" " "
  146. (org-remove-indentation
  147. (org-export-format-code-default example-block info))))
  148. (defun org-md-export-block (export-block contents info)
  149. "Transcode a EXPORT-BLOCK element from Org to Markdown.
  150. CONTENTS is nil. INFO is a plist holding contextual information."
  151. (if (member (org-element-property :type export-block) '("MARKDOWN" "MD"))
  152. (org-remove-indentation (org-element-property :value export-block))
  153. ;; Also include HTML export blocks.
  154. (org-export-with-backend 'html export-block contents info)))
  155. ;;;; Headline
  156. (defun org-md-headline (headline contents info)
  157. "Transcode HEADLINE element into Markdown format.
  158. CONTENTS is the headline contents. INFO is a plist used as
  159. a communication channel."
  160. (unless (org-element-property :footnote-section-p headline)
  161. (let* ((level (org-export-get-relative-level headline info))
  162. (title (org-export-data (org-element-property :title headline) info))
  163. (todo (and (plist-get info :with-todo-keywords)
  164. (let ((todo (org-element-property :todo-keyword
  165. headline)))
  166. (and todo (concat (org-export-data todo info) " ")))))
  167. (tags (and (plist-get info :with-tags)
  168. (let ((tag-list (org-export-get-tags headline info)))
  169. (and tag-list
  170. (concat " " (org-make-tag-string tag-list))))))
  171. (priority
  172. (and (plist-get info :with-priority)
  173. (let ((char (org-element-property :priority headline)))
  174. (and char (format "[#%c] " char)))))
  175. ;; Headline text without tags.
  176. (heading (concat todo priority title))
  177. (style (plist-get info :md-headline-style)))
  178. (cond
  179. ;; Cannot create a headline. Fall-back to a list.
  180. ((or (org-export-low-level-p headline info)
  181. (not (memq style '(atx setext)))
  182. (and (eq style 'atx) (> level 6))
  183. (and (eq style 'setext) (> level 2)))
  184. (let ((bullet
  185. (if (not (org-export-numbered-headline-p headline info)) "-"
  186. (concat (number-to-string
  187. (car (last (org-export-get-headline-number
  188. headline info))))
  189. "."))))
  190. (concat bullet (make-string (- 4 (length bullet)) ?\s) heading tags "\n\n"
  191. (and contents (replace-regexp-in-string "^" " " contents)))))
  192. (t
  193. (let ((anchor
  194. (and (org-md--headline-referred-p headline info)
  195. (format "<a id=\"%s\"></a>"
  196. (or (org-element-property :CUSTOM_ID headline)
  197. (org-export-get-reference headline info))))))
  198. (concat (org-md--headline-title style level heading anchor tags)
  199. contents)))))))
  200. (defun org-md--headline-referred-p (headline info)
  201. "Non-nil when HEADLINE is being referred to.
  202. INFO is a plist used as a communication channel. Links and table
  203. of contents can refer to headlines."
  204. (unless (org-element-property :footnote-section-p headline)
  205. (or
  206. ;; Global table of contents includes HEADLINE.
  207. (and (plist-get info :with-toc)
  208. (memq headline
  209. (org-export-collect-headlines info (plist-get info :with-toc))))
  210. ;; A local table of contents includes HEADLINE.
  211. (cl-some
  212. (lambda (h)
  213. (let ((section (car (org-element-contents h))))
  214. (and
  215. (eq 'section (org-element-type section))
  216. (org-element-map section 'keyword
  217. (lambda (keyword)
  218. (when (equal "TOC" (org-element-property :key keyword))
  219. (let ((case-fold-search t)
  220. (value (org-element-property :value keyword)))
  221. (and (string-match-p "\\<headlines\\>" value)
  222. (let ((n (and
  223. (string-match "\\<[0-9]+\\>" value)
  224. (string-to-number (match-string 0 value))))
  225. (local? (string-match-p "\\<local\\>" value)))
  226. (memq headline
  227. (org-export-collect-headlines
  228. info n (and local? keyword))))))))
  229. info t))))
  230. (org-element-lineage headline))
  231. ;; A link refers internally to HEADLINE.
  232. (org-element-map (plist-get info :parse-tree) 'link
  233. (lambda (link)
  234. (eq headline
  235. (pcase (org-element-property :type link)
  236. ((or "custom-id" "id") (org-export-resolve-id-link link info))
  237. ("fuzzy" (org-export-resolve-fuzzy-link link info))
  238. (_ nil))))
  239. info t))))
  240. (defun org-md--headline-title (style level title &optional anchor tags)
  241. "Generate a headline title in the preferred Markdown headline style.
  242. STYLE is the preferred style (`atx' or `setext'). LEVEL is the
  243. header level. TITLE is the headline title. ANCHOR is the HTML
  244. anchor tag for the section as a string. TAGS are the tags set on
  245. the section."
  246. (let ((anchor-lines (and anchor (concat anchor "\n\n"))))
  247. ;; Use "Setext" style
  248. (if (and (eq style 'setext) (< level 3))
  249. (let* ((underline-char (if (= level 1) ?= ?-))
  250. (underline (concat (make-string (length title) underline-char)
  251. "\n")))
  252. (concat "\n" anchor-lines title tags "\n" underline "\n"))
  253. ;; Use "Atx" style
  254. (let ((level-mark (make-string level ?#)))
  255. (concat "\n" anchor-lines level-mark " " title tags "\n\n")))))
  256. ;;;; Horizontal Rule
  257. (defun org-md-horizontal-rule (_horizontal-rule _contents _info)
  258. "Transcode HORIZONTAL-RULE element into Markdown format.
  259. CONTENTS is the horizontal rule contents. INFO is a plist used
  260. as a communication channel."
  261. "---")
  262. ;;;; Italic
  263. (defun org-md-italic (_italic contents _info)
  264. "Transcode ITALIC object into Markdown format.
  265. CONTENTS is the text within italic markup. INFO is a plist used
  266. as a communication channel."
  267. (format "*%s*" contents))
  268. ;;;; Item
  269. (defun org-md-item (item contents info)
  270. "Transcode ITEM element into Markdown format.
  271. CONTENTS is the item contents. INFO is a plist used as
  272. a communication channel."
  273. (let* ((type (org-element-property :type (org-export-get-parent item)))
  274. (struct (org-element-property :structure item))
  275. (bullet (if (not (eq type 'ordered)) "-"
  276. (concat (number-to-string
  277. (car (last (org-list-get-item-number
  278. (org-element-property :begin item)
  279. struct
  280. (org-list-prevs-alist struct)
  281. (org-list-parents-alist struct)))))
  282. "."))))
  283. (concat bullet
  284. (make-string (- 4 (length bullet)) ? )
  285. (pcase (org-element-property :checkbox item)
  286. (`on "[X] ")
  287. (`trans "[-] ")
  288. (`off "[ ] "))
  289. (let ((tag (org-element-property :tag item)))
  290. (and tag (format "**%s:** "(org-export-data tag info))))
  291. (and contents
  292. (org-trim (replace-regexp-in-string "^" " " contents))))))
  293. ;;;; Keyword
  294. (defun org-md-keyword (keyword contents info)
  295. "Transcode a KEYWORD element into Markdown format.
  296. CONTENTS is nil. INFO is a plist used as a communication
  297. channel."
  298. (pcase (org-element-property :key keyword)
  299. ((or "MARKDOWN" "MD") (org-element-property :value keyword))
  300. ("TOC"
  301. (let ((case-fold-search t)
  302. (value (org-element-property :value keyword)))
  303. (cond
  304. ((string-match-p "\\<headlines\\>" value)
  305. (let ((depth (and (string-match "\\<[0-9]+\\>" value)
  306. (string-to-number (match-string 0 value))))
  307. (local? (string-match-p "\\<local\\>" value)))
  308. (org-remove-indentation
  309. (org-md--build-toc info depth keyword local?)))))))
  310. (_ (org-export-with-backend 'html keyword contents info))))
  311. ;;;; Line Break
  312. (defun org-md-line-break (_line-break _contents _info)
  313. "Transcode LINE-BREAK object into Markdown format.
  314. CONTENTS is nil. INFO is a plist used as a communication
  315. channel."
  316. " \n")
  317. ;;;; Link
  318. (defun org-md-link (link contents info)
  319. "Transcode LINE-BREAK object into Markdown format.
  320. CONTENTS is the link's description. INFO is a plist used as
  321. a communication channel."
  322. (let ((link-org-files-as-md
  323. (lambda (raw-path)
  324. ;; Treat links to `file.org' as links to `file.md'.
  325. (if (string= ".org" (downcase (file-name-extension raw-path ".")))
  326. (concat (file-name-sans-extension raw-path) ".md")
  327. raw-path)))
  328. (type (org-element-property :type link)))
  329. (cond
  330. ;; Link type is handled by a special function.
  331. ((org-export-custom-protocol-maybe link contents 'md))
  332. ((member type '("custom-id" "id" "fuzzy"))
  333. (let ((destination (if (string= type "fuzzy")
  334. (org-export-resolve-fuzzy-link link info)
  335. (org-export-resolve-id-link link info))))
  336. (pcase (org-element-type destination)
  337. (`plain-text ; External file.
  338. (let ((path (funcall link-org-files-as-md destination)))
  339. (if (not contents) (format "<%s>" path)
  340. (format "[%s](%s)" contents path))))
  341. (`headline
  342. (format
  343. "[%s](#%s)"
  344. ;; Description.
  345. (cond ((org-string-nw-p contents))
  346. ((org-export-numbered-headline-p destination info)
  347. (mapconcat #'number-to-string
  348. (org-export-get-headline-number destination info)
  349. "."))
  350. (t (org-export-data (org-element-property :title destination)
  351. info)))
  352. ;; Reference.
  353. (or (org-element-property :CUSTOM_ID destination)
  354. (org-export-get-reference destination info))))
  355. (_
  356. (let ((description
  357. (or (org-string-nw-p contents)
  358. (let ((number (org-export-get-ordinal destination info)))
  359. (cond
  360. ((not number) nil)
  361. ((atom number) (number-to-string number))
  362. (t (mapconcat #'number-to-string number ".")))))))
  363. (when description
  364. (format "[%s](#%s)"
  365. description
  366. (org-export-get-reference destination info))))))))
  367. ((org-export-inline-image-p link org-html-inline-image-rules)
  368. (let ((path (let ((raw-path (org-element-property :path link)))
  369. (cond ((not (equal "file" type)) (concat type ":" raw-path))
  370. ((not (file-name-absolute-p raw-path)) raw-path)
  371. (t (expand-file-name raw-path)))))
  372. (caption (org-export-data
  373. (org-export-get-caption
  374. (org-export-get-parent-element link)) info)))
  375. (format "![img](%s)"
  376. (if (not (org-string-nw-p caption)) path
  377. (format "%s \"%s\"" path caption)))))
  378. ((string= type "coderef")
  379. (let ((ref (org-element-property :path link)))
  380. (format (org-export-get-coderef-format ref contents)
  381. (org-export-resolve-coderef ref info))))
  382. ((equal type "radio") contents)
  383. (t (let* ((raw-path (org-element-property :path link))
  384. (path
  385. (cond
  386. ((member type '("http" "https" "ftp" "mailto"))
  387. (concat type ":" raw-path))
  388. ((string= type "file")
  389. (org-export-file-uri (funcall link-org-files-as-md raw-path)))
  390. (t raw-path))))
  391. (if (not contents) (format "<%s>" path)
  392. (format "[%s](%s)" contents path)))))))
  393. ;;;; Node Property
  394. (defun org-md-node-property (node-property _contents _info)
  395. "Transcode a NODE-PROPERTY element into Markdown syntax.
  396. CONTENTS is nil. INFO is a plist holding contextual
  397. information."
  398. (format "%s:%s"
  399. (org-element-property :key node-property)
  400. (let ((value (org-element-property :value node-property)))
  401. (if value (concat " " value) ""))))
  402. ;;;; Paragraph
  403. (defun org-md-paragraph (paragraph contents _info)
  404. "Transcode PARAGRAPH element into Markdown format.
  405. CONTENTS is the paragraph contents. INFO is a plist used as
  406. a communication channel."
  407. (let ((first-object (car (org-element-contents paragraph))))
  408. ;; If paragraph starts with a #, protect it.
  409. (if (and (stringp first-object) (string-prefix-p "#" first-object))
  410. (concat "\\" contents)
  411. contents)))
  412. ;;;; Plain List
  413. (defun org-md-plain-list (_plain-list contents _info)
  414. "Transcode PLAIN-LIST element into Markdown format.
  415. CONTENTS is the plain-list contents. INFO is a plist used as
  416. a communication channel."
  417. contents)
  418. ;;;; Plain Text
  419. (defun org-md-plain-text (text info)
  420. "Transcode a TEXT string into Markdown format.
  421. TEXT is the string to transcode. INFO is a plist holding
  422. contextual information."
  423. (when (plist-get info :with-smart-quotes)
  424. (setq text (org-export-activate-smart-quotes text :html info)))
  425. ;; The below series of replacements in `text' is order sensitive.
  426. ;; Protect `, *, _, and \
  427. (setq text (replace-regexp-in-string "[`*_\\]" "\\\\\\&" text))
  428. ;; Protect ambiguous #. This will protect # at the beginning of
  429. ;; a line, but not at the beginning of a paragraph. See
  430. ;; `org-md-paragraph'.
  431. (setq text (replace-regexp-in-string "\n#" "\n\\\\#" text))
  432. ;; Protect ambiguous !
  433. (setq text (replace-regexp-in-string "\\(!\\)\\[" "\\\\!" text nil nil 1))
  434. ;; Handle special strings, if required.
  435. (when (plist-get info :with-special-strings)
  436. (setq text (org-html-convert-special-strings text)))
  437. ;; Handle break preservation, if required.
  438. (when (plist-get info :preserve-breaks)
  439. (setq text (replace-regexp-in-string "[ \t]*\n" " \n" text)))
  440. ;; Return value.
  441. text)
  442. ;;;; Property Drawer
  443. (defun org-md-property-drawer (_property-drawer contents _info)
  444. "Transcode a PROPERTY-DRAWER element into Markdown format.
  445. CONTENTS holds the contents of the drawer. INFO is a plist
  446. holding contextual information."
  447. (and (org-string-nw-p contents)
  448. (replace-regexp-in-string "^" " " contents)))
  449. ;;;; Quote Block
  450. (defun org-md-quote-block (_quote-block contents _info)
  451. "Transcode QUOTE-BLOCK element into Markdown format.
  452. CONTENTS is the quote-block contents. INFO is a plist used as
  453. a communication channel."
  454. (replace-regexp-in-string
  455. "^" "> "
  456. (replace-regexp-in-string "\n\\'" "" contents)))
  457. ;;;; Section
  458. (defun org-md-section (_section contents _info)
  459. "Transcode SECTION element into Markdown format.
  460. CONTENTS is the section contents. INFO is a plist used as
  461. a communication channel."
  462. contents)
  463. ;;;; Template
  464. (defun org-md--build-toc (info &optional n keyword local)
  465. "Return a table of contents.
  466. INFO is a plist used as a communication channel.
  467. Optional argument N, when non-nil, is an integer specifying the
  468. depth of the table.
  469. Optional argument KEYWORD specifies the TOC keyword, if any, from
  470. which the table of contents generation has been initiated.
  471. When optional argument LOCAL is non-nil, build a table of
  472. contents according to the current headline."
  473. (concat
  474. (unless local
  475. (let ((style (plist-get info :md-headline-style))
  476. (title (org-html--translate "Table of Contents" info)))
  477. (org-md--headline-title style 1 title nil)))
  478. (mapconcat
  479. (lambda (headline)
  480. (let* ((indentation
  481. (make-string
  482. (* 4 (1- (org-export-get-relative-level headline info)))
  483. ?\s))
  484. (bullet
  485. (if (not (org-export-numbered-headline-p headline info)) "- "
  486. (let ((prefix
  487. (format "%d." (org-last (org-export-get-headline-number
  488. headline info)))))
  489. (concat prefix (make-string (max 1 (- 4 (length prefix)))
  490. ?\s)))))
  491. (title
  492. (format "[%s](#%s)"
  493. (org-export-data-with-backend
  494. (org-export-get-alt-title headline info)
  495. (org-export-toc-entry-backend 'md)
  496. info)
  497. (or (org-element-property :CUSTOM_ID headline)
  498. (org-export-get-reference headline info))))
  499. (tags (and (plist-get info :with-tags)
  500. (not (eq 'not-in-toc (plist-get info :with-tags)))
  501. (org-make-tag-string
  502. (org-export-get-tags headline info)))))
  503. (concat indentation bullet title tags)))
  504. (org-export-collect-headlines info n (and local keyword)) "\n")
  505. "\n"))
  506. (defun org-md--footnote-formatted (footnote info)
  507. "Formats a single footnote entry FOOTNOTE.
  508. FOOTNOTE is a cons cell of the form (number . definition).
  509. INFO is a plist with contextual information."
  510. (let* ((fn-num (car footnote))
  511. (fn-text (cdr footnote))
  512. (fn-format (plist-get info :md-footnote-format))
  513. (fn-anchor (format "fn.%d" fn-num))
  514. (fn-href (format " href=\"#fnr.%d\"" fn-num))
  515. (fn-link-to-ref (org-html--anchor fn-anchor fn-num fn-href info)))
  516. (concat (format fn-format fn-link-to-ref) " " fn-text "\n")))
  517. (defun org-md--footnote-section (info)
  518. "Format the footnote section.
  519. INFO is a plist used as a communication channel."
  520. (let* ((fn-alist (org-export-collect-footnote-definitions info))
  521. (fn-alist (cl-loop for (n _type raw) in fn-alist collect
  522. (cons n (org-trim (org-export-data raw info)))))
  523. (headline-style (plist-get info :md-headline-style))
  524. (section-title (org-html--translate "Footnotes" info)))
  525. (when fn-alist
  526. (format (plist-get info :md-footnotes-section)
  527. (org-md--headline-title headline-style 1 section-title)
  528. (mapconcat (lambda (fn) (org-md--footnote-formatted fn info))
  529. fn-alist
  530. "\n")))))
  531. (defun org-md-inner-template (contents info)
  532. "Return body of document after converting it to Markdown syntax.
  533. CONTENTS is the transcoded contents string. INFO is a plist
  534. holding export options."
  535. ;; Make sure CONTENTS is separated from table of contents and
  536. ;; footnotes with at least a blank line.
  537. (concat
  538. ;; Table of contents.
  539. (let ((depth (plist-get info :with-toc)))
  540. (when depth
  541. (concat (org-md--build-toc info (and (wholenump depth) depth)) "\n")))
  542. ;; Document contents.
  543. contents
  544. "\n"
  545. ;; Footnotes section.
  546. (org-md--footnote-section info)))
  547. (defun org-md-template (contents _info)
  548. "Return complete document string after Markdown conversion.
  549. CONTENTS is the transcoded contents string. INFO is a plist used
  550. as a communication channel."
  551. contents)
  552. ;;; Interactive function
  553. ;;;###autoload
  554. (defun org-md-export-as-markdown (&optional async subtreep visible-only)
  555. "Export current buffer to a Markdown buffer.
  556. If narrowing is active in the current buffer, only export its
  557. narrowed part.
  558. If a region is active, export that region.
  559. A non-nil optional argument ASYNC means the process should happen
  560. asynchronously. The resulting buffer should be accessible
  561. through the `org-export-stack' interface.
  562. When optional argument SUBTREEP is non-nil, export the sub-tree
  563. at point, extracting information from the headline properties
  564. first.
  565. When optional argument VISIBLE-ONLY is non-nil, don't export
  566. contents of hidden elements.
  567. Export is done in a buffer named \"*Org MD Export*\", which will
  568. be displayed when `org-export-show-temporary-export-buffer' is
  569. non-nil."
  570. (interactive)
  571. (org-export-to-buffer 'md "*Org MD Export*"
  572. async subtreep visible-only nil nil (lambda () (text-mode))))
  573. ;;;###autoload
  574. (defun org-md-convert-region-to-md ()
  575. "Assume the current region has Org syntax, and convert it to Markdown.
  576. This can be used in any buffer. For example, you can write an
  577. itemized list in Org syntax in a Markdown buffer and use
  578. this command to convert it."
  579. (interactive)
  580. (org-export-replace-region-by 'md))
  581. ;;;###autoload
  582. (defun org-md-export-to-markdown (&optional async subtreep visible-only)
  583. "Export current buffer to a Markdown file.
  584. If narrowing is active in the current buffer, only export its
  585. narrowed part.
  586. If a region is active, export that region.
  587. A non-nil optional argument ASYNC means the process should happen
  588. asynchronously. The resulting file should be accessible through
  589. the `org-export-stack' interface.
  590. When optional argument SUBTREEP is non-nil, export the sub-tree
  591. at point, extracting information from the headline properties
  592. first.
  593. When optional argument VISIBLE-ONLY is non-nil, don't export
  594. contents of hidden elements.
  595. Return output file's name."
  596. (interactive)
  597. (let ((outfile (org-export-output-file-name ".md" subtreep)))
  598. (org-export-to-file 'md outfile async subtreep visible-only)))
  599. ;;;###autoload
  600. (defun org-md-publish-to-md (plist filename pub-dir)
  601. "Publish an org file to Markdown.
  602. FILENAME is the filename of the Org file to be published. PLIST
  603. is the property list for the given project. PUB-DIR is the
  604. publishing directory.
  605. Return output file name."
  606. (org-publish-org-to 'md filename ".md" plist pub-dir))
  607. (provide 'ox-md)
  608. ;; Local variables:
  609. ;; generated-autoload-file: "org-loaddefs.el"
  610. ;; End:
  611. ;;; ox-md.el ends here