ob-gnuplot.el 10 KB

123456789101112131415161718192021222324252627282930313233343536373839404142434445464748495051525354555657585960616263646566676869707172737475767778798081828384858687888990919293949596979899100101102103104105106107108109110111112113114115116117118119120121122123124125126127128129130131132133134135136137138139140141142143144145146147148149150151152153154155156157158159160161162163164165166167168169170171172173174175176177178179180181182183184185186187188189190191192193194195196197198199200201202203204205206207208209210211212213214215216217218219220221222223224225226227228229230231232233234235236237238239240241242243244245246247248249250251252253254255256257258259260261262263264265266267268269270271272273274275276277278279280281282283284
  1. ;;; ob-gnuplot.el --- Babel Functions for Gnuplot -*- lexical-binding: t; -*-
  2. ;; Copyright (C) 2009-2018 Free Software Foundation, Inc.
  3. ;; Author: Eric Schulte
  4. ;; Keywords: literate programming, reproducible research
  5. ;; Homepage: https://orgmode.org
  6. ;; This file is part of GNU Emacs.
  7. ;; GNU Emacs is free software: you can redistribute it and/or modify
  8. ;; it under the terms of the GNU General Public License as published by
  9. ;; the Free Software Foundation, either version 3 of the License, or
  10. ;; (at your option) any later version.
  11. ;; GNU Emacs is distributed in the hope that it will be useful,
  12. ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  13. ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  14. ;; GNU General Public License for more details.
  15. ;; You should have received a copy of the GNU General Public License
  16. ;; along with GNU Emacs. If not, see <https://www.gnu.org/licenses/>.
  17. ;;; Commentary:
  18. ;; Org-Babel support for evaluating gnuplot source code.
  19. ;;
  20. ;; This differs from most standard languages in that
  21. ;;
  22. ;; 1) we are generally only going to return results of type "file"
  23. ;;
  24. ;; 2) we are adding the "file" and "cmdline" header arguments
  25. ;;; Requirements:
  26. ;; - gnuplot :: http://www.gnuplot.info/
  27. ;;
  28. ;; - gnuplot-mode :: http://cars9.uchicago.edu/~ravel/software/gnuplot-mode.html
  29. ;;; Code:
  30. (require 'ob)
  31. (require 'org-macs)
  32. (declare-function org-time-string-to-time "org" (s))
  33. (declare-function orgtbl-to-generic "org-table" (table params))
  34. (declare-function gnuplot-mode "ext:gnuplot-mode" ())
  35. (declare-function gnuplot-send-string-to-gnuplot "ext:gnuplot-mode" (str txt))
  36. (declare-function gnuplot-send-buffer-to-gnuplot "ext:gnuplot-mode" ())
  37. (defvar org-babel-default-header-args:gnuplot
  38. '((:results . "file") (:exports . "results") (:session . nil))
  39. "Default arguments to use when evaluating a gnuplot source block.")
  40. (defvar org-babel-header-args:gnuplot
  41. '((title . :any)
  42. (lines . :any)
  43. (sets . :any)
  44. (x-labels . :any)
  45. (y-labels . :any)
  46. (timefmt . :any)
  47. (time-ind . :any)
  48. (missing . :any)
  49. (term . :any))
  50. "Gnuplot specific header args.")
  51. (defvar org-babel-gnuplot-timestamp-fmt nil) ; Dynamically scoped.
  52. (defvar *org-babel-gnuplot-missing* nil)
  53. (defcustom *org-babel-gnuplot-terms*
  54. '((eps . "postscript eps"))
  55. "List of file extensions and the associated gnuplot terminal."
  56. :group 'org-babel
  57. :type '(repeat (cons (symbol :tag "File extension")
  58. (string :tag "Gnuplot terminal"))))
  59. (defun org-babel-gnuplot-process-vars (params)
  60. "Extract variables from PARAMS and process the variables.
  61. Dumps all vectors into files and returns an association list
  62. of variable names and the related value to be used in the gnuplot
  63. code."
  64. (let ((*org-babel-gnuplot-missing* (cdr (assq :missing params))))
  65. (mapcar
  66. (lambda (pair)
  67. (cons
  68. (car pair) ;; variable name
  69. (let* ((val (cdr pair)) ;; variable value
  70. (lp (listp val)))
  71. (if lp
  72. (org-babel-gnuplot-table-to-data
  73. (let* ((first (car val))
  74. (tablep (or (listp first) (symbolp first))))
  75. (if tablep val (mapcar 'list val)))
  76. (org-babel-temp-file "gnuplot-") params)
  77. val))))
  78. (org-babel--get-vars params))))
  79. (defun org-babel-expand-body:gnuplot (body params)
  80. "Expand BODY according to PARAMS, return the expanded body."
  81. (save-window-excursion
  82. (let* ((vars (org-babel-gnuplot-process-vars params))
  83. (out-file (cdr (assq :file params)))
  84. (prologue (cdr (assq :prologue params)))
  85. (epilogue (cdr (assq :epilogue params)))
  86. (term (or (cdr (assq :term params))
  87. (when out-file
  88. (let ((ext (file-name-extension out-file)))
  89. (or (cdr (assoc (intern (downcase ext))
  90. *org-babel-gnuplot-terms*))
  91. ext)))))
  92. (title (cdr (assq :title params)))
  93. (lines (cdr (assq :line params)))
  94. (sets (cdr (assq :set params)))
  95. (x-labels (cdr (assq :xlabels params)))
  96. (y-labels (cdr (assq :ylabels params)))
  97. (timefmt (cdr (assq :timefmt params)))
  98. (time-ind (or (cdr (assq :timeind params))
  99. (when timefmt 1)))
  100. (directory (and (buffer-file-name)
  101. (file-name-directory (buffer-file-name))))
  102. (add-to-body (lambda (text) (setq body (concat text "\n" body)))))
  103. ;; append header argument settings to body
  104. (when title (funcall add-to-body (format "set title '%s'" title)))
  105. (when lines (mapc (lambda (el) (funcall add-to-body el)) lines))
  106. (when sets
  107. (mapc (lambda (el) (funcall add-to-body (format "set %s" el))) sets))
  108. (when x-labels
  109. (funcall add-to-body
  110. (format "set xtics (%s)"
  111. (mapconcat (lambda (pair)
  112. (format "\"%s\" %d"
  113. (cdr pair) (car pair)))
  114. x-labels ", "))))
  115. (when y-labels
  116. (funcall add-to-body
  117. (format "set ytics (%s)"
  118. (mapconcat (lambda (pair)
  119. (format "\"%s\" %d"
  120. (cdr pair) (car pair)))
  121. y-labels ", "))))
  122. (when time-ind
  123. (funcall add-to-body "set xdata time")
  124. (funcall add-to-body (concat "set timefmt \""
  125. (or timefmt
  126. "%Y-%m-%d-%H:%M:%S") "\"")))
  127. (when out-file
  128. ;; set the terminal at the top of the block
  129. (funcall add-to-body (format "set output \"%s\"" out-file))
  130. ;; and close the terminal at the bottom of the block
  131. (setq body (concat body "\nset output\n")))
  132. (when term (funcall add-to-body (format "set term %s" term)))
  133. ;; insert variables into code body: this should happen last
  134. ;; placing the variables at the *top* of the code in case their
  135. ;; values are used later
  136. (funcall add-to-body
  137. (mapconcat #'identity
  138. (org-babel-variable-assignments:gnuplot params)
  139. "\n"))
  140. ;; replace any variable names preceded by '$' with the actual
  141. ;; value of the variable
  142. (mapc (lambda (pair)
  143. (setq body (replace-regexp-in-string
  144. (format "\\$%s" (car pair)) (cdr pair) body)))
  145. vars)
  146. (when prologue (funcall add-to-body prologue))
  147. (when epilogue (setq body (concat body "\n" epilogue)))
  148. ;; Setting the directory needs to be done first so that
  149. ;; subsequent 'output' directive goes to the right place.
  150. (when directory (funcall add-to-body (format "cd '%s'" directory))))
  151. body))
  152. (defun org-babel-execute:gnuplot (body params)
  153. "Execute a block of Gnuplot code.
  154. This function is called by `org-babel-execute-src-block'."
  155. (require 'gnuplot)
  156. (let ((session (cdr (assq :session params)))
  157. (result-type (cdr (assq :results params)))
  158. (body (org-babel-expand-body:gnuplot body params))
  159. output)
  160. (save-window-excursion
  161. ;; evaluate the code body with gnuplot
  162. (if (string= session "none")
  163. (let ((script-file (org-babel-temp-file "gnuplot-script-")))
  164. (with-temp-file script-file
  165. (insert (concat body "\n")))
  166. (message "gnuplot \"%s\"" script-file)
  167. (setq output
  168. (shell-command-to-string
  169. (format
  170. "gnuplot \"%s\""
  171. (org-babel-process-file-name
  172. script-file
  173. (if (member system-type '(cygwin windows-nt ms-dos))
  174. t nil)))))
  175. (message "%s" output))
  176. (with-temp-buffer
  177. (insert (concat body "\n"))
  178. (gnuplot-mode)
  179. (gnuplot-send-buffer-to-gnuplot)))
  180. (if (member "output" (split-string result-type))
  181. output
  182. nil)))) ;; signal that output has already been written to file
  183. (defun org-babel-prep-session:gnuplot (session params)
  184. "Prepare SESSION according to the header arguments in PARAMS."
  185. (let* ((session (org-babel-gnuplot-initiate-session session))
  186. (var-lines (org-babel-variable-assignments:gnuplot params)))
  187. (message "%S" session)
  188. (org-babel-comint-in-buffer session
  189. (dolist (var-line var-lines)
  190. (insert var-line)
  191. (comint-send-input nil t)
  192. (org-babel-comint-wait-for-output session)
  193. (sit-for .1)
  194. (goto-char (point-max))))
  195. session))
  196. (defun org-babel-load-session:gnuplot (session body params)
  197. "Load BODY into SESSION."
  198. (save-window-excursion
  199. (let ((buffer (org-babel-prep-session:gnuplot session params)))
  200. (with-current-buffer buffer
  201. (goto-char (process-mark (get-buffer-process (current-buffer))))
  202. (insert (org-babel-chomp body)))
  203. buffer)))
  204. (defun org-babel-variable-assignments:gnuplot (params)
  205. "Return list of gnuplot statements assigning the block's variables."
  206. (mapcar
  207. (lambda (pair) (format "%s = \"%s\"" (car pair) (cdr pair)))
  208. (org-babel-gnuplot-process-vars params)))
  209. (defvar gnuplot-buffer)
  210. (defun org-babel-gnuplot-initiate-session (&optional session _params)
  211. "Initiate a gnuplot session.
  212. If there is not a current inferior-process-buffer in SESSION
  213. then create one. Return the initialized session. The current
  214. `gnuplot-mode' doesn't provide support for multiple sessions."
  215. (require 'gnuplot)
  216. (unless (string= session "none")
  217. (save-window-excursion
  218. (gnuplot-send-string-to-gnuplot "" "line")
  219. gnuplot-buffer)))
  220. (defun org-babel-gnuplot-quote-timestamp-field (s)
  221. "Convert S from timestamp to Unix time and export to gnuplot."
  222. (format-time-string org-babel-gnuplot-timestamp-fmt
  223. (org-time-string-to-time s)))
  224. (defvar org-table-number-regexp)
  225. (defvar org-ts-regexp3)
  226. (defun org-babel-gnuplot-quote-tsv-field (s)
  227. "Quote S for export to gnuplot."
  228. (unless (stringp s)
  229. (setq s (format "%s" s)))
  230. (if (string-match org-table-number-regexp s) s
  231. (if (string-match org-ts-regexp3 s)
  232. (org-babel-gnuplot-quote-timestamp-field s)
  233. (if (zerop (length s))
  234. (or *org-babel-gnuplot-missing* s)
  235. (if (string-match "[ \"]" s)
  236. (concat "\"" (mapconcat 'identity (split-string s "\"") "\"\"")
  237. "\"")
  238. s)))))
  239. (defun org-babel-gnuplot-table-to-data (table data-file params)
  240. "Export TABLE to DATA-FILE in a format readable by gnuplot.
  241. Pass PARAMS through to `orgtbl-to-generic' when exporting TABLE."
  242. (with-temp-file data-file
  243. (insert (let ((org-babel-gnuplot-timestamp-fmt
  244. (or (plist-get params :timefmt) "%Y-%m-%d-%H:%M:%S")))
  245. (orgtbl-to-generic
  246. table
  247. (org-combine-plists
  248. '(:sep "\t" :fmt org-babel-gnuplot-quote-tsv-field)
  249. params)))))
  250. data-file)
  251. (provide 'ob-gnuplot)
  252. ;;; ob-gnuplot.el ends here