org-protocol.el 25 KB

123456789101112131415161718192021222324252627282930313233343536373839404142434445464748495051525354555657585960616263646566676869707172737475767778798081828384858687888990919293949596979899100101102103104105106107108109110111112113114115116117118119120121122123124125126127128129130131132133134135136137138139140141142143144145146147148149150151152153154155156157158159160161162163164165166167168169170171172173174175176177178179180181182183184185186187188189190191192193194195196197198199200201202203204205206207208209210211212213214215216217218219220221222223224225226227228229230231232233234235236237238239240241242243244245246247248249250251252253254255256257258259260261262263264265266267268269270271272273274275276277278279280281282283284285286287288289290291292293294295296297298299300301302303304305306307308309310311312313314315316317318319320321322323324325326327328329330331332333334335336337338339340341342343344345346347348349350351352353354355356357358359360361362363364365366367368369370371372373374375376377378379380381382383384385386387388389390391392393394395396397398399400401402403404405406407408409410411412413414415416417418419420421422423424425426427428429430431432433434435436437438439440441442443444445446447448449450451452453454455456457458459460461462463464465466467468469470471472473474475476477478479480481482483484485486487488489490491492493494495496497498499500501502503504505506507508509510511512513514515516517518519520521522523524525526527528529530531532533534535536537538539540541542543544545546547548549550551552553554555556557558559560561562563564565566567568569570571572573574575576577578579580581582583584585586587588589590591592593594595596597598599600601602603604605606607608609610611612613614615616617618619620621622623624625626627628629630631632633634635636637638639
  1. ;;; org-protocol.el --- Intercept calls from emacsclient to trigger custom actions.
  2. ;;
  3. ;; Copyright (C) 2008-2015 Free Software Foundation, Inc.
  4. ;;
  5. ;; Authors: Bastien Guerry <bzg@gnu.org>
  6. ;; Daniel M German <dmg AT uvic DOT org>
  7. ;; Sebastian Rose <sebastian_rose AT gmx DOT de>
  8. ;; Ross Patterson <me AT rpatterson DOT net>
  9. ;; Maintainer: Sebastian Rose <sebastian_rose AT gmx DOT de>
  10. ;; Keywords: org, emacsclient, wp
  11. ;; This file is part of GNU Emacs.
  12. ;;
  13. ;; GNU Emacs is free software: you can redistribute it and/or modify
  14. ;; it under the terms of the GNU General Public License as published by
  15. ;; the Free Software Foundation, either version 3 of the License, or
  16. ;; (at your option) any later version.
  17. ;; GNU Emacs is distributed in the hope that it will be useful,
  18. ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  19. ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  20. ;; GNU General Public License for more details.
  21. ;; You should have received a copy of the GNU General Public License
  22. ;; along with GNU Emacs. If not, see <http://www.gnu.org/licenses/>.
  23. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  24. ;;; Commentary:
  25. ;;
  26. ;; Intercept calls from emacsclient to trigger custom actions.
  27. ;;
  28. ;; This is done by advising `server-visit-files' to scan the list of filenames
  29. ;; for `org-protocol-the-protocol' and sub-protocols defined in
  30. ;; `org-protocol-protocol-alist' and `org-protocol-protocol-alist-default'.
  31. ;;
  32. ;; Any application that supports calling external programs with an URL
  33. ;; as argument may be used with this functionality.
  34. ;;
  35. ;;
  36. ;; Usage:
  37. ;; ------
  38. ;;
  39. ;; 1.) Add this to your init file (.emacs probably):
  40. ;;
  41. ;; (add-to-list 'load-path "/path/to/org-protocol/")
  42. ;; (require 'org-protocol)
  43. ;;
  44. ;; 3.) Ensure emacs-server is up and running.
  45. ;; 4.) Try this from the command line (adjust the URL as needed):
  46. ;;
  47. ;; $ emacsclient \
  48. ;; org-protocol://store-link://http:%2F%2Flocalhost%2Findex.html/The%20title
  49. ;;
  50. ;; 5.) Optionally add custom sub-protocols and handlers:
  51. ;;
  52. ;; (setq org-protocol-protocol-alist
  53. ;; '(("my-protocol"
  54. ;; :protocol "my-protocol"
  55. ;; :function my-protocol-handler-function)))
  56. ;;
  57. ;; A "sub-protocol" will be found in URLs like this:
  58. ;;
  59. ;; org-protocol://sub-protocol://data
  60. ;;
  61. ;; If it works, you can now setup other applications for using this feature.
  62. ;;
  63. ;;
  64. ;; As of March 2009 Firefox users follow the steps documented on
  65. ;; http://kb.mozillazine.org/Register_protocol, Opera setup is described here:
  66. ;; http://www.opera.com/support/kb/view/535/
  67. ;;
  68. ;;
  69. ;; Documentation
  70. ;; -------------
  71. ;;
  72. ;; org-protocol.el comes with and installs handlers to open sources of published
  73. ;; online content, store and insert the browser's URLs and cite online content
  74. ;; by clicking on a bookmark in Firefox, Opera and probably other browsers and
  75. ;; applications:
  76. ;;
  77. ;; * `org-protocol-open-source' uses the sub-protocol \"open-source\" and maps
  78. ;; URLs to local filenames defined in `org-protocol-project-alist'.
  79. ;;
  80. ;; * `org-protocol-store-link' stores an Org-link (if Org-mode is present) and
  81. ;; pushes the browsers URL to the `kill-ring' for yanking. This handler is
  82. ;; triggered through the sub-protocol \"store-link\".
  83. ;;
  84. ;; * Call `org-protocol-capture' by using the sub-protocol \"capture\". If
  85. ;; Org-mode is loaded, Emacs will pop-up a capture buffer and fill the
  86. ;; template with the data provided. I.e. the browser's URL is inserted as an
  87. ;; Org-link of which the page title will be the description part. If text
  88. ;; was select in the browser, that text will be the body of the entry.
  89. ;;
  90. ;; You may use the same bookmark URL for all those standard handlers and just
  91. ;; adjust the sub-protocol used:
  92. ;;
  93. ;; location.href='org-protocol://sub-protocol://'+
  94. ;; encodeURIComponent(location.href)+'/'+
  95. ;; encodeURIComponent(document.title)+'/'+
  96. ;; encodeURIComponent(window.getSelection())
  97. ;;
  98. ;; The handler for the sub-protocol \"capture\" detects an optional template
  99. ;; char that, if present, triggers the use of a special template.
  100. ;; Example:
  101. ;;
  102. ;; location.href='org-protocol://sub-protocol://x/'+ ...
  103. ;;
  104. ;; use template ?x.
  105. ;;
  106. ;; Note, that using double slashes is optional from org-protocol.el's point of
  107. ;; view because emacsclient squashes the slashes to one.
  108. ;;
  109. ;;
  110. ;; provides: 'org-protocol
  111. ;;
  112. ;;; Code:
  113. (require 'org)
  114. (eval-when-compile
  115. (require 'cl))
  116. (declare-function org-publish-get-project-from-filename "org-publish"
  117. (filename &optional up))
  118. (declare-function server-edit "server" (&optional arg))
  119. (define-obsolete-function-alias
  120. 'org-protocol-unhex-compound 'org-link-unescape-compound
  121. "2011-02-17")
  122. (define-obsolete-function-alias
  123. 'org-protocol-unhex-string 'org-link-unescape
  124. "2011-02-17")
  125. (define-obsolete-function-alias
  126. 'org-protocol-unhex-single-byte-sequence
  127. 'org-link-unescape-single-byte-sequence
  128. "2011-02-17")
  129. (defgroup org-protocol nil
  130. "Intercept calls from emacsclient to trigger custom actions.
  131. This is done by advising `server-visit-files' to scan the list of filenames
  132. for `org-protocol-the-protocol' and sub-protocols defined in
  133. `org-protocol-protocol-alist' and `org-protocol-protocol-alist-default'."
  134. :version "22.1"
  135. :group 'convenience
  136. :group 'org)
  137. ;;; Variables:
  138. (defconst org-protocol-protocol-alist-default
  139. '(("org-capture" :protocol "capture" :function org-protocol-capture :kill-client t)
  140. ("org-store-link" :protocol "store-link" :function org-protocol-store-link)
  141. ("org-open-source" :protocol "open-source" :function org-protocol-open-source))
  142. "Default protocols to use.
  143. See `org-protocol-protocol-alist' for a description of this variable.")
  144. (defconst org-protocol-the-protocol "org-protocol"
  145. "This is the protocol to detect if org-protocol.el is loaded.
  146. `org-protocol-protocol-alist-default' and `org-protocol-protocol-alist' hold
  147. the sub-protocols that trigger the required action. You will have to define
  148. just one protocol handler OS-wide (MS-Windows) or per application (Linux).
  149. That protocol handler should call emacsclient.")
  150. ;;; User variables:
  151. (defcustom org-protocol-reverse-list-of-files t
  152. "Non-nil means re-reverse the list of filenames passed on the command line.
  153. The filenames passed on the command line are passed to the emacs-server in
  154. reverse order. Set to t (default) to re-reverse the list, i.e. use the
  155. sequence on the command line. If nil, the sequence of the filenames is
  156. unchanged."
  157. :group 'org-protocol
  158. :type 'boolean)
  159. (defcustom org-protocol-project-alist nil
  160. "Map URLs to local filenames for `org-protocol-open-source' (open-source).
  161. Each element of this list must be of the form:
  162. (module-name :property value property: value ...)
  163. where module-name is an arbitrary name. All the values are strings.
  164. Possible properties are:
  165. :online-suffix - the suffix to strip from the published URLs
  166. :working-suffix - the replacement for online-suffix
  167. :base-url - the base URL, e.g. http://www.example.com/project/
  168. Last slash required.
  169. :working-directory - the local working directory. This is, what base-url will
  170. be replaced with.
  171. :redirects - A list of cons cells, each of which maps a regular
  172. expression to match to a path relative to :working-directory.
  173. Example:
  174. (setq org-protocol-project-alist
  175. \\='((\"http://orgmode.org/worg/\"
  176. :online-suffix \".php\"
  177. :working-suffix \".org\"
  178. :base-url \"http://orgmode.org/worg/\"
  179. :working-directory \"/home/user/org/Worg/\")
  180. (\"http://localhost/org-notes/\"
  181. :online-suffix \".html\"
  182. :working-suffix \".org\"
  183. :base-url \"http://localhost/org/\"
  184. :working-directory \"/home/user/org/\"
  185. :rewrites ((\"org/?$\" . \"index.php\")))))
  186. The last line tells `org-protocol-open-source' to open
  187. /home/user/org/index.php, if the URL cannot be mapped to an existing
  188. file, and ends with either \"org\" or \"org/\".
  189. Consider using the interactive functions `org-protocol-create' and
  190. `org-protocol-create-for-org' to help you filling this variable with valid contents."
  191. :group 'org-protocol
  192. :type 'alist)
  193. (defcustom org-protocol-protocol-alist nil
  194. "Register custom handlers for org-protocol.
  195. Each element of this list must be of the form:
  196. (module-name :protocol protocol :function func :kill-client nil)
  197. protocol - protocol to detect in a filename without trailing colon and slashes.
  198. See rfc1738 section 2.1 for more on this.
  199. If you define a protocol \"my-protocol\", `org-protocol-check-filename-for-protocol'
  200. will search filenames for \"org-protocol:/my-protocol:/\"
  201. and trigger your action for every match. `org-protocol' is defined in
  202. `org-protocol-the-protocol'. Double and triple slashes are compressed
  203. to one by emacsclient.
  204. function - function that handles requests with protocol and takes exactly one
  205. argument: the filename with all protocols stripped. If the function
  206. returns nil, emacsclient and -server do nothing. Any non-nil return
  207. value is considered a valid filename and thus passed to the server.
  208. `org-protocol.el provides some support for handling those filenames,
  209. if you stay with the conventions used for the standard handlers in
  210. `org-protocol-protocol-alist-default'. See `org-protocol-split-data'.
  211. kill-client - If t, kill the client immediately, once the sub-protocol is
  212. detected. This is necessary for actions that can be interrupted by
  213. `C-g' to avoid dangling emacsclients. Note, that all other command
  214. line arguments but the this one will be discarded, greedy handlers
  215. still receive the whole list of arguments though.
  216. Here is an example:
  217. (setq org-protocol-protocol-alist
  218. \\='((\"my-protocol\"
  219. :protocol \"my-protocol\"
  220. :function my-protocol-handler-function)
  221. (\"your-protocol\"
  222. :protocol \"your-protocol\"
  223. :function your-protocol-handler-function)))"
  224. :group 'org-protocol
  225. :type '(alist))
  226. (defcustom org-protocol-default-template-key nil
  227. "The default template key to use.
  228. This is usually a single character string but can also be a
  229. string with two characters."
  230. :group 'org-protocol
  231. :type '(choice (const nil) (string)))
  232. (defcustom org-protocol-data-separator "/+\\|\\?"
  233. "The default data separator to use.
  234. This should be a single regexp string."
  235. :group 'org-protocol
  236. :version "24.4"
  237. :package-version '(Org . "8.0")
  238. :type 'string)
  239. ;;; Helper functions:
  240. (defun org-protocol-sanitize-uri (uri)
  241. "emacsclient compresses double and triple slashes.
  242. Slashes are sanitized to double slashes here."
  243. (when (string-match "^\\([a-z]+\\):/" uri)
  244. (let* ((splitparts (split-string uri "/+")))
  245. (setq uri (concat (car splitparts) "//" (mapconcat 'identity (cdr splitparts) "/")))))
  246. uri)
  247. (defun org-protocol-split-data (data &optional unhexify separator)
  248. "Split what an org-protocol handler function gets as only argument.
  249. DATA is that one argument. DATA is split at each occurrence of
  250. SEPARATOR (regexp). If no SEPARATOR is specified or SEPARATOR is
  251. nil, assume \"/+\". The results of that splitting are returned
  252. as a list. If UNHEXIFY is non-nil, hex-decode each split part.
  253. If UNHEXIFY is a function, use that function to decode each split
  254. part."
  255. (let* ((sep (or separator "/+\\|\\?"))
  256. (split-parts (split-string data sep)))
  257. (if unhexify
  258. (if (fboundp unhexify)
  259. (mapcar unhexify split-parts)
  260. (mapcar 'org-link-unescape split-parts))
  261. split-parts)))
  262. (defun org-protocol-flatten-greedy (param-list &optional strip-path replacement)
  263. "Greedy handlers might receive a list like this from emacsclient:
  264. ((\"/dir/org-protocol:/greedy:/~/path1\" (23 . 12)) (\"/dir/param\"))
  265. where \"/dir/\" is the absolute path to emacsclients working directory. This
  266. function transforms it into a flat list using `org-protocol-flatten' and
  267. transforms the elements of that list as follows:
  268. If strip-path is non-nil, remove the \"/dir/\" prefix from all members of
  269. param-list.
  270. If replacement is string, replace the \"/dir/\" prefix with it.
  271. The first parameter, the one that contains the protocols, is always changed.
  272. Everything up to the end of the protocols is stripped.
  273. Note, that this function will always behave as if
  274. `org-protocol-reverse-list-of-files' was set to t and the returned list will
  275. reflect that. I.e. emacsclients first parameter will be the first one in the
  276. returned list."
  277. (let* ((l (org-protocol-flatten (if org-protocol-reverse-list-of-files
  278. param-list
  279. (reverse param-list))))
  280. (trigger (car l))
  281. (len 0)
  282. dir
  283. ret)
  284. (when (string-match "^\\(.*\\)\\(org-protocol:/+[a-zA-z0-9][-_a-zA-z0-9]*:/+\\)\\(.*\\)" trigger)
  285. (setq dir (match-string 1 trigger))
  286. (setq len (length dir))
  287. (setcar l (concat dir (match-string 3 trigger))))
  288. (if strip-path
  289. (progn
  290. (dolist (e l ret)
  291. (setq ret
  292. (append ret
  293. (list
  294. (if (stringp e)
  295. (if (stringp replacement)
  296. (setq e (concat replacement (substring e len)))
  297. (setq e (substring e len)))
  298. e)))))
  299. ret)
  300. l)))
  301. (defun org-protocol-flatten (l)
  302. "Greedy handlers might receive a list like this from emacsclient:
  303. ((\"/dir/org-protocol:/greedy:/~/path1\" (23 . 12)) (\"/dir/param\"))
  304. where \"/dir/\" is the absolute path to emacsclients working directory.
  305. This function transforms it into a flat list."
  306. (if (null l) ()
  307. (if (listp l)
  308. (append (org-protocol-flatten (car l)) (org-protocol-flatten (cdr l)))
  309. (list l))))
  310. ;;; Standard protocol handlers:
  311. (defun org-protocol-store-link (fname)
  312. "Process an org-protocol://store-link:// style url.
  313. Additionally store a browser URL as an org link. Also pushes the
  314. link's URL to the `kill-ring'.
  315. The location for a browser's bookmark has to look like this:
  316. javascript:location.href=\\='org-protocol://store-link://\\='+ \\
  317. encodeURIComponent(location.href)
  318. encodeURIComponent(document.title)+\\='/\\='+ \\
  319. Don't use `escape()'! Use `encodeURIComponent()' instead. The title of the page
  320. could contain slashes and the location definitely will.
  321. The sub-protocol used to reach this function is set in
  322. `org-protocol-protocol-alist'."
  323. (let* ((splitparts (org-protocol-split-data fname t org-protocol-data-separator))
  324. (uri (org-protocol-sanitize-uri (car splitparts)))
  325. (title (cadr splitparts))
  326. orglink)
  327. (if (boundp 'org-stored-links)
  328. (setq org-stored-links (cons (list uri title) org-stored-links)))
  329. (kill-new uri)
  330. (message "`%s' to insert new org-link, `%s' to insert `%s'"
  331. (substitute-command-keys"\\[org-insert-link]")
  332. (substitute-command-keys"\\[yank]")
  333. uri))
  334. nil)
  335. (defun org-protocol-capture (info)
  336. "Process an org-protocol://capture:// style url.
  337. The sub-protocol used to reach this function is set in
  338. `org-protocol-protocol-alist'.
  339. This function detects an URL, title and optional text, separated
  340. by `/'. The location for a browser's bookmark looks like this:
  341. javascript:location.href=\\='org-protocol://capture://\\='+ \\
  342. encodeURIComponent(location.href)+\\='/\\=' \\
  343. encodeURIComponent(document.title)+\\='/\\='+ \\
  344. encodeURIComponent(window.getSelection())
  345. By default, it uses the character `org-protocol-default-template-key',
  346. which should be associated with a template in `org-capture-templates'.
  347. But you may prepend the encoded URL with a character and a slash like so:
  348. javascript:location.href=\\='org-protocol://capture://b/\\='+ ...
  349. Now template ?b will be used."
  350. (if (and (boundp 'org-stored-links)
  351. (org-protocol-do-capture info))
  352. (message "Item captured."))
  353. nil)
  354. (defun org-protocol-convert-query-to-plist (query)
  355. "Convert query string that is part of url to property list."
  356. (if query
  357. (apply 'append (mapcar (lambda (x)
  358. (let ((c (split-string x "=")))
  359. (list (intern (concat ":" (car c))) (cadr c))))
  360. (split-string query "&")))))
  361. (defun org-protocol-do-capture (info)
  362. "Support `org-capture'."
  363. (let* ((parts (org-protocol-split-data info t org-protocol-data-separator))
  364. (template (or (and (>= 2 (length (car parts))) (pop parts))
  365. org-protocol-default-template-key))
  366. (url (org-protocol-sanitize-uri (car parts)))
  367. (type (if (string-match "^\\([a-z]+\\):" url)
  368. (match-string 1 url)))
  369. (title (or (cadr parts) ""))
  370. (region (or (caddr parts) ""))
  371. (orglink (org-make-link-string
  372. url (if (string-match "[^[:space:]]" title) title url)))
  373. (query (or (org-protocol-convert-query-to-plist (cadddr parts)) ""))
  374. (org-capture-link-is-already-stored t)) ;; avoid call to org-store-link
  375. (setq org-stored-links
  376. (cons (list url title) org-stored-links))
  377. (kill-new orglink)
  378. (org-store-link-props :type type
  379. :link url
  380. :description title
  381. :annotation orglink
  382. :initial region
  383. :query query)
  384. (raise-frame)
  385. (funcall 'org-capture nil template)))
  386. (defun org-protocol-open-source (fname)
  387. "Process an org-protocol://open-source:// style url.
  388. Change a filename by mapping URLs to local filenames as set
  389. in `org-protocol-project-alist'.
  390. The location for a browser's bookmark should look like this:
  391. javascript:location.href=\\='org-protocol://open-source://\\='+ \\
  392. encodeURIComponent(location.href)"
  393. ;; As we enter this function for a match on our protocol, the return value
  394. ;; defaults to nil.
  395. (let ((result nil)
  396. (f (org-link-unescape fname)))
  397. (catch 'result
  398. (dolist (prolist org-protocol-project-alist)
  399. (let* ((base-url (plist-get (cdr prolist) :base-url))
  400. (wsearch (regexp-quote base-url)))
  401. (when (string-match wsearch f)
  402. (let* ((wdir (plist-get (cdr prolist) :working-directory))
  403. (strip-suffix (plist-get (cdr prolist) :online-suffix))
  404. (add-suffix (plist-get (cdr prolist) :working-suffix))
  405. ;; Strip "[?#].*$" if `f' is a redirect with another
  406. ;; ending than strip-suffix here:
  407. (f1 (substring f 0 (string-match "\\([\\?#].*\\)?$" f)))
  408. (start-pos (+ (string-match wsearch f1) (length base-url)))
  409. (end-pos (string-match
  410. (regexp-quote strip-suffix) f1))
  411. ;; We have to compare redirects without suffix below:
  412. (f2 (concat wdir (substring f1 start-pos end-pos)))
  413. (the-file (concat f2 add-suffix)))
  414. ;; Note: the-file may still contain `%C3' et al here because browsers
  415. ;; tend to encode `&auml;' in URLs to `%25C3' - `%25' being `%'.
  416. ;; So the results may vary.
  417. ;; -- start redirects --
  418. (unless (file-exists-p the-file)
  419. (message "File %s does not exist.\nTesting for rewritten URLs." the-file)
  420. (let ((rewrites (plist-get (cdr prolist) :rewrites)))
  421. (when rewrites
  422. (message "Rewrites found: %S" rewrites)
  423. (mapc
  424. (lambda (rewrite)
  425. "Try to match a rewritten URL and map it to a real file."
  426. ;; Compare redirects without suffix:
  427. (if (string-match (car rewrite) f2)
  428. (throw 'result (concat wdir (cdr rewrite)))))
  429. rewrites))))
  430. ;; -- end of redirects --
  431. (if (file-readable-p the-file)
  432. (throw 'result the-file))
  433. (if (file-exists-p the-file)
  434. (message "%s: permission denied!" the-file)
  435. (message "%s: no such file or directory." the-file))))))
  436. result)))
  437. ;;; Core functions:
  438. (defun org-protocol-check-filename-for-protocol (fname restoffiles client)
  439. "Detect if `org-protocol-the-protocol' and a known sub-protocol is used in fname.
  440. Sub-protocols are registered in `org-protocol-protocol-alist' and
  441. `org-protocol-protocol-alist-default'.
  442. This is, how the matching is done:
  443. (string-match \"protocol:/+sub-protocol:/+\" ...)
  444. protocol and sub-protocol are regexp-quoted.
  445. If a matching protocol is found, the protocol is stripped from fname and the
  446. result is passed to the protocols function as the only parameter. If the
  447. function returns nil, the filename is removed from the list of filenames
  448. passed from emacsclient to the server.
  449. If the function returns a non nil value, that value is passed to the server
  450. as filename."
  451. (let ((sub-protocols (append org-protocol-protocol-alist
  452. org-protocol-protocol-alist-default)))
  453. (catch 'fname
  454. (let ((the-protocol (concat (regexp-quote org-protocol-the-protocol) ":/+")))
  455. (when (string-match the-protocol fname)
  456. (dolist (prolist sub-protocols)
  457. (let ((proto (concat the-protocol
  458. (regexp-quote (plist-get (cdr prolist) :protocol)) ":/+")))
  459. (when (string-match proto fname)
  460. (let* ((func (plist-get (cdr prolist) :function))
  461. (greedy (plist-get (cdr prolist) :greedy))
  462. (split (split-string fname proto))
  463. (result (if greedy restoffiles (cadr split))))
  464. (when (plist-get (cdr prolist) :kill-client)
  465. (message "Greedy org-protocol handler. Killing client.")
  466. (server-edit))
  467. (when (fboundp func)
  468. (unless greedy
  469. (throw 'fname (funcall func result)))
  470. (funcall func result)
  471. (throw 'fname t))))))))
  472. ;; (message "fname: %s" fname)
  473. fname)))
  474. (defadvice server-visit-files (before org-protocol-detect-protocol-server activate)
  475. "Advice server-visit-flist to call `org-protocol-modify-filename-for-protocol'."
  476. (let ((flist (if org-protocol-reverse-list-of-files
  477. (reverse (ad-get-arg 0))
  478. (ad-get-arg 0)))
  479. (client (ad-get-arg 1)))
  480. (catch 'greedy
  481. (dolist (var flist)
  482. ;; `\' to `/' on windows. FIXME: could this be done any better?
  483. (let ((fname (expand-file-name (car var))))
  484. (setq fname (org-protocol-check-filename-for-protocol
  485. fname (member var flist) client))
  486. (if (eq fname t) ;; greedy? We need the t return value.
  487. (progn
  488. (ad-set-arg 0 nil)
  489. (throw 'greedy t))
  490. (if (stringp fname) ;; probably filename
  491. (setcar var fname)
  492. (ad-set-arg 0 (delq var (ad-get-arg 0))))))))))
  493. ;;; Org specific functions:
  494. (defun org-protocol-create-for-org ()
  495. "Create a org-protocol project for the current file's Org-mode project.
  496. The visited file needs to be part of a publishing project in
  497. `org-publish-project-alist' for this to work. The function
  498. delegates most of the work to `org-protocol-create'."
  499. (interactive)
  500. (require 'org-publish)
  501. (let ((all (or (org-publish-get-project-from-filename buffer-file-name))))
  502. (if all (org-protocol-create (cdr all))
  503. (message "Not in an org-project. Did mean %s?"
  504. (substitute-command-keys"\\[org-protocol-create]")))))
  505. (defun org-protocol-create (&optional project-plist)
  506. "Create a new org-protocol project interactively.
  507. An org-protocol project is an entry in
  508. `org-protocol-project-alist' which is used by
  509. `org-protocol-open-source'. Optionally use PROJECT-PLIST to
  510. initialize the defaults for this project. If PROJECT-PLIST is
  511. the cdr of an element in `org-publish-project-alist', reuse
  512. :base-directory, :html-extension and :base-extension."
  513. (interactive)
  514. (let ((working-dir (expand-file-name
  515. (or (plist-get project-plist :base-directory)
  516. default-directory)))
  517. (base-url "http://orgmode.org/worg/")
  518. (strip-suffix (or (plist-get project-plist :html-extension) ".html"))
  519. (working-suffix (if (plist-get project-plist :base-extension)
  520. (concat "." (plist-get project-plist :base-extension))
  521. ".org"))
  522. (worglet-buffer nil)
  523. (insert-default-directory t)
  524. (minibuffer-allow-text-properties nil))
  525. (setq base-url (read-string "Base URL of published content: " base-url nil base-url t))
  526. (if (not (string-match "\\/$" base-url))
  527. (setq base-url (concat base-url "/")))
  528. (setq working-dir
  529. (expand-file-name
  530. (read-directory-name "Local working directory: " working-dir working-dir t)))
  531. (if (not (string-match "\\/$" working-dir))
  532. (setq working-dir (concat working-dir "/")))
  533. (setq strip-suffix
  534. (read-string
  535. (concat "Extension to strip from published URLs (" strip-suffix "): ")
  536. strip-suffix nil strip-suffix t))
  537. (setq working-suffix
  538. (read-string
  539. (concat "Extension of editable files (" working-suffix "): ")
  540. working-suffix nil working-suffix t))
  541. (when (yes-or-no-p "Save the new org-protocol-project to your init file? ")
  542. (setq org-protocol-project-alist
  543. (cons `(,base-url . (:base-url ,base-url
  544. :working-directory ,working-dir
  545. :online-suffix ,strip-suffix
  546. :working-suffix ,working-suffix))
  547. org-protocol-project-alist))
  548. (customize-save-variable 'org-protocol-project-alist org-protocol-project-alist))))
  549. (provide 'org-protocol)
  550. ;;; org-protocol.el ends here