ob-latex.el 8.3 KB

123456789101112131415161718192021222324252627282930313233343536373839404142434445464748495051525354555657585960616263646566676869707172737475767778798081828384858687888990919293949596979899100101102103104105106107108109110111112113114115116117118119120121122123124125126127128129130131132133134135136137138139140141142143144145146147148149150151152153154155156157158159160161162163164165166167168169170171172173174175176177178179180181182183184185186187188189190191192193194195196197198199200201202203204205206207208209210211212213214215216217218219220221222
  1. ;;; ob-latex.el --- Babel Functions for LaTeX -*- lexical-binding: t; -*-
  2. ;; Copyright (C) 2009-2015 Free Software Foundation, Inc.
  3. ;; Author: Eric Schulte
  4. ;; Keywords: literate programming, reproducible research
  5. ;; Homepage: http://orgmode.org
  6. ;; This file is part of GNU Emacs.
  7. ;; GNU Emacs is free software: you can redistribute it and/or modify
  8. ;; it under the terms of the GNU General Public License as published by
  9. ;; the Free Software Foundation, either version 3 of the License, or
  10. ;; (at your option) any later version.
  11. ;; GNU Emacs is distributed in the hope that it will be useful,
  12. ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  13. ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  14. ;; GNU General Public License for more details.
  15. ;; You should have received a copy of the GNU General Public License
  16. ;; along with GNU Emacs. If not, see <http://www.gnu.org/licenses/>.
  17. ;;; Commentary:
  18. ;; Org-Babel support for evaluating LaTeX source code.
  19. ;;
  20. ;; Currently on evaluation this returns raw LaTeX code, unless a :file
  21. ;; header argument is given in which case small png or pdf files will
  22. ;; be created directly form the latex source code.
  23. ;;; Code:
  24. (require 'ob)
  25. (declare-function org-create-formula-image "org" (string tofile options buffer))
  26. (declare-function org-splice-latex-header "org"
  27. (tpl def-pkg pkg snippets-p &optional extra))
  28. (declare-function org-latex-guess-inputenc "ox-latex" (header))
  29. (declare-function org-latex-compile "ox-latex" (file))
  30. (defvar org-babel-tangle-lang-exts)
  31. (add-to-list 'org-babel-tangle-lang-exts '("latex" . "tex"))
  32. (defvar org-format-latex-header) ; From org.el
  33. (defvar org-format-latex-options) ; From org.el
  34. (defvar org-latex-default-packages-alist) ; From org.el
  35. (defvar org-latex-packages-alist) ; From org.el
  36. (defvar org-babel-default-header-args:latex
  37. '((:results . "latex") (:exports . "results"))
  38. "Default arguments to use when evaluating a LaTeX source block.")
  39. (defconst org-babel-header-args:latex
  40. '((border . :any)
  41. (fit . :any)
  42. (iminoptions . :any)
  43. (imoutoptions . :any)
  44. (packages . :any)
  45. (pdfheight . :any)
  46. (pdfpng . :any)
  47. (pdfwidth . :any))
  48. "LaTeX-specific header arguments.")
  49. (defcustom org-babel-latex-htlatex "htlatex"
  50. "The htlatex command to enable conversion of latex to SVG or HTML."
  51. :group 'org-babel
  52. :type 'string)
  53. (defcustom org-babel-latex-htlatex-packages
  54. '("[usenames]{color}" "{tikz}" "{color}" "{listings}" "{amsmath}")
  55. "Packages to use for htlatex export."
  56. :group 'org-babel
  57. :type '(repeat (string)))
  58. (defun org-babel-expand-body:latex (body params)
  59. "Expand BODY according to PARAMS, return the expanded body."
  60. (mapc (lambda (pair) ;; replace variables
  61. (setq body
  62. (replace-regexp-in-string
  63. (regexp-quote (format "%S" (car pair)))
  64. (if (stringp (cdr pair))
  65. (cdr pair) (format "%S" (cdr pair)))
  66. body))) (mapcar #'cdr (org-babel-get-header params :var)))
  67. (org-babel-trim body))
  68. (defun org-babel-execute:latex (body params)
  69. "Execute a block of Latex code with Babel.
  70. This function is called by `org-babel-execute-src-block'."
  71. (setq body (org-babel-expand-body:latex body params))
  72. (if (cdr (assoc :file params))
  73. (let* ((out-file (cdr (assoc :file params)))
  74. (tex-file (org-babel-temp-file "latex-" ".tex"))
  75. (border (cdr (assoc :border params)))
  76. (imagemagick (cdr (assoc :imagemagick params)))
  77. (im-in-options (cdr (assoc :iminoptions params)))
  78. (im-out-options (cdr (assoc :imoutoptions params)))
  79. (fit (or (cdr (assoc :fit params)) border))
  80. (height (and fit (cdr (assoc :pdfheight params))))
  81. (width (and fit (cdr (assoc :pdfwidth params))))
  82. (headers (cdr (assoc :headers params)))
  83. (in-buffer (not (string= "no" (cdr (assoc :buffer params)))))
  84. (org-latex-packages-alist
  85. (append (cdr (assoc :packages params)) org-latex-packages-alist)))
  86. (cond
  87. ((and (string-match "\\.png$" out-file) (not imagemagick))
  88. (org-create-formula-image
  89. body out-file org-format-latex-options in-buffer))
  90. ((string-match "\\.tikz$" out-file)
  91. (when (file-exists-p out-file) (delete-file out-file))
  92. (with-temp-file out-file
  93. (insert body)))
  94. ((and (or (string-match "\\.svg$" out-file)
  95. (string-match "\\.html$" out-file))
  96. (executable-find org-babel-latex-htlatex))
  97. ;; TODO: this is a very different way of generating the
  98. ;; frame latex document than in the pdf case. Ideally, both
  99. ;; would be unified. This would prevent bugs creeping in
  100. ;; such as the one fixed on Aug 16 2014 whereby :headers was
  101. ;; not included in the SVG/HTML case.
  102. (with-temp-file tex-file
  103. (insert (concat
  104. "\\documentclass[preview]{standalone}
  105. \\def\\pgfsysdriver{pgfsys-tex4ht.def}
  106. "
  107. (mapconcat (lambda (pkg)
  108. (concat "\\usepackage" pkg))
  109. org-babel-latex-htlatex-packages
  110. "\n")
  111. (if headers
  112. (concat "\n"
  113. (if (listp headers)
  114. (mapconcat #'identity headers "\n")
  115. headers) "\n")
  116. "")
  117. "\\begin{document}"
  118. body
  119. "\\end{document}")))
  120. (when (file-exists-p out-file) (delete-file out-file))
  121. (let ((default-directory (file-name-directory tex-file)))
  122. (shell-command (format "%s %s" org-babel-latex-htlatex tex-file)))
  123. (cond
  124. ((file-exists-p (concat (file-name-sans-extension tex-file) "-1.svg"))
  125. (if (string-match "\\.svg$" out-file)
  126. (progn
  127. (shell-command "pwd")
  128. (shell-command (format "mv %s %s"
  129. (concat (file-name-sans-extension tex-file) "-1.svg")
  130. out-file)))
  131. (error "SVG file produced but HTML file requested")))
  132. ((file-exists-p (concat (file-name-sans-extension tex-file) ".html"))
  133. (if (string-match "\\.html$" out-file)
  134. (shell-command "mv %s %s"
  135. (concat (file-name-sans-extension tex-file)
  136. ".html")
  137. out-file)
  138. (error "HTML file produced but SVG file requested")))))
  139. ((or (string-match "\\.pdf$" out-file) imagemagick)
  140. (with-temp-file tex-file
  141. (require 'ox-latex)
  142. (insert
  143. (org-latex-guess-inputenc
  144. (org-splice-latex-header
  145. org-format-latex-header
  146. (delq
  147. nil
  148. (mapcar
  149. (lambda (el)
  150. (unless (and (listp el) (string= "hyperref" (cadr el)))
  151. el))
  152. org-latex-default-packages-alist))
  153. org-latex-packages-alist
  154. nil))
  155. (if fit "\n\\usepackage[active, tightpage]{preview}\n" "")
  156. (if border (format "\\setlength{\\PreviewBorder}{%s}" border) "")
  157. (if height (concat "\n" (format "\\pdfpageheight %s" height)) "")
  158. (if width (concat "\n" (format "\\pdfpagewidth %s" width)) "")
  159. (if headers
  160. (concat "\n"
  161. (if (listp headers)
  162. (mapconcat #'identity headers "\n")
  163. headers) "\n")
  164. "")
  165. (if fit
  166. (concat "\n\\begin{document}\n\\begin{preview}\n" body
  167. "\n\\end{preview}\n\\end{document}\n")
  168. (concat "\n\\begin{document}\n" body "\n\\end{document}\n"))))
  169. (when (file-exists-p out-file) (delete-file out-file))
  170. (let ((transient-pdf-file (org-babel-latex-tex-to-pdf tex-file)))
  171. (cond
  172. ((string-match "\\.pdf$" out-file)
  173. (rename-file transient-pdf-file out-file))
  174. (imagemagick
  175. (org-babel-latex-convert-pdf
  176. transient-pdf-file out-file im-in-options im-out-options)
  177. (when (file-exists-p transient-pdf-file)
  178. (delete-file transient-pdf-file))))))
  179. ((string-match "\\.\\([^\\.]+\\)$" out-file)
  180. (error "Can not create %s files, please specify a .png or .pdf file or try the :imagemagick header argument"
  181. (match-string 1 out-file))))
  182. nil) ;; signal that output has already been written to file
  183. body))
  184. (defun org-babel-latex-convert-pdf (pdffile out-file im-in-options im-out-options)
  185. "Generate a file from a pdf file using imagemagick."
  186. (let ((cmd (concat "convert " im-in-options " " pdffile " "
  187. im-out-options " " out-file)))
  188. (message "Converting pdffile file %s..." cmd)
  189. (shell-command cmd)))
  190. (defun org-babel-latex-tex-to-pdf (file)
  191. "Generate a pdf file according to the contents FILE."
  192. (require 'ox-latex)
  193. (org-latex-compile file))
  194. (defun org-babel-prep-session:latex (_session _params)
  195. "Return an error because LaTeX doesn't support sessions."
  196. (error "LaTeX does not support sessions"))
  197. (provide 'ob-latex)
  198. ;;; ob-latex.el ends here