ob-haskell.el 8.6 KB

123456789101112131415161718192021222324252627282930313233343536373839404142434445464748495051525354555657585960616263646566676869707172737475767778798081828384858687888990919293949596979899100101102103104105106107108109110111112113114115116117118119120121122123124125126127128129130131132133134135136137138139140141142143144145146147148149150151152153154155156157158159160161162163164165166167168169170171172173174175176177178179180181182183184185186187188189190191192193194195196197198199200201202203204205206207208209210211212213214215216217218219
  1. ;;; ob-haskell.el --- Babel Functions for Haskell -*- lexical-binding: t; -*-
  2. ;; Copyright (C) 2009-2015 Free Software Foundation, Inc.
  3. ;; Author: Eric Schulte
  4. ;; Keywords: literate programming, reproducible research
  5. ;; Homepage: http://orgmode.org
  6. ;; This file is part of GNU Emacs.
  7. ;; GNU Emacs is free software: you can redistribute it and/or modify
  8. ;; it under the terms of the GNU General Public License as published by
  9. ;; the Free Software Foundation, either version 3 of the License, or
  10. ;; (at your option) any later version.
  11. ;; GNU Emacs is distributed in the hope that it will be useful,
  12. ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  13. ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  14. ;; GNU General Public License for more details.
  15. ;; You should have received a copy of the GNU General Public License
  16. ;; along with GNU Emacs. If not, see <http://www.gnu.org/licenses/>.
  17. ;;; Commentary:
  18. ;; Org-Babel support for evaluating haskell source code. This one will
  19. ;; be sort of tricky because haskell programs must be compiled before
  20. ;; they can be run, but haskell code can also be run through an
  21. ;; interactive interpreter.
  22. ;;
  23. ;; For now lets only allow evaluation using the haskell interpreter.
  24. ;;; Requirements:
  25. ;; - haskell-mode :: http://www.iro.umontreal.ca/~monnier/elisp/#haskell-mode
  26. ;;
  27. ;; - inf-haskell :: http://www.iro.umontreal.ca/~monnier/elisp/#haskell-mode
  28. ;;
  29. ;; - (optionally) lhs2tex :: http://people.cs.uu.nl/andres/lhs2tex/
  30. ;;; Code:
  31. (require 'ob)
  32. (require 'comint)
  33. (eval-when-compile (require 'cl))
  34. (declare-function org-remove-indentation "org" (code &optional n))
  35. (declare-function haskell-mode "ext:haskell-mode" ())
  36. (declare-function run-haskell "ext:inf-haskell" (&optional arg))
  37. (declare-function inferior-haskell-load-file
  38. "ext:inf-haskell" (&optional reload))
  39. (defvar org-babel-tangle-lang-exts)
  40. (add-to-list 'org-babel-tangle-lang-exts '("haskell" . "hs"))
  41. (defvar org-babel-default-header-args:haskell
  42. '((:padlines . "no")))
  43. (defvar org-babel-haskell-lhs2tex-command "lhs2tex")
  44. (defvar org-babel-haskell-eoe "\"org-babel-haskell-eoe\"")
  45. (defun org-babel-execute:haskell (body params)
  46. "Execute a block of Haskell code."
  47. (let* ((session (cdr (assoc :session params)))
  48. (result-type (cdr (assoc :result-type params)))
  49. (full-body (org-babel-expand-body:generic
  50. body params
  51. (org-babel-variable-assignments:haskell params)))
  52. (session (org-babel-haskell-initiate-session session params))
  53. (raw (org-babel-comint-with-output
  54. (session org-babel-haskell-eoe t full-body)
  55. (insert (org-babel-trim full-body))
  56. (comint-send-input nil t)
  57. (insert org-babel-haskell-eoe)
  58. (comint-send-input nil t)))
  59. (results (mapcar
  60. #'org-babel-haskell-read-string
  61. (cdr (member org-babel-haskell-eoe
  62. (reverse (mapcar #'org-babel-trim raw)))))))
  63. (org-babel-reassemble-table
  64. (let ((result
  65. (case result-type
  66. (output (mapconcat #'identity (reverse (cdr results)) "\n"))
  67. (value (car results)))))
  68. (org-babel-result-cond (cdr (assoc :result-params params))
  69. result (org-babel-script-escape result)))
  70. (org-babel-pick-name (cdr (assoc :colname-names params))
  71. (cdr (assoc :colname-names params)))
  72. (org-babel-pick-name (cdr (assoc :rowname-names params))
  73. (cdr (assoc :rowname-names params))))))
  74. (defun org-babel-haskell-read-string (string)
  75. "Strip \\\"s from around a haskell string."
  76. (if (string-match "^\"\\([^\000]+\\)\"$" string)
  77. (match-string 1 string)
  78. string))
  79. (defun org-babel-haskell-initiate-session (&optional _session _params)
  80. "Initiate a haskell session.
  81. If there is not a current inferior-process-buffer in SESSION
  82. then create one. Return the initialized session."
  83. (require 'inf-haskell)
  84. (or (get-buffer "*haskell*")
  85. (save-window-excursion (run-haskell) (sleep-for 0.25) (current-buffer))))
  86. (defun org-babel-load-session:haskell (session body params)
  87. "Load BODY into SESSION."
  88. (save-window-excursion
  89. (let* ((buffer (org-babel-prep-session:haskell session params))
  90. (load-file (concat (org-babel-temp-file "haskell-load-") ".hs")))
  91. (with-temp-buffer
  92. (insert body) (write-file load-file)
  93. (haskell-mode) (inferior-haskell-load-file))
  94. buffer)))
  95. (defun org-babel-prep-session:haskell (session params)
  96. "Prepare SESSION according to the header arguments in PARAMS."
  97. (save-window-excursion
  98. (let ((buffer (org-babel-haskell-initiate-session session)))
  99. (org-babel-comint-in-buffer buffer
  100. (mapc (lambda (line)
  101. (insert line)
  102. (comint-send-input nil t))
  103. (org-babel-variable-assignments:haskell params)))
  104. (current-buffer))))
  105. (defun org-babel-variable-assignments:haskell (params)
  106. "Return list of haskell statements assigning the block's variables."
  107. (mapcar (lambda (pair)
  108. (format "let %s = %s"
  109. (car pair)
  110. (org-babel-haskell-var-to-haskell (cdr pair))))
  111. (mapcar #'cdr (org-babel-get-header params :var))))
  112. (defun org-babel-haskell-var-to-haskell (var)
  113. "Convert an elisp value VAR into a haskell variable.
  114. The elisp VAR is converted to a string of haskell source code
  115. specifying a variable of the same value."
  116. (if (listp var)
  117. (concat "[" (mapconcat #'org-babel-haskell-var-to-haskell var ", ") "]")
  118. (format "%S" var)))
  119. (defvar org-export-copy-to-kill-ring)
  120. (declare-function org-export-to-file "ox"
  121. (backend file
  122. &optional async subtreep visible-only body-only ext-plist))
  123. (defun org-babel-haskell-export-to-lhs (&optional arg)
  124. "Export to a .lhs file with all haskell code blocks escaped.
  125. When called with a prefix argument the resulting
  126. .lhs file will be exported to a .tex file. This function will
  127. create two new files, base-name.lhs and base-name.tex where
  128. base-name is the name of the current org-mode file.
  129. Note that all standard Babel literate programming
  130. constructs (header arguments, no-web syntax etc...) are ignored."
  131. (interactive "P")
  132. (let* ((contents (buffer-string))
  133. (haskell-regexp
  134. (concat "^\\([ \t]*\\)#\\+begin_src[ \t]haskell*\\(.*\\)?[\r\n]"
  135. "\\([^\000]*?\\)[\r\n][ \t]*#\\+end_src.*"))
  136. (base-name (file-name-sans-extension (buffer-file-name)))
  137. (tmp-file (org-babel-temp-file "haskell-"))
  138. (tmp-org-file (concat tmp-file ".org"))
  139. (tmp-tex-file (concat tmp-file ".tex"))
  140. (lhs-file (concat base-name ".lhs"))
  141. (tex-file (concat base-name ".tex"))
  142. (command (concat org-babel-haskell-lhs2tex-command
  143. " " (org-babel-process-file-name lhs-file)
  144. " > " (org-babel-process-file-name tex-file)))
  145. (preserve-indentp org-src-preserve-indentation)
  146. indentation)
  147. ;; escape haskell source-code blocks
  148. (with-temp-file tmp-org-file
  149. (insert contents)
  150. (goto-char (point-min))
  151. (while (re-search-forward haskell-regexp nil t)
  152. (save-match-data (setq indentation (length (match-string 1))))
  153. (replace-match (save-match-data
  154. (concat
  155. "#+begin_latex\n\\begin{code}\n"
  156. (if (or preserve-indentp
  157. (string-match "-i" (match-string 2)))
  158. (match-string 3)
  159. (org-remove-indentation (match-string 3)))
  160. "\n\\end{code}\n#+end_latex\n"))
  161. t t)
  162. (indent-code-rigidly (match-beginning 0) (match-end 0) indentation)))
  163. (save-excursion
  164. ;; export to latex w/org and save as .lhs
  165. (require 'ox-latex)
  166. (find-file tmp-org-file)
  167. ;; Ensure we do not clutter kill ring with incomplete results.
  168. (let (org-export-copy-to-kill-ring)
  169. (org-export-to-file 'latex tmp-tex-file))
  170. (kill-buffer nil)
  171. (delete-file tmp-org-file)
  172. (find-file tmp-tex-file)
  173. (goto-char (point-min)) (forward-line 2)
  174. (insert "%include polycode.fmt\n")
  175. ;; ensure all \begin/end{code} statements start at the first column
  176. (while (re-search-forward "^[ \t]+\\\\begin{code}[^\000]+\\\\end{code}" nil t)
  177. (replace-match (save-match-data (org-remove-indentation (match-string 0)))
  178. t t))
  179. (setq contents (buffer-string))
  180. (save-buffer) (kill-buffer nil))
  181. (delete-file tmp-tex-file)
  182. ;; save org exported latex to a .lhs file
  183. (with-temp-file lhs-file (insert contents))
  184. (if (not arg)
  185. (find-file lhs-file)
  186. ;; process .lhs file with lhs2tex
  187. (message "running %s" command) (shell-command command) (find-file tex-file))))
  188. (provide 'ob-haskell)
  189. ;;; ob-haskell.el ends here