ob-comint.el 5.8 KB

123456789101112131415161718192021222324252627282930313233343536373839404142434445464748495051525354555657585960616263646566676869707172737475767778798081828384858687888990919293949596979899100101102103104105106107108109110111112113114115116117118119120121122123124125126127128129130131132133134135136137138139140141142143144145146147148149150151152153154155156157
  1. ;;; ob-comint.el --- Babel Functions for Interaction with Comint Buffers -*- lexical-binding: t; -*-
  2. ;; Copyright (C) 2009-2018 Free Software Foundation, Inc.
  3. ;; Author: Eric Schulte
  4. ;; Keywords: literate programming, reproducible research, comint
  5. ;; Homepage: https://orgmode.org
  6. ;; This file is part of GNU Emacs.
  7. ;; GNU Emacs is free software: you can redistribute it and/or modify
  8. ;; it under the terms of the GNU General Public License as published by
  9. ;; the Free Software Foundation, either version 3 of the License, or
  10. ;; (at your option) any later version.
  11. ;; GNU Emacs is distributed in the hope that it will be useful,
  12. ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  13. ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  14. ;; GNU General Public License for more details.
  15. ;; You should have received a copy of the GNU General Public License
  16. ;; along with GNU Emacs. If not, see <https://www.gnu.org/licenses/>.
  17. ;;; Commentary:
  18. ;; These functions build on comint to ease the sending and receiving
  19. ;; of commands and results from comint buffers.
  20. ;; Note that the buffers in this file are analogous to sessions in
  21. ;; org-babel at large.
  22. ;;; Code:
  23. (require 'ob-core)
  24. (require 'org-compat)
  25. (require 'comint)
  26. (defun org-babel-comint-buffer-livep (buffer)
  27. "Check if BUFFER is a comint buffer with a live process."
  28. (let ((buffer (when buffer (get-buffer buffer))))
  29. (and buffer (buffer-live-p buffer) (get-buffer-process buffer) buffer)))
  30. (defmacro org-babel-comint-in-buffer (buffer &rest body)
  31. "Check BUFFER and execute BODY.
  32. BUFFER is checked with `org-babel-comint-buffer-livep'. BODY is
  33. executed inside the protection of `save-excursion' and
  34. `save-match-data'."
  35. (declare (indent 1))
  36. `(progn
  37. (unless (org-babel-comint-buffer-livep ,buffer)
  38. (error "Buffer %s does not exist or has no process" ,buffer))
  39. (save-match-data
  40. (with-current-buffer ,buffer
  41. (save-excursion
  42. (let ((comint-input-filter (lambda (_input) nil)))
  43. ,@body))))))
  44. (def-edebug-spec org-babel-comint-in-buffer (form body))
  45. (defmacro org-babel-comint-with-output (meta &rest body)
  46. "Evaluate BODY in BUFFER and return process output.
  47. Will wait until EOE-INDICATOR appears in the output, then return
  48. all process output. If REMOVE-ECHO and FULL-BODY are present and
  49. non-nil, then strip echo'd body from the returned output. META
  50. should be a list containing the following where the last two
  51. elements are optional.
  52. (BUFFER EOE-INDICATOR REMOVE-ECHO FULL-BODY)
  53. This macro ensures that the filter is removed in case of an error
  54. or user `keyboard-quit' during execution of body."
  55. (declare (indent 1))
  56. (let ((buffer (nth 0 meta))
  57. (eoe-indicator (nth 1 meta))
  58. (remove-echo (nth 2 meta))
  59. (full-body (nth 3 meta)))
  60. `(org-babel-comint-in-buffer ,buffer
  61. (let* ((string-buffer "")
  62. (comint-output-filter-functions
  63. (cons (lambda (text) (setq string-buffer (concat string-buffer text)))
  64. comint-output-filter-functions))
  65. dangling-text)
  66. ;; got located, and save dangling text
  67. (goto-char (process-mark (get-buffer-process (current-buffer))))
  68. (let ((start (point))
  69. (end (point-max)))
  70. (setq dangling-text (buffer-substring start end))
  71. (delete-region start end))
  72. ;; pass FULL-BODY to process
  73. ,@body
  74. ;; wait for end-of-evaluation indicator
  75. (while (progn
  76. (goto-char comint-last-input-end)
  77. (not (save-excursion
  78. (and (re-search-forward
  79. (regexp-quote ,eoe-indicator) nil t)
  80. (re-search-forward
  81. comint-prompt-regexp nil t)))))
  82. (accept-process-output (get-buffer-process (current-buffer)))
  83. ;; thought the following this would allow async
  84. ;; background running, but I was wrong...
  85. ;; (run-with-timer .5 .5 'accept-process-output
  86. ;; (get-buffer-process (current-buffer)))
  87. )
  88. ;; replace cut dangling text
  89. (goto-char (process-mark (get-buffer-process (current-buffer))))
  90. (insert dangling-text)
  91. ;; remove echo'd FULL-BODY from input
  92. (when (and ,remove-echo ,full-body
  93. (string-match
  94. (replace-regexp-in-string
  95. "\n" "[\r\n]+" (regexp-quote (or ,full-body "")))
  96. string-buffer))
  97. (setq string-buffer (substring string-buffer (match-end 0))))
  98. (split-string string-buffer comint-prompt-regexp)))))
  99. (def-edebug-spec org-babel-comint-with-output (sexp body))
  100. (defun org-babel-comint-input-command (buffer cmd)
  101. "Pass CMD to BUFFER.
  102. The input will not be echoed."
  103. (org-babel-comint-in-buffer buffer
  104. (goto-char (process-mark (get-buffer-process buffer)))
  105. (insert cmd)
  106. (comint-send-input)
  107. (org-babel-comint-wait-for-output buffer)))
  108. (defun org-babel-comint-wait-for-output (buffer)
  109. "Wait until output arrives from BUFFER.
  110. Note: this is only safe when waiting for the result of a single
  111. statement (not large blocks of code)."
  112. (org-babel-comint-in-buffer buffer
  113. (while (progn
  114. (goto-char comint-last-input-end)
  115. (not (and (re-search-forward comint-prompt-regexp nil t)
  116. (goto-char (match-beginning 0))
  117. (string= (face-name (face-at-point))
  118. "comint-highlight-prompt"))))
  119. (accept-process-output (get-buffer-process buffer)))))
  120. (defun org-babel-comint-eval-invisibly-and-wait-for-file
  121. (buffer file string &optional period)
  122. "Evaluate STRING in BUFFER invisibly.
  123. Don't return until FILE exists. Code in STRING must ensure that
  124. FILE exists at end of evaluation."
  125. (unless (org-babel-comint-buffer-livep buffer)
  126. (error "Buffer %s does not exist or has no process" buffer))
  127. (when (file-exists-p file) (delete-file file))
  128. (process-send-string
  129. (get-buffer-process buffer)
  130. (if (= (aref string (1- (length string))) ?\n) string (concat string "\n")))
  131. (while (not (file-exists-p file)) (sit-for (or period 0.25))))
  132. (provide 'ob-comint)
  133. ;;; ob-comint.el ends here