org-macro.el 15 KB

123456789101112131415161718192021222324252627282930313233343536373839404142434445464748495051525354555657585960616263646566676869707172737475767778798081828384858687888990919293949596979899100101102103104105106107108109110111112113114115116117118119120121122123124125126127128129130131132133134135136137138139140141142143144145146147148149150151152153154155156157158159160161162163164165166167168169170171172173174175176177178179180181182183184185186187188189190191192193194195196197198199200201202203204205206207208209210211212213214215216217218219220221222223224225226227228229230231232233234235236237238239240241242243244245246247248249250251252253254255256257258259260261262263264265266267268269270271272273274275276277278279280281282283284285286287288289290291292293294295296297298299300301302303304305306307308309310311312313314315316317318319320321322323324325326327328329330331332333334335336337338339340341342343344345346347348349350351352353354355356357358359360361362363364365366367368369370371372373374375376377378379380381382383384385386387388389390391392393394395396397398399400401402403404405406407408
  1. ;;; org-macro.el --- Macro Replacement Code for Org -*- lexical-binding: t; -*-
  2. ;; Copyright (C) 2013-2018 Free Software Foundation, Inc.
  3. ;; Author: Nicolas Goaziou <n.goaziou@gmail.com>
  4. ;; Keywords: outlines, hypermedia, calendar, wp
  5. ;; This file is part of GNU Emacs.
  6. ;; GNU Emacs is free software: you can redistribute it and/or modify
  7. ;; it under the terms of the GNU General Public License as published by
  8. ;; the Free Software Foundation, either version 3 of the License, or
  9. ;; (at your option) any later version.
  10. ;; GNU Emacs is distributed in the hope that it will be useful,
  11. ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  12. ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  13. ;; GNU General Public License for more details.
  14. ;; You should have received a copy of the GNU General Public License
  15. ;; along with GNU Emacs. If not, see <https://www.gnu.org/licenses/>.
  16. ;;; Commentary:
  17. ;; Macros are expanded with `org-macro-replace-all', which relies
  18. ;; internally on `org-macro-expand'.
  19. ;; Default templates for expansion are stored in the buffer-local
  20. ;; variable `org-macro-templates'. This variable is updated by
  21. ;; `org-macro-initialize-templates', which recursively calls
  22. ;; `org-macro--collect-macros' in order to read setup files.
  23. ;; Argument in macros are separated with commas. Proper escaping rules
  24. ;; are implemented in `org-macro-escape-arguments' and arguments can
  25. ;; be extracted from a string with `org-macro-extract-arguments'.
  26. ;; Along with macros defined through #+MACRO: keyword, default
  27. ;; templates include the following hard-coded macros:
  28. ;; {{{time(format-string)}}},
  29. ;; {{{property(node-property)}}},
  30. ;; {{{input-file}}},
  31. ;; {{{modification-time(format-string)}}},
  32. ;; {{{n(counter,action}}}.
  33. ;; Upon exporting, "ox.el" will also provide {{{author}}}, {{{date}}},
  34. ;; {{{email}}} and {{{title}}} macros.
  35. ;;; Code:
  36. (require 'cl-lib)
  37. (require 'org-macs)
  38. (require 'org-compat)
  39. (declare-function org-element-at-point "org-element" ())
  40. (declare-function org-element-context "org-element" (&optional element))
  41. (declare-function org-element-copy "org-element" (datum))
  42. (declare-function org-element-macro-parser "org-element" ())
  43. (declare-function org-element-parse-secondary-string "org-element" (string restriction &optional parent))
  44. (declare-function org-element-property "org-element" (property element))
  45. (declare-function org-element-restriction "org-element" (element))
  46. (declare-function org-element-type "org-element" (element))
  47. (declare-function org-entry-get "org" (pom property &optional inherit literal-nil))
  48. (declare-function org-file-contents "org" (file &optional noerror nocache))
  49. (declare-function org-file-url-p "org" (file))
  50. (declare-function org-in-commented-heading-p "org" (&optional no-inheritance))
  51. (declare-function org-link-search "org" (s &optional avoid-pos stealth))
  52. (declare-function org-mode "org" ())
  53. (declare-function vc-backend "vc-hooks" (f))
  54. (declare-function vc-call "vc-hooks" (fun file &rest args) t)
  55. (declare-function vc-exec-after "vc-dispatcher" (code))
  56. (defvar org-link-search-must-match-exact-headline)
  57. ;;; Variables
  58. (defvar-local org-macro-templates nil
  59. "Alist containing all macro templates in current buffer.
  60. Associations are in the shape of (NAME . TEMPLATE) where NAME
  61. stands for macro's name and template for its replacement value,
  62. both as strings. This is an internal variable. Do not set it
  63. directly, use instead:
  64. #+MACRO: name template")
  65. ;;; Functions
  66. (defun org-macro--collect-macros ()
  67. "Collect macro definitions in current buffer and setup files.
  68. Return an alist containing all macro templates found."
  69. (letrec ((collect-macros
  70. (lambda (files templates)
  71. ;; Return an alist of macro templates. FILES is a list
  72. ;; of setup files names read so far, used to avoid
  73. ;; circular dependencies. TEMPLATES is the alist
  74. ;; collected so far.
  75. (let ((case-fold-search t))
  76. (org-with-wide-buffer
  77. (goto-char (point-min))
  78. (while (re-search-forward
  79. "^[ \t]*#\\+\\(MACRO\\|SETUPFILE\\):" nil t)
  80. (let ((element (org-element-at-point)))
  81. (when (eq (org-element-type element) 'keyword)
  82. (let ((val (org-element-property :value element)))
  83. (if (equal (org-element-property :key element) "MACRO")
  84. ;; Install macro in TEMPLATES.
  85. (when (string-match
  86. "^\\(.*?\\)\\(?:\\s-+\\(.*\\)\\)?\\s-*$" val)
  87. (let* ((name (match-string 1 val))
  88. (template (or (match-string 2 val) ""))
  89. (old-cell (assoc name templates)))
  90. (if old-cell (setcdr old-cell template)
  91. (push (cons name template) templates))))
  92. ;; Enter setup file.
  93. (let* ((uri (org-strip-quotes (org-trim val)))
  94. (uri-is-url (org-file-url-p uri))
  95. (uri (if uri-is-url
  96. uri
  97. (expand-file-name uri))))
  98. ;; Avoid circular dependencies.
  99. (unless (member uri files)
  100. (with-temp-buffer
  101. (unless uri-is-url
  102. (setq default-directory
  103. (file-name-directory uri)))
  104. (org-mode)
  105. (insert (org-file-contents uri 'noerror))
  106. (setq templates
  107. (funcall collect-macros (cons uri files)
  108. templates)))))))))))
  109. templates))))
  110. (funcall collect-macros nil nil)))
  111. (defun org-macro-initialize-templates ()
  112. "Collect macro templates defined in current buffer.
  113. Templates are stored in buffer-local variable
  114. `org-macro-templates'.
  115. In addition to buffer-defined macros, the function installs the
  116. following ones: \"n\", \"author\", \"email\", \"keyword\",
  117. \"time\", \"property\", and, if the buffer is associated to
  118. a file, \"input-file\" and \"modification-time\"."
  119. (org-macro--counter-initialize) ;for "n" macro
  120. (setq org-macro-templates
  121. (nconc
  122. ;; Install user-defined macros.
  123. (org-macro--collect-macros)
  124. ;; Install file-specific macros.
  125. (let ((visited-file (buffer-file-name (buffer-base-buffer))))
  126. (and visited-file
  127. (file-exists-p visited-file)
  128. (list
  129. `("input-file" . ,(file-name-nondirectory visited-file))
  130. `("modification-time" .
  131. ,(format "(eval
  132. \(format-time-string $1
  133. (or (and (org-string-nw-p $2)
  134. (org-macro--vc-modified-time %s))
  135. '%s)))"
  136. (prin1-to-string visited-file)
  137. (prin1-to-string
  138. (nth 5 (file-attributes visited-file))))))))
  139. ;; Install built-in macros.
  140. (list
  141. '("n" . "(eval (org-macro--counter-increment $1 $2))")
  142. `("author" . ,(org-macro--find-keyword-value "AUTHOR"))
  143. `("email" . ,(org-macro--find-keyword-value "EMAIL"))
  144. '("keyword" . "(eval (org-macro--find-keyword-value $1))")
  145. '("time" . "(eval (format-time-string $1))")
  146. `("title" . ,(org-macro--find-keyword-value "TITLE"))
  147. '("property" . "(eval (org-macro--get-property $1 $2))")
  148. `("date" .
  149. ,(let* ((value (org-macro--find-keyword-value "DATE"))
  150. (date (org-element-parse-secondary-string
  151. value (org-element-restriction 'keyword))))
  152. (if (and (consp date)
  153. (not (cdr date))
  154. (eq 'timestamp (org-element-type (car date))))
  155. (format "(eval (if (org-string-nw-p $1) %s %S))"
  156. (format "(org-timestamp-format '%S $1)"
  157. (org-element-copy (car date)))
  158. value)
  159. value)))))))
  160. (defun org-macro-expand (macro templates)
  161. "Return expanded MACRO, as a string.
  162. MACRO is an object, obtained, for example, with
  163. `org-element-context'. TEMPLATES is an alist of templates used
  164. for expansion. See `org-macro-templates' for a buffer-local
  165. default value. Return nil if no template was found."
  166. (let ((template
  167. ;; Macro names are case-insensitive.
  168. (cdr (assoc-string (org-element-property :key macro) templates t))))
  169. (when template
  170. (let* ((eval? (string-match-p "\\`(eval\\>" template))
  171. (value
  172. (replace-regexp-in-string
  173. "\\$[0-9]+"
  174. (lambda (m)
  175. (let ((arg (or (nth (1- (string-to-number (substring m 1)))
  176. (org-element-property :args macro))
  177. ;; No argument: remove place-holder.
  178. "")))
  179. ;; `eval' implies arguments are strings.
  180. (if eval? (format "%S" arg) arg)))
  181. template nil 'literal)))
  182. (when eval?
  183. (setq value (eval (condition-case nil (read value)
  184. (error (debug))))))
  185. ;; Force return value to be a string.
  186. (format "%s" (or value ""))))))
  187. (defun org-macro-replace-all (templates &optional keywords)
  188. "Replace all macros in current buffer by their expansion.
  189. TEMPLATES is an alist of templates used for expansion. See
  190. `org-macro-templates' for a buffer-local default value.
  191. Optional argument KEYWORDS, when non-nil is a list of keywords,
  192. as strings, where macro expansion is allowed.
  193. Return an error if a macro in the buffer cannot be associated to
  194. a definition in TEMPLATES."
  195. (org-with-wide-buffer
  196. (goto-char (point-min))
  197. (let ((properties-regexp (format "\\`EXPORT_%s\\+?\\'"
  198. (regexp-opt keywords)))
  199. record)
  200. (while (re-search-forward "{{{[-A-Za-z0-9_]" nil t)
  201. (unless (save-match-data (org-in-commented-heading-p))
  202. (let* ((datum (save-match-data (org-element-context)))
  203. (type (org-element-type datum))
  204. (macro
  205. (cond
  206. ((eq type 'macro) datum)
  207. ;; In parsed keywords and associated node
  208. ;; properties, force macro recognition.
  209. ((or (and (eq type 'keyword)
  210. (member (org-element-property :key datum) keywords))
  211. (and (eq type 'node-property)
  212. (string-match-p properties-regexp
  213. (org-element-property :key datum))))
  214. (save-excursion
  215. (goto-char (match-beginning 0))
  216. (org-element-macro-parser))))))
  217. (when macro
  218. (let* ((key (org-element-property :key macro))
  219. (value (org-macro-expand macro templates))
  220. (begin (org-element-property :begin macro))
  221. (signature (list begin
  222. macro
  223. (org-element-property :args macro))))
  224. ;; Avoid circular dependencies by checking if the same
  225. ;; macro with the same arguments is expanded at the
  226. ;; same position twice.
  227. (cond ((member signature record)
  228. (error "Circular macro expansion: %s" key))
  229. (value
  230. (push signature record)
  231. (delete-region
  232. begin
  233. ;; Preserve white spaces after the macro.
  234. (progn (goto-char (org-element-property :end macro))
  235. (skip-chars-backward " \t")
  236. (point)))
  237. ;; Leave point before replacement in case of
  238. ;; recursive expansions.
  239. (save-excursion (insert value)))
  240. ;; Special "results" macro: if it is not defined,
  241. ;; simply leave it as-is. It will be expanded in
  242. ;; a second phase.
  243. ((equal key "results"))
  244. (t
  245. (error "Undefined Org macro: %s; aborting"
  246. (org-element-property :key macro))))))))))))
  247. (defun org-macro-escape-arguments (&rest args)
  248. "Build macro's arguments string from ARGS.
  249. ARGS are strings. Return value is a string with arguments
  250. properly escaped and separated with commas. This is the opposite
  251. of `org-macro-extract-arguments'."
  252. (let ((s ""))
  253. (dolist (arg (reverse args) (substring s 1))
  254. (setq s
  255. (concat
  256. ","
  257. (replace-regexp-in-string
  258. "\\(\\\\*\\),"
  259. (lambda (m)
  260. (concat (make-string (1+ (* 2 (length (match-string 1 m)))) ?\\)
  261. ","))
  262. ;; If a non-terminal argument ends on backslashes, make
  263. ;; sure to also escape them as they will be followed by
  264. ;; a comma.
  265. (concat arg (and (not (equal s ""))
  266. (string-match "\\\\+\\'" arg)
  267. (match-string 0 arg)))
  268. nil t)
  269. s)))))
  270. (defun org-macro-extract-arguments (s)
  271. "Extract macro arguments from string S.
  272. S is a string containing comma separated values properly escaped.
  273. Return a list of arguments, as strings. This is the opposite of
  274. `org-macro-escape-arguments'."
  275. ;; Do not use `org-split-string' since empty strings are
  276. ;; meaningful here.
  277. (split-string
  278. (replace-regexp-in-string
  279. "\\(\\\\*\\),"
  280. (lambda (str)
  281. (let ((len (length (match-string 1 str))))
  282. (concat (make-string (/ len 2) ?\\)
  283. (if (zerop (mod len 2)) "\000" ","))))
  284. s nil t)
  285. "\000"))
  286. ;;; Helper functions and variables for internal macros
  287. (defun org-macro--get-property (property location)
  288. "Find PROPERTY's value at LOCATION.
  289. PROPERTY is a string. LOCATION is a search string, as expected
  290. by `org-link-search', or the empty string."
  291. (save-excursion
  292. (when (org-string-nw-p location)
  293. (condition-case _
  294. (let ((org-link-search-must-match-exact-headline t))
  295. (org-link-search location nil t))
  296. (error
  297. (error "Macro property failed: cannot find location %s" location))))
  298. (org-entry-get nil property 'selective)))
  299. (defun org-macro--find-keyword-value (name)
  300. "Find value for keyword NAME in current buffer.
  301. KEYWORD is a string. Return value associated to the keywords
  302. named after NAME, as a string, or nil."
  303. (org-with-point-at 1
  304. (let ((regexp (format "^[ \t]*#\\+%s:" (regexp-quote name)))
  305. (case-fold-search t)
  306. (result nil))
  307. (while (re-search-forward regexp nil t)
  308. (let ((element (org-element-at-point)))
  309. (when (eq 'keyword (org-element-type element))
  310. (setq result (concat result
  311. " "
  312. (org-element-property :value element))))))
  313. (and result (org-trim result)))))
  314. (defun org-macro--vc-modified-time (file)
  315. (save-window-excursion
  316. (when (vc-backend file)
  317. (let ((buf (get-buffer-create " *org-vc*"))
  318. (case-fold-search t)
  319. date)
  320. (unwind-protect
  321. (progn
  322. (vc-call print-log file buf nil nil 1)
  323. (with-current-buffer buf
  324. (vc-exec-after
  325. (lambda ()
  326. (goto-char (point-min))
  327. (when (re-search-forward "Date:?[ \t]*" nil t)
  328. (let ((time (parse-time-string
  329. (buffer-substring
  330. (point) (line-end-position)))))
  331. (when (cl-some #'identity time)
  332. (setq date (apply #'encode-time time))))))))
  333. (let ((proc (get-buffer-process buf)))
  334. (while (and proc (accept-process-output proc .5 nil t)))))
  335. (kill-buffer buf))
  336. date))))
  337. (defvar org-macro--counter-table nil
  338. "Hash table containing counter value per name.")
  339. (defun org-macro--counter-initialize ()
  340. "Initialize `org-macro--counter-table'."
  341. (setq org-macro--counter-table (make-hash-table :test #'equal)))
  342. (defun org-macro--counter-increment (name &optional action)
  343. "Increment counter NAME.
  344. NAME is a string identifying the counter.
  345. When non-nil, optional argument ACTION is a string.
  346. If the string is \"-\", keep the NAME counter at its current
  347. value, i.e. do not increment.
  348. If the string represents an integer, set the counter to this number.
  349. Any other non-empty string resets the counter to 1."
  350. (let ((name-trimmed (org-trim name))
  351. (action-trimmed (when (org-string-nw-p action)
  352. (org-trim action))))
  353. (puthash name-trimmed
  354. (cond ((not (org-string-nw-p action-trimmed))
  355. (1+ (gethash name-trimmed org-macro--counter-table 0)))
  356. ((string= "-" action-trimmed)
  357. (gethash name-trimmed org-macro--counter-table 1))
  358. ((string-match-p "\\`[0-9]+\\'" action-trimmed)
  359. (string-to-number action-trimmed))
  360. (t 1))
  361. org-macro--counter-table)))
  362. (provide 'org-macro)
  363. ;;; org-macro.el ends here