ob-ocaml.el 6.1 KB

123456789101112131415161718192021222324252627282930313233343536373839404142434445464748495051525354555657585960616263646566676869707172737475767778798081828384858687888990919293949596979899100101102103104105106107108109110111112113114115116117118119120121122123124125126127128129130131132133134135136137138139140141142143144145146147148149150151152153154155156157158159160161162163164165166167168169170171172
  1. ;;; ob-ocaml.el --- Babel Functions for Ocaml -*- lexical-binding: t; -*-
  2. ;; Copyright (C) 2009-2018 Free Software Foundation, Inc.
  3. ;; Author: Eric Schulte
  4. ;; Keywords: literate programming, reproducible research
  5. ;; Homepage: https://orgmode.org
  6. ;; This file is part of GNU Emacs.
  7. ;; GNU Emacs is free software: you can redistribute it and/or modify
  8. ;; it under the terms of the GNU General Public License as published by
  9. ;; the Free Software Foundation, either version 3 of the License, or
  10. ;; (at your option) any later version.
  11. ;; GNU Emacs is distributed in the hope that it will be useful,
  12. ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  13. ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  14. ;; GNU General Public License for more details.
  15. ;; You should have received a copy of the GNU General Public License
  16. ;; along with GNU Emacs. If not, see <https://www.gnu.org/licenses/>.
  17. ;;; Commentary:
  18. ;; Org-Babel support for evaluating ocaml source code. This one will
  19. ;; be sort of tricky because ocaml programs must be compiled before
  20. ;; they can be run, but ocaml code can also be run through an
  21. ;; interactive interpreter.
  22. ;;
  23. ;; For now lets only allow evaluation using the ocaml interpreter.
  24. ;;; Requirements:
  25. ;; - tuareg-mode :: http://www-rocq.inria.fr/~acohen/tuareg/
  26. ;;; Code:
  27. (require 'ob)
  28. (require 'comint)
  29. (require 'org-macs)
  30. (declare-function tuareg-run-caml "ext:tuareg" ())
  31. (declare-function tuareg-run-ocaml "ext:tuareg" ())
  32. (declare-function tuareg-interactive-send-input "ext:tuareg" ())
  33. (defvar org-babel-tangle-lang-exts)
  34. (add-to-list 'org-babel-tangle-lang-exts '("ocaml" . "ml"))
  35. (defvar org-babel-default-header-args:ocaml '())
  36. (defvar org-babel-ocaml-eoe-indicator "\"org-babel-ocaml-eoe\";;")
  37. (defvar org-babel-ocaml-eoe-output "org-babel-ocaml-eoe")
  38. (defcustom org-babel-ocaml-command "ocaml"
  39. "Name of the command for executing Ocaml code."
  40. :version "24.4"
  41. :package-version '(Org . "8.0")
  42. :group 'org-babel
  43. :type 'string)
  44. (defun org-babel-execute:ocaml (body params)
  45. "Execute a block of Ocaml code with Babel."
  46. (let* ((full-body (org-babel-expand-body:generic
  47. body params
  48. (org-babel-variable-assignments:ocaml params)))
  49. (session (org-babel-prep-session:ocaml
  50. (cdr (assq :session params)) params))
  51. (raw (org-babel-comint-with-output
  52. (session org-babel-ocaml-eoe-output nil full-body)
  53. (insert
  54. (concat
  55. (org-babel-chomp full-body) ";;\n"
  56. org-babel-ocaml-eoe-indicator))
  57. (tuareg-interactive-send-input)))
  58. (clean
  59. (car (let ((re (regexp-quote org-babel-ocaml-eoe-output)) out)
  60. (delq nil (mapcar (lambda (line)
  61. (if out
  62. (progn (setq out nil) line)
  63. (when (string-match re line)
  64. (progn (setq out t) nil))))
  65. (mapcar #'org-trim (reverse raw)))))))
  66. (raw (org-trim clean))
  67. (result-params (cdr (assq :result-params params))))
  68. (string-match
  69. "\\(\\(.*\n\\)*\\)[^:\n]+ : \\([^=\n]+\\) =\\(\n\\| \\)\\(.+\\)$"
  70. raw)
  71. (let ((output (match-string 1 raw))
  72. (type (match-string 3 raw))
  73. (value (match-string 5 raw)))
  74. (org-babel-reassemble-table
  75. (org-babel-result-cond result-params
  76. (cond
  77. ((member "verbatim" result-params) raw)
  78. ((member "output" result-params) output)
  79. (t raw))
  80. (if (and value type)
  81. (org-babel-ocaml-parse-output value type)
  82. raw))
  83. (org-babel-pick-name
  84. (cdr (assq :colname-names params)) (cdr (assq :colnames params)))
  85. (org-babel-pick-name
  86. (cdr (assq :rowname-names params)) (cdr (assq :rownames params)))))))
  87. (defvar tuareg-interactive-buffer-name)
  88. (defun org-babel-prep-session:ocaml (session _params)
  89. "Prepare SESSION according to the header arguments in PARAMS."
  90. (require 'tuareg)
  91. (let ((tuareg-interactive-buffer-name (if (and (not (string= session "none"))
  92. (not (string= session "default"))
  93. (stringp session))
  94. session
  95. tuareg-interactive-buffer-name)))
  96. (save-window-excursion (if (fboundp 'tuareg-run-process-if-needed)
  97. (tuareg-run-process-if-needed org-babel-ocaml-command)
  98. (tuareg-run-caml)))
  99. (get-buffer tuareg-interactive-buffer-name)))
  100. (defun org-babel-variable-assignments:ocaml (params)
  101. "Return list of ocaml statements assigning the block's variables."
  102. (mapcar
  103. (lambda (pair) (format "let %s = %s;;" (car pair)
  104. (org-babel-ocaml-elisp-to-ocaml (cdr pair))))
  105. (org-babel--get-vars params)))
  106. (defun org-babel-ocaml-elisp-to-ocaml (val)
  107. "Return a string of ocaml code which evaluates to VAL."
  108. (if (listp val)
  109. (concat "[|" (mapconcat #'org-babel-ocaml-elisp-to-ocaml val "; ") "|]")
  110. (format "%S" val)))
  111. (defun org-babel-ocaml-parse-output (value type)
  112. "Parse VALUE of type TYPE.
  113. VALUE and TYPE are string output from an ocaml process."
  114. (cond
  115. ((string= "string" type)
  116. (org-babel-read value))
  117. ((or (string= "int" type)
  118. (string= "float" type))
  119. (string-to-number value))
  120. ((string-match "list" type)
  121. (org-babel-ocaml-read-list value))
  122. ((string-match "array" type)
  123. (org-babel-ocaml-read-array value))
  124. (t (message "don't recognize type %s" type) value)))
  125. (defun org-babel-ocaml-read-list (results)
  126. "Convert RESULTS into an elisp table or string.
  127. If the results look like a table, then convert them into an
  128. Emacs-lisp table, otherwise return the results as a string."
  129. ;; XXX: This probably does not behave as expected when a semicolon
  130. ;; is in a string in a list. The same comment applies to
  131. ;; `org-babel-ocaml-read-array' below (with even more failure
  132. ;; modes).
  133. (org-babel-script-escape (replace-regexp-in-string ";" "," results)))
  134. (defun org-babel-ocaml-read-array (results)
  135. "Convert RESULTS into an elisp table or string.
  136. If the results look like a table, then convert them into an
  137. Emacs-lisp table, otherwise return the results as a string."
  138. (org-babel-script-escape
  139. (replace-regexp-in-string
  140. "\\[|" "[" (replace-regexp-in-string
  141. "|\\]" "]" (replace-regexp-in-string
  142. "; " "," results)))))
  143. (provide 'ob-ocaml)
  144. ;;; ob-ocaml.el ends here