ox-texinfo.el 60 KB

123456789101112131415161718192021222324252627282930313233343536373839404142434445464748495051525354555657585960616263646566676869707172737475767778798081828384858687888990919293949596979899100101102103104105106107108109110111112113114115116117118119120121122123124125126127128129130131132133134135136137138139140141142143144145146147148149150151152153154155156157158159160161162163164165166167168169170171172173174175176177178179180181182183184185186187188189190191192193194195196197198199200201202203204205206207208209210211212213214215216217218219220221222223224225226227228229230231232233234235236237238239240241242243244245246247248249250251252253254255256257258259260261262263264265266267268269270271272273274275276277278279280281282283284285286287288289290291292293294295296297298299300301302303304305306307308309310311312313314315316317318319320321322323324325326327328329330331332333334335336337338339340341342343344345346347348349350351352353354355356357358359360361362363364365366367368369370371372373374375376377378379380381382383384385386387388389390391392393394395396397398399400401402403404405406407408409410411412413414415416417418419420421422423424425426427428429430431432433434435436437438439440441442443444445446447448449450451452453454455456457458459460461462463464465466467468469470471472473474475476477478479480481482483484485486487488489490491492493494495496497498499500501502503504505506507508509510511512513514515516517518519520521522523524525526527528529530531532533534535536537538539540541542543544545546547548549550551552553554555556557558559560561562563564565566567568569570571572573574575576577578579580581582583584585586587588589590591592593594595596597598599600601602603604605606607608609610611612613614615616617618619620621622623624625626627628629630631632633634635636637638639640641642643644645646647648649650651652653654655656657658659660661662663664665666667668669670671672673674675676677678679680681682683684685686687688689690691692693694695696697698699700701702703704705706707708709710711712713714715716717718719720721722723724725726727728729730731732733734735736737738739740741742743744745746747748749750751752753754755756757758759760761762763764765766767768769770771772773774775776777778779780781782783784785786787788789790791792793794795796797798799800801802803804805806807808809810811812813814815816817818819820821822823824825826827828829830831832833834835836837838839840841842843844845846847848849850851852853854855856857858859860861862863864865866867868869870871872873874875876877878879880881882883884885886887888889890891892893894895896897898899900901902903904905906907908909910911912913914915916917918919920921922923924925926927928929930931932933934935936937938939940941942943944945946947948949950951952953954955956957958959960961962963964965966967968969970971972973974975976977978979980981982983984985986987988989990991992993994995996997998999100010011002100310041005100610071008100910101011101210131014101510161017101810191020102110221023102410251026102710281029103010311032103310341035103610371038103910401041104210431044104510461047104810491050105110521053105410551056105710581059106010611062106310641065106610671068106910701071107210731074107510761077107810791080108110821083108410851086108710881089109010911092109310941095109610971098109911001101110211031104110511061107110811091110111111121113111411151116111711181119112011211122112311241125112611271128112911301131113211331134113511361137113811391140114111421143114411451146114711481149115011511152115311541155115611571158115911601161116211631164116511661167116811691170117111721173117411751176117711781179118011811182118311841185118611871188118911901191119211931194119511961197119811991200120112021203120412051206120712081209121012111212121312141215121612171218121912201221122212231224122512261227122812291230123112321233123412351236123712381239124012411242124312441245124612471248124912501251125212531254125512561257125812591260126112621263126412651266126712681269127012711272127312741275127612771278127912801281128212831284128512861287128812891290129112921293129412951296129712981299130013011302130313041305130613071308130913101311131213131314131513161317131813191320132113221323132413251326132713281329133013311332133313341335133613371338133913401341134213431344134513461347134813491350135113521353135413551356135713581359136013611362136313641365136613671368136913701371137213731374137513761377137813791380138113821383138413851386138713881389139013911392139313941395139613971398139914001401140214031404140514061407140814091410141114121413141414151416141714181419142014211422142314241425142614271428142914301431143214331434143514361437143814391440144114421443144414451446144714481449145014511452145314541455145614571458145914601461146214631464146514661467146814691470147114721473147414751476147714781479148014811482148314841485148614871488148914901491149214931494149514961497149814991500150115021503150415051506150715081509151015111512151315141515151615171518151915201521152215231524152515261527152815291530153115321533153415351536153715381539154015411542154315441545154615471548154915501551155215531554155515561557155815591560156115621563156415651566156715681569157015711572157315741575157615771578157915801581158215831584158515861587158815891590159115921593159415951596159715981599160016011602160316041605160616071608160916101611161216131614161516161617161816191620162116221623162416251626162716281629163016311632163316341635163616371638163916401641164216431644164516461647164816491650165116521653165416551656165716581659166016611662166316641665166616671668166916701671167216731674167516761677167816791680168116821683168416851686168716881689169016911692169316941695169616971698169917001701
  1. ;;; ox-texinfo.el --- Texinfo Back-End for Org Export Engine -*- lexical-binding: t; -*-
  2. ;; Copyright (C) 2012-2017 Free Software Foundation, Inc.
  3. ;; Author: Jonathan Leech-Pepin <jonathan.leechpepin at gmail dot com>
  4. ;; Keywords: outlines, hypermedia, calendar, wp
  5. ;; This file is part of GNU Emacs.
  6. ;; GNU Emacs is free software: you can redistribute it and/or modify
  7. ;; it under the terms of the GNU General Public License as published by
  8. ;; the Free Software Foundation, either version 3 of the License, or
  9. ;; (at your option) any later version.
  10. ;; GNU Emacs is distributed in the hope that it will be useful,
  11. ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  12. ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  13. ;; GNU General Public License for more details.
  14. ;; You should have received a copy of the GNU General Public License
  15. ;; along with GNU Emacs. If not, see <https://www.gnu.org/licenses/>.
  16. ;;; Commentary:
  17. ;;
  18. ;; See Org manual for details.
  19. ;;; Code:
  20. (require 'cl-lib)
  21. (require 'ox)
  22. (defvar orgtbl-exp-regexp)
  23. ;;; Define Back-End
  24. (org-export-define-backend 'texinfo
  25. '((bold . org-texinfo-bold)
  26. (center-block . org-texinfo-center-block)
  27. (clock . org-texinfo-clock)
  28. (code . org-texinfo-code)
  29. (drawer . org-texinfo-drawer)
  30. (dynamic-block . org-texinfo-dynamic-block)
  31. (entity . org-texinfo-entity)
  32. (example-block . org-texinfo-example-block)
  33. (export-block . org-texinfo-export-block)
  34. (export-snippet . org-texinfo-export-snippet)
  35. (fixed-width . org-texinfo-fixed-width)
  36. (footnote-definition . org-texinfo-footnote-definition)
  37. (footnote-reference . org-texinfo-footnote-reference)
  38. (headline . org-texinfo-headline)
  39. (inline-src-block . org-texinfo-inline-src-block)
  40. (inlinetask . org-texinfo-inlinetask)
  41. (italic . org-texinfo-italic)
  42. (item . org-texinfo-item)
  43. (keyword . org-texinfo-keyword)
  44. (line-break . org-texinfo-line-break)
  45. (link . org-texinfo-link)
  46. (node-property . org-texinfo-node-property)
  47. (paragraph . org-texinfo-paragraph)
  48. (plain-list . org-texinfo-plain-list)
  49. (plain-text . org-texinfo-plain-text)
  50. (planning . org-texinfo-planning)
  51. (property-drawer . org-texinfo-property-drawer)
  52. (quote-block . org-texinfo-quote-block)
  53. (radio-target . org-texinfo-radio-target)
  54. (section . org-texinfo-section)
  55. (special-block . org-texinfo-special-block)
  56. (src-block . org-texinfo-src-block)
  57. (statistics-cookie . org-texinfo-statistics-cookie)
  58. (strike-through . org-texinfo-strike-through)
  59. (subscript . org-texinfo-subscript)
  60. (superscript . org-texinfo-superscript)
  61. (table . org-texinfo-table)
  62. (table-cell . org-texinfo-table-cell)
  63. (table-row . org-texinfo-table-row)
  64. (target . org-texinfo-target)
  65. (template . org-texinfo-template)
  66. (timestamp . org-texinfo-timestamp)
  67. (underline . org-texinfo-underline)
  68. (verbatim . org-texinfo-verbatim)
  69. (verse-block . org-texinfo-verse-block))
  70. :filters-alist
  71. '((:filter-headline . org-texinfo--filter-section-blank-lines)
  72. (:filter-parse-tree . org-texinfo--normalize-headlines)
  73. (:filter-section . org-texinfo--filter-section-blank-lines))
  74. :menu-entry
  75. '(?i "Export to Texinfo"
  76. ((?t "As TEXI file" org-texinfo-export-to-texinfo)
  77. (?i "As INFO file" org-texinfo-export-to-info)
  78. (?o "As INFO file and open"
  79. (lambda (a s v b)
  80. (if a (org-texinfo-export-to-info t s v b)
  81. (org-open-file (org-texinfo-export-to-info nil s v b)))))))
  82. :options-alist
  83. '((:texinfo-filename "TEXINFO_FILENAME" nil nil t)
  84. (:texinfo-class "TEXINFO_CLASS" nil org-texinfo-default-class t)
  85. (:texinfo-header "TEXINFO_HEADER" nil nil newline)
  86. (:texinfo-post-header "TEXINFO_POST_HEADER" nil nil newline)
  87. (:subtitle "SUBTITLE" nil nil parse)
  88. (:subauthor "SUBAUTHOR" nil nil newline)
  89. (:texinfo-dircat "TEXINFO_DIR_CATEGORY" nil nil t)
  90. (:texinfo-dirtitle "TEXINFO_DIR_TITLE" nil nil t)
  91. (:texinfo-dirdesc "TEXINFO_DIR_DESC" nil nil t)
  92. (:texinfo-printed-title "TEXINFO_PRINTED_TITLE" nil nil t)
  93. ;; Other variables.
  94. (:texinfo-classes nil nil org-texinfo-classes)
  95. (:texinfo-format-headline-function nil nil org-texinfo-format-headline-function)
  96. (:texinfo-node-description-column nil nil org-texinfo-node-description-column)
  97. (:texinfo-active-timestamp-format nil nil org-texinfo-active-timestamp-format)
  98. (:texinfo-inactive-timestamp-format nil nil org-texinfo-inactive-timestamp-format)
  99. (:texinfo-diary-timestamp-format nil nil org-texinfo-diary-timestamp-format)
  100. (:texinfo-link-with-unknown-path-format nil nil org-texinfo-link-with-unknown-path-format)
  101. (:texinfo-tables-verbatim nil nil org-texinfo-tables-verbatim)
  102. (:texinfo-table-scientific-notation nil nil org-texinfo-table-scientific-notation)
  103. (:texinfo-table-default-markup nil nil org-texinfo-table-default-markup)
  104. (:texinfo-text-markup-alist nil nil org-texinfo-text-markup-alist)
  105. (:texinfo-format-drawer-function nil nil org-texinfo-format-drawer-function)
  106. (:texinfo-format-inlinetask-function nil nil org-texinfo-format-inlinetask-function)))
  107. ;;; User Configurable Variables
  108. (defgroup org-export-texinfo nil
  109. "Options for exporting Org mode files to Texinfo."
  110. :tag "Org Export Texinfo"
  111. :version "24.4"
  112. :package-version '(Org . "8.0")
  113. :group 'org-export)
  114. ;;;; Preamble
  115. (defcustom org-texinfo-coding-system nil
  116. "Default document encoding for Texinfo output.
  117. If nil it will default to `buffer-file-coding-system'."
  118. :group 'org-export-texinfo
  119. :type 'coding-system)
  120. (defcustom org-texinfo-default-class "info"
  121. "The default Texinfo class."
  122. :group 'org-export-texinfo
  123. :type '(string :tag "Texinfo class"))
  124. (defcustom org-texinfo-classes
  125. '(("info"
  126. "@documentencoding AUTO\n@documentlanguage AUTO"
  127. ("@chapter %s" "@unnumbered %s" "@appendix %s")
  128. ("@section %s" "@unnumberedsec %s" "@appendixsec %s")
  129. ("@subsection %s" "@unnumberedsubsec %s" "@appendixsubsec %s")
  130. ("@subsubsection %s" "@unnumberedsubsubsec %s" "@appendixsubsubsec %s")))
  131. "Alist of Texinfo classes and associated header and structure.
  132. If #+TEXINFO_CLASS is set in the buffer, use its value and the
  133. associated information. Here is the structure of a class
  134. definition:
  135. (class-name
  136. header-string
  137. (numbered-1 unnumbered-1 appendix-1)
  138. (numbered-2 unnumbered-2 appendix-2)
  139. ...)
  140. The header string
  141. -----------------
  142. The header string is inserted in the header of the generated
  143. document, right after \"@setfilename\" and \"@settitle\"
  144. commands.
  145. If it contains the special string
  146. \"@documentencoding AUTO\"
  147. \"AUTO\" will be replaced with an appropriate coding system. See
  148. `org-texinfo-coding-system' for more information. Likewise, if
  149. the string contains the special string
  150. \"@documentlanguage AUTO\"
  151. \"AUTO\" will be replaced with the language defined in the
  152. buffer, through #+LANGUAGE keyword, or globally, with
  153. `org-export-default-language', which see.
  154. The sectioning structure
  155. ------------------------
  156. The sectioning structure of the class is given by the elements
  157. following the header string. For each sectioning level, a number
  158. of strings is specified. A %s formatter is mandatory in each
  159. section string and will be replaced by the title of the section."
  160. :group 'org-export-texinfo
  161. :version "26.1"
  162. :package-version '(Org . "9.1")
  163. :type '(repeat
  164. (list (string :tag "Texinfo class")
  165. (string :tag "Texinfo header")
  166. (repeat :tag "Levels" :inline t
  167. (choice
  168. (list :tag "Heading"
  169. (string :tag " numbered")
  170. (string :tag "unnumbered")
  171. (string :tag " appendix")))))))
  172. ;;;; Headline
  173. (defcustom org-texinfo-format-headline-function
  174. 'org-texinfo-format-headline-default-function
  175. "Function to format headline text.
  176. This function will be called with 5 arguments:
  177. TODO the todo keyword (string or nil).
  178. TODO-TYPE the type of todo (symbol: `todo', `done', nil)
  179. PRIORITY the priority of the headline (integer or nil)
  180. TEXT the main headline text (string).
  181. TAGS the tags as a list of strings (list of strings or nil).
  182. The function result will be used in the section format string."
  183. :group 'org-export-texinfo
  184. :type 'function
  185. :version "26.1"
  186. :package-version '(Org . "8.3"))
  187. ;;;; Node listing (menu)
  188. (defcustom org-texinfo-node-description-column 32
  189. "Column at which to start the description in the node listings.
  190. If a node title is greater than this length, the description will
  191. be placed after the end of the title."
  192. :group 'org-export-texinfo
  193. :type 'integer)
  194. ;;;; Timestamps
  195. (defcustom org-texinfo-active-timestamp-format "@emph{%s}"
  196. "A printf format string to be applied to active timestamps."
  197. :group 'org-export-texinfo
  198. :type 'string)
  199. (defcustom org-texinfo-inactive-timestamp-format "@emph{%s}"
  200. "A printf format string to be applied to inactive timestamps."
  201. :group 'org-export-texinfo
  202. :type 'string)
  203. (defcustom org-texinfo-diary-timestamp-format "@emph{%s}"
  204. "A printf format string to be applied to diary timestamps."
  205. :group 'org-export-texinfo
  206. :type 'string)
  207. ;;;; Links
  208. (defcustom org-texinfo-link-with-unknown-path-format "@indicateurl{%s}"
  209. "Format string for links with unknown path type."
  210. :group 'org-export-texinfo
  211. :type 'string)
  212. ;;;; Tables
  213. (defcustom org-texinfo-tables-verbatim nil
  214. "When non-nil, tables are exported verbatim."
  215. :group 'org-export-texinfo
  216. :type 'boolean)
  217. (defcustom org-texinfo-table-scientific-notation "%s\\,(%s)"
  218. "Format string to display numbers in scientific notation.
  219. The format should have \"%s\" twice, for mantissa and exponent
  220. \(i.e. \"%s\\\\times10^{%s}\").
  221. When nil, no transformation is made."
  222. :group 'org-export-texinfo
  223. :type '(choice
  224. (string :tag "Format string")
  225. (const :tag "No formatting" nil)))
  226. (defcustom org-texinfo-table-default-markup "@asis"
  227. "Default markup for first column in two-column tables.
  228. This should an indicating command, e.g., \"@code\", \"@kbd\" or
  229. \"@samp\".
  230. It can be overridden locally using the \":indic\" attribute."
  231. :group 'org-export-texinfo
  232. :type 'string
  233. :version "26.1"
  234. :package-version '(Org . "9.1")
  235. :safe #'stringp)
  236. ;;;; Text markup
  237. (defcustom org-texinfo-text-markup-alist '((bold . "@strong{%s}")
  238. (code . code)
  239. (italic . "@emph{%s}")
  240. (verbatim . samp))
  241. "Alist of Texinfo expressions to convert text markup.
  242. The key must be a symbol among `bold', `code', `italic',
  243. `strike-through', `underscore' and `verbatim'. The value is
  244. a formatting string to wrap fontified text with.
  245. Value can also be set to the following symbols: `verb', `samp'
  246. and `code'. With the first one, Org uses \"@verb\" to create
  247. a format string and selects a delimiter character that isn't in
  248. the string. For the other two, Org uses \"@samp\" or \"@code\"
  249. to typeset and protects special characters.
  250. When no association is found for a given markup, text is returned
  251. as-is."
  252. :group 'org-export-texinfo
  253. :version "26.1"
  254. :package-version '(Org . "9.1")
  255. :type 'alist
  256. :options '(bold code italic strike-through underscore verbatim))
  257. ;;;; Drawers
  258. (defcustom org-texinfo-format-drawer-function (lambda (_name contents) contents)
  259. "Function called to format a drawer in Texinfo code.
  260. The function must accept two parameters:
  261. NAME the drawer name, like \"LOGBOOK\"
  262. CONTENTS the contents of the drawer.
  263. The function should return the string to be exported.
  264. The default function simply returns the value of CONTENTS."
  265. :group 'org-export-texinfo
  266. :version "24.4"
  267. :package-version '(Org . "8.2")
  268. :type 'function)
  269. ;;;; Inlinetasks
  270. (defcustom org-texinfo-format-inlinetask-function
  271. 'org-texinfo-format-inlinetask-default-function
  272. "Function called to format an inlinetask in Texinfo code.
  273. The function must accept six parameters:
  274. TODO the todo keyword, as a string
  275. TODO-TYPE the todo type, a symbol among `todo', `done' and nil.
  276. PRIORITY the inlinetask priority, as a string
  277. NAME the inlinetask name, as a string.
  278. TAGS the inlinetask tags, as a list of strings.
  279. CONTENTS the contents of the inlinetask, as a string.
  280. The function should return the string to be exported."
  281. :group 'org-export-texinfo
  282. :type 'function)
  283. ;;;; Compilation
  284. (defcustom org-texinfo-info-process '("makeinfo --no-split %f")
  285. "Commands to process a Texinfo file to an INFO file.
  286. This is a list of strings, each of them will be given to the
  287. shell as a command. %f in the command will be replaced by the
  288. relative file name, %F by the absolute file name, %b by the file
  289. base name (i.e. without directory and extension parts), %o by the
  290. base directory of the file and %O by the absolute file name of
  291. the output file."
  292. :group 'org-export-texinfo
  293. :version "26.1"
  294. :package-version '(Org . "9.1")
  295. :type '(repeat :tag "Shell command sequence"
  296. (string :tag "Shell command")))
  297. (defcustom org-texinfo-logfiles-extensions
  298. '("aux" "toc" "cp" "fn" "ky" "pg" "tp" "vr")
  299. "The list of file extensions to consider as Texinfo logfiles.
  300. The logfiles will be remove if `org-texinfo-remove-logfiles' is
  301. non-nil."
  302. :group 'org-export-texinfo
  303. :type '(repeat (string :tag "Extension")))
  304. (defcustom org-texinfo-remove-logfiles t
  305. "Non-nil means remove the logfiles produced by compiling a Texinfo file.
  306. By default, logfiles are files with these extensions: .aux, .toc,
  307. .cp, .fn, .ky, .pg and .tp. To define the set of logfiles to remove,
  308. set `org-texinfo-logfiles-extensions'."
  309. :group 'org-export-latex
  310. :type 'boolean)
  311. ;;; Constants
  312. (defconst org-texinfo-max-toc-depth 4
  313. "Maximum depth for creation of detailed menu listings.
  314. Beyond this depth, Texinfo will not recognize the nodes and will
  315. cause errors. Left as a constant in case this value ever
  316. changes.")
  317. (defconst org-texinfo-supported-coding-systems
  318. '("US-ASCII" "UTF-8" "ISO-8859-15" "ISO-8859-1" "ISO-8859-2" "koi8-r" "koi8-u")
  319. "List of coding systems supported by Texinfo, as strings.
  320. Specified coding system will be matched against these strings.
  321. If two strings share the same prefix (e.g. \"ISO-8859-1\" and
  322. \"ISO-8859-15\"), the most specific one has to be listed first.")
  323. (defconst org-texinfo-inline-image-rules
  324. (list (cons "file"
  325. (regexp-opt '("eps" "pdf" "png" "jpg" "jpeg" "gif" "svg"))))
  326. "Rules characterizing image files that can be inlined.")
  327. ;;; Internal Functions
  328. (defun org-texinfo--filter-section-blank-lines (headline _backend _info)
  329. "Filter controlling number of blank lines after a section."
  330. (replace-regexp-in-string "\n\\(?:\n[ \t]*\\)*\\'" "\n\n" headline))
  331. (defun org-texinfo--normalize-headlines (tree _backend info)
  332. "Normalize headlines in TREE.
  333. BACK-END is the symbol specifying back-end used for export. INFO
  334. is a plist used as a communication channel.
  335. Make sure every headline in TREE contains a section, since those
  336. are required to install a menu. Also put exactly one blank line
  337. at the end of each section.
  338. Return new tree."
  339. (org-element-map tree 'headline
  340. (lambda (hl)
  341. (org-element-put-property hl :post-blank 1)
  342. (let ((contents (org-element-contents hl)))
  343. (when contents
  344. (let ((first (org-element-map contents '(headline section)
  345. #'identity info t)))
  346. (unless (eq (org-element-type first) 'section)
  347. (apply #'org-element-set-contents
  348. hl
  349. (cons `(section (:parent ,hl)) contents)))))))
  350. info)
  351. tree)
  352. (defun org-texinfo--find-verb-separator (s)
  353. "Return a character not used in string S.
  354. This is used to choose a separator for constructs like \\verb."
  355. (let ((ll "~,./?;':\"|!@#%^&-_=+abcdefghijklmnopqrstuvwxyzABCDEFGHIJKLMNOPQRSTUVWXYZ<>()[]{}"))
  356. (cl-loop for c across ll
  357. when (not (string-match (regexp-quote (char-to-string c)) s))
  358. return (char-to-string c))))
  359. (defun org-texinfo--text-markup (text markup _info)
  360. "Format TEXT depending on MARKUP text markup.
  361. INFO is a plist used as a communication channel. See
  362. `org-texinfo-text-markup-alist' for details."
  363. (pcase (cdr (assq markup org-texinfo-text-markup-alist))
  364. (`nil text) ;no markup: return raw text
  365. (`code (format "@code{%s}" (org-texinfo--sanitize-content text)))
  366. (`samp (format "@samp{%s}" (org-texinfo--sanitize-content text)))
  367. (`verb
  368. (let ((separator (org-texinfo--find-verb-separator text)))
  369. (format "@verb{%s%s%s}" separator text separator)))
  370. ;; Else use format string.
  371. (fmt (format fmt text))))
  372. (defun org-texinfo--get-node (datum info)
  373. "Return node or anchor associated to DATUM.
  374. DATUM is an element or object. INFO is a plist used as
  375. a communication channel. The function guarantees the node or
  376. anchor name is unique."
  377. (let ((cache (plist-get info :texinfo-node-cache)))
  378. (or (cdr (assq datum cache))
  379. (let* ((salt 0)
  380. (basename
  381. (org-texinfo--sanitize-node
  382. (if (eq (org-element-type datum) 'headline)
  383. (org-texinfo--sanitize-title
  384. (org-export-get-alt-title datum info) info)
  385. (org-export-get-reference datum info))))
  386. (name basename))
  387. ;; Ensure NAME is unique and not reserved node name "Top".
  388. (while (or (equal name "Top") (rassoc name cache))
  389. (setq name (concat basename (format " %d" (cl-incf salt)))))
  390. (plist-put info :texinfo-node-cache (cons (cons datum name) cache))
  391. name))))
  392. (defun org-texinfo--sanitize-node (title)
  393. "Bend string TITLE to node line requirements.
  394. Trim string and collapse multiple whitespace characters as they
  395. are not significant. Replace leading left parenthesis, when
  396. followed by a right parenthesis, with a square bracket. Remove
  397. periods, commas and colons."
  398. (org-trim
  399. (replace-regexp-in-string
  400. "[ \t]+" " "
  401. (replace-regexp-in-string
  402. "[:,.]" ""
  403. (replace-regexp-in-string "\\`(\\(.*?)\\)" "[\\1" title)))))
  404. (defun org-texinfo--sanitize-title (title info)
  405. "Make TITLE suitable as a section name.
  406. TITLE is a string or a secondary string. INFO is the current
  407. export state, as a plist."
  408. (org-export-data-with-backend
  409. title
  410. (org-export-create-backend
  411. :parent 'texinfo
  412. :transcoders '((footnote-reference . ignore)
  413. (link . (lambda (object c i) c))
  414. (radio-target . (lambda (object c i) c))
  415. (target . ignore)))
  416. info))
  417. (defun org-texinfo--sanitize-content (text)
  418. "Escape special characters in string TEXT.
  419. Special characters are: @ { }"
  420. (replace-regexp-in-string "[@{}]" "@\\&" text))
  421. (defun org-texinfo--wrap-float (value info &optional type label caption short)
  422. "Wrap string VALUE within a @float command.
  423. INFO is the current export state, as a plist. TYPE is float
  424. type, as a string. LABEL is the cross reference label for the
  425. float, as a string. CAPTION and SHORT are, respectively, the
  426. caption and shortcaption used for the float, as secondary
  427. strings (e.g., returned by `org-export-get-caption')."
  428. (let* ((backend
  429. (org-export-create-backend
  430. :parent 'texinfo
  431. :transcoders '((link . (lambda (object c i) c))
  432. (radio-target . (lambda (object c i) c))
  433. (target . ignore))))
  434. (short-backend
  435. (org-export-create-backend
  436. :parent 'texinfo
  437. :transcoders '((footnote-reference . ignore)
  438. (inline-src-block . ignore)
  439. (link . (lambda (object c i) c))
  440. (radio-target . (lambda (object c i) c))
  441. (target . ignore)
  442. (verbatim . ignore))))
  443. (short-str
  444. (if (and short caption)
  445. (format "@shortcaption{%s}\n"
  446. (org-export-data-with-backend short short-backend info))
  447. ""))
  448. (caption-str
  449. (if (or short caption)
  450. (format "@caption{%s}\n"
  451. (org-export-data-with-backend
  452. (or caption short)
  453. (if (equal short-str "") short-backend backend)
  454. info))
  455. "")))
  456. (format "@float %s%s\n%s\n%s%s@end float"
  457. type (if label (concat "," label) "") value caption-str short-str)))
  458. ;;; Template
  459. (defun org-texinfo-template (contents info)
  460. "Return complete document string after Texinfo conversion.
  461. CONTENTS is the transcoded contents string. INFO is a plist
  462. holding export options."
  463. (let ((title (org-export-data (plist-get info :title) info))
  464. ;; Copying data is the contents of the first headline in
  465. ;; parse tree with a non-nil copying property.
  466. (copying (org-element-map (plist-get info :parse-tree) 'headline
  467. (lambda (hl)
  468. (and (org-not-nil (org-element-property :COPYING hl))
  469. (org-element-contents hl)))
  470. info t)))
  471. (concat
  472. "\\input texinfo @c -*- texinfo -*-\n"
  473. "@c %**start of header\n"
  474. (let ((file (or (plist-get info :texinfo-filename)
  475. (let ((f (plist-get info :output-file)))
  476. (and f (concat (file-name-sans-extension f) ".info"))))))
  477. (and file (format "@setfilename %s\n" file)))
  478. (format "@settitle %s\n" title)
  479. ;; Insert class-defined header.
  480. (org-element-normalize-string
  481. (let ((header (nth 1 (assoc (plist-get info :texinfo-class)
  482. org-texinfo-classes)))
  483. (coding
  484. (catch 'coding-system
  485. (let ((case-fold-search t)
  486. (name (symbol-name (or org-texinfo-coding-system
  487. buffer-file-coding-system))))
  488. (dolist (system org-texinfo-supported-coding-systems "UTF-8")
  489. (when (string-match-p (regexp-quote system) name)
  490. (throw 'coding-system system))))))
  491. (language (plist-get info :language))
  492. (case-fold-search nil))
  493. ;; Auto coding system.
  494. (replace-regexp-in-string
  495. "^@documentencoding \\(AUTO\\)$"
  496. coding
  497. (replace-regexp-in-string
  498. "^@documentlanguage \\(AUTO\\)$" language header t nil 1) t nil 1)))
  499. ;; Additional header options set by #+TEXINFO_HEADER.
  500. (let ((texinfo-header (plist-get info :texinfo-header)))
  501. (and texinfo-header (org-element-normalize-string texinfo-header)))
  502. "@c %**end of header\n\n"
  503. ;; Additional options set by #+TEXINFO_POST_HEADER.
  504. (let ((texinfo-post-header (plist-get info :texinfo-post-header)))
  505. (and texinfo-post-header
  506. (org-element-normalize-string texinfo-post-header)))
  507. ;; Copying.
  508. (and copying
  509. (format "@copying\n%s@end copying\n\n"
  510. (org-element-normalize-string
  511. (org-export-data copying info))))
  512. ;; Info directory information. Only supply if both title and
  513. ;; category are provided.
  514. (let ((dircat (plist-get info :texinfo-dircat))
  515. (dirtitle
  516. (let ((title (plist-get info :texinfo-dirtitle)))
  517. (and title
  518. (string-match "^\\(?:\\* \\)?\\(.*?\\)\\(\\.\\)?$" title)
  519. (format "* %s." (match-string 1 title))))))
  520. (when (and dircat dirtitle)
  521. (concat "@dircategory " dircat "\n"
  522. "@direntry\n"
  523. (let ((dirdesc
  524. (let ((desc (plist-get info :texinfo-dirdesc)))
  525. (cond ((not desc) nil)
  526. ((string-suffix-p "." desc) desc)
  527. (t (concat desc "."))))))
  528. (if dirdesc (format "%-23s %s" dirtitle dirdesc) dirtitle))
  529. "\n"
  530. "@end direntry\n\n")))
  531. ;; Title
  532. "@finalout\n"
  533. "@titlepage\n"
  534. (when (plist-get info :with-title)
  535. (concat
  536. (format "@title %s\n"
  537. (or (plist-get info :texinfo-printed-title) title ""))
  538. (let ((subtitle (plist-get info :subtitle)))
  539. (when subtitle
  540. (format "@subtitle %s\n"
  541. (org-export-data subtitle info))))))
  542. (when (plist-get info :with-author)
  543. (concat
  544. ;; Primary author.
  545. (let ((author (org-string-nw-p
  546. (org-export-data (plist-get info :author) info)))
  547. (email (and (plist-get info :with-email)
  548. (org-string-nw-p
  549. (org-export-data (plist-get info :email) info)))))
  550. (cond ((and author email)
  551. (format "@author %s (@email{%s})\n" author email))
  552. (author (format "@author %s\n" author))
  553. (email (format "@author @email{%s}\n" email))))
  554. ;; Other authors.
  555. (let ((subauthor (plist-get info :subauthor)))
  556. (and subauthor
  557. (org-element-normalize-string
  558. (replace-regexp-in-string "^" "@author " subauthor))))))
  559. (and copying "@page\n@vskip 0pt plus 1filll\n@insertcopying\n")
  560. "@end titlepage\n\n"
  561. ;; Table of contents.
  562. (and (plist-get info :with-toc) "@contents\n\n")
  563. ;; Configure Top Node when not for TeX. Also include contents
  564. ;; from the first section of the document.
  565. "@ifnottex\n"
  566. "@node Top\n"
  567. (format "@top %s\n" title)
  568. (let* ((first-section
  569. (org-element-map (plist-get info :parse-tree) 'section
  570. #'identity info t '(headline)))
  571. (top-contents
  572. (org-export-data (org-element-contents first-section) info)))
  573. (and (org-string-nw-p top-contents) (concat "\n" top-contents)))
  574. "@end ifnottex\n\n"
  575. ;; Menu.
  576. (org-texinfo-make-menu (plist-get info :parse-tree) info 'master)
  577. "\n"
  578. ;; Document's body.
  579. contents "\n"
  580. ;; Creator.
  581. (and (plist-get info :with-creator)
  582. (concat (plist-get info :creator) "\n"))
  583. ;; Document end.
  584. "@bye")))
  585. ;;; Transcode Functions
  586. ;;;; Bold
  587. (defun org-texinfo-bold (_bold contents info)
  588. "Transcode BOLD from Org to Texinfo.
  589. CONTENTS is the text with bold markup. INFO is a plist holding
  590. contextual information."
  591. (org-texinfo--text-markup contents 'bold info))
  592. ;;;; Center Block
  593. (defun org-texinfo-center-block (_center-block contents _info)
  594. "Transcode a CENTER-BLOCK element from Org to Texinfo.
  595. CONTENTS holds the contents of the block. INFO is a plist used
  596. as a communication channel."
  597. contents)
  598. ;;;; Clock
  599. (defun org-texinfo-clock (clock _contents info)
  600. "Transcode a CLOCK element from Org to Texinfo.
  601. CONTENTS is nil. INFO is a plist holding contextual
  602. information."
  603. (concat
  604. "@noindent"
  605. (format "@strong{%s} " org-clock-string)
  606. (format (plist-get info :texinfo-inactive-timestamp-format)
  607. (concat (org-timestamp-translate (org-element-property :value clock))
  608. (let ((time (org-element-property :duration clock)))
  609. (and time (format " (%s)" time)))))
  610. "@*"))
  611. ;;;; Code
  612. (defun org-texinfo-code (code _contents info)
  613. "Transcode a CODE object from Org to Texinfo.
  614. CONTENTS is nil. INFO is a plist used as a communication
  615. channel."
  616. (org-texinfo--text-markup (org-element-property :value code) 'code info))
  617. ;;;; Drawer
  618. (defun org-texinfo-drawer (drawer contents info)
  619. "Transcode a DRAWER element from Org to Texinfo.
  620. CONTENTS holds the contents of the block. INFO is a plist
  621. holding contextual information."
  622. (let* ((name (org-element-property :drawer-name drawer))
  623. (output (funcall (plist-get info :texinfo-format-drawer-function)
  624. name contents)))
  625. output))
  626. ;;;; Dynamic Block
  627. (defun org-texinfo-dynamic-block (_dynamic-block contents _info)
  628. "Transcode a DYNAMIC-BLOCK element from Org to Texinfo.
  629. CONTENTS holds the contents of the block. INFO is a plist
  630. holding contextual information."
  631. contents)
  632. ;;;; Entity
  633. (defun org-texinfo-entity (entity _contents _info)
  634. "Transcode an ENTITY object from Org to Texinfo."
  635. ;; Since there is not specific Texinfo entry in entities, use
  636. ;; Texinfo-specific commands whenever possible, and fallback to
  637. ;; UTF-8 otherwise.
  638. (pcase (org-element-property :name entity)
  639. ("AElig" "@AE{}")
  640. ("aelig" "@ae{}")
  641. ((or "bull" "bullet") "@bullet{}")
  642. ("copy" "@copyright{}")
  643. ("deg" "@textdegree{}")
  644. ((or "dots" "hellip") "@dots{}")
  645. ("equiv" "@equiv{}")
  646. ((or "euro" "EUR") "@euro{}")
  647. ((or "ge" "geq") "@geq{}")
  648. ("laquo" "@guillemetleft{}")
  649. ("iexcl" "@exclamdown{}")
  650. ("imath" "@dotless{i}")
  651. ("iquest" "@questiondown{}")
  652. ("jmath" "@dotless{j}")
  653. ((or "le" "leq") "@leq{}")
  654. ("lsaquo" "@guilsinglleft{}")
  655. ("mdash" "---")
  656. ("minus" "@minus{}")
  657. ("nbsp" "@tie{}")
  658. ("ndash" "--")
  659. ("OElig" "@OE{}")
  660. ("oelig" "@oe{}")
  661. ("ordf" "@ordf{}")
  662. ("ordm" "@ordm{}")
  663. ("pound" "@pound{}")
  664. ("raquo" "@guillemetright{}")
  665. ((or "rArr" "Rightarrow") "@result{}")
  666. ("reg" "@registeredsymbol{}")
  667. ((or "rightarrow" "to" "rarr") "@arrow{}")
  668. ("rsaquo" "@guilsinglright{}")
  669. ("thorn" "@th{}")
  670. ("THORN" "@TH{}")
  671. ((and (pred (string-prefix-p "_")) name) ;spacing entities
  672. (format "@w{%s}" (substring name 1)))
  673. (_ (org-element-property :utf-8 entity))))
  674. ;;;; Example Block
  675. (defun org-texinfo-example-block (example-block _contents info)
  676. "Transcode an EXAMPLE-BLOCK element from Org to Texinfo.
  677. CONTENTS is nil. INFO is a plist holding contextual
  678. information."
  679. (format "@example\n%s@end example"
  680. (org-texinfo--sanitize-content
  681. (org-export-format-code-default example-block info))))
  682. ;;; Export Block
  683. (defun org-texinfo-export-block (export-block _contents _info)
  684. "Transcode a EXPORT-BLOCK element from Org to Texinfo.
  685. CONTENTS is nil. INFO is a plist holding contextual information."
  686. (when (string= (org-element-property :type export-block) "TEXINFO")
  687. (org-remove-indentation (org-element-property :value export-block))))
  688. ;;; Export Snippet
  689. (defun org-texinfo-export-snippet (export-snippet _contents _info)
  690. "Transcode a EXPORT-SNIPPET object from Org to Texinfo.
  691. CONTENTS is nil. INFO is a plist holding contextual information."
  692. (when (eq (org-export-snippet-backend export-snippet) 'texinfo)
  693. (org-element-property :value export-snippet)))
  694. ;;;; Fixed Width
  695. (defun org-texinfo-fixed-width (fixed-width _contents _info)
  696. "Transcode a FIXED-WIDTH element from Org to Texinfo.
  697. CONTENTS is nil. INFO is a plist holding contextual information."
  698. (format "@example\n%s@end example"
  699. (org-remove-indentation
  700. (org-texinfo--sanitize-content
  701. (org-element-property :value fixed-width)))))
  702. ;;;; Footnote Reference
  703. (defun org-texinfo-footnote-reference (footnote _contents info)
  704. "Create a footnote reference for FOOTNOTE.
  705. FOOTNOTE is the footnote to define. CONTENTS is nil. INFO is a
  706. plist holding contextual information."
  707. (let ((def (org-export-get-footnote-definition footnote info)))
  708. (format "@footnote{%s}"
  709. (org-trim (org-export-data def info)))))
  710. ;;;; Headline
  711. (defun org-texinfo--structuring-command (headline info)
  712. "Return Texinfo structuring command string for HEADLINE element.
  713. Return nil if HEADLINE is to be ignored, `plain-list' if it
  714. should be exported as a plain-list item. INFO is a plist holding
  715. contextual information."
  716. (cond
  717. ((org-element-property :footnote-section-p headline) nil)
  718. ((org-not-nil (org-export-get-node-property :COPYING headline t)) nil)
  719. ((org-export-low-level-p headline info) 'plain-list)
  720. (t
  721. (let ((class (plist-get info :texinfo-class)))
  722. (pcase (assoc class (plist-get info :texinfo-classes))
  723. (`(,_ ,_ . ,sections)
  724. (pcase (nth (1- (org-export-get-relative-level headline info))
  725. sections)
  726. (`(,numbered ,unnumbered ,appendix)
  727. (cond
  728. ((org-not-nil (org-export-get-node-property :APPENDIX headline t))
  729. appendix)
  730. ((org-not-nil (org-export-get-node-property :INDEX headline t))
  731. unnumbered)
  732. ((org-export-numbered-headline-p headline info) numbered)
  733. (t unnumbered)))
  734. (`nil 'plain-list)
  735. (_ (user-error "Invalid Texinfo class specification: %S" class))))
  736. (_ (user-error "Invalid Texinfo class specification: %S" class)))))))
  737. (defun org-texinfo-headline (headline contents info)
  738. "Transcode a HEADLINE element from Org to Texinfo.
  739. CONTENTS holds the contents of the headline. INFO is a plist
  740. holding contextual information."
  741. (let ((section-fmt (org-texinfo--structuring-command headline info)))
  742. (when section-fmt
  743. (let* ((todo
  744. (and (plist-get info :with-todo-keywords)
  745. (let ((todo (org-element-property :todo-keyword headline)))
  746. (and todo (org-export-data todo info)))))
  747. (todo-type (and todo (org-element-property :todo-type headline)))
  748. (tags (and (plist-get info :with-tags)
  749. (org-export-get-tags headline info)))
  750. (priority (and (plist-get info :with-priority)
  751. (org-element-property :priority headline)))
  752. (text (org-texinfo--sanitize-title
  753. (org-element-property :title headline) info))
  754. (full-text
  755. (funcall (plist-get info :texinfo-format-headline-function)
  756. todo todo-type priority text tags))
  757. (contents
  758. (concat "\n"
  759. (if (org-string-nw-p contents)
  760. (concat "\n" contents)
  761. "")
  762. (let ((index (org-element-property :INDEX headline)))
  763. (and (member index '("cp" "fn" "ky" "pg" "tp" "vr"))
  764. (format "\n@printindex %s\n" index))))))
  765. (cond
  766. ((eq section-fmt 'plain-list)
  767. (let ((numbered? (org-export-numbered-headline-p headline info)))
  768. (concat (and (org-export-first-sibling-p headline info)
  769. (format "@%s\n" (if numbered? 'enumerate 'itemize)))
  770. "@item\n" full-text "\n"
  771. contents
  772. (if (org-export-last-sibling-p headline info)
  773. (format "@end %s" (if numbered? 'enumerate 'itemize))
  774. "\n"))))
  775. (t
  776. (concat (format "@node %s\n" (org-texinfo--get-node headline info))
  777. (format section-fmt full-text)
  778. contents)))))))
  779. (defun org-texinfo-format-headline-default-function
  780. (todo _todo-type priority text tags)
  781. "Default format function for a headline.
  782. See `org-texinfo-format-headline-function' for details."
  783. (concat (when todo (format "@strong{%s} " todo))
  784. (when priority (format "@emph{#%s} " priority))
  785. text
  786. (when tags (format " :%s:" (mapconcat 'identity tags ":")))))
  787. ;;;; Inline Src Block
  788. (defun org-texinfo-inline-src-block (inline-src-block _contents _info)
  789. "Transcode an INLINE-SRC-BLOCK element from Org to Texinfo.
  790. CONTENTS holds the contents of the item. INFO is a plist holding
  791. contextual information."
  792. (format "@code{%s}"
  793. (org-texinfo--sanitize-content
  794. (org-element-property :value inline-src-block))))
  795. ;;;; Inlinetask
  796. (defun org-texinfo-inlinetask (inlinetask contents info)
  797. "Transcode an INLINETASK element from Org to Texinfo.
  798. CONTENTS holds the contents of the block. INFO is a plist
  799. holding contextual information."
  800. (let ((title (org-export-data (org-element-property :title inlinetask) info))
  801. (todo (and (plist-get info :with-todo-keywords)
  802. (let ((todo (org-element-property :todo-keyword inlinetask)))
  803. (and todo (org-export-data todo info)))))
  804. (todo-type (org-element-property :todo-type inlinetask))
  805. (tags (and (plist-get info :with-tags)
  806. (org-export-get-tags inlinetask info)))
  807. (priority (and (plist-get info :with-priority)
  808. (org-element-property :priority inlinetask))))
  809. (funcall (plist-get info :texinfo-format-inlinetask-function)
  810. todo todo-type priority title tags contents)))
  811. (defun org-texinfo-format-inlinetask-default-function
  812. (todo _todo-type priority title tags contents)
  813. "Default format function for a inlinetasks.
  814. See `org-texinfo-format-inlinetask-function' for details."
  815. (let ((full-title
  816. (concat (when todo (format "@strong{%s} " todo))
  817. (when priority (format "#%c " priority))
  818. title
  819. (when tags (format ":%s:" (mapconcat #'identity tags ":"))))))
  820. (format "@center %s\n\n%s\n" full-title contents)))
  821. ;;;; Italic
  822. (defun org-texinfo-italic (_italic contents info)
  823. "Transcode ITALIC from Org to Texinfo.
  824. CONTENTS is the text with italic markup. INFO is a plist holding
  825. contextual information."
  826. (org-texinfo--text-markup contents 'italic info))
  827. ;;;; Item
  828. (defun org-texinfo-item (item contents info)
  829. "Transcode an ITEM element from Org to Texinfo.
  830. CONTENTS holds the contents of the item. INFO is a plist holding
  831. contextual information."
  832. (let* ((tag (org-element-property :tag item))
  833. (split (org-string-nw-p
  834. (org-export-read-attribute :attr_texinfo
  835. (org-element-property :parent item)
  836. :sep)))
  837. (items (and tag
  838. (let ((tag (org-export-data tag info)))
  839. (if split
  840. (split-string tag (regexp-quote split) t "[ \t\n]+")
  841. (list tag))))))
  842. (format "%s\n%s"
  843. (pcase items
  844. (`nil "@item")
  845. (`(,item) (concat "@item " item))
  846. (`(,item . ,items)
  847. (concat "@item " item "\n"
  848. (mapconcat (lambda (i) (concat "@itemx " i))
  849. items
  850. "\n"))))
  851. (or contents ""))))
  852. ;;;; Keyword
  853. (defun org-texinfo-keyword (keyword _contents info)
  854. "Transcode a KEYWORD element from Org to Texinfo.
  855. CONTENTS is nil. INFO is a plist holding contextual information."
  856. (let ((value (org-element-property :value keyword)))
  857. (pcase (org-element-property :key keyword)
  858. ("TEXINFO" value)
  859. ("CINDEX" (format "@cindex %s" value))
  860. ("FINDEX" (format "@findex %s" value))
  861. ("KINDEX" (format "@kindex %s" value))
  862. ("PINDEX" (format "@pindex %s" value))
  863. ("TINDEX" (format "@tindex %s" value))
  864. ("VINDEX" (format "@vindex %s" value))
  865. ("TOC"
  866. (cond ((string-match-p "\\<tables\\>" value)
  867. (concat "@listoffloats "
  868. (org-export-translate "Table" :utf-8 info)))
  869. ((string-match-p "\\<listings\\>" value)
  870. (concat "@listoffloats "
  871. (org-export-translate "Listing" :utf-8 info))))))))
  872. ;;;; Line Break
  873. (defun org-texinfo-line-break (_line-break _contents _info)
  874. "Transcode a LINE-BREAK object from Org to Texinfo.
  875. CONTENTS is nil. INFO is a plist holding contextual information."
  876. "@*\n")
  877. ;;;; Link
  878. (defun org-texinfo--@ref (datum description info)
  879. "Return @ref command for element or object DATUM.
  880. DESCRIPTION is the name of the section to print, as a string."
  881. (let ((node-name (org-texinfo--get-node datum info))
  882. ;; Sanitize DESCRIPTION for cross-reference use. In
  883. ;; particular, remove colons as they seem to cause (even
  884. ;; within @asis{...} to the Texinfo reader.
  885. (title (replace-regexp-in-string
  886. "[ \t]*:+" ""
  887. (replace-regexp-in-string "," "@comma{}" description))))
  888. (if (equal title node-name)
  889. (format "@ref{%s}" node-name)
  890. (format "@ref{%s, , %s}" node-name title))))
  891. (defun org-texinfo-link (link desc info)
  892. "Transcode a LINK object from Org to Texinfo.
  893. DESC is the description part of the link, or the empty string.
  894. INFO is a plist holding contextual information. See
  895. `org-export-data'."
  896. (let* ((type (org-element-property :type link))
  897. (raw-path (org-element-property :path link))
  898. ;; Ensure DESC really exists, or set it to nil.
  899. (desc (and (not (string= desc "")) desc))
  900. (path (cond
  901. ((member type '("http" "https" "ftp"))
  902. (concat type ":" raw-path))
  903. ((string= type "file") (org-export-file-uri raw-path))
  904. (t raw-path))))
  905. (cond
  906. ((org-export-custom-protocol-maybe link desc 'texinfo))
  907. ((org-export-inline-image-p link org-texinfo-inline-image-rules)
  908. (org-texinfo--inline-image link info))
  909. ((equal type "radio")
  910. (let ((destination (org-export-resolve-radio-link link info)))
  911. (if (not destination) desc
  912. (org-texinfo--@ref destination desc info))))
  913. ((member type '("custom-id" "id" "fuzzy"))
  914. (let ((destination
  915. (if (equal type "fuzzy")
  916. (org-export-resolve-fuzzy-link link info)
  917. (org-export-resolve-id-link link info))))
  918. (pcase (org-element-type destination)
  919. (`nil
  920. (format org-texinfo-link-with-unknown-path-format
  921. (org-texinfo--sanitize-content path)))
  922. ;; Id link points to an external file.
  923. (`plain-text
  924. (if desc (format "@uref{file://%s,%s}" destination desc)
  925. (format "@uref{file://%s}" destination)))
  926. ((or `headline
  927. ;; Targets within headlines cannot be turned into
  928. ;; @anchor{}, so we refer to the headline parent
  929. ;; directly.
  930. (and `target
  931. (guard (eq 'headline
  932. (org-element-type
  933. (org-element-property :parent destination))))))
  934. (let ((headline (org-element-lineage destination '(headline) t)))
  935. (org-texinfo--@ref
  936. headline
  937. (or desc (org-texinfo--sanitize-title
  938. (org-element-property :title headline) info))
  939. info)))
  940. (_
  941. (org-texinfo--@ref
  942. destination
  943. (or desc
  944. (pcase (org-export-get-ordinal destination info)
  945. ((and (pred integerp) n) (number-to-string n))
  946. ((and (pred consp) n) (mapconcat #'number-to-string n "."))
  947. (_ "???"))) ;cannot guess the description
  948. info)))))
  949. ((string= type "mailto")
  950. (format "@email{%s}"
  951. (concat (org-texinfo--sanitize-content path)
  952. (and desc (concat ", " desc)))))
  953. ;; External link with a description part.
  954. ((and path desc) (format "@uref{%s, %s}" path desc))
  955. ;; External link without a description part.
  956. (path (format "@uref{%s}" path))
  957. ;; No path, only description. Try to do something useful.
  958. (t
  959. (format (plist-get info :texinfo-link-with-unknown-path-format) desc)))))
  960. (defun org-texinfo--inline-image (link info)
  961. "Return Texinfo code for an inline image.
  962. LINK is the link pointing to the inline image. INFO is the
  963. current state of the export, as a plist."
  964. (let* ((parent (org-export-get-parent-element link))
  965. (label (and (org-element-property :name parent)
  966. (org-texinfo--get-node parent info)))
  967. (caption (org-export-get-caption parent))
  968. (shortcaption (org-export-get-caption parent t))
  969. (path (org-element-property :path link))
  970. (filename
  971. (file-name-sans-extension
  972. (if (file-name-absolute-p path) (expand-file-name path) path)))
  973. (extension (file-name-extension path))
  974. (attributes (org-export-read-attribute :attr_texinfo parent))
  975. (height (or (plist-get attributes :height) ""))
  976. (width (or (plist-get attributes :width) ""))
  977. (alt (or (plist-get attributes :alt) ""))
  978. (image (format "@image{%s,%s,%s,%s,%s}"
  979. filename width height alt extension)))
  980. (cond ((or caption shortcaption)
  981. (org-texinfo--wrap-float image
  982. info
  983. (org-export-translate "Figure" :utf-8 info)
  984. label
  985. caption
  986. shortcaption))
  987. (label (concat "@anchor{" label "}\n" image))
  988. (t image))))
  989. ;;;; Menu
  990. (defun org-texinfo-make-menu (scope info &optional master)
  991. "Create the menu for inclusion in the Texinfo document.
  992. SCOPE is a headline or a full parse tree. INFO is the
  993. communication channel, as a plist.
  994. When optional argument MASTER is non-nil, generate a master menu,
  995. including detailed node listing."
  996. (let ((menu (org-texinfo--build-menu scope info)))
  997. (when (org-string-nw-p menu)
  998. (org-element-normalize-string
  999. (format
  1000. "@menu\n%s@end menu"
  1001. (concat menu
  1002. (when master
  1003. (let ((detailmenu
  1004. (org-texinfo--build-menu
  1005. scope info
  1006. (let ((toc-depth (plist-get info :with-toc)))
  1007. (if (wholenump toc-depth) toc-depth
  1008. org-texinfo-max-toc-depth)))))
  1009. (when (org-string-nw-p detailmenu)
  1010. (concat "\n@detailmenu\n"
  1011. "--- The Detailed Node Listing ---\n\n"
  1012. detailmenu
  1013. "@end detailmenu\n"))))))))))
  1014. (defun org-texinfo--build-menu (scope info &optional level)
  1015. "Build menu for entries within SCOPE.
  1016. SCOPE is a headline or a full parse tree. INFO is a plist
  1017. containing contextual information. When optional argument LEVEL
  1018. is an integer, build the menu recursively, down to this depth."
  1019. (cond
  1020. ((not level)
  1021. (org-texinfo--format-entries (org-texinfo--menu-entries scope info) info))
  1022. ((zerop level) nil)
  1023. (t
  1024. (org-element-normalize-string
  1025. (mapconcat
  1026. (lambda (h)
  1027. (let ((entries (org-texinfo--menu-entries h info)))
  1028. (when entries
  1029. (concat
  1030. (format "%s\n\n%s\n"
  1031. (org-export-data (org-export-get-alt-title h info) info)
  1032. (org-texinfo--format-entries entries info))
  1033. (org-texinfo--build-menu h info (1- level))))))
  1034. (org-texinfo--menu-entries scope info) "\n")))))
  1035. (defun org-texinfo--format-entries (entries info)
  1036. "Format all direct menu entries in SCOPE, as a string.
  1037. SCOPE is either a headline or a full Org document. INFO is
  1038. a plist containing contextual information."
  1039. (org-element-normalize-string
  1040. (mapconcat
  1041. (lambda (h)
  1042. (let* ((title
  1043. ;; Colons are used as a separator between title and node
  1044. ;; name. Remove them.
  1045. (replace-regexp-in-string
  1046. "[ \t]+:+" ""
  1047. (org-texinfo--sanitize-title
  1048. (org-export-get-alt-title h info) info)))
  1049. (node (org-texinfo--get-node h info))
  1050. (entry (concat "* " title ":"
  1051. (if (string= title node) ":"
  1052. (concat " " node ". "))))
  1053. (desc (org-element-property :DESCRIPTION h)))
  1054. (if (not desc) entry
  1055. (format (format "%%-%ds %%s" org-texinfo-node-description-column)
  1056. entry desc))))
  1057. entries "\n")))
  1058. (defun org-texinfo--menu-entries (scope info)
  1059. "List direct children in SCOPE needing a menu entry.
  1060. SCOPE is a headline or a full parse tree. INFO is a plist
  1061. holding contextual information."
  1062. (let* ((cache (or (plist-get info :texinfo-entries-cache)
  1063. (plist-get (plist-put info :texinfo-entries-cache
  1064. (make-hash-table :test #'eq))
  1065. :texinfo-entries-cache)))
  1066. (cached-entries (gethash scope cache 'no-cache)))
  1067. (if (not (eq cached-entries 'no-cache)) cached-entries
  1068. (puthash scope
  1069. (cl-remove-if
  1070. (lambda (h)
  1071. (org-not-nil (org-export-get-node-property :COPYING h t)))
  1072. (org-export-collect-headlines info 1 scope))
  1073. cache))))
  1074. ;;;; Node Property
  1075. (defun org-texinfo-node-property (node-property _contents _info)
  1076. "Transcode a NODE-PROPERTY element from Org to Texinfo.
  1077. CONTENTS is nil. INFO is a plist holding contextual
  1078. information."
  1079. (format "%s:%s"
  1080. (org-element-property :key node-property)
  1081. (let ((value (org-element-property :value node-property)))
  1082. (if value (concat " " value) ""))))
  1083. ;;;; Paragraph
  1084. (defun org-texinfo-paragraph (_paragraph contents _info)
  1085. "Transcode a PARAGRAPH element from Org to Texinfo.
  1086. CONTENTS is the contents of the paragraph, as a string. INFO is
  1087. the plist used as a communication channel."
  1088. contents)
  1089. ;;;; Plain List
  1090. (defun org-texinfo-plain-list (plain-list contents info)
  1091. "Transcode a PLAIN-LIST element from Org to Texinfo.
  1092. CONTENTS is the contents of the list. INFO is a plist holding
  1093. contextual information."
  1094. (let* ((attr (org-export-read-attribute :attr_texinfo plain-list))
  1095. (indic (let ((i (or (plist-get attr :indic)
  1096. (plist-get info :texinfo-table-default-markup))))
  1097. ;; Allow indicating commands with missing @ sign.
  1098. (if (string-prefix-p "@" i) i (concat "@" i))))
  1099. (table-type (plist-get attr :table-type))
  1100. (type (org-element-property :type plain-list))
  1101. (list-type (cond
  1102. ((eq type 'ordered) "enumerate")
  1103. ((eq type 'unordered) "itemize")
  1104. ((member table-type '("ftable" "vtable")) table-type)
  1105. (t "table"))))
  1106. (format "@%s\n%s@end %s"
  1107. (if (eq type 'descriptive) (concat list-type " " indic) list-type)
  1108. contents
  1109. list-type)))
  1110. ;;;; Plain Text
  1111. (defun org-texinfo-plain-text (text info)
  1112. "Transcode a TEXT string from Org to Texinfo.
  1113. TEXT is the string to transcode. INFO is a plist holding
  1114. contextual information."
  1115. ;; First protect @, { and }.
  1116. (let ((output (org-texinfo--sanitize-content text)))
  1117. ;; Activate smart quotes. Be sure to provide original TEXT string
  1118. ;; since OUTPUT may have been modified.
  1119. (when (plist-get info :with-smart-quotes)
  1120. (setq output
  1121. (org-export-activate-smart-quotes output :texinfo info text)))
  1122. ;; LaTeX into @LaTeX{} and TeX into @TeX{}
  1123. (let ((case-fold-search nil))
  1124. (setq output (replace-regexp-in-string "\\(?:La\\)?TeX" "@\\&{}" output)))
  1125. ;; Convert special strings.
  1126. (when (plist-get info :with-special-strings)
  1127. (setq output
  1128. (replace-regexp-in-string
  1129. "\\.\\.\\." "@dots{}"
  1130. (replace-regexp-in-string "\\\\-" "@-" output))))
  1131. ;; Handle break preservation if required.
  1132. (when (plist-get info :preserve-breaks)
  1133. (setq output (replace-regexp-in-string
  1134. "\\(\\\\\\\\\\)?[ \t]*\n" " @*\n" output)))
  1135. ;; Return value.
  1136. output))
  1137. ;;;; Planning
  1138. (defun org-texinfo-planning (planning _contents info)
  1139. "Transcode a PLANNING element from Org to Texinfo.
  1140. CONTENTS is nil. INFO is a plist holding contextual
  1141. information."
  1142. (concat
  1143. "@noindent"
  1144. (mapconcat
  1145. 'identity
  1146. (delq nil
  1147. (list
  1148. (let ((closed (org-element-property :closed planning)))
  1149. (when closed
  1150. (concat
  1151. (format "@strong{%s} " org-closed-string)
  1152. (format (plist-get info :texinfo-inactive-timestamp-format)
  1153. (org-timestamp-translate closed)))))
  1154. (let ((deadline (org-element-property :deadline planning)))
  1155. (when deadline
  1156. (concat
  1157. (format "@strong{%s} " org-deadline-string)
  1158. (format (plist-get info :texinfo-active-timestamp-format)
  1159. (org-timestamp-translate deadline)))))
  1160. (let ((scheduled (org-element-property :scheduled planning)))
  1161. (when scheduled
  1162. (concat
  1163. (format "@strong{%s} " org-scheduled-string)
  1164. (format (plist-get info :texinfo-active-timestamp-format)
  1165. (org-timestamp-translate scheduled)))))))
  1166. " ")
  1167. "@*"))
  1168. ;;;; Property Drawer
  1169. (defun org-texinfo-property-drawer (_property-drawer contents _info)
  1170. "Transcode a PROPERTY-DRAWER element from Org to Texinfo.
  1171. CONTENTS holds the contents of the drawer. INFO is a plist
  1172. holding contextual information."
  1173. (and (org-string-nw-p contents)
  1174. (format "@verbatim\n%s@end verbatim" contents)))
  1175. ;;;; Quote Block
  1176. (defun org-texinfo-quote-block (quote-block contents _info)
  1177. "Transcode a QUOTE-BLOCK element from Org to Texinfo.
  1178. CONTENTS holds the contents of the block. INFO is a plist
  1179. holding contextual information."
  1180. (let* ((title (org-element-property :name quote-block))
  1181. (start-quote (concat "@quotation"
  1182. (if title
  1183. (format " %s" title)))))
  1184. (format "%s\n%s@end quotation" start-quote contents)))
  1185. ;;;; Radio Target
  1186. (defun org-texinfo-radio-target (radio-target text info)
  1187. "Transcode a RADIO-TARGET object from Org to Texinfo.
  1188. TEXT is the text of the target. INFO is a plist holding
  1189. contextual information."
  1190. (format "@anchor{%s}%s"
  1191. (org-texinfo--get-node radio-target info)
  1192. text))
  1193. ;;;; Section
  1194. (defun org-texinfo-section (section contents info)
  1195. "Transcode a SECTION element from Org to Texinfo.
  1196. CONTENTS holds the contents of the section. INFO is a plist
  1197. holding contextual information."
  1198. (let ((parent (org-export-get-parent-headline section)))
  1199. (when parent ;ignore very first section
  1200. (org-trim
  1201. (concat contents "\n" (org-texinfo-make-menu parent info))))))
  1202. ;;;; Special Block
  1203. (defun org-texinfo-special-block (special-block contents _info)
  1204. "Transcode a SPECIAL-BLOCK element from Org to Texinfo.
  1205. CONTENTS holds the contents of the block. INFO is a plist used
  1206. as a communication channel."
  1207. (let ((opt (org-export-read-attribute :attr_texinfo special-block :options))
  1208. (type (org-element-property :type special-block)))
  1209. (format "@%s%s\n%s@end %s"
  1210. type
  1211. (if opt (concat " " opt) "")
  1212. (or contents "")
  1213. type)))
  1214. ;;;; Src Block
  1215. (defun org-texinfo-src-block (src-block _contents info)
  1216. "Transcode a SRC-BLOCK element from Org to Texinfo.
  1217. CONTENTS holds the contents of the item. INFO is a plist holding
  1218. contextual information."
  1219. (let* ((lisp (string-match-p "lisp"
  1220. (org-element-property :language src-block)))
  1221. (code (org-texinfo--sanitize-content
  1222. (org-export-format-code-default src-block info)))
  1223. (value (format
  1224. (if lisp "@lisp\n%s@end lisp" "@example\n%s@end example")
  1225. code))
  1226. (caption (org-export-get-caption src-block))
  1227. (shortcaption (org-export-get-caption src-block t)))
  1228. (if (not (or caption shortcaption)) value
  1229. (org-texinfo--wrap-float value
  1230. info
  1231. (org-export-translate "Listing" :utf-8 info)
  1232. (org-texinfo--get-node src-block info)
  1233. caption
  1234. shortcaption))))
  1235. ;;;; Statistics Cookie
  1236. (defun org-texinfo-statistics-cookie (statistics-cookie _contents _info)
  1237. "Transcode a STATISTICS-COOKIE object from Org to Texinfo.
  1238. CONTENTS is nil. INFO is a plist holding contextual information."
  1239. (org-element-property :value statistics-cookie))
  1240. ;;;; Strike-through
  1241. (defun org-texinfo-strike-through (_strike-through contents info)
  1242. "Transcode STRIKE-THROUGH from Org to Texinfo.
  1243. CONTENTS is the text with strike-through markup. INFO is a plist
  1244. holding contextual information."
  1245. (org-texinfo--text-markup contents 'strike-through info))
  1246. ;;;; Subscript
  1247. (defun org-texinfo-subscript (_subscript contents _info)
  1248. "Transcode a SUBSCRIPT object from Org to Texinfo.
  1249. CONTENTS is the contents of the object. INFO is a plist holding
  1250. contextual information."
  1251. (format "@math{_%s}" contents))
  1252. ;;;; Superscript
  1253. (defun org-texinfo-superscript (_superscript contents _info)
  1254. "Transcode a SUPERSCRIPT object from Org to Texinfo.
  1255. CONTENTS is the contents of the object. INFO is a plist holding
  1256. contextual information."
  1257. (format "@math{^%s}" contents))
  1258. ;;;; Table
  1259. (defun org-texinfo-table (table contents info)
  1260. "Transcode a TABLE element from Org to Texinfo.
  1261. CONTENTS is the contents of the table. INFO is a plist holding
  1262. contextual information."
  1263. (if (eq (org-element-property :type table) 'table.el)
  1264. (format "@verbatim\n%s@end verbatim"
  1265. (org-element-normalize-string
  1266. (org-element-property :value table)))
  1267. (let* ((col-width (org-export-read-attribute :attr_texinfo table :columns))
  1268. (columns
  1269. (if col-width (format "@columnfractions %s" col-width)
  1270. (org-texinfo-table-column-widths table info)))
  1271. (caption (org-export-get-caption table))
  1272. (shortcaption (org-export-get-caption table t))
  1273. (table-str (format "@multitable %s\n%s@end multitable"
  1274. columns
  1275. contents)))
  1276. (if (not (or caption shortcaption)) table-str
  1277. (org-texinfo--wrap-float table-str
  1278. info
  1279. (org-export-translate "Table" :utf-8 info)
  1280. (org-texinfo--get-node table info)
  1281. caption
  1282. shortcaption)))))
  1283. (defun org-texinfo-table-column-widths (table info)
  1284. "Determine the largest table cell in each column to process alignment.
  1285. TABLE is the table element to transcode. INFO is a plist used as
  1286. a communication channel."
  1287. (let ((widths (make-vector (cdr (org-export-table-dimensions table info)) 0)))
  1288. (org-element-map table 'table-row
  1289. (lambda (row)
  1290. (let ((idx 0))
  1291. (org-element-map row 'table-cell
  1292. (lambda (cell)
  1293. ;; Length of the cell in the original buffer is only an
  1294. ;; approximation of the length of the cell in the
  1295. ;; output. It can sometimes fail (e.g. it considers
  1296. ;; "/a/" being larger than "ab").
  1297. (let ((w (- (org-element-property :contents-end cell)
  1298. (org-element-property :contents-begin cell))))
  1299. (aset widths idx (max w (aref widths idx))))
  1300. (cl-incf idx))
  1301. info)))
  1302. info)
  1303. (format "{%s}" (mapconcat (lambda (w) (make-string w ?a)) widths "} {"))))
  1304. ;;;; Table Cell
  1305. (defun org-texinfo-table-cell (table-cell contents info)
  1306. "Transcode a TABLE-CELL element from Org to Texinfo.
  1307. CONTENTS is the cell contents. INFO is a plist used as
  1308. a communication channel."
  1309. (concat
  1310. (let ((scientific-notation
  1311. (plist-get info :texinfo-table-scientific-notation)))
  1312. (if (and contents
  1313. scientific-notation
  1314. (string-match orgtbl-exp-regexp contents))
  1315. ;; Use appropriate format string for scientific notation.
  1316. (format scientific-notation
  1317. (match-string 1 contents)
  1318. (match-string 2 contents))
  1319. contents))
  1320. (when (org-export-get-next-element table-cell info) "\n@tab ")))
  1321. ;;;; Table Row
  1322. (defun org-texinfo-table-row (table-row contents info)
  1323. "Transcode a TABLE-ROW element from Org to Texinfo.
  1324. CONTENTS is the contents of the row. INFO is a plist used as
  1325. a communication channel."
  1326. ;; Rules are ignored since table separators are deduced from
  1327. ;; borders of the current row.
  1328. (when (eq (org-element-property :type table-row) 'standard)
  1329. (let ((rowgroup-tag
  1330. (if (and (= 1 (org-export-table-row-group table-row info))
  1331. (org-export-table-has-header-p
  1332. (org-export-get-parent-table table-row) info))
  1333. "@headitem "
  1334. "@item ")))
  1335. (concat rowgroup-tag contents "\n"))))
  1336. ;;;; Target
  1337. (defun org-texinfo-target (target _contents info)
  1338. "Transcode a TARGET object from Org to Texinfo.
  1339. CONTENTS is nil. INFO is a plist holding contextual
  1340. information."
  1341. (format "@anchor{%s}" (org-texinfo--get-node target info)))
  1342. ;;;; Timestamp
  1343. (defun org-texinfo-timestamp (timestamp _contents info)
  1344. "Transcode a TIMESTAMP object from Org to Texinfo.
  1345. CONTENTS is nil. INFO is a plist holding contextual
  1346. information."
  1347. (let ((value (org-texinfo-plain-text
  1348. (org-timestamp-translate timestamp) info)))
  1349. (pcase (org-element-property :type timestamp)
  1350. ((or `active `active-range)
  1351. (format (plist-get info :texinfo-active-timestamp-format) value))
  1352. ((or `inactive `inactive-range)
  1353. (format (plist-get info :texinfo-inactive-timestamp-format) value))
  1354. (_ (format (plist-get info :texinfo-diary-timestamp-format) value)))))
  1355. ;;;; Underline
  1356. (defun org-texinfo-underline (_underline contents info)
  1357. "Transcode UNDERLINE from Org to Texinfo.
  1358. CONTENTS is the text with underline markup. INFO is a plist
  1359. holding contextual information."
  1360. (org-texinfo--text-markup contents 'underline info))
  1361. ;;;; Verbatim
  1362. (defun org-texinfo-verbatim (verbatim _contents info)
  1363. "Transcode a VERBATIM object from Org to Texinfo.
  1364. CONTENTS is nil. INFO is a plist used as a communication
  1365. channel."
  1366. (org-texinfo--text-markup
  1367. (org-element-property :value verbatim) 'verbatim info))
  1368. ;;;; Verse Block
  1369. (defun org-texinfo-verse-block (_verse-block contents _info)
  1370. "Transcode a VERSE-BLOCK element from Org to Texinfo.
  1371. CONTENTS is verse block contents. INFO is a plist holding
  1372. contextual information."
  1373. (format "@display\n%s@end display" contents))
  1374. ;;; Interactive functions
  1375. ;;;###autoload
  1376. (defun org-texinfo-export-to-texinfo
  1377. (&optional async subtreep visible-only body-only ext-plist)
  1378. "Export current buffer to a Texinfo file.
  1379. If narrowing is active in the current buffer, only export its
  1380. narrowed part.
  1381. If a region is active, export that region.
  1382. A non-nil optional argument ASYNC means the process should happen
  1383. asynchronously. The resulting file should be accessible through
  1384. the `org-export-stack' interface.
  1385. When optional argument SUBTREEP is non-nil, export the sub-tree
  1386. at point, extracting information from the headline properties
  1387. first.
  1388. When optional argument VISIBLE-ONLY is non-nil, don't export
  1389. contents of hidden elements.
  1390. When optional argument BODY-ONLY is non-nil, only write code
  1391. between \"\\begin{document}\" and \"\\end{document}\".
  1392. EXT-PLIST, when provided, is a property list with external
  1393. parameters overriding Org default settings, but still inferior to
  1394. file-local settings.
  1395. Return output file's name."
  1396. (interactive)
  1397. (let ((outfile (org-export-output-file-name ".texi" subtreep))
  1398. (org-export-coding-system org-texinfo-coding-system))
  1399. (org-export-to-file 'texinfo outfile
  1400. async subtreep visible-only body-only ext-plist)))
  1401. ;;;###autoload
  1402. (defun org-texinfo-export-to-info
  1403. (&optional async subtreep visible-only body-only ext-plist)
  1404. "Export current buffer to Texinfo then process through to INFO.
  1405. If narrowing is active in the current buffer, only export its
  1406. narrowed part.
  1407. If a region is active, export that region.
  1408. A non-nil optional argument ASYNC means the process should happen
  1409. asynchronously. The resulting file should be accessible through
  1410. the `org-export-stack' interface.
  1411. When optional argument SUBTREEP is non-nil, export the sub-tree
  1412. at point, extracting information from the headline properties
  1413. first.
  1414. When optional argument VISIBLE-ONLY is non-nil, don't export
  1415. contents of hidden elements.
  1416. When optional argument BODY-ONLY is non-nil, only write code
  1417. between \"\\begin{document}\" and \"\\end{document}\".
  1418. EXT-PLIST, when provided, is a property list with external
  1419. parameters overriding Org default settings, but still inferior to
  1420. file-local settings.
  1421. When optional argument PUB-DIR is set, use it as the publishing
  1422. directory.
  1423. Return INFO file's name."
  1424. (interactive)
  1425. (let ((outfile (org-export-output-file-name ".texi" subtreep))
  1426. (org-export-coding-system org-texinfo-coding-system))
  1427. (org-export-to-file 'texinfo outfile
  1428. async subtreep visible-only body-only ext-plist
  1429. (lambda (file) (org-texinfo-compile file)))))
  1430. ;;;###autoload
  1431. (defun org-texinfo-publish-to-texinfo (plist filename pub-dir)
  1432. "Publish an org file to Texinfo.
  1433. FILENAME is the filename of the Org file to be published. PLIST
  1434. is the property list for the given project. PUB-DIR is the
  1435. publishing directory.
  1436. Return output file name."
  1437. (org-publish-org-to 'texinfo filename ".texi" plist pub-dir))
  1438. ;;;###autoload
  1439. (defun org-texinfo-convert-region-to-texinfo ()
  1440. "Assume the current region has Org syntax, and convert it to Texinfo.
  1441. This can be used in any buffer. For example, you can write an
  1442. itemized list in Org syntax in an Texinfo buffer and use this
  1443. command to convert it."
  1444. (interactive)
  1445. (org-export-replace-region-by 'texinfo))
  1446. (defun org-texinfo-compile (file)
  1447. "Compile a texinfo file.
  1448. FILE is the name of the file being compiled. Processing is done
  1449. through the command specified in `org-texinfo-info-process',
  1450. which see. Output is redirected to \"*Org INFO Texinfo Output*\"
  1451. buffer.
  1452. Return INFO file name or an error if it couldn't be produced."
  1453. (message "Processing Texinfo file %s..." file)
  1454. (let* ((log-name "*Org INFO Texinfo Output*")
  1455. (log (get-buffer-create log-name))
  1456. (output
  1457. (org-compile-file file org-texinfo-info-process "info"
  1458. (format "See %S for details" log-name)
  1459. log)))
  1460. (when org-texinfo-remove-logfiles
  1461. (let ((base (file-name-sans-extension output)))
  1462. (dolist (ext org-texinfo-logfiles-extensions)
  1463. (let ((file (concat base "." ext)))
  1464. (when (file-exists-p file) (delete-file file))))))
  1465. (message "Process completed.")
  1466. output))
  1467. (provide 'ox-texinfo)
  1468. ;; Local variables:
  1469. ;; generated-autoload-file: "org-loaddefs.el"
  1470. ;; End:
  1471. ;;; ox-texinfo.el ends here