ob-tangle.el 23 KB

123456789101112131415161718192021222324252627282930313233343536373839404142434445464748495051525354555657585960616263646566676869707172737475767778798081828384858687888990919293949596979899100101102103104105106107108109110111112113114115116117118119120121122123124125126127128129130131132133134135136137138139140141142143144145146147148149150151152153154155156157158159160161162163164165166167168169170171172173174175176177178179180181182183184185186187188189190191192193194195196197198199200201202203204205206207208209210211212213214215216217218219220221222223224225226227228229230231232233234235236237238239240241242243244245246247248249250251252253254255256257258259260261262263264265266267268269270271272273274275276277278279280281282283284285286287288289290291292293294295296297298299300301302303304305306307308309310311312313314315316317318319320321322323324325326327328329330331332333334335336337338339340341342343344345346347348349350351352353354355356357358359360361362363364365366367368369370371372373374375376377378379380381382383384385386387388389390391392393394395396397398399400401402403404405406407408409410411412413414415416417418419420421422423424425426427428429430431432433434435436437438439440441442443444445446447448449450451452453454455456457458459460461462463464465466467468469470471472473474475476477478479480481482483484485486487488489490491492493494495496497498499500501502503504505506507508509510511512513514515516517518519520521522523524525526527528529530531532533534535536537538539540541542543544545546547548549550551552553554555556557558559560561562563564565566567568569570571572573574575576577578579580581582583584585586587588589590591592593594595596597598599
  1. ;;; ob-tangle.el --- extract source code from org-mode files
  2. ;; Copyright (C) 2009-2015 Free Software Foundation, Inc.
  3. ;; Author: Eric Schulte
  4. ;; Keywords: literate programming, reproducible research
  5. ;; Homepage: http://orgmode.org
  6. ;; This file is part of GNU Emacs.
  7. ;; GNU Emacs is free software: you can redistribute it and/or modify
  8. ;; it under the terms of the GNU General Public License as published by
  9. ;; the Free Software Foundation, either version 3 of the License, or
  10. ;; (at your option) any later version.
  11. ;; GNU Emacs is distributed in the hope that it will be useful,
  12. ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  13. ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  14. ;; GNU General Public License for more details.
  15. ;; You should have received a copy of the GNU General Public License
  16. ;; along with GNU Emacs. If not, see <http://www.gnu.org/licenses/>.
  17. ;;; Commentary:
  18. ;; Extract the code from source blocks out into raw source-code files.
  19. ;;; Code:
  20. (require 'org-src)
  21. (declare-function make-directory "files" (dir &optional parents))
  22. (declare-function org-babel-update-block-body "org" (new-body))
  23. (declare-function org-back-to-heading "org" (invisible-ok))
  24. (declare-function org-before-first-heading-p "org" ())
  25. (declare-function org-edit-special "org" (&optional arg))
  26. (declare-function org-fill-template "org" (template alist))
  27. (declare-function org-heading-components "org" ())
  28. (declare-function org-in-commented-heading-p "org" (&optional no-inheritance))
  29. (declare-function org-link-escape "org" (text &optional table))
  30. (declare-function org-open-link-from-string "org" (s &optional arg reference-buffer))
  31. (declare-function org-store-link "org" (arg))
  32. (declare-function org-up-heading-safe "org" ())
  33. (declare-function outline-previous-heading "outline" ())
  34. (defcustom org-babel-tangle-lang-exts
  35. '(("emacs-lisp" . "el")
  36. ("elisp" . "el"))
  37. "Alist mapping languages to their file extensions.
  38. The key is the language name, the value is the string that should
  39. be inserted as the extension commonly used to identify files
  40. written in this language. If no entry is found in this list,
  41. then the name of the language is used."
  42. :group 'org-babel-tangle
  43. :version "24.1"
  44. :type '(repeat
  45. (cons
  46. (string "Language name")
  47. (string "File Extension"))))
  48. (defcustom org-babel-tangle-use-relative-file-links t
  49. "Use relative path names in links from tangled source back the Org-mode file."
  50. :group 'org-babel-tangle
  51. :type 'boolean)
  52. (defcustom org-babel-post-tangle-hook nil
  53. "Hook run in code files tangled by `org-babel-tangle'."
  54. :group 'org-babel
  55. :version "24.1"
  56. :type 'hook)
  57. (defcustom org-babel-pre-tangle-hook '(save-buffer)
  58. "Hook run at the beginning of `org-babel-tangle'."
  59. :group 'org-babel
  60. :version "24.1"
  61. :type 'hook)
  62. (defcustom org-babel-tangle-body-hook nil
  63. "Hook run over the contents of each code block body."
  64. :group 'org-babel
  65. :version "24.1"
  66. :type 'hook)
  67. (defcustom org-babel-tangle-comment-format-beg "[[%link][%source-name]]"
  68. "Format of inserted comments in tangled code files.
  69. The following format strings can be used to insert special
  70. information into the output using `org-fill-template'.
  71. %start-line --- the line number at the start of the code block
  72. %file --------- the file from which the code block was tangled
  73. %link --------- Org-mode style link to the code block
  74. %source-name -- name of the code block
  75. Upon insertion the formatted comment will be commented out, and
  76. followed by a newline. To inhibit this post-insertion processing
  77. set the `org-babel-tangle-uncomment-comments' variable to a
  78. non-nil value.
  79. Whether or not comments are inserted during tangling is
  80. controlled by the :comments header argument."
  81. :group 'org-babel
  82. :version "24.1"
  83. :type 'string)
  84. (defcustom org-babel-tangle-comment-format-end "%source-name ends here"
  85. "Format of inserted comments in tangled code files.
  86. The following format strings can be used to insert special
  87. information into the output using `org-fill-template'.
  88. %start-line --- the line number at the start of the code block
  89. %file --------- the file from which the code block was tangled
  90. %link --------- Org-mode style link to the code block
  91. %source-name -- name of the code block
  92. Upon insertion the formatted comment will be commented out, and
  93. followed by a newline. To inhibit this post-insertion processing
  94. set the `org-babel-tangle-uncomment-comments' variable to a
  95. non-nil value.
  96. Whether or not comments are inserted during tangling is
  97. controlled by the :comments header argument."
  98. :group 'org-babel
  99. :version "24.1"
  100. :type 'string)
  101. (defcustom org-babel-tangle-uncomment-comments nil
  102. "Inhibits automatic commenting and addition of trailing newline
  103. of tangle comments. Use `org-babel-tangle-comment-format-beg'
  104. and `org-babel-tangle-comment-format-end' to customize the format
  105. of tangled comments."
  106. :group 'org-babel
  107. :type 'boolean)
  108. (defcustom org-babel-process-comment-text #'org-remove-indentation
  109. "Function called to process raw Org-mode text collected to be
  110. inserted as comments in tangled source-code files. The function
  111. should take a single string argument and return a string
  112. result. The default value is `org-remove-indentation'."
  113. :group 'org-babel
  114. :version "24.1"
  115. :type 'function)
  116. (defun org-babel-find-file-noselect-refresh (file)
  117. "Find file ensuring that the latest changes on disk are
  118. represented in the file."
  119. (find-file-noselect file 'nowarn)
  120. (with-current-buffer (get-file-buffer file)
  121. (revert-buffer t t t)))
  122. (defmacro org-babel-with-temp-filebuffer (file &rest body)
  123. "Open FILE into a temporary buffer execute BODY there like
  124. `progn', then kill the FILE buffer returning the result of
  125. evaluating BODY."
  126. (declare (indent 1))
  127. (let ((temp-path (make-symbol "temp-path"))
  128. (temp-result (make-symbol "temp-result"))
  129. (temp-file (make-symbol "temp-file"))
  130. (visited-p (make-symbol "visited-p")))
  131. `(let* ((,temp-path ,file)
  132. (,visited-p (get-file-buffer ,temp-path))
  133. ,temp-result ,temp-file)
  134. (org-babel-find-file-noselect-refresh ,temp-path)
  135. (setf ,temp-file (get-file-buffer ,temp-path))
  136. (with-current-buffer ,temp-file
  137. (setf ,temp-result (progn ,@body)))
  138. (unless ,visited-p (kill-buffer ,temp-file))
  139. ,temp-result)))
  140. (def-edebug-spec org-babel-with-temp-filebuffer (form body))
  141. ;;;###autoload
  142. (defun org-babel-tangle-file (file &optional target-file lang)
  143. "Extract the bodies of source code blocks in FILE.
  144. Source code blocks are extracted with `org-babel-tangle'.
  145. Optional argument TARGET-FILE can be used to specify a default
  146. export file for all source blocks. Optional argument LANG can be
  147. used to limit the exported source code blocks by language.
  148. Return a list whose CAR is the tangled file name."
  149. (interactive "fFile to tangle: \nP")
  150. (let ((visited-p (get-file-buffer (expand-file-name file)))
  151. to-be-removed)
  152. (prog1
  153. (save-window-excursion
  154. (find-file file)
  155. (setq to-be-removed (current-buffer))
  156. (mapcar #'expand-file-name (org-babel-tangle nil target-file lang)))
  157. (unless visited-p
  158. (kill-buffer to-be-removed)))))
  159. (defun org-babel-tangle-publish (_ filename pub-dir)
  160. "Tangle FILENAME and place the results in PUB-DIR."
  161. (unless (file-exists-p pub-dir)
  162. (make-directory pub-dir t))
  163. (mapc (lambda (el) (copy-file el pub-dir t)) (org-babel-tangle-file filename)))
  164. ;;;###autoload
  165. (defun org-babel-tangle (&optional arg target-file lang)
  166. "Write code blocks to source-specific files.
  167. Extract the bodies of all source code blocks from the current
  168. file into their own source-specific files.
  169. With one universal prefix argument, only tangle the block at point.
  170. When two universal prefix arguments, only tangle blocks for the
  171. tangle file of the block at point.
  172. Optional argument TARGET-FILE can be used to specify a default
  173. export file for all source blocks. Optional argument LANG can be
  174. used to limit the exported source code blocks by language."
  175. (interactive "P")
  176. (run-hooks 'org-babel-pre-tangle-hook)
  177. ;; Possibly Restrict the buffer to the current code block
  178. (save-restriction
  179. (save-excursion
  180. (when (equal arg '(4))
  181. (let ((head (org-babel-where-is-src-block-head)))
  182. (if head
  183. (goto-char head)
  184. (user-error "Point is not in a source code block"))))
  185. (let ((block-counter 0)
  186. (org-babel-default-header-args
  187. (if target-file
  188. (org-babel-merge-params org-babel-default-header-args
  189. (list (cons :tangle target-file)))
  190. org-babel-default-header-args))
  191. (tangle-file
  192. (when (equal arg '(16))
  193. (or (cdr (assoc :tangle (nth 2 (org-babel-get-src-block-info 'light))))
  194. (user-error "Point is not in a source code block"))))
  195. path-collector)
  196. (mapc ;; map over all languages
  197. (lambda (by-lang)
  198. (let* ((lang (car by-lang))
  199. (specs (cdr by-lang))
  200. (ext (or (cdr (assoc lang org-babel-tangle-lang-exts)) lang))
  201. (lang-f (intern
  202. (concat
  203. (or (and (cdr (assoc lang org-src-lang-modes))
  204. (symbol-name
  205. (cdr (assoc lang org-src-lang-modes))))
  206. lang)
  207. "-mode")))
  208. she-banged)
  209. (mapc
  210. (lambda (spec)
  211. (let ((get-spec (lambda (name) (cdr (assoc name (nth 4 spec))))))
  212. (let* ((tangle (funcall get-spec :tangle))
  213. (she-bang (let ((sheb (funcall get-spec :shebang)))
  214. (when (> (length sheb) 0) sheb)))
  215. (tangle-mode (funcall get-spec :tangle-mode))
  216. (base-name (cond
  217. ((string= "yes" tangle)
  218. (file-name-sans-extension
  219. (nth 1 spec)))
  220. ((string= "no" tangle) nil)
  221. ((> (length tangle) 0) tangle)))
  222. (file-name (when base-name
  223. ;; decide if we want to add ext to base-name
  224. (if (and ext (string= "yes" tangle))
  225. (concat base-name "." ext) base-name))))
  226. (when file-name
  227. ;; Possibly create the parent directories for file.
  228. (let ((m (funcall get-spec :mkdirp))
  229. (fnd (file-name-directory file-name)))
  230. (and m fnd (not (string= m "no"))
  231. (make-directory fnd 'parents)))
  232. ;; delete any old versions of file
  233. (and (file-exists-p file-name)
  234. (not (member file-name (mapcar #'car path-collector)))
  235. (delete-file file-name))
  236. ;; drop source-block to file
  237. (with-temp-buffer
  238. (when (fboundp lang-f) (ignore-errors (funcall lang-f)))
  239. (when (and she-bang (not (member file-name she-banged)))
  240. (insert (concat she-bang "\n"))
  241. (setq she-banged (cons file-name she-banged)))
  242. (org-babel-spec-to-string spec)
  243. ;; We avoid append-to-file as it does not work with tramp.
  244. (let ((content (buffer-string)))
  245. (with-temp-buffer
  246. (if (file-exists-p file-name)
  247. (insert-file-contents file-name))
  248. (goto-char (point-max))
  249. ;; Handle :padlines unless first line in file
  250. (unless (or (string= "no" (cdr (assoc :padline (nth 4 spec))))
  251. (= (point) (point-min)))
  252. (insert "\n"))
  253. (insert content)
  254. (write-region nil nil file-name))))
  255. ;; if files contain she-bangs, then make the executable
  256. (when she-bang
  257. (unless tangle-mode (setq tangle-mode #o755)))
  258. ;; update counter
  259. (setq block-counter (+ 1 block-counter))
  260. (add-to-list 'path-collector
  261. (cons file-name tangle-mode)
  262. nil
  263. (lambda (a b) (equal (car a) (car b))))))))
  264. specs)))
  265. (if (equal arg '(4))
  266. (org-babel-tangle-single-block 1 t)
  267. (org-babel-tangle-collect-blocks lang tangle-file)))
  268. (message "Tangled %d code block%s from %s" block-counter
  269. (if (= block-counter 1) "" "s")
  270. (file-name-nondirectory
  271. (buffer-file-name
  272. (or (buffer-base-buffer) (current-buffer)))))
  273. ;; run `org-babel-post-tangle-hook' in all tangled files
  274. (when org-babel-post-tangle-hook
  275. (mapc
  276. (lambda (file)
  277. (org-babel-with-temp-filebuffer file
  278. (run-hooks 'org-babel-post-tangle-hook)))
  279. (mapcar #'car path-collector)))
  280. ;; set permissions on tangled files
  281. (mapc (lambda (pair)
  282. (when (cdr pair) (set-file-modes (car pair) (cdr pair))))
  283. path-collector)
  284. (mapcar #'car path-collector)))))
  285. (defun org-babel-tangle-clean ()
  286. "Remove comments inserted by `org-babel-tangle'.
  287. Call this function inside of a source-code file generated by
  288. `org-babel-tangle' to remove all comments inserted automatically
  289. by `org-babel-tangle'. Warning, this comment removes any lines
  290. containing constructs which resemble org-mode file links or noweb
  291. references."
  292. (interactive)
  293. (goto-char (point-min))
  294. (while (or (re-search-forward "\\[\\[file:.*\\]\\[.*\\]\\]" nil t)
  295. (re-search-forward (org-babel-noweb-wrap) nil t))
  296. (delete-region (save-excursion (beginning-of-line 1) (point))
  297. (save-excursion (end-of-line 1) (forward-char 1) (point)))))
  298. (defvar org-stored-links)
  299. (defvar org-bracket-link-regexp)
  300. (defun org-babel-spec-to-string (spec)
  301. "Insert SPEC into the current file.
  302. Insert the source-code specified by SPEC into the current source
  303. code file. This function uses `comment-region' which assumes
  304. that the appropriate major-mode is set. SPEC has the form:
  305. (start-line file link source-name params body comment)"
  306. (let* ((start-line (nth 0 spec))
  307. (file (if org-babel-tangle-use-relative-file-links
  308. (file-relative-name (nth 1 spec))
  309. (nth 1 spec)))
  310. (link (let ((link (nth 2 spec)))
  311. (if org-babel-tangle-use-relative-file-links
  312. (when (string-match "^\\(file:\\|docview:\\)\\(.*\\)" link)
  313. (let* ((type (match-string 1 link))
  314. (path (match-string 2 link))
  315. (origpath path)
  316. (case-fold-search nil))
  317. (setq path (file-relative-name path))
  318. (concat type path)))
  319. link)))
  320. (source-name (nth 3 spec))
  321. (body (nth 5 spec))
  322. (comment (nth 6 spec))
  323. (comments (cdr (assoc :comments (nth 4 spec))))
  324. (link-p (or (string= comments "both") (string= comments "link")
  325. (string= comments "yes") (string= comments "noweb")))
  326. (link-data (mapcar (lambda (el)
  327. (cons (symbol-name el)
  328. (let ((le (eval el)))
  329. (if (stringp le) le (format "%S" le)))))
  330. '(start-line file link source-name)))
  331. (insert-comment (lambda (text)
  332. (when (and comments (not (string= comments "no"))
  333. (> (length text) 0))
  334. (if org-babel-tangle-uncomment-comments
  335. ;; Plain comments: no processing.
  336. (insert text)
  337. ;; Ensure comments are made to be
  338. ;; comments, and add a trailing
  339. ;; newline. Also ignore invisible
  340. ;; characters when commenting.
  341. (comment-region
  342. (point)
  343. (progn (insert (org-no-properties text))
  344. (point)))
  345. (end-of-line)
  346. (insert "\n"))))))
  347. (when comment (funcall insert-comment comment))
  348. (when link-p
  349. (funcall
  350. insert-comment
  351. (org-fill-template org-babel-tangle-comment-format-beg link-data)))
  352. (insert
  353. (format
  354. "%s\n"
  355. (org-unescape-code-in-string
  356. (org-babel-trim body (if org-src-preserve-indentation "[\f\n\r\v]")))))
  357. (when link-p
  358. (funcall
  359. insert-comment
  360. (org-fill-template org-babel-tangle-comment-format-end link-data)))))
  361. (defun org-babel-tangle-collect-blocks (&optional language tangle-file)
  362. "Collect source blocks in the current Org file.
  363. Return an association list of source-code block specifications of
  364. the form used by `org-babel-spec-to-string' grouped by language.
  365. Optional argument LANGUAGE can be used to limit the collected
  366. source code blocks by language. Optional argument TANGLE-FILE
  367. can be used to limit the collected code blocks by target file."
  368. (let ((counter 0) last-heading-pos blocks)
  369. (org-babel-map-src-blocks (buffer-file-name)
  370. (let ((current-heading-pos
  371. (org-with-wide-buffer
  372. (org-with-limited-levels (outline-previous-heading)))))
  373. (cond ((eq last-heading-pos current-heading-pos) (incf counter))
  374. ((= counter 1))
  375. (t (setq counter 1))))
  376. (unless (org-in-commented-heading-p)
  377. (let* ((info (org-babel-get-src-block-info 'light))
  378. (src-lang (nth 0 info))
  379. (src-tfile (cdr (assq :tangle (nth 2 info)))))
  380. (unless (or (string= (cdr (assq :tangle (nth 2 info))) "no")
  381. (and tangle-file (not (equal tangle-file src-tfile)))
  382. (and language (not (string= language src-lang))))
  383. ;; Add the spec for this block to blocks under its
  384. ;; language.
  385. (let ((by-lang (assoc src-lang blocks))
  386. (block (org-babel-tangle-single-block counter)))
  387. (if by-lang (setcdr by-lang (cons block (cdr by-lang)))
  388. (push (cons src-lang (list block)) blocks)))))))
  389. ;; Ensure blocks are in the correct order.
  390. (mapcar (lambda (b) (cons (car b) (nreverse (cdr b)))) blocks)))
  391. (defun org-babel-tangle-single-block
  392. (block-counter &optional only-this-block)
  393. "Collect the tangled source for current block.
  394. Return the list of block attributes needed by
  395. `org-babel-tangle-collect-blocks'.
  396. When ONLY-THIS-BLOCK is non-nil, return the full association
  397. list to be used by `org-babel-tangle' directly."
  398. (let* ((info (org-babel-get-src-block-info))
  399. (start-line
  400. (save-restriction (widen)
  401. (+ 1 (line-number-at-pos (point)))))
  402. (file (buffer-file-name (buffer-base-buffer)))
  403. (src-lang (nth 0 info))
  404. (params (nth 2 info))
  405. (extra (nth 3 info))
  406. (cref-fmt (or (and (string-match "-l \"\\(.+\\)\"" extra)
  407. (match-string 1 extra))
  408. org-coderef-label-format))
  409. (link (let ((link (org-no-properties
  410. (org-store-link nil))))
  411. (and (string-match org-bracket-link-regexp link)
  412. (match-string 1 link))))
  413. (source-name
  414. (intern (or (nth 4 info)
  415. (format "%s:%d"
  416. (or (ignore-errors (nth 4 (org-heading-components)))
  417. "No heading")
  418. block-counter))))
  419. (expand-cmd
  420. (intern (concat "org-babel-expand-body:" src-lang)))
  421. (assignments-cmd
  422. (intern (concat "org-babel-variable-assignments:" src-lang)))
  423. (body
  424. ;; Run the tangle-body-hook.
  425. (let* ((body ;; Expand the body in language specific manner.
  426. (if (org-babel-noweb-p params :tangle)
  427. (org-babel-expand-noweb-references info)
  428. (nth 1 info)))
  429. (body
  430. (if (assoc :no-expand params)
  431. body
  432. (if (fboundp expand-cmd)
  433. (funcall expand-cmd body params)
  434. (org-babel-expand-body:generic
  435. body params
  436. (and (fboundp assignments-cmd)
  437. (funcall assignments-cmd params)))))))
  438. (with-temp-buffer
  439. (insert body)
  440. (when (string-match "-r" extra)
  441. (goto-char (point-min))
  442. (while (re-search-forward
  443. (replace-regexp-in-string "%s" ".+" cref-fmt) nil t)
  444. (replace-match "")))
  445. (run-hooks 'org-babel-tangle-body-hook)
  446. (buffer-string))))
  447. (comment
  448. (when (or (string= "both" (cdr (assoc :comments params)))
  449. (string= "org" (cdr (assoc :comments params))))
  450. ;; From the previous heading or code-block end
  451. (funcall
  452. org-babel-process-comment-text
  453. (buffer-substring
  454. (max (condition-case nil
  455. (save-excursion
  456. (org-back-to-heading t) ; Sets match data
  457. (match-end 0))
  458. (error (point-min)))
  459. (save-excursion
  460. (if (re-search-backward
  461. org-babel-src-block-regexp nil t)
  462. (match-end 0)
  463. (point-min))))
  464. (point)))))
  465. (result
  466. (list start-line file link source-name params body comment)))
  467. (if only-this-block
  468. (list (cons src-lang (list result)))
  469. result)))
  470. (defun org-babel-tangle-comment-links ( &optional info)
  471. "Return a list of begin and end link comments for the code block at point."
  472. (let* ((start-line (org-babel-where-is-src-block-head))
  473. (file (buffer-file-name))
  474. (link (org-link-escape (progn (call-interactively 'org-store-link)
  475. (org-no-properties
  476. (car (pop org-stored-links))))))
  477. (source-name (nth 4 (or info (org-babel-get-src-block-info 'light))))
  478. (link-data (mapcar (lambda (el)
  479. (cons (symbol-name el)
  480. (let ((le (eval el)))
  481. (if (stringp le) le (format "%S" le)))))
  482. '(start-line file link source-name))))
  483. (list (org-fill-template org-babel-tangle-comment-format-beg link-data)
  484. (org-fill-template org-babel-tangle-comment-format-end link-data))))
  485. ;; de-tangling functions
  486. (defvar org-bracket-link-analytic-regexp)
  487. (defun org-babel-detangle (&optional source-code-file)
  488. "Propagate changes in source file back original to Org-mode file.
  489. This requires that code blocks were tangled with link comments
  490. which enable the original code blocks to be found."
  491. (interactive)
  492. (save-excursion
  493. (when source-code-file (find-file source-code-file))
  494. (goto-char (point-min))
  495. (let ((counter 0) new-body end)
  496. (while (re-search-forward org-bracket-link-analytic-regexp nil t)
  497. (when (re-search-forward
  498. (concat " " (regexp-quote (match-string 5)) " ends here"))
  499. (setq end (match-end 0))
  500. (forward-line -1)
  501. (save-excursion
  502. (when (setq new-body (org-babel-tangle-jump-to-org))
  503. (org-babel-update-block-body new-body)))
  504. (setq counter (+ 1 counter)))
  505. (goto-char end))
  506. (prog1 counter (message "Detangled %d code blocks" counter)))))
  507. (defun org-babel-tangle-jump-to-org ()
  508. "Jump from a tangled code file to the related Org-mode file."
  509. (interactive)
  510. (let ((mid (point))
  511. start body-start end done
  512. target-buffer target-char link path block-name body)
  513. (save-window-excursion
  514. (save-excursion
  515. (while (and (re-search-backward org-bracket-link-analytic-regexp nil t)
  516. (not ; ever wider searches until matching block comments
  517. (and (setq start (point-at-eol))
  518. (setq body-start (save-excursion
  519. (forward-line 2) (point-at-bol)))
  520. (setq link (match-string 0))
  521. (setq path (match-string 3))
  522. (setq block-name (match-string 5))
  523. (save-excursion
  524. (save-match-data
  525. (re-search-forward
  526. (concat " " (regexp-quote block-name)
  527. " ends here") nil t)
  528. (setq end (point-at-bol))))))))
  529. (unless (and start (< start mid) (< mid end))
  530. (error "Not in tangled code"))
  531. (setq body (org-babel-trim (buffer-substring start end))))
  532. (when (string-match "::" path)
  533. (setq path (substring path 0 (match-beginning 0))))
  534. (find-file path) (setq target-buffer (current-buffer))
  535. (goto-char start) (org-open-link-from-string link)
  536. (if (string-match "[^ \t\n\r]:\\([[:digit:]]+\\)" block-name)
  537. (org-babel-next-src-block
  538. (string-to-number (match-string 1 block-name)))
  539. (org-babel-goto-named-src-block block-name))
  540. ;; position at the beginning of the code block body
  541. (goto-char (org-babel-where-is-src-block-head))
  542. (forward-line 1)
  543. ;; Use org-edit-special to isolate the code.
  544. (org-edit-special)
  545. ;; Then move forward the correct number of characters in the
  546. ;; code buffer.
  547. (forward-char (- mid body-start))
  548. ;; And return to the Org-mode buffer with the point in the right
  549. ;; place.
  550. (org-edit-src-exit)
  551. (setq target-char (point)))
  552. (org-src-switch-to-buffer target-buffer t)
  553. (prog1 body (goto-char target-char))))
  554. (provide 'ob-tangle)
  555. ;; Local variables:
  556. ;; generated-autoload-file: "org-loaddefs.el"
  557. ;; End:
  558. ;;; ob-tangle.el ends here