org-capture.el 75 KB

1234567891011121314151617181920212223242526272829303132333435363738394041424344454647484950515253545556575859606162636465666768697071727374757677787980818283848586878889909192939495969798991001011021031041051061071081091101111121131141151161171181191201211221231241251261271281291301311321331341351361371381391401411421431441451461471481491501511521531541551561571581591601611621631641651661671681691701711721731741751761771781791801811821831841851861871881891901911921931941951961971981992002012022032042052062072082092102112122132142152162172182192202212222232242252262272282292302312322332342352362372382392402412422432442452462472482492502512522532542552562572582592602612622632642652662672682692702712722732742752762772782792802812822832842852862872882892902912922932942952962972982993003013023033043053063073083093103113123133143153163173183193203213223233243253263273283293303313323333343353363373383393403413423433443453463473483493503513523533543553563573583593603613623633643653663673683693703713723733743753763773783793803813823833843853863873883893903913923933943953963973983994004014024034044054064074084094104114124134144154164174184194204214224234244254264274284294304314324334344354364374384394404414424434444454464474484494504514524534544554564574584594604614624634644654664674684694704714724734744754764774784794804814824834844854864874884894904914924934944954964974984995005015025035045055065075085095105115125135145155165175185195205215225235245255265275285295305315325335345355365375385395405415425435445455465475485495505515525535545555565575585595605615625635645655665675685695705715725735745755765775785795805815825835845855865875885895905915925935945955965975985996006016026036046056066076086096106116126136146156166176186196206216226236246256266276286296306316326336346356366376386396406416426436446456466476486496506516526536546556566576586596606616626636646656666676686696706716726736746756766776786796806816826836846856866876886896906916926936946956966976986997007017027037047057067077087097107117127137147157167177187197207217227237247257267277287297307317327337347357367377387397407417427437447457467477487497507517527537547557567577587597607617627637647657667677687697707717727737747757767777787797807817827837847857867877887897907917927937947957967977987998008018028038048058068078088098108118128138148158168178188198208218228238248258268278288298308318328338348358368378388398408418428438448458468478488498508518528538548558568578588598608618628638648658668678688698708718728738748758768778788798808818828838848858868878888898908918928938948958968978988999009019029039049059069079089099109119129139149159169179189199209219229239249259269279289299309319329339349359369379389399409419429439449459469479489499509519529539549559569579589599609619629639649659669679689699709719729739749759769779789799809819829839849859869879889899909919929939949959969979989991000100110021003100410051006100710081009101010111012101310141015101610171018101910201021102210231024102510261027102810291030103110321033103410351036103710381039104010411042104310441045104610471048104910501051105210531054105510561057105810591060106110621063106410651066106710681069107010711072107310741075107610771078107910801081108210831084108510861087108810891090109110921093109410951096109710981099110011011102110311041105110611071108110911101111111211131114111511161117111811191120112111221123112411251126112711281129113011311132113311341135113611371138113911401141114211431144114511461147114811491150115111521153115411551156115711581159116011611162116311641165116611671168116911701171117211731174117511761177117811791180118111821183118411851186118711881189119011911192119311941195119611971198119912001201120212031204120512061207120812091210121112121213121412151216121712181219122012211222122312241225122612271228122912301231123212331234123512361237123812391240124112421243124412451246124712481249125012511252125312541255125612571258125912601261126212631264126512661267126812691270127112721273127412751276127712781279128012811282128312841285128612871288128912901291129212931294129512961297129812991300130113021303130413051306130713081309131013111312131313141315131613171318131913201321132213231324132513261327132813291330133113321333133413351336133713381339134013411342134313441345134613471348134913501351135213531354135513561357135813591360136113621363136413651366136713681369137013711372137313741375137613771378137913801381138213831384138513861387138813891390139113921393139413951396139713981399140014011402140314041405140614071408140914101411141214131414141514161417141814191420142114221423142414251426142714281429143014311432143314341435143614371438143914401441144214431444144514461447144814491450145114521453145414551456145714581459146014611462146314641465146614671468146914701471147214731474147514761477147814791480148114821483148414851486148714881489149014911492149314941495149614971498149915001501150215031504150515061507150815091510151115121513151415151516151715181519152015211522152315241525152615271528152915301531153215331534153515361537153815391540154115421543154415451546154715481549155015511552155315541555155615571558155915601561156215631564156515661567156815691570157115721573157415751576157715781579158015811582158315841585158615871588158915901591159215931594159515961597159815991600160116021603160416051606160716081609161016111612161316141615161616171618161916201621162216231624162516261627162816291630163116321633163416351636163716381639164016411642164316441645164616471648164916501651165216531654165516561657165816591660166116621663166416651666166716681669167016711672167316741675167616771678167916801681168216831684168516861687168816891690169116921693169416951696169716981699170017011702170317041705170617071708170917101711171217131714171517161717171817191720172117221723172417251726172717281729173017311732173317341735173617371738173917401741174217431744174517461747174817491750175117521753175417551756175717581759176017611762176317641765176617671768176917701771177217731774177517761777177817791780178117821783178417851786178717881789179017911792179317941795179617971798179918001801180218031804180518061807180818091810181118121813181418151816181718181819182018211822182318241825182618271828182918301831183218331834183518361837183818391840184118421843184418451846184718481849185018511852185318541855185618571858185918601861186218631864186518661867186818691870187118721873187418751876187718781879188018811882188318841885188618871888188918901891189218931894189518961897189818991900190119021903190419051906190719081909191019111912191319141915191619171918191919201921192219231924192519261927192819291930193119321933
  1. ;;; org-capture.el --- Fast note taking in Org -*- lexical-binding: t; -*-
  2. ;; Copyright (C) 2010-2020 Free Software Foundation, Inc.
  3. ;; Author: Carsten Dominik <carsten at orgmode dot org>
  4. ;; Keywords: outlines, hypermedia, calendar, wp
  5. ;; Homepage: https://orgmode.org
  6. ;;
  7. ;; This file is part of GNU Emacs.
  8. ;;
  9. ;; GNU Emacs is free software: you can redistribute it and/or modify
  10. ;; it under the terms of the GNU General Public License as published by
  11. ;; the Free Software Foundation, either version 3 of the License, or
  12. ;; (at your option) any later version.
  13. ;; GNU Emacs is distributed in the hope that it will be useful,
  14. ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  15. ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  16. ;; GNU General Public License for more details.
  17. ;; You should have received a copy of the GNU General Public License
  18. ;; along with GNU Emacs. If not, see <https://www.gnu.org/licenses/>.
  19. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  20. ;;
  21. ;;; Commentary:
  22. ;; This file contains an alternative implementation of the functionality
  23. ;; that used to be provided by org-remember.el. The implementation is more
  24. ;; streamlined, can produce more target types (e.g. plain list items or
  25. ;; table lines). Also, it does not use a temporary buffer for editing
  26. ;; the captured entry - instead it uses an indirect buffer that visits
  27. ;; the new entry already in the target buffer (this was an idea by Samuel
  28. ;; Wales). John Wiegley's excellent `remember.el' is not needed anymore
  29. ;; for this implementation, even though we borrow heavily from its ideas.
  30. ;; This implementation heavily draws on ideas by James TD Smith and
  31. ;; Samuel Wales, and, of cause, uses John Wiegley's remember.el as inspiration.
  32. ;;; TODO
  33. ;; - find a clever way to not always insert an annotation maybe a
  34. ;; predicate function that can check for conditions for %a to be
  35. ;; used. This could be one of the properties.
  36. ;; - Should there be plist members that arrange for properties to be
  37. ;; asked for, like James proposed in his RFC?
  38. ;;; Code:
  39. (require 'cl-lib)
  40. (require 'org)
  41. (require 'org-refile)
  42. (declare-function org-at-encrypted-entry-p "org-crypt" ())
  43. (declare-function org-at-table-p "org-table" (&optional table-type))
  44. (declare-function org-clock-update-mode-line "org-clock" (&optional refresh))
  45. (declare-function org-datetree-find-date-create "org-datetree" (date &optional keep-restriction))
  46. (declare-function org-datetree-find-month-create (d &optional keep-restriction))
  47. (declare-function org-decrypt-entry "org-crypt" ())
  48. (declare-function org-element-at-point "org-element" ())
  49. (declare-function org-element-lineage "org-element" (datum &optional types with-self))
  50. (declare-function org-element-property "org-element" (property element))
  51. (declare-function org-encrypt-entry "org-crypt" ())
  52. (declare-function org-insert-link "ol" (&optional complete-file link-location default-description))
  53. (declare-function org-link-make-string "ol" (link &optional description))
  54. (declare-function org-table-analyze "org-table" ())
  55. (declare-function org-table-current-dline "org-table" ())
  56. (declare-function org-table-fix-formulas "org-table" (key replace &optional limit delta remove))
  57. (declare-function org-table-goto-line "org-table" (N))
  58. (defvar dired-buffers)
  59. (defvar org-end-time-was-given)
  60. (defvar org-keyword-properties)
  61. (defvar org-remember-default-headline)
  62. (defvar org-remember-templates)
  63. (defvar org-store-link-plist)
  64. (defvar org-table-border-regexp)
  65. (defvar org-table-current-begin-pos)
  66. (defvar org-table-dataline-regexp)
  67. (defvar org-table-fix-formulas-confirm)
  68. (defvar org-table-hline-regexp)
  69. (defvar org-table-hlines)
  70. (defvar org-capture-clock-was-started nil
  71. "Internal flag, noting if the clock was started.")
  72. (defvar org-capture-last-stored-marker (make-marker)
  73. "Marker pointing to the entry most recently stored with `org-capture'.")
  74. ;; The following variable is scoped dynamically by org-protocol
  75. ;; to indicate that the link properties have already been stored
  76. (defvar org-capture-link-is-already-stored nil)
  77. (defvar org-capture-is-refiling nil
  78. "Non-nil when capture process is refiling an entry.")
  79. (defvar org-capture--prompt-history-table (make-hash-table :test #'equal)
  80. "Hash table for all history lists per prompt.")
  81. (defvar org-capture--prompt-history nil
  82. "History list for prompt placeholders.")
  83. (defgroup org-capture nil
  84. "Options concerning capturing new entries."
  85. :tag "Org Capture"
  86. :group 'org)
  87. (defun org-capture-upgrade-templates (templates)
  88. "Update the template list to the new format.
  89. TEMPLATES is a template list, as in `org-capture-templates'. The
  90. new format unifies all the date/week tree targets into one that
  91. also allows for an optional outline path to specify a target."
  92. (let ((modified-templates
  93. (mapcar
  94. (lambda (entry)
  95. (pcase entry
  96. ;; Match templates with an obsolete "tree" target type. Replace
  97. ;; it with common `file+olp-datetree'. Add new properties
  98. ;; (i.e., `:time-prompt' and `:tree-type') if needed.
  99. (`(,key ,desc ,type (file+datetree . ,path) ,tpl . ,props)
  100. `(,key ,desc ,type (file+olp+datetree ,@path) ,tpl ,@props))
  101. (`(,key ,desc ,type (file+datetree+prompt . ,path) ,tpl . ,props)
  102. `(,key ,desc ,type (file+olp+datetree ,@path) ,tpl
  103. :time-prompt t ,@props))
  104. (`(,key ,desc ,type (file+weektree . ,path) ,tpl . ,props)
  105. `(,key ,desc ,type (file+olp+datetree ,@path) ,tpl
  106. :tree-type week ,@props))
  107. (`(,key ,desc ,type (file+weektree+prompt . ,path) ,tpl . ,props)
  108. `(,key ,desc ,type (file+olp+datetree ,@path) ,tpl
  109. :tree-type week :time-prompt t ,@props))
  110. ;; Other templates are left unchanged.
  111. (_ entry)))
  112. templates)))
  113. (unless (equal modified-templates templates)
  114. (message "Deprecated date/weektree capture templates changed to `file+olp+datetree'."))
  115. modified-templates))
  116. (defcustom org-capture-templates nil
  117. "Templates for the creation of new entries.
  118. Each entry is a list with the following items:
  119. keys The keys that will select the template, as a string, characters
  120. only, for example \"a\" for a template to be selected with a
  121. single key, or \"bt\" for selection with two keys. When using
  122. several keys, keys using the same prefix key must be together
  123. in the list and preceded by a 2-element entry explaining the
  124. prefix key, for example
  125. (\"b\" \"Templates for marking stuff to buy\")
  126. The \"C\" key is used by default for quick access to the
  127. customization of the template variable. But if you want to use
  128. that key for a template, you can.
  129. description A short string describing the template, will be shown during
  130. selection.
  131. type The type of entry. Valid types are:
  132. entry an Org node, with a headline. Will be filed
  133. as the child of the target entry or as a
  134. top-level entry.
  135. item a plain list item, will be placed in the
  136. first plain list at the target
  137. location.
  138. checkitem a checkbox item. This differs from the
  139. plain list item only in so far as it uses a
  140. different default template.
  141. table-line a new line in the first table at target location.
  142. plain text to be inserted as it is.
  143. target Specification of where the captured item should be placed.
  144. In Org files, targets usually define a node. Entries will
  145. become children of this node, other types will be added to the
  146. table or list in the body of this node.
  147. Most target specifications contain a file name. If that file
  148. name is the empty string, it defaults to `org-default-notes-file'.
  149. A file can also be given as a variable or as a function called
  150. with no argument. When an absolute path is not specified for a
  151. target, it is taken as relative to `org-directory'.
  152. Valid values are:
  153. (file \"path/to/file\")
  154. Text will be placed at the beginning or end of that file
  155. (id \"id of existing Org entry\")
  156. File as child of this entry, or in the body of the entry
  157. (file+headline \"path/to/file\" \"node headline\")
  158. Fast configuration if the target heading is unique in the file
  159. (file+olp \"path/to/file\" \"Level 1 heading\" \"Level 2\" ...)
  160. For non-unique headings, the full outline path is safer
  161. (file+regexp \"path/to/file\" \"regexp to find location\")
  162. File to the entry matching regexp
  163. (file+olp+datetree \"path/to/file\" \"Level 1 heading\" ...)
  164. Will create a heading in a date tree for today's date.
  165. If no heading is given, the tree will be on top level.
  166. To prompt for date instead of using TODAY, use the
  167. :time-prompt property. To create a week-tree, use the
  168. :tree-type property.
  169. (file+function \"path/to/file\" function-finding-location)
  170. A function to find the right location in the file
  171. (clock)
  172. File to the entry that is currently being clocked
  173. (function function-finding-location)
  174. Most general way: write your own function which both visits
  175. the file and moves point to the right location
  176. template The template for creating the capture item. If you leave this
  177. empty, an appropriate default template will be used. See below
  178. for more details. Instead of a string, this may also be one of
  179. (file \"/path/to/template-file\")
  180. (function function-returning-the-template)
  181. in order to get a template from a file, or dynamically
  182. from a function.
  183. The rest of the entry is a property list of additional options. Recognized
  184. properties are:
  185. :prepend Normally newly captured information will be appended at
  186. the target location (last child, last table line,
  187. last list item...). Setting this property will
  188. change that.
  189. :immediate-finish When set, do not offer to edit the information, just
  190. file it away immediately. This makes sense if the
  191. template only needs information that can be added
  192. automatically.
  193. :jump-to-captured When set, jump to the captured entry when finished.
  194. :empty-lines Set this to the number of lines that should be inserted
  195. before and after the new item. Default 0, only common
  196. other value is 1.
  197. :empty-lines-before Set this to the number of lines that should be inserted
  198. before the new item. Overrides :empty-lines for the
  199. number lines inserted before.
  200. :empty-lines-after Set this to the number of lines that should be inserted
  201. after the new item. Overrides :empty-lines for the
  202. number of lines inserted after.
  203. :clock-in Start the clock in this item.
  204. :clock-keep Keep the clock running when filing the captured entry.
  205. :clock-resume Start the interrupted clock when finishing the capture.
  206. Note that :clock-keep has precedence over :clock-resume.
  207. When setting both to t, the current clock will run and
  208. the previous one will not be resumed.
  209. :time-prompt Prompt for a date/time to be used for date/week trees
  210. and when filling the template.
  211. :tree-type When `week', make a week tree instead of the month tree.
  212. :unnarrowed Do not narrow the target buffer, simply show the
  213. full buffer. Default is to narrow it so that you
  214. only see the new stuff.
  215. :table-line-pos Specification of the location in the table where the
  216. new line should be inserted. It should be a string like
  217. \"II-3\", meaning that the new line should become the
  218. third line before the second horizontal separator line.
  219. :kill-buffer If the target file was not yet visited by a buffer when
  220. capture was invoked, kill the buffer again after capture
  221. is finalized.
  222. :no-save Do not save the target file after finishing the capture.
  223. The template defines the text to be inserted. Often this is an
  224. Org mode entry (so the first line should start with a star) that
  225. will be filed as a child of the target headline. It can also be
  226. freely formatted text. Furthermore, the following %-escapes will
  227. be replaced with content and expanded:
  228. %[pathname] Insert the contents of the file given by
  229. `pathname'. These placeholders are expanded at the very
  230. beginning of the process so they can be used to extend the
  231. current template.
  232. %(sexp) Evaluate elisp `(sexp)' and replace it with the results.
  233. Only placeholders pre-existing within the template, or
  234. introduced with %[pathname] are expanded this way. Since this
  235. happens after expanding non-interactive %-escapes, those can
  236. be used to fill the expression.
  237. %<...> The result of format-time-string on the ... format specification.
  238. %t Time stamp, date only. The time stamp is the current time,
  239. except when called from agendas with `\\[org-agenda-capture]' or
  240. with `org-capture-use-agenda-date' set.
  241. %T Time stamp as above, with date and time.
  242. %u, %U Like the above, but inactive time stamps.
  243. %i Initial content, copied from the active region. If
  244. there is text before %i on the same line, such as
  245. indentation, and %i is not inside a %(sexp), that prefix
  246. will be added before every line in the inserted text.
  247. %a Annotation, normally the link created with `org-store-link'.
  248. %A Like %a, but prompt for the description part.
  249. %l Like %a, but only insert the literal link.
  250. %c Current kill ring head.
  251. %x Content of the X clipboard.
  252. %k Title of currently clocked task.
  253. %K Link to currently clocked task.
  254. %n User name (taken from the variable `user-full-name').
  255. %f File visited by current buffer when org-capture was called.
  256. %F Full path of the file or directory visited by current buffer.
  257. %:keyword Specific information for certain link types, see below.
  258. %^g Prompt for tags, with completion on tags in target file.
  259. %^G Prompt for tags, with completion on all tags in all agenda files.
  260. %^t Like %t, but prompt for date. Similarly %^T, %^u, %^U.
  261. You may define a prompt like: %^{Please specify birthday}t.
  262. The default date is that of %t, see above.
  263. %^C Interactive selection of which kill or clip to use.
  264. %^L Like %^C, but insert as link.
  265. %^{prop}p Prompt the user for a value for property `prop'.
  266. %^{prompt} Prompt the user for a string and replace this sequence with it.
  267. A default value and a completion table ca be specified like this:
  268. %^{prompt|default|completion2|completion3|...}.
  269. %? After completing the template, position cursor here.
  270. %\\1 ... %\\N Insert the text entered at the nth %^{prompt}, where N
  271. is a number, starting from 1.
  272. Apart from these general escapes, you can access information specific to
  273. the link type that is created. For example, calling `org-capture' in emails
  274. or in Gnus will record the author and the subject of the message, which you
  275. can access with \"%:from\" and \"%:subject\", respectively. Here is a
  276. complete list of what is recorded for each link type.
  277. Link type | Available information
  278. ------------------------+------------------------------------------------------
  279. bbdb | %:type %:name %:company
  280. vm, wl, mh, mew, rmail, | %:type %:subject %:message-id
  281. gnus | %:from %:fromname %:fromaddress
  282. | %:to %:toname %:toaddress
  283. | %:fromto (either \"to NAME\" or \"from NAME\")
  284. | %:date %:date-timestamp (as active timestamp)
  285. | %:date-timestamp-inactive (as inactive timestamp)
  286. gnus | %:group, for messages also all email fields
  287. eww, w3, w3m | %:type %:url
  288. info | %:type %:file %:node
  289. calendar | %:type %:date
  290. When you need to insert a literal percent sign in the template,
  291. you can escape ambiguous cases with a backward slash, e.g., \\%i."
  292. :group 'org-capture
  293. :version "24.1"
  294. :set (lambda (s v) (set s (org-capture-upgrade-templates v)))
  295. :type
  296. (let ((file-variants '(choice :tag "Filename "
  297. (file :tag "Literal")
  298. (function :tag "Function")
  299. (variable :tag "Variable")
  300. (sexp :tag "Form"))))
  301. `(repeat
  302. (choice :value ("" "" entry (file "~/org/notes.org") "")
  303. (list :tag "Multikey description"
  304. (string :tag "Keys ")
  305. (string :tag "Description"))
  306. (list :tag "Template entry"
  307. (string :tag "Keys ")
  308. (string :tag "Description ")
  309. (choice :tag "Capture Type " :value entry
  310. (const :tag "Org entry" entry)
  311. (const :tag "Plain list item" item)
  312. (const :tag "Checkbox item" checkitem)
  313. (const :tag "Plain text" plain)
  314. (const :tag "Table line" table-line))
  315. (choice :tag "Target location"
  316. (list :tag "File"
  317. (const :format "" file)
  318. ,file-variants)
  319. (list :tag "ID"
  320. (const :format "" id)
  321. (string :tag " ID"))
  322. (list :tag "File & Headline"
  323. (const :format "" file+headline)
  324. ,file-variants
  325. (string :tag " Headline"))
  326. (list :tag "File & Outline path"
  327. (const :format "" file+olp)
  328. ,file-variants
  329. (repeat :tag "Outline path" :inline t
  330. (string :tag "Headline")))
  331. (list :tag "File & Regexp"
  332. (const :format "" file+regexp)
  333. ,file-variants
  334. (regexp :tag " Regexp"))
  335. (list :tag "File [ & Outline path ] & Date tree"
  336. (const :format "" file+olp+datetree)
  337. ,file-variants
  338. (option (repeat :tag "Outline path" :inline t
  339. (string :tag "Headline"))))
  340. (list :tag "File & function"
  341. (const :format "" file+function)
  342. ,file-variants
  343. (sexp :tag " Function"))
  344. (list :tag "Current clocking task"
  345. (const :format "" clock))
  346. (list :tag "Function"
  347. (const :format "" function)
  348. (sexp :tag " Function")))
  349. (choice :tag "Template "
  350. (string)
  351. (list :tag "File"
  352. (const :format "" file)
  353. (file :tag "Template file"))
  354. (list :tag "Function"
  355. (const :format "" function)
  356. (function :tag "Template function")))
  357. (plist :inline t
  358. ;; Give the most common options as checkboxes
  359. :options (((const :format "%v " :prepend) (const t))
  360. ((const :format "%v " :immediate-finish) (const t))
  361. ((const :format "%v " :jump-to-captured) (const t))
  362. ((const :format "%v " :empty-lines) (const 1))
  363. ((const :format "%v " :empty-lines-before) (const 1))
  364. ((const :format "%v " :empty-lines-after) (const 1))
  365. ((const :format "%v " :clock-in) (const t))
  366. ((const :format "%v " :clock-keep) (const t))
  367. ((const :format "%v " :clock-resume) (const t))
  368. ((const :format "%v " :time-prompt) (const t))
  369. ((const :format "%v " :tree-type) (const week))
  370. ((const :format "%v " :unnarrowed) (const t))
  371. ((const :format "%v " :table-line-pos) (string))
  372. ((const :format "%v " :kill-buffer) (const t)))))))))
  373. (defcustom org-capture-before-finalize-hook nil
  374. "Hook that is run right before a capture process is finalized.
  375. The capture buffer is still current when this hook runs and it is
  376. widened to the entire buffer."
  377. :group 'org-capture
  378. :version "24.1"
  379. :type 'hook)
  380. (defcustom org-capture-after-finalize-hook nil
  381. "Hook that is run right after a capture process is finalized.
  382. Suitable for window cleanup."
  383. :group 'org-capture
  384. :version "24.1"
  385. :type 'hook)
  386. (defcustom org-capture-prepare-finalize-hook nil
  387. "Hook that is run before the finalization starts.
  388. The capture buffer is current and still narrowed."
  389. :group 'org-capture
  390. :version "24.1"
  391. :type 'hook)
  392. (defcustom org-capture-bookmark t
  393. "When non-nil, add a bookmark pointing at the last stored
  394. position when capturing."
  395. :group 'org-capture
  396. :version "24.3"
  397. :type 'boolean)
  398. ;;; The property list for keeping information about the capture process
  399. (defvar org-capture-plist nil
  400. "Plist for the current capture process, global, to avoid having to pass it.")
  401. (defvar org-capture-current-plist nil
  402. "Local variable holding the plist in a capture buffer.
  403. This is used to store the plist for use when finishing a capture process
  404. because another such process might have changed the global variable by then.
  405. Each time a new capture buffer has been set up, the global `org-capture-plist'
  406. is copied to this variable, which is local in the indirect buffer.")
  407. (defvar org-capture-clock-keep nil
  408. "Local variable to store the value of the :clock-keep parameter.
  409. This is needed in case org-capture-finalize is called interactively.")
  410. (defun org-capture-put (&rest stuff)
  411. "Add properties to the capture property list `org-capture-plist'."
  412. (while stuff
  413. (setq org-capture-plist (plist-put org-capture-plist
  414. (pop stuff) (pop stuff)))))
  415. (defun org-capture-get (prop &optional local)
  416. "Get properties from the capture property list `org-capture-plist'.
  417. When LOCAL is set, use the local variable `org-capture-current-plist',
  418. this is necessary after initialization of the capture process,
  419. to avoid conflicts with other active capture processes."
  420. (plist-get (if local org-capture-current-plist org-capture-plist) prop))
  421. ;;; The minor mode
  422. (defvar org-capture-mode-map
  423. (let ((map (make-sparse-keymap)))
  424. (define-key map "\C-c\C-c" #'org-capture-finalize)
  425. (define-key map "\C-c\C-k" #'org-capture-kill)
  426. (define-key map "\C-c\C-w" #'org-capture-refile)
  427. map)
  428. "Keymap for `org-capture-mode', a minor mode.
  429. Use this map to set additional keybindings for when Org mode is used
  430. for a capture buffer.")
  431. (defvar org-capture-mode-hook nil
  432. "Hook for the `org-capture-mode' minor mode.")
  433. (define-minor-mode org-capture-mode
  434. "Minor mode for special key bindings in a capture buffer.
  435. Turning on this mode runs the normal hook `org-capture-mode-hook'."
  436. nil " Cap" org-capture-mode-map
  437. (setq-local
  438. header-line-format
  439. (substitute-command-keys
  440. "\\<org-capture-mode-map>Capture buffer. Finish \
  441. `\\[org-capture-finalize]', refile `\\[org-capture-refile]', \
  442. abort `\\[org-capture-kill]'.")))
  443. ;;; The main commands
  444. (defvar org-capture-initial nil)
  445. (defvar org-capture-entry nil)
  446. ;;;###autoload
  447. (defun org-capture-string (string &optional keys)
  448. "Capture STRING with the template selected by KEYS."
  449. (interactive "sInitial text: \n")
  450. (let ((org-capture-initial string)
  451. (org-capture-entry (org-capture-select-template keys)))
  452. (org-capture)))
  453. (defcustom org-capture-templates-contexts nil
  454. "Alist of capture templates and valid contexts.
  455. For example, if you have a capture template \"c\" and you want
  456. this template to be accessible only from `message-mode' buffers,
  457. use this:
  458. \\='((\"c\" ((in-mode . \"message-mode\"))))
  459. Here are the available contexts definitions:
  460. in-file: command displayed only in matching files
  461. in-mode: command displayed only in matching modes
  462. not-in-file: command not displayed in matching files
  463. not-in-mode: command not displayed in matching modes
  464. in-buffer: command displayed only in matching buffers
  465. not-in-buffer: command not displayed in matching buffers
  466. [function]: a custom function taking no argument
  467. If you define several checks, the agenda command will be
  468. accessible if there is at least one valid check.
  469. You can also bind a key to another capture template depending on
  470. contextual rules.
  471. \\='((\"c\" \"d\" ((in-mode . \"message-mode\"))))
  472. Here it means: in `message-mode buffers', use \"c\" as the
  473. key for the capture template otherwise associated with \"d\".
  474. \(The template originally associated with \"d\" is not displayed
  475. to avoid duplicates.)"
  476. :version "24.3"
  477. :group 'org-capture
  478. :type '(repeat (list :tag "Rule"
  479. (string :tag " Capture key")
  480. (string :tag "Replace by template")
  481. (repeat :tag "Available when"
  482. (choice
  483. (cons :tag "Condition"
  484. (choice
  485. (const :tag "In file" in-file)
  486. (const :tag "Not in file" not-in-file)
  487. (const :tag "In buffer" in-buffer)
  488. (const :tag "Not in buffer" not-in-buffer)
  489. (const :tag "In mode" in-mode)
  490. (const :tag "Not in mode" not-in-mode))
  491. (regexp))
  492. (function :tag "Custom function"))))))
  493. (defcustom org-capture-use-agenda-date nil
  494. "Non-nil means use the date at point when capturing from agendas.
  495. When nil, you can still capture using the date at point with
  496. `\\[org-agenda-capture]'."
  497. :group 'org-capture
  498. :version "24.3"
  499. :type 'boolean)
  500. ;;;###autoload
  501. (defun org-capture (&optional goto keys)
  502. "Capture something.
  503. \\<org-capture-mode-map>
  504. This will let you select a template from `org-capture-templates', and
  505. then file the newly captured information. The text is immediately
  506. inserted at the target location, and an indirect buffer is shown where
  507. you can edit it. Pressing `\\[org-capture-finalize]' brings you back to the \
  508. previous
  509. state of Emacs, so that you can continue your work.
  510. When called interactively with a `\\[universal-argument]' prefix argument \
  511. GOTO, don't
  512. capture anything, just go to the file/headline where the selected
  513. template stores its notes.
  514. With a `\\[universal-argument] \\[universal-argument]' prefix argument, go to \
  515. the last note stored.
  516. When called with a `C-0' (zero) prefix, insert a template at point.
  517. When called with a `C-1' (one) prefix, force prompting for a date when
  518. a datetree entry is made.
  519. ELisp programs can set KEYS to a string associated with a template
  520. in `org-capture-templates'. In this case, interactive selection
  521. will be bypassed.
  522. If `org-capture-use-agenda-date' is non-nil, capturing from the
  523. agenda will use the date at point as the default date. Then, a
  524. `C-1' prefix will tell the capture process to use the HH:MM time
  525. of the day at point (if any) or the current HH:MM time."
  526. (interactive "P")
  527. (when (and org-capture-use-agenda-date
  528. (eq major-mode 'org-agenda-mode))
  529. (setq org-overriding-default-time
  530. (org-get-cursor-date (equal goto 1))))
  531. (cond
  532. ((equal goto '(4)) (org-capture-goto-target keys))
  533. ((equal goto '(16)) (org-capture-goto-last-stored))
  534. (t
  535. (let* ((orig-buf (current-buffer))
  536. (annotation (if (and (boundp 'org-capture-link-is-already-stored)
  537. org-capture-link-is-already-stored)
  538. (plist-get org-store-link-plist :annotation)
  539. (ignore-errors (org-store-link nil))))
  540. (entry (or org-capture-entry (org-capture-select-template keys)))
  541. initial)
  542. (setq initial (or org-capture-initial
  543. (and (org-region-active-p)
  544. (buffer-substring (point) (mark)))))
  545. (when (stringp initial)
  546. (remove-text-properties 0 (length initial) '(read-only t) initial))
  547. (when (stringp annotation)
  548. (remove-text-properties 0 (length annotation)
  549. '(read-only t) annotation))
  550. (cond
  551. ((equal entry "C")
  552. (customize-variable 'org-capture-templates))
  553. ((equal entry "q")
  554. (user-error "Abort"))
  555. (t
  556. (org-capture-set-plist entry)
  557. (org-capture-get-template)
  558. (org-capture-put :original-buffer orig-buf
  559. :original-file (or (buffer-file-name orig-buf)
  560. (and (featurep 'dired)
  561. (car (rassq orig-buf
  562. dired-buffers))))
  563. :original-file-nondirectory
  564. (and (buffer-file-name orig-buf)
  565. (file-name-nondirectory
  566. (buffer-file-name orig-buf)))
  567. :annotation annotation
  568. :initial initial
  569. :return-to-wconf (current-window-configuration)
  570. :default-time (or org-overriding-default-time
  571. (org-current-time)))
  572. (org-capture-set-target-location (and (equal goto 0) 'here))
  573. (condition-case error
  574. (org-capture-put :template (org-capture-fill-template))
  575. ((error quit)
  576. (if (get-buffer "*Capture*") (kill-buffer "*Capture*"))
  577. (error "Capture abort: %s" (error-message-string error))))
  578. (setq org-capture-clock-keep (org-capture-get :clock-keep))
  579. (condition-case error
  580. (org-capture-place-template
  581. (eq (car (org-capture-get :target)) 'function))
  582. ((error quit)
  583. (when (and (buffer-base-buffer (current-buffer))
  584. (string-prefix-p "CAPTURE-" (buffer-name)))
  585. (kill-buffer (current-buffer)))
  586. (set-window-configuration (org-capture-get :return-to-wconf))
  587. (error "Capture template `%s': %s"
  588. (org-capture-get :key)
  589. (error-message-string error))))
  590. (when (and (derived-mode-p 'org-mode) (org-capture-get :clock-in))
  591. (condition-case nil
  592. (progn
  593. (when (org-clock-is-active)
  594. (org-capture-put :interrupted-clock
  595. (copy-marker org-clock-marker)))
  596. (org-clock-in)
  597. (setq-local org-capture-clock-was-started t))
  598. (error "Could not start the clock in this capture buffer")))
  599. (when (org-capture-get :immediate-finish)
  600. (org-capture-finalize))))))))
  601. (defun org-capture-get-template ()
  602. "Get the template from a file or a function if necessary."
  603. (org-capture-put
  604. :template
  605. (pcase (org-capture-get :template)
  606. (`nil "")
  607. ((and (pred stringp) template) template)
  608. (`(file ,file)
  609. (let ((filename (expand-file-name file org-directory)))
  610. (if (file-exists-p filename) (org-file-contents filename)
  611. (format "* Template file %S not found" file))))
  612. (`(function ,f)
  613. (if (functionp f) (funcall f)
  614. (format "* Template function %S not found" f)))
  615. (_ "* Invalid capture template"))))
  616. (defun org-capture-finalize (&optional stay-with-capture)
  617. "Finalize the capture process.
  618. With prefix argument STAY-WITH-CAPTURE, jump to the location of the
  619. captured item after finalizing."
  620. (interactive "P")
  621. (when (org-capture-get :jump-to-captured)
  622. (setq stay-with-capture t))
  623. (unless (and org-capture-mode
  624. (buffer-base-buffer (current-buffer)))
  625. (error "This does not seem to be a capture buffer for Org mode"))
  626. (run-hooks 'org-capture-prepare-finalize-hook)
  627. ;; Did we start the clock in this capture buffer?
  628. (when (and org-capture-clock-was-started
  629. org-clock-marker
  630. (eq (marker-buffer org-clock-marker) (buffer-base-buffer))
  631. (>= org-clock-marker (point-min))
  632. (< org-clock-marker (point-max)))
  633. ;; Looks like the clock we started is still running.
  634. (if org-capture-clock-keep
  635. ;; User may have completed clocked heading from the template.
  636. ;; Refresh clock mode line.
  637. (org-clock-update-mode-line t)
  638. ;; Clock out. Possibly resume interrupted clock.
  639. (let (org-log-note-clock-out) (org-clock-out))
  640. (when (and (org-capture-get :clock-resume 'local)
  641. (markerp (org-capture-get :interrupted-clock 'local))
  642. (buffer-live-p (marker-buffer
  643. (org-capture-get :interrupted-clock 'local))))
  644. (let ((clock-in-task (org-capture-get :interrupted-clock 'local)))
  645. (org-with-point-at clock-in-task (org-clock-in)))
  646. (message "Interrupted clock has been resumed"))))
  647. (let ((abort-note nil))
  648. ;; Store the size of the capture buffer
  649. (org-capture-put :captured-entry-size (- (point-max) (point-min)))
  650. (widen)
  651. ;; Store the insertion point in the target buffer
  652. (org-capture-put :insertion-point (point))
  653. (if org-note-abort
  654. (let ((beg (org-capture-get :begin-marker 'local))
  655. (end (org-capture-get :end-marker 'local)))
  656. (if (not (and beg end)) (setq abort-note 'dirty)
  657. (setq abort-note t)
  658. (org-with-wide-buffer (kill-region beg end))))
  659. ;; Postprocessing: Update Statistics cookies, do the sorting
  660. (when (derived-mode-p 'org-mode)
  661. (save-excursion
  662. (when (ignore-errors (org-back-to-heading))
  663. (org-update-parent-todo-statistics)
  664. (org-update-checkbox-count)))
  665. ;; FIXME Here we should do the sorting
  666. ;; If we have added a table line, maybe recompute?
  667. (when (and (eq (org-capture-get :type 'local) 'table-line)
  668. (org-at-table-p))
  669. (if (not (org-table-get-stored-formulas)) (org-table-align)
  670. ;; Adjust formulas, if necessary. We assume a non-nil
  671. ;; `:immediate-finish' means that no confirmation is
  672. ;; required. Else, obey `org-table-fix-formulas-confirm'.
  673. ;;
  674. ;; The delta required to fix formulas depends on the
  675. ;; number of rows inserted by the template.
  676. (when (or (org-capture-get :immediate-finish)
  677. (not org-table-fix-formulas-confirm)
  678. (funcall org-table-fix-formulas-confirm "Fix formulas? "))
  679. (org-table-fix-formulas
  680. "@" nil (1- (org-table-current-dline))
  681. (count-lines (org-capture-get :begin-marker 'local)
  682. (org-capture-get :end-marker 'local))))
  683. (org-table-recalculate 'all)))) ;FIXME: should we iterate?
  684. ;; Store this place as the last one where we stored something
  685. ;; Do the marking in the base buffer, so that it makes sense after
  686. ;; the indirect buffer has been killed.
  687. (org-capture-store-last-position)
  688. ;; Run the hook
  689. (run-hooks 'org-capture-before-finalize-hook))
  690. (when (org-capture-get :decrypted)
  691. (save-excursion
  692. (goto-char (org-capture-get :decrypted))
  693. (org-encrypt-entry)))
  694. (unless (org-capture-get :no-save) (save-buffer))
  695. (let ((return-wconf (org-capture-get :return-to-wconf 'local))
  696. (new-buffer (org-capture-get :new-buffer 'local))
  697. (kill-buffer (org-capture-get :kill-buffer 'local))
  698. (base-buffer (buffer-base-buffer (current-buffer))))
  699. ;; Kill the indirect buffer
  700. (kill-buffer (current-buffer))
  701. ;; Narrow back the target buffer to its previous state
  702. (with-current-buffer (org-capture-get :buffer)
  703. (let ((reg (org-capture-get :initial-target-region))
  704. (pos (org-capture-get :initial-target-position))
  705. (ipt (org-capture-get :insertion-point))
  706. (size (org-capture-get :captured-entry-size)))
  707. (if (not reg)
  708. (widen)
  709. (cond ((< ipt (car reg))
  710. ;; insertion point is before the narrowed region
  711. (narrow-to-region (+ size (car reg)) (+ size (cdr reg))))
  712. ((> ipt (cdr reg))
  713. ;; insertion point is after the narrowed region
  714. (narrow-to-region (car reg) (cdr reg)))
  715. (t
  716. ;; insertion point is within the narrowed region
  717. (narrow-to-region (car reg) (+ size (cdr reg)))))
  718. ;; now place back the point at its original position
  719. (if (< ipt (car reg))
  720. (goto-char (+ size pos))
  721. (goto-char (if (< ipt pos) (+ size pos) pos))))))
  722. ;; Kill the target buffer if that is desired
  723. (when (and base-buffer new-buffer kill-buffer)
  724. (with-current-buffer base-buffer (save-buffer))
  725. (kill-buffer base-buffer))
  726. ;; Restore the window configuration before capture
  727. (set-window-configuration return-wconf))
  728. (run-hooks 'org-capture-after-finalize-hook)
  729. ;; Special cases
  730. (cond
  731. (abort-note
  732. (cl-case abort-note
  733. (clean
  734. (message "Capture process aborted and target buffer cleaned up"))
  735. (dirty
  736. (error "Capture process aborted, but target buffer could not be \
  737. cleaned up correctly"))))
  738. (stay-with-capture
  739. (org-capture-goto-last-stored)))
  740. ;; Return if we did store something
  741. (not abort-note)))
  742. (defun org-capture-refile ()
  743. "Finalize the current capture and then refile the entry.
  744. Refiling is done from the base buffer, because the indirect buffer is then
  745. already gone. Any prefix argument will be passed to the refile command."
  746. (interactive)
  747. (unless (eq (org-capture-get :type 'local) 'entry)
  748. (user-error "Refiling from a capture buffer makes only sense \
  749. for `entry'-type templates"))
  750. (let* ((base (or (buffer-base-buffer) (current-buffer)))
  751. (pos (make-marker))
  752. (org-capture-is-refiling t)
  753. (kill-buffer (org-capture-get :kill-buffer 'local))
  754. (jump-to-captured (org-capture-get :jump-to-captured 'local)))
  755. ;; Since `org-capture-finalize' may alter buffer contents (e.g.,
  756. ;; empty lines) around entry, use a marker to refer to the
  757. ;; headline to be refiled. Place the marker in the base buffer,
  758. ;; as the current indirect one is going to be killed.
  759. (set-marker pos (save-excursion (org-back-to-heading t) (point)) base)
  760. ;; `org-capture-finalize' calls `org-capture-goto-last-stored' too
  761. ;; early. We want to wait for the refiling to be over, so we
  762. ;; control when the latter function is called.
  763. (org-capture-put :kill-buffer nil :jump-to-captured nil)
  764. (org-capture-finalize)
  765. (save-window-excursion
  766. (with-current-buffer base
  767. (org-with-point-at pos
  768. (call-interactively 'org-refile))))
  769. (when kill-buffer
  770. (with-current-buffer base (save-buffer))
  771. (kill-buffer base))
  772. (when jump-to-captured (org-capture-goto-last-stored))))
  773. (defun org-capture-kill ()
  774. "Abort the current capture process."
  775. (interactive)
  776. ;; FIXME: This does not do the right thing, we need to remove the
  777. ;; new stuff by hand it is easy: undo, then kill the buffer
  778. (let ((org-note-abort t)
  779. (org-capture-before-finalize-hook nil))
  780. (org-capture-finalize)))
  781. (defun org-capture-goto-last-stored ()
  782. "Go to the location where the last capture note was stored."
  783. (interactive)
  784. (org-goto-marker-or-bmk org-capture-last-stored-marker
  785. (plist-get org-bookmark-names-plist
  786. :last-capture))
  787. (message "This is the last note stored by a capture process"))
  788. ;;; Supporting functions for handling the process
  789. (defun org-capture-put-target-region-and-position ()
  790. "Store the initial region with `org-capture-put'."
  791. (org-capture-put
  792. :initial-target-region
  793. ;; Check if the buffer is currently narrowed
  794. (when (org-buffer-narrowed-p)
  795. (cons (point-min) (point-max))))
  796. ;; store the current point
  797. (org-capture-put :initial-target-position (point)))
  798. (defvar org-time-was-given) ; dynamically scoped parameter
  799. (defun org-capture-set-target-location (&optional target)
  800. "Find TARGET buffer and position.
  801. Store them in the capture property list."
  802. (let ((target-entry-p t))
  803. (save-excursion
  804. (pcase (or target (org-capture-get :target))
  805. (`here
  806. (org-capture-put :exact-position (point) :insert-here t))
  807. (`(file ,path)
  808. (set-buffer (org-capture-target-buffer path))
  809. (org-capture-put-target-region-and-position)
  810. (widen)
  811. (setq target-entry-p nil))
  812. (`(id ,id)
  813. (pcase (org-id-find id)
  814. (`(,path . ,position)
  815. (set-buffer (org-capture-target-buffer path))
  816. (widen)
  817. (org-capture-put-target-region-and-position)
  818. (goto-char position))
  819. (_ (error "Cannot find target ID \"%s\"" id))))
  820. (`(file+headline ,path ,headline)
  821. (set-buffer (org-capture-target-buffer path))
  822. ;; Org expects the target file to be in Org mode, otherwise
  823. ;; it throws an error. However, the default notes files
  824. ;; should work out of the box. In this case, we switch it to
  825. ;; Org mode.
  826. (unless (derived-mode-p 'org-mode)
  827. (org-display-warning
  828. (format "Capture requirement: switching buffer %S to Org mode"
  829. (current-buffer)))
  830. (org-mode))
  831. (org-capture-put-target-region-and-position)
  832. (widen)
  833. (goto-char (point-min))
  834. (if (re-search-forward (format org-complex-heading-regexp-format
  835. (regexp-quote headline))
  836. nil t)
  837. (beginning-of-line)
  838. (goto-char (point-max))
  839. (unless (bolp) (insert "\n"))
  840. (insert "* " headline "\n")
  841. (beginning-of-line 0)))
  842. (`(file+olp ,path . ,outline-path)
  843. (let ((m (org-find-olp (cons (org-capture-expand-file path)
  844. outline-path))))
  845. (set-buffer (marker-buffer m))
  846. (org-capture-put-target-region-and-position)
  847. (widen)
  848. (goto-char m)
  849. (set-marker m nil)))
  850. (`(file+regexp ,path ,regexp)
  851. (set-buffer (org-capture-target-buffer path))
  852. (org-capture-put-target-region-and-position)
  853. (widen)
  854. (goto-char (point-min))
  855. (if (not (re-search-forward regexp nil t))
  856. (error "No match for target regexp in file %s" path)
  857. (goto-char (if (org-capture-get :prepend)
  858. (match-beginning 0)
  859. (match-end 0)))
  860. (org-capture-put :exact-position (point))
  861. (setq target-entry-p
  862. (and (derived-mode-p 'org-mode) (org-at-heading-p)))))
  863. (`(file+olp+datetree ,path . ,outline-path)
  864. (let ((m (if outline-path
  865. (org-find-olp (cons (org-capture-expand-file path)
  866. outline-path))
  867. (set-buffer (org-capture-target-buffer path))
  868. (point-marker))))
  869. (set-buffer (marker-buffer m))
  870. (org-capture-put-target-region-and-position)
  871. (widen)
  872. (goto-char m)
  873. (set-marker m nil)
  874. (require 'org-datetree)
  875. (org-capture-put-target-region-and-position)
  876. (widen)
  877. ;; Make a date/week tree entry, with the current date (or
  878. ;; yesterday, if we are extending dates for a couple of
  879. ;; hours)
  880. (funcall
  881. (pcase (org-capture-get :tree-type)
  882. (`week #'org-datetree-find-iso-week-create)
  883. (`month #'org-datetree-find-month-create)
  884. (_ #'org-datetree-find-date-create))
  885. (calendar-gregorian-from-absolute
  886. (cond
  887. (org-overriding-default-time
  888. ;; Use the overriding default time.
  889. (time-to-days org-overriding-default-time))
  890. ((or (org-capture-get :time-prompt)
  891. (equal current-prefix-arg 1))
  892. ;; Prompt for date.
  893. (let ((prompt-time (org-read-date
  894. nil t nil "Date for tree entry:")))
  895. (org-capture-put
  896. :default-time
  897. (cond ((and (or (not (boundp 'org-time-was-given))
  898. (not org-time-was-given))
  899. (not (= (time-to-days prompt-time) (org-today))))
  900. ;; Use 00:00 when no time is given for another
  901. ;; date than today?
  902. (apply #'encode-time 0 0
  903. org-extend-today-until
  904. (cl-cdddr (decode-time prompt-time))))
  905. ((string-match "\\([^ ]+\\)-[^ ]+[ ]+\\(.*\\)"
  906. org-read-date-final-answer)
  907. ;; Replace any time range by its start.
  908. (apply #'encode-time
  909. (org-read-date-analyze
  910. (replace-match "\\1 \\2" nil nil
  911. org-read-date-final-answer)
  912. prompt-time (decode-time prompt-time))))
  913. (t prompt-time)))
  914. (time-to-days prompt-time)))
  915. (t
  916. ;; Current date, possibly corrected for late night
  917. ;; workers.
  918. (org-today))))
  919. ;; the following is the keep-restriction argument for
  920. ;; org-datetree-find-date-create
  921. (when outline-path 'subtree-at-point))))
  922. (`(file+function ,path ,function)
  923. (set-buffer (org-capture-target-buffer path))
  924. (org-capture-put-target-region-and-position)
  925. (widen)
  926. (funcall function)
  927. (org-capture-put :exact-position (point))
  928. (setq target-entry-p
  929. (and (derived-mode-p 'org-mode) (org-at-heading-p))))
  930. (`(function ,fun)
  931. (funcall fun)
  932. (org-capture-put :exact-position (point))
  933. (setq target-entry-p
  934. (and (derived-mode-p 'org-mode) (org-at-heading-p))))
  935. (`(clock)
  936. (if (and (markerp org-clock-hd-marker)
  937. (marker-buffer org-clock-hd-marker))
  938. (progn (set-buffer (marker-buffer org-clock-hd-marker))
  939. (org-capture-put-target-region-and-position)
  940. (widen)
  941. (goto-char org-clock-hd-marker))
  942. (user-error "No running clock that could be used as capture target")))
  943. (target (error "Invalid capture target specification: %S" target)))
  944. (org-capture-put :buffer (current-buffer)
  945. :pos (point)
  946. :target-entry-p target-entry-p
  947. :decrypted
  948. (and (featurep 'org-crypt)
  949. (org-at-encrypted-entry-p)
  950. (save-excursion
  951. (org-decrypt-entry)
  952. (and (org-back-to-heading t) (point))))))))
  953. (defun org-capture-expand-file (file)
  954. "Expand functions, symbols and file names for FILE.
  955. When FILE is a function, call it. When it is a form, evaluate
  956. it. When it is a variable, return its value. When it is
  957. a string, treat it as a file name, possibly expanding it
  958. according to `org-directory', and return it. If it is the empty
  959. string, however, return `org-default-notes-file'. In any other
  960. case, raise an error."
  961. (let ((location (cond ((equal file "") org-default-notes-file)
  962. ((stringp file) (expand-file-name file org-directory))
  963. ((functionp file) (funcall file))
  964. ((and (symbolp file) (boundp file)) (symbol-value file))
  965. (t nil))))
  966. (or (org-string-nw-p location)
  967. (error "Invalid file location: %S" location))))
  968. (defun org-capture-target-buffer (file)
  969. "Get a buffer for FILE.
  970. FILE is a generalized file location, as handled by
  971. `org-capture-expand-file'."
  972. (let ((file (org-capture-expand-file file)))
  973. (or (org-find-base-buffer-visiting file)
  974. (progn (org-capture-put :new-buffer t)
  975. (find-file-noselect file)))))
  976. (defun org-capture-place-template (&optional inhibit-wconf-store)
  977. "Insert the template at the target location, and display the buffer.
  978. When `inhibit-wconf-store', don't store the window configuration, as it
  979. may have been stored before."
  980. (unless inhibit-wconf-store
  981. (org-capture-put :return-to-wconf (current-window-configuration)))
  982. (delete-other-windows)
  983. (org-switch-to-buffer-other-window
  984. (org-capture-get-indirect-buffer (org-capture-get :buffer) "CAPTURE"))
  985. (widen)
  986. (org-show-all)
  987. (goto-char (org-capture-get :pos))
  988. (setq-local outline-level 'org-outline-level)
  989. (pcase (org-capture-get :type)
  990. ((or `nil `entry) (org-capture-place-entry))
  991. (`table-line (org-capture-place-table-line))
  992. (`plain (org-capture-place-plain-text))
  993. (`item (org-capture-place-item))
  994. (`checkitem (org-capture-place-item)))
  995. (setq-local org-capture-current-plist org-capture-plist)
  996. (org-capture-mode 1))
  997. (defun org-capture-place-entry ()
  998. "Place the template as a new Org entry."
  999. (let ((template (org-capture-get :template))
  1000. (reversed? (org-capture-get :prepend))
  1001. (exact-position (org-capture-get :exact-position))
  1002. (insert-here? (org-capture-get :insert-here))
  1003. (level 1))
  1004. (org-capture-verify-tree template)
  1005. (when exact-position (goto-char exact-position))
  1006. (cond
  1007. ;; Force insertion at point.
  1008. ((org-capture-get :insert-here) nil)
  1009. ;; Insert as a child of the current entry.
  1010. ((org-capture-get :target-entry-p)
  1011. (setq level (org-get-valid-level
  1012. (if (org-at-heading-p) (org-outline-level) 1)
  1013. 1))
  1014. (if reversed? (outline-next-heading) (org-end-of-subtree t t)))
  1015. ;; Insert as a top-level entry at the beginning of the file.
  1016. (reversed?
  1017. (goto-char (point-min))
  1018. (unless (org-at-heading-p) (outline-next-heading)))
  1019. ;; Otherwise, insert as a top-level entry at the end of the file.
  1020. (t (goto-char (point-max))))
  1021. (let ((origin (point)))
  1022. (unless (bolp) (insert "\n"))
  1023. (org-capture-empty-lines-before)
  1024. (let ((beg (point)))
  1025. (save-restriction
  1026. (when insert-here? (narrow-to-region beg beg))
  1027. (org-paste-subtree level template 'for-yank))
  1028. (org-capture-position-for-last-stored beg)
  1029. (org-capture-empty-lines-after)
  1030. (unless (org-at-heading-p) (outline-next-heading))
  1031. (org-capture-mark-kill-region origin (point))
  1032. (org-capture-narrow beg (if (eobp) (point) (1- (point))))
  1033. (org-capture--position-cursor beg (point))))))
  1034. (defun org-capture-place-item ()
  1035. "Place the template as a new plain list item."
  1036. (let ((prepend? (org-capture-get :prepend))
  1037. (template (org-remove-indentation (org-capture-get :template)))
  1038. item)
  1039. ;; Make template suitable for insertion. In particular, add
  1040. ;; a main bullet if it is missing.
  1041. (unless (string-match-p (concat "\\`" (org-item-re)) template)
  1042. (setq template (concat "- " (mapconcat #'identity
  1043. (split-string template "\n")
  1044. "\n "))))
  1045. ;; Delimit the area where we should look for a plain list.
  1046. (pcase-let ((`(,beg . ,end)
  1047. (cond ((org-capture-get :exact-position)
  1048. ;; User gave a specific position. Start
  1049. ;; looking for lists from here.
  1050. (org-with-point-at (org-capture-get :exact-position)
  1051. (cons (line-beginning-position)
  1052. (if (org-capture-get :insert-here)
  1053. (line-beginning-position)
  1054. (org-entry-end-position)))))
  1055. ((org-capture-get :target-entry-p)
  1056. ;; At a heading, limit search to its body.
  1057. (cons (line-beginning-position 2)
  1058. (org-entry-end-position)))
  1059. (t
  1060. ;; Table is not necessarily under a heading.
  1061. ;; Search whole buffer.
  1062. (cons (point-min) (point-max))))))
  1063. ;; Find the first plain list in the delimited area.
  1064. (goto-char beg)
  1065. (let ((item-regexp (org-item-beginning-re)))
  1066. (catch :found
  1067. (while (re-search-forward item-regexp end t)
  1068. (when (setq item (org-element-lineage
  1069. (org-element-at-point) '(plain-list) t))
  1070. (goto-char (org-element-property (if prepend? :post-affiliated
  1071. :contents-end)
  1072. item))
  1073. (throw :found t)))
  1074. ;; No list found. Move to the location when to insert
  1075. ;; template. Skip planning info and properties drawers, if
  1076. ;; any.
  1077. (goto-char (cond ((org-capture-get :insert-here) beg)
  1078. ((not prepend?) end)
  1079. ((org-before-first-heading-p) beg)
  1080. (t (max (save-excursion
  1081. (org-end-of-meta-data)
  1082. (point))
  1083. beg)))))))
  1084. ;; Insert template.
  1085. (let ((origin (point)))
  1086. (unless (bolp) (insert "\n"))
  1087. ;; When a new list is created, always obey to `:empty-lines' and
  1088. ;; friends.
  1089. ;;
  1090. ;; When capturing in an existing list, do not change blank lines
  1091. ;; above or below the list; consider it to be a stable
  1092. ;; structure. However, we can control how many blank lines
  1093. ;; separate items. So obey to `:empty-lines' between items as
  1094. ;; long as it does not insert more than one empty line. In the
  1095. ;; specific case of empty lines above, it means we only obey the
  1096. ;; parameter when appending an item.
  1097. (unless (and item prepend?)
  1098. (org-capture-empty-lines-before
  1099. (and item
  1100. (not prepend?)
  1101. (min 1 (or (org-capture-get :empty-lines-before)
  1102. (org-capture-get :empty-lines)
  1103. 0)))))
  1104. (org-capture-position-for-last-stored (point))
  1105. (let ((beg (line-beginning-position))
  1106. (end (progn
  1107. (insert (org-trim template) "\n")
  1108. (point-marker))))
  1109. (when item
  1110. (let ((i (save-excursion
  1111. (goto-char (org-element-property :post-affiliated item))
  1112. (current-indentation))))
  1113. (save-excursion
  1114. (goto-char beg)
  1115. (save-excursion
  1116. (while (< (point) end)
  1117. (indent-to i)
  1118. (forward-line)))
  1119. ;; Pre-pending an item could change the type of the list
  1120. ;; if there is a mismatch. In this situation,
  1121. ;; prioritize the existing list.
  1122. (when prepend?
  1123. (let ((ordered? (eq 'ordered (org-element-property :type item))))
  1124. (when (org-xor ordered?
  1125. (string-match-p "\\`[A-Za-z0-9]\\([.)]\\)"
  1126. template))
  1127. (org-cycle-list-bullet (if ordered? "1." "-")))))
  1128. ;; Eventually repair the list for proper indentation and
  1129. ;; bullets.
  1130. (org-list-repair))))
  1131. ;; Limit number of empty lines. See above for details.
  1132. (unless (and item (not prepend?))
  1133. (org-capture-empty-lines-after
  1134. (and item
  1135. prepend?
  1136. (min 1 (or (org-capture-get :empty-lines-after)
  1137. (org-capture-get :empty-lines)
  1138. 0)))))
  1139. (org-capture-mark-kill-region origin (point))
  1140. ;; ITEM always end with a newline character. Make sure we do
  1141. ;; not narrow at the beginning of the next line, possibly
  1142. ;; altering its structure (e.g., when it is a headline).
  1143. (org-capture-narrow beg (1- end))
  1144. (org-capture--position-cursor beg end)))))
  1145. (defun org-capture-place-table-line ()
  1146. "Place the template as a table line."
  1147. (require 'org-table)
  1148. (let ((text
  1149. (pcase (org-trim (org-capture-get :template))
  1150. ((pred (string-match-p org-table-border-regexp))
  1151. "| %?Bad template |")
  1152. (text (concat text "\n"))))
  1153. (table-line-pos (org-capture-get :table-line-pos))
  1154. beg end)
  1155. (cond
  1156. ((org-capture-get :exact-position)
  1157. (org-with-point-at (org-capture-get :exact-position)
  1158. (setq beg (line-beginning-position))
  1159. (setq end (if (org-capture-get :insert-here) beg
  1160. (org-entry-end-position)))))
  1161. ((not (org-capture-get :target-entry-p))
  1162. ;; Table is not necessarily under a heading. Find first table
  1163. ;; in the buffer.
  1164. (setq beg (point-min) end (point-max)))
  1165. (t
  1166. ;; We are at a heading, limit search to the body.
  1167. (setq beg (line-beginning-position 2))
  1168. (setq end (save-excursion (outline-next-heading) (point)))))
  1169. (goto-char beg)
  1170. ;; Narrow to the table, possibly creating one if necessary.
  1171. (catch :found
  1172. (while (re-search-forward org-table-dataline-regexp end t)
  1173. (pcase (org-element-lineage (org-element-at-point) '(table) t)
  1174. (`nil nil)
  1175. ((pred (lambda (e) (eq 'table.el (org-element-property :type e))))
  1176. nil)
  1177. (table
  1178. (goto-char (org-element-property :contents-end table))
  1179. (narrow-to-region (org-element-property :post-affiliated table)
  1180. (point))
  1181. (throw :found t))))
  1182. ;; No table found. Create it with an empty header.
  1183. (goto-char end)
  1184. (unless (bolp) (insert "\n"))
  1185. (let ((origin (point)))
  1186. (insert "| |\n|---|\n")
  1187. (narrow-to-region origin (point))))
  1188. ;; In the current table, find the appropriate location for TEXT.
  1189. (cond
  1190. ((org-capture-get :insert-here) nil)
  1191. ((and table-line-pos
  1192. (string-match "\\(I+\\)\\([-+][0-9]+\\)" table-line-pos))
  1193. (goto-char (point-min))
  1194. (let ((line
  1195. (condition-case _
  1196. (progn
  1197. (save-match-data (org-table-analyze))
  1198. (aref org-table-hlines
  1199. (- (match-end 1) (match-beginning 1))))
  1200. (error
  1201. (error "Invalid table line specification %S" table-line-pos))))
  1202. (delta (string-to-number (match-string 2 table-line-pos))))
  1203. (forward-line (+ line delta (if (< delta 0) 0 -1)))
  1204. (forward-line))) ;insert below
  1205. ((org-capture-get :prepend)
  1206. (goto-char (point-min))
  1207. (cond
  1208. ((not (re-search-forward org-table-hline-regexp nil t)))
  1209. ((re-search-forward org-table-dataline-regexp nil t) (beginning-of-line))
  1210. (t (goto-char (org-table-end)))))
  1211. (t
  1212. (goto-char (org-table-end))))
  1213. ;; Insert text and position point according to template.
  1214. (let ((origin (point)))
  1215. (unless (bolp) (insert "\n"))
  1216. (let ((beg (point))
  1217. (end (save-excursion
  1218. (insert text)
  1219. (point))))
  1220. (org-capture-position-for-last-stored 'table-line)
  1221. (org-capture-mark-kill-region origin end)
  1222. ;; TEXT is guaranteed to end with a newline character. Ignore
  1223. ;; it when narrowing so as to not alter data on the next line.
  1224. (org-capture-narrow beg (1- end))
  1225. (org-capture--position-cursor beg (1- end))))))
  1226. (defun org-capture-place-plain-text ()
  1227. "Place the template plainly.
  1228. If the target locator points at an Org node, place the template into
  1229. the text of the entry, before the first child. If not, place the
  1230. template at the beginning or end of the file.
  1231. Of course, if exact position has been required, just put it there."
  1232. (cond
  1233. ((org-capture-get :exact-position)
  1234. (goto-char (org-capture-get :exact-position)))
  1235. ((org-capture-get :target-entry-p)
  1236. ;; Place the text into this entry.
  1237. (if (org-capture-get :prepend)
  1238. ;; Skip meta data and drawers.
  1239. (org-end-of-meta-data t)
  1240. ;; Go to end of the entry text, before the next headline.
  1241. (outline-next-heading)))
  1242. (t
  1243. ;; Beginning or end of file.
  1244. (goto-char (if (org-capture-get :prepend) (point-min) (point-max)))))
  1245. (let ((origin (point)))
  1246. (unless (bolp) (insert "\n"))
  1247. (org-capture-empty-lines-before)
  1248. (org-capture-position-for-last-stored (point))
  1249. (let ((beg (point)))
  1250. (insert (org-capture-get :template))
  1251. (unless (bolp) (insert "\n"))
  1252. ;; Ignore the final newline character so as to not alter data
  1253. ;; after inserted text. Yet, if the template is empty, make
  1254. ;; sure END matches BEG instead of pointing before it.
  1255. (let ((end (max beg (1- (point)))))
  1256. (org-capture-empty-lines-after)
  1257. (org-capture-mark-kill-region origin (point))
  1258. (org-capture-narrow beg end)
  1259. (org-capture--position-cursor beg end)))))
  1260. (defun org-capture-mark-kill-region (beg end)
  1261. "Mark the region that will have to be killed when aborting capture."
  1262. (let ((m1 (copy-marker beg))
  1263. (m2 (copy-marker end t)))
  1264. (org-capture-put :begin-marker m1)
  1265. (org-capture-put :end-marker m2)))
  1266. (defun org-capture-position-for-last-stored (where)
  1267. "Memorize the position that should later become the position of last capture."
  1268. (cond
  1269. ((integerp where)
  1270. (org-capture-put :position-for-last-stored
  1271. (move-marker (make-marker) where
  1272. (or (buffer-base-buffer (current-buffer))
  1273. (current-buffer)))))
  1274. ((eq where 'table-line)
  1275. (org-capture-put :position-for-last-stored
  1276. (list 'table-line
  1277. (org-table-current-dline))))
  1278. (t (error "This should not happen"))))
  1279. (defun org-capture-store-last-position ()
  1280. "Store the last-captured position."
  1281. (let* ((where (org-capture-get :position-for-last-stored 'local))
  1282. (pos (cond
  1283. ((markerp where)
  1284. (prog1 (marker-position where)
  1285. (move-marker where nil)))
  1286. ((and (listp where) (eq (car where) 'table-line))
  1287. (if (org-at-table-p)
  1288. (save-excursion
  1289. (org-table-goto-line (nth 1 where))
  1290. (point-at-bol))
  1291. (point))))))
  1292. (with-current-buffer (buffer-base-buffer (current-buffer))
  1293. (org-with-point-at pos
  1294. (when org-capture-bookmark
  1295. (let ((bookmark (plist-get org-bookmark-names-plist :last-capture)))
  1296. (when bookmark (with-demoted-errors (bookmark-set bookmark)))))
  1297. (move-marker org-capture-last-stored-marker (point))))))
  1298. (defun org-capture-narrow (beg end)
  1299. "Narrow, unless configuration says not to narrow."
  1300. (unless (org-capture-get :unnarrowed)
  1301. (narrow-to-region beg end)))
  1302. (defun org-capture--position-cursor (beg end)
  1303. "Move point to first \"%?\" location or at start of template.
  1304. BEG and END are buffer positions at the beginning and end position
  1305. of the template."
  1306. (goto-char beg)
  1307. (when (search-forward "%?" end t)
  1308. (replace-match "")))
  1309. (defun org-capture-empty-lines-before (&optional n)
  1310. "Set the correct number of empty lines before the insertion point.
  1311. Point will be after the empty lines, so insertion can directly be done."
  1312. (setq n (or n (org-capture-get :empty-lines-before)
  1313. (org-capture-get :empty-lines) 0))
  1314. (let ((pos (point)))
  1315. (org-back-over-empty-lines)
  1316. (delete-region (point) pos)
  1317. (when (> n 0) (newline n))))
  1318. (defun org-capture-empty-lines-after (&optional n)
  1319. "Set the correct number of empty lines after the inserted string.
  1320. Point will remain at the first line after the inserted text."
  1321. (setq n (or n (org-capture-get :empty-lines-after)
  1322. (org-capture-get :empty-lines) 0))
  1323. (org-back-over-empty-lines)
  1324. (while (looking-at "[ \t]*\n") (replace-match ""))
  1325. (let ((pos (point)))
  1326. (when (> n 0) (newline n))
  1327. (goto-char pos)))
  1328. (defvar org-clock-marker) ; Defined in org.el
  1329. (defun org-capture-set-plist (entry)
  1330. "Initialize the property list from the template definition."
  1331. (setq org-capture-plist (copy-sequence (nthcdr 5 entry)))
  1332. (org-capture-put :key (car entry) :description (nth 1 entry)
  1333. :target (nth 3 entry))
  1334. (let ((txt (nth 4 entry)) (type (or (nth 2 entry) 'entry)))
  1335. (when (or (not txt) (and (stringp txt) (not (string-match "\\S-" txt))))
  1336. ;; The template may be empty or omitted for special types.
  1337. ;; Here we insert the default templates for such cases.
  1338. (cond
  1339. ((eq type 'item) (setq txt "- %?"))
  1340. ((eq type 'checkitem) (setq txt "- [ ] %?"))
  1341. ((eq type 'table-line) (setq txt "| %? |"))
  1342. ((member type '(nil entry)) (setq txt "* %?\n %a"))))
  1343. (org-capture-put :template txt :type type)))
  1344. (defun org-capture-goto-target (&optional template-key)
  1345. "Go to the target location of a capture template.
  1346. The user is queried for the template."
  1347. (interactive)
  1348. (let ((entry (org-capture-select-template template-key)))
  1349. (unless entry (error "No capture template selected"))
  1350. (org-capture-set-plist entry)
  1351. (org-capture-set-target-location)
  1352. (pop-to-buffer-same-window (org-capture-get :buffer))
  1353. (goto-char (org-capture-get :pos))))
  1354. (defun org-capture-get-indirect-buffer (&optional buffer prefix)
  1355. "Make an indirect buffer for a capture process.
  1356. Use PREFIX as a prefix for the name of the indirect buffer."
  1357. (setq buffer (or buffer (current-buffer)))
  1358. (let ((n 1) (base (buffer-name buffer)) bname)
  1359. (setq bname (concat prefix "-" base))
  1360. (while (buffer-live-p (get-buffer bname))
  1361. (setq bname (concat prefix "-" (number-to-string (cl-incf n)) "-" base)))
  1362. (condition-case nil
  1363. (make-indirect-buffer buffer bname 'clone)
  1364. (error
  1365. (let ((buf (make-indirect-buffer buffer bname)))
  1366. (with-current-buffer buf (org-mode))
  1367. buf)))))
  1368. (defun org-capture-verify-tree (tree)
  1369. "Throw error if TREE is not a valid tree."
  1370. (unless (org-kill-is-subtree-p tree)
  1371. (error "Template is not a valid Org entry or tree")))
  1372. ;;; The template code
  1373. (defun org-capture-select-template (&optional keys)
  1374. "Select a capture template.
  1375. Lisp programs can force the template by setting KEYS to a string."
  1376. (let ((org-capture-templates
  1377. (or (org-contextualize-keys
  1378. (org-capture-upgrade-templates org-capture-templates)
  1379. org-capture-templates-contexts)
  1380. '(("t" "Task" entry (file+headline "" "Tasks")
  1381. "* TODO %?\n %u\n %a")))))
  1382. (if keys
  1383. (or (assoc keys org-capture-templates)
  1384. (error "No capture template referred to by \"%s\" keys" keys))
  1385. (org-mks org-capture-templates
  1386. "Select a capture template\n========================="
  1387. "Template key: "
  1388. '(("C" "Customize org-capture-templates")
  1389. ("q" "Abort"))))))
  1390. (defvar org-capture--clipboards nil
  1391. "List various clipboards values.")
  1392. (defun org-capture-fill-template (&optional template initial annotation)
  1393. "Fill a template and return the filled template as a string.
  1394. The template may still contain \"%?\" for cursor positioning."
  1395. (let* ((template (or template (org-capture-get :template)))
  1396. (buffer (org-capture-get :buffer))
  1397. (file (buffer-file-name (or (buffer-base-buffer buffer) buffer)))
  1398. (time (let* ((c (or (org-capture-get :default-time) (current-time)))
  1399. (d (decode-time c)))
  1400. (if (< (nth 2 d) org-extend-today-until)
  1401. (encode-time 0 59 23 (1- (nth 3 d)) (nth 4 d) (nth 5 d))
  1402. c)))
  1403. (v-t (format-time-string (org-time-stamp-format nil) time))
  1404. (v-T (format-time-string (org-time-stamp-format t) time))
  1405. (v-u (format-time-string (org-time-stamp-format nil t) time))
  1406. (v-U (format-time-string (org-time-stamp-format t t) time))
  1407. (v-c (and kill-ring (current-kill 0)))
  1408. (v-x (or (org-get-x-clipboard 'PRIMARY)
  1409. (org-get-x-clipboard 'CLIPBOARD)
  1410. (org-get-x-clipboard 'SECONDARY)
  1411. "")) ;ensure it is a string
  1412. ;; `initial' and `annotation' might have been passed. But if
  1413. ;; the property list has them, we prefer those values.
  1414. (v-i (or (plist-get org-store-link-plist :initial)
  1415. (and (stringp initial) (org-no-properties initial))
  1416. (org-capture-get :initial)
  1417. ""))
  1418. (v-a
  1419. (let ((a (or (plist-get org-store-link-plist :annotation)
  1420. annotation
  1421. (org-capture-get :annotation)
  1422. "")))
  1423. ;; Is the link empty? Then we do not want it...
  1424. (if (equal a "[[]]") "" a)))
  1425. (l-re "\\[\\[\\(.*?\\)\\]\\(\\[.*?\\]\\)?\\]")
  1426. (v-A (if (and v-a (string-match l-re v-a))
  1427. (replace-match "[[\\1][%^{Link description}]]" nil nil v-a)
  1428. v-a))
  1429. (v-l (if (and v-a (string-match l-re v-a))
  1430. (replace-match "[[\\1]]" nil nil v-a)
  1431. v-a))
  1432. (v-n user-full-name)
  1433. (v-k (if (marker-buffer org-clock-marker)
  1434. (org-no-properties org-clock-heading)
  1435. ""))
  1436. (v-K (if (marker-buffer org-clock-marker)
  1437. (org-link-make-string
  1438. (format "%s::*%s"
  1439. (buffer-file-name (marker-buffer org-clock-marker))
  1440. v-k)
  1441. v-k)
  1442. ""))
  1443. (v-f (or (org-capture-get :original-file-nondirectory) ""))
  1444. (v-F (or (org-capture-get :original-file) ""))
  1445. (org-capture--clipboards
  1446. (delq nil
  1447. (list v-i
  1448. (org-get-x-clipboard 'PRIMARY)
  1449. (org-get-x-clipboard 'CLIPBOARD)
  1450. (org-get-x-clipboard 'SECONDARY)
  1451. v-c))))
  1452. (setq org-store-link-plist (plist-put org-store-link-plist :annotation v-a))
  1453. (setq org-store-link-plist (plist-put org-store-link-plist :initial v-i))
  1454. (unless template
  1455. (setq template "")
  1456. (message "no template") (ding)
  1457. (sit-for 1))
  1458. (save-window-excursion
  1459. (org-switch-to-buffer-other-window (get-buffer-create "*Capture*"))
  1460. (erase-buffer)
  1461. (setq buffer-file-name nil)
  1462. (setq mark-active nil)
  1463. (insert template)
  1464. (goto-char (point-min))
  1465. ;; %[] insert contents of a file.
  1466. (save-excursion
  1467. (while (re-search-forward "%\\[\\(.+\\)\\]" nil t)
  1468. (let ((filename (expand-file-name (match-string 1)))
  1469. (beg (copy-marker (match-beginning 0)))
  1470. (end (copy-marker (match-end 0))))
  1471. (unless (org-capture-escaped-%)
  1472. (delete-region beg end)
  1473. (set-marker beg nil)
  1474. (set-marker end nil)
  1475. (condition-case error
  1476. (insert-file-contents filename)
  1477. (error
  1478. (insert (format "%%![couldn not insert %s: %s]"
  1479. filename
  1480. error))))))))
  1481. ;; Mark %() embedded elisp for later evaluation.
  1482. (org-capture-expand-embedded-elisp 'mark)
  1483. ;; Expand non-interactive templates.
  1484. (let ((regexp "%\\(:[-A-Za-z]+\\|<\\([^>\n]+\\)>\\|[aAcfFikKlntTuUx]\\)"))
  1485. (save-excursion
  1486. (while (re-search-forward regexp nil t)
  1487. ;; `org-capture-escaped-%' may modify buffer and cripple
  1488. ;; match-data. Use markers instead. Ditto for other
  1489. ;; templates.
  1490. (let ((pos (copy-marker (match-beginning 0)))
  1491. (end (copy-marker (match-end 0)))
  1492. (value (match-string 1))
  1493. (time-string (match-string 2)))
  1494. (unless (org-capture-escaped-%)
  1495. (delete-region pos end)
  1496. (set-marker pos nil)
  1497. (set-marker end nil)
  1498. (let* ((inside-sexp? (org-capture-inside-embedded-elisp-p))
  1499. (replacement
  1500. (pcase (string-to-char value)
  1501. (?< (format-time-string time-string time))
  1502. (?:
  1503. (or (plist-get org-store-link-plist (intern value))
  1504. ""))
  1505. (?i
  1506. (if inside-sexp? v-i
  1507. ;; Outside embedded Lisp, repeat leading
  1508. ;; characters before initial place holder
  1509. ;; every line.
  1510. (let ((lead (concat "\n"
  1511. (org-current-line-string t))))
  1512. (replace-regexp-in-string "\n" lead v-i nil t))))
  1513. (?a v-a)
  1514. (?A v-A)
  1515. (?c v-c)
  1516. (?f v-f)
  1517. (?F v-F)
  1518. (?k v-k)
  1519. (?K v-K)
  1520. (?l v-l)
  1521. (?n v-n)
  1522. (?t v-t)
  1523. (?T v-T)
  1524. (?u v-u)
  1525. (?U v-U)
  1526. (?x v-x))))
  1527. (insert
  1528. (if inside-sexp?
  1529. ;; Escape sensitive characters.
  1530. (replace-regexp-in-string "[\\\"]" "\\\\\\&" replacement)
  1531. replacement))))))))
  1532. ;; Expand %() embedded Elisp. Limit to Sexp originally marked.
  1533. (org-capture-expand-embedded-elisp)
  1534. ;; Expand interactive templates. This is the last step so that
  1535. ;; template is mostly expanded when prompting happens. Turn on
  1536. ;; Org mode and set local variables. This is to support
  1537. ;; completion in interactive prompts.
  1538. (let ((org-inhibit-startup t)) (org-mode))
  1539. (org-clone-local-variables buffer "\\`org-")
  1540. (let (strings) ; Stores interactive answers.
  1541. (save-excursion
  1542. (let ((regexp "%\\^\\(?:{\\([^}]*\\)}\\)?\\([CgGLptTuU]\\)?"))
  1543. (while (re-search-forward regexp nil t)
  1544. (let* ((items (and (match-end 1)
  1545. (save-match-data
  1546. (split-string (match-string-no-properties 1)
  1547. "|"))))
  1548. (key (match-string 2))
  1549. (beg (copy-marker (match-beginning 0)))
  1550. (end (copy-marker (match-end 0)))
  1551. (prompt (nth 0 items))
  1552. (default (nth 1 items))
  1553. (completions (nthcdr 2 items)))
  1554. (unless (org-capture-escaped-%)
  1555. (delete-region beg end)
  1556. (set-marker beg nil)
  1557. (set-marker end nil)
  1558. (pcase key
  1559. ((or "G" "g")
  1560. (let* ((org-last-tags-completion-table
  1561. (org-global-tags-completion-table
  1562. (cond ((equal key "G") (org-agenda-files))
  1563. (file (list file))
  1564. (t nil))))
  1565. (org-add-colon-after-tag-completion t)
  1566. (ins (mapconcat
  1567. #'identity
  1568. (org-split-string
  1569. (completing-read
  1570. (if prompt (concat prompt ": ") "Tags: ")
  1571. 'org-tags-completion-function nil nil nil
  1572. 'org-tags-history)
  1573. "[^[:alnum:]_@#%]+")
  1574. ":")))
  1575. (when (org-string-nw-p ins)
  1576. (unless (eq (char-before) ?:) (insert ":"))
  1577. (insert ins)
  1578. (unless (eq (char-after) ?:) (insert ":"))
  1579. (when (org-at-heading-p) (org-align-tags)))))
  1580. ((or "C" "L")
  1581. (let ((insert-fun (if (equal key "C") #'insert
  1582. (lambda (s) (org-insert-link 0 s)))))
  1583. (pcase org-capture--clipboards
  1584. (`nil nil)
  1585. (`(,value) (funcall insert-fun value))
  1586. (`(,first-value . ,_)
  1587. (funcall insert-fun
  1588. (read-string "Clipboard/kill value: "
  1589. first-value
  1590. 'org-capture--clipboards
  1591. first-value)))
  1592. (_ (error "Invalid `org-capture--clipboards' value: %S"
  1593. org-capture--clipboards)))))
  1594. ("p"
  1595. ;; We remove keyword properties inherited from
  1596. ;; target buffer so `org-read-property-value' has
  1597. ;; a chance to find allowed values in sub-trees
  1598. ;; from the target buffer.
  1599. (setq-local org-keyword-properties nil)
  1600. (let* ((origin (set-marker (make-marker)
  1601. (org-capture-get :pos)
  1602. (org-capture-get :buffer)))
  1603. ;; Find location from where to get allowed
  1604. ;; values. If `:target-entry-p' is
  1605. ;; non-nil, the current headline in the
  1606. ;; target buffer is going to be a parent
  1607. ;; headline, so location is fine.
  1608. ;; Otherwise, find the parent headline in
  1609. ;; the target buffer.
  1610. (pom (if (org-capture-get :target-entry-p) origin
  1611. (let ((level (progn
  1612. (while (org-up-heading-safe))
  1613. (org-current-level))))
  1614. (org-with-point-at origin
  1615. (let ((l (if (org-at-heading-p)
  1616. (org-current-level)
  1617. most-positive-fixnum)))
  1618. (while (and l (>= l level))
  1619. (setq l (org-up-heading-safe)))
  1620. (if l (point-marker)
  1621. (point-min-marker)))))))
  1622. (value (org-read-property-value prompt pom)))
  1623. (org-set-property prompt value)))
  1624. ((or "t" "T" "u" "U")
  1625. ;; These are the date/time related ones.
  1626. (let* ((upcase? (equal (upcase key) key))
  1627. (org-end-time-was-given nil)
  1628. (time (org-read-date upcase? t nil prompt)))
  1629. (org-insert-time-stamp
  1630. time (or org-time-was-given upcase?)
  1631. (member key '("u" "U"))
  1632. nil nil (list org-end-time-was-given))))
  1633. (`nil
  1634. ;; Load history list for current prompt.
  1635. (setq org-capture--prompt-history
  1636. (gethash prompt org-capture--prompt-history-table))
  1637. (push (org-completing-read
  1638. (concat (or prompt "Enter string")
  1639. (and default (format " [%s]" default))
  1640. ": ")
  1641. completions
  1642. nil nil nil 'org-capture--prompt-history default)
  1643. strings)
  1644. (insert (car strings))
  1645. ;; Save updated history list for current prompt.
  1646. (puthash prompt org-capture--prompt-history
  1647. org-capture--prompt-history-table))
  1648. (_
  1649. (error "Unknown template placeholder: \"%%^%s\""
  1650. key))))))))
  1651. ;; Replace %n escapes with nth %^{...} string.
  1652. (setq strings (nreverse strings))
  1653. (save-excursion
  1654. (while (re-search-forward "%\\\\\\([1-9][0-9]*\\)" nil t)
  1655. (unless (org-capture-escaped-%)
  1656. (replace-match
  1657. (nth (1- (string-to-number (match-string 1))) strings)
  1658. nil t)))))
  1659. ;; Make sure there are no empty lines before the text, and that
  1660. ;; it ends with a newline character or it is empty.
  1661. (skip-chars-forward " \t\n")
  1662. (delete-region (point-min) (line-beginning-position))
  1663. (goto-char (point-max))
  1664. (skip-chars-backward " \t\n")
  1665. (if (bobp) (delete-region (point) (line-end-position))
  1666. (end-of-line)
  1667. (delete-region (point) (point-max))
  1668. (insert "\n"))
  1669. ;; Return the expanded template and kill the capture buffer.
  1670. (untabify (point-min) (point-max))
  1671. (set-buffer-modified-p nil)
  1672. (prog1 (buffer-substring-no-properties (point-min) (point-max))
  1673. (kill-buffer (current-buffer))))))
  1674. (defun org-capture-escaped-% ()
  1675. "Non-nil if % was escaped.
  1676. If yes, unescape it now. Assume match-data contains the
  1677. placeholder to check."
  1678. (save-excursion
  1679. (goto-char (match-beginning 0))
  1680. (let ((n (abs (skip-chars-backward "\\\\"))))
  1681. (delete-char (/ (1+ n) 2))
  1682. (= (% n 2) 1))))
  1683. (defun org-capture-expand-embedded-elisp (&optional mark)
  1684. "Evaluate embedded elisp %(sexp) and replace with the result.
  1685. When optional MARK argument is non-nil, mark Sexp with a text
  1686. property (`org-embedded-elisp') for later evaluation. Only
  1687. marked Sexp are evaluated when this argument is nil."
  1688. (save-excursion
  1689. (goto-char (point-min))
  1690. (while (re-search-forward "%(" nil t)
  1691. (cond
  1692. ((get-text-property (match-beginning 0) 'org-embedded-elisp)
  1693. (goto-char (match-beginning 0))
  1694. (let ((template-start (point)))
  1695. (forward-char 1)
  1696. (let* ((sexp (read (current-buffer)))
  1697. (result (org-eval
  1698. (org-capture--expand-keyword-in-embedded-elisp
  1699. sexp))))
  1700. (delete-region template-start (point))
  1701. (cond
  1702. ((not result) nil)
  1703. ((stringp result) (insert result))
  1704. (t (error
  1705. "Capture template sexp `%s' must evaluate to string or nil"
  1706. sexp))))))
  1707. ((not mark) nil)
  1708. ;; Only mark valid and non-escaped sexp.
  1709. ((org-capture-escaped-%) nil)
  1710. (t
  1711. (let ((end (with-syntax-table emacs-lisp-mode-syntax-table
  1712. (ignore-errors (scan-sexps (1- (point)) 1)))))
  1713. (when end
  1714. (put-text-property (- (point) 2) end 'org-embedded-elisp t))))))))
  1715. (defun org-capture--expand-keyword-in-embedded-elisp (attr)
  1716. "Recursively replace capture link keywords in ATTR sexp.
  1717. Such keywords are prefixed with \"%:\". See
  1718. `org-capture-template' for more information."
  1719. (cond ((consp attr)
  1720. (mapcar 'org-capture--expand-keyword-in-embedded-elisp attr))
  1721. ((symbolp attr)
  1722. (let* ((attr-symbol (symbol-name attr))
  1723. (key (and (string-match "%\\(:.*\\)" attr-symbol)
  1724. (intern (match-string 1 attr-symbol)))))
  1725. (or (plist-get org-store-link-plist key)
  1726. attr)))
  1727. (t attr)))
  1728. (defun org-capture-inside-embedded-elisp-p ()
  1729. "Non-nil if point is inside of embedded elisp %(sexp).
  1730. Assume sexps have been marked with
  1731. `org-capture-expand-embedded-elisp' beforehand."
  1732. (get-text-property (point) 'org-embedded-elisp))
  1733. ;;;###autoload
  1734. (defun org-capture-import-remember-templates ()
  1735. "Set `org-capture-templates' to be similar to `org-remember-templates'."
  1736. (interactive)
  1737. (when (and (yes-or-no-p
  1738. "Import old remember templates into org-capture-templates? ")
  1739. (yes-or-no-p
  1740. "Note that this will remove any templates currently defined in `org-capture-templates'. Do you still want to go ahead? "))
  1741. (require 'org-remember)
  1742. (setq org-capture-templates
  1743. (mapcar
  1744. (lambda (entry)
  1745. (let ((desc (car entry))
  1746. (key (char-to-string (nth 1 entry)))
  1747. (template (nth 2 entry))
  1748. (file (or (nth 3 entry) org-default-notes-file))
  1749. (position (or (nth 4 entry) org-remember-default-headline))
  1750. (type 'entry)
  1751. (prepend org-reverse-note-order)
  1752. immediate target jump-to-captured)
  1753. (cond
  1754. ((member position '(top bottom))
  1755. (setq target (list 'file file)
  1756. prepend (eq position 'top)))
  1757. ((eq position 'date-tree)
  1758. (setq target (list 'file+datetree file)
  1759. prepend nil))
  1760. (t (setq target (list 'file+headline file position))))
  1761. (when (string-match "%!" template)
  1762. (setq template (replace-match "" t t template)
  1763. immediate t))
  1764. (when (string-match "%&" template)
  1765. (setq jump-to-captured t))
  1766. (append (list key desc type target template)
  1767. (and prepend '(:prepend t))
  1768. (and immediate '(:immediate-finish t))
  1769. (and jump-to-captured '(:jump-to-captured t)))))
  1770. org-remember-templates))))
  1771. (provide 'org-capture)
  1772. ;; Local variables:
  1773. ;; generated-autoload-file: "org-loaddefs.el"
  1774. ;; End:
  1775. ;;; org-capture.el ends here