ol.el 69 KB

12345678910111213141516171819202122232425262728293031323334353637383940414243444546474849505152535455565758596061626364656667686970717273747576777879808182838485868788899091929394959697989910010110210310410510610710810911011111211311411511611711811912012112212312412512612712812913013113213313413513613713813914014114214314414514614714814915015115215315415515615715815916016116216316416516616716816917017117217317417517617717817918018118218318418518618718818919019119219319419519619719819920020120220320420520620720820921021121221321421521621721821922022122222322422522622722822923023123223323423523623723823924024124224324424524624724824925025125225325425525625725825926026126226326426526626726826927027127227327427527627727827928028128228328428528628728828929029129229329429529629729829930030130230330430530630730830931031131231331431531631731831932032132232332432532632732832933033133233333433533633733833934034134234334434534634734834935035135235335435535635735835936036136236336436536636736836937037137237337437537637737837938038138238338438538638738838939039139239339439539639739839940040140240340440540640740840941041141241341441541641741841942042142242342442542642742842943043143243343443543643743843944044144244344444544644744844945045145245345445545645745845946046146246346446546646746846947047147247347447547647747847948048148248348448548648748848949049149249349449549649749849950050150250350450550650750850951051151251351451551651751851952052152252352452552652752852953053153253353453553653753853954054154254354454554654754854955055155255355455555655755855956056156256356456556656756856957057157257357457557657757857958058158258358458558658758858959059159259359459559659759859960060160260360460560660760860961061161261361461561661761861962062162262362462562662762862963063163263363463563663763863964064164264364464564664764864965065165265365465565665765865966066166266366466566666766866967067167267367467567667767867968068168268368468568668768868969069169269369469569669769869970070170270370470570670770870971071171271371471571671771871972072172272372472572672772872973073173273373473573673773873974074174274374474574674774874975075175275375475575675775875976076176276376476576676776876977077177277377477577677777877978078178278378478578678778878979079179279379479579679779879980080180280380480580680780880981081181281381481581681781881982082182282382482582682782882983083183283383483583683783883984084184284384484584684784884985085185285385485585685785885986086186286386486586686786886987087187287387487587687787887988088188288388488588688788888989089189289389489589689789889990090190290390490590690790890991091191291391491591691791891992092192292392492592692792892993093193293393493593693793893994094194294394494594694794894995095195295395495595695795895996096196296396496596696796896997097197297397497597697797897998098198298398498598698798898999099199299399499599699799899910001001100210031004100510061007100810091010101110121013101410151016101710181019102010211022102310241025102610271028102910301031103210331034103510361037103810391040104110421043104410451046104710481049105010511052105310541055105610571058105910601061106210631064106510661067106810691070107110721073107410751076107710781079108010811082108310841085108610871088108910901091109210931094109510961097109810991100110111021103110411051106110711081109111011111112111311141115111611171118111911201121112211231124112511261127112811291130113111321133113411351136113711381139114011411142114311441145114611471148114911501151115211531154115511561157115811591160116111621163116411651166116711681169117011711172117311741175117611771178117911801181118211831184118511861187118811891190119111921193119411951196119711981199120012011202120312041205120612071208120912101211121212131214121512161217121812191220122112221223122412251226122712281229123012311232123312341235123612371238123912401241124212431244124512461247124812491250125112521253125412551256125712581259126012611262126312641265126612671268126912701271127212731274127512761277127812791280128112821283128412851286128712881289129012911292129312941295129612971298129913001301130213031304130513061307130813091310131113121313131413151316131713181319132013211322132313241325132613271328132913301331133213331334133513361337133813391340134113421343134413451346134713481349135013511352135313541355135613571358135913601361136213631364136513661367136813691370137113721373137413751376137713781379138013811382138313841385138613871388138913901391139213931394139513961397139813991400140114021403140414051406140714081409141014111412141314141415141614171418141914201421142214231424142514261427142814291430143114321433143414351436143714381439144014411442144314441445144614471448144914501451145214531454145514561457145814591460146114621463146414651466146714681469147014711472147314741475147614771478147914801481148214831484148514861487148814891490149114921493149414951496149714981499150015011502150315041505150615071508150915101511151215131514151515161517151815191520152115221523152415251526152715281529153015311532153315341535153615371538153915401541154215431544154515461547154815491550155115521553155415551556155715581559156015611562156315641565156615671568156915701571157215731574157515761577157815791580158115821583158415851586158715881589159015911592159315941595159615971598159916001601160216031604160516061607160816091610161116121613161416151616161716181619162016211622162316241625162616271628162916301631163216331634163516361637163816391640164116421643164416451646164716481649165016511652165316541655165616571658165916601661166216631664166516661667166816691670167116721673167416751676167716781679168016811682168316841685168616871688168916901691169216931694169516961697169816991700170117021703170417051706170717081709171017111712171317141715171617171718171917201721172217231724172517261727172817291730173117321733173417351736173717381739174017411742174317441745174617471748174917501751175217531754175517561757175817591760176117621763176417651766176717681769177017711772177317741775177617771778177917801781178217831784178517861787178817891790179117921793179417951796179717981799180018011802180318041805180618071808180918101811181218131814181518161817181818191820182118221823182418251826182718281829183018311832183318341835183618371838183918401841184218431844184518461847184818491850185118521853185418551856185718581859186018611862186318641865186618671868186918701871187218731874187518761877187818791880188118821883188418851886188718881889189018911892189318941895189618971898189919001901190219031904190519061907
  1. ;;; ol.el --- Org links library -*- lexical-binding: t; -*-
  2. ;; Copyright (C) 2018 Free Software Foundation, Inc.
  3. ;; Author: Carsten Dominik <carsten at orgmode dot org>
  4. ;; Keywords: outlines, hypermedia, calendar, wp
  5. ;; This program is free software; you can redistribute it and/or modify
  6. ;; it under the terms of the GNU General Public License as published by
  7. ;; the Free Software Foundation, either version 3 of the License, or
  8. ;; (at your option) any later version.
  9. ;; This program is distributed in the hope that it will be useful,
  10. ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  11. ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  12. ;; GNU General Public License for more details.
  13. ;; You should have received a copy of the GNU General Public License
  14. ;; along with this program. If not, see <https://www.gnu.org/licenses/>.
  15. ;;; Commentary:
  16. ;; This library provides tooling to handle both external and internal
  17. ;; links.
  18. ;;; Code:
  19. (require 'org-compat)
  20. (require 'org-macs)
  21. (defvar clean-buffer-list-kill-buffer-names)
  22. (defvar org-agenda-buffer-name)
  23. (defvar org-comment-string)
  24. (defvar org-highlight-links)
  25. (defvar org-id-link-to-org-use-id)
  26. (defvar org-inhibit-startup)
  27. (defvar org-outline-regexp-bol)
  28. (defvar org-src-source-file-name)
  29. (defvar org-time-stamp-formats)
  30. (defvar org-ts-regexp)
  31. (declare-function calendar-cursor-to-date "calendar" (&optional error event))
  32. (declare-function dired-get-filename "dired" (&optional localp no-error-if-not-filep))
  33. (declare-function org-at-heading-p "org" (&optional _))
  34. (declare-function org-back-to-heading "org" (&optional invisible-ok))
  35. (declare-function org-do-occur "org" (regexp &optional cleanup))
  36. (declare-function org-element-at-point "org-element" ())
  37. (declare-function org-element-cache-refresh "org-element" (pos))
  38. (declare-function org-element-context "org-element" (&optional element))
  39. (declare-function org-element-lineage "org-element" (datum &optional types with-self))
  40. (declare-function org-element-link-parser "org-element" ())
  41. (declare-function org-element-property "org-element" (property element))
  42. (declare-function org-element-type "org-element" (element))
  43. (declare-function org-element-update-syntax "org-element" ())
  44. (declare-function org-entry-get "org" (pom property &optional inherit literal-nil))
  45. (declare-function org-find-property "org" (property &optional value))
  46. (declare-function org-get-heading "org" (&optional no-tags no-todo no-priority no-comment))
  47. (declare-function org-heading-components "org" ())
  48. (declare-function org-id-find-id-file "org-id" (id))
  49. (declare-function org-id-store-link "org-id" ())
  50. (declare-function org-insert-heading "org" (&optional arg invisible-ok top))
  51. (declare-function org-load-modules-maybe "org" (&optional force))
  52. (declare-function org-mark-ring-push "org" (&optional pos buffer))
  53. (declare-function org-occur "org" (regexp &optional keep-previous callback))
  54. (declare-function org-open-file "org" (path &optional in-emacs line search))
  55. (declare-function org-overview "org" ())
  56. (declare-function org-restart-font-lock "org" ())
  57. (declare-function org-show-context "org" (&optional key))
  58. (declare-function org-src-coderef-format "org-src" (&optional element))
  59. (declare-function org-src-coderef-regexp "org-src" (fmt &optional label))
  60. (declare-function org-src-edit-buffer-p "org-src" (&optional buffer))
  61. (declare-function org-src-source-buffer "org-src" ())
  62. (declare-function org-src-source-type "org-src" ())
  63. (declare-function org-time-stamp-format "org" (&optional long inactive))
  64. (declare-function outline-next-heading "outline" ())
  65. ;;; Customization
  66. (defgroup org-link nil
  67. "Options concerning links in Org mode."
  68. :tag "Org Link"
  69. :group 'org)
  70. (defcustom org-link-parameters nil
  71. "An alist of properties that defines all the links in Org mode.
  72. The key in each association is a string of the link type.
  73. Subsequent optional elements make up a plist of link properties.
  74. :follow - A function that takes the link path as an argument.
  75. :export - A function that takes the link path, description and
  76. export-backend as arguments.
  77. :store - A function responsible for storing the link. See the
  78. function `org-store-link-functions'.
  79. :complete - A function that inserts a link with completion. The
  80. function takes one optional prefix argument.
  81. :face - A face for the link, or a function that returns a face.
  82. The function takes one argument which is the link path. The
  83. default face is `org-link'.
  84. :mouse-face - The mouse-face. The default is `highlight'.
  85. :display - `full' will not fold the link in descriptive
  86. display. Default is `org-link'.
  87. :help-echo - A string or function that takes (window object position)
  88. as arguments and returns a string.
  89. :keymap - A keymap that is active on the link. The default is
  90. `org-mouse-map'.
  91. :htmlize-link - A function for the htmlize-link. Defaults
  92. to (list :uri \"type:path\")
  93. :activate-func - A function to run at the end of font-lock
  94. activation. The function must accept (link-start link-end path bracketp)
  95. as arguments."
  96. :group 'org-link
  97. :package-version '(Org . "9.1")
  98. :type '(alist :tag "Link display parameters"
  99. :value-type plist)
  100. :safe nil)
  101. (defcustom org-link-descriptive t
  102. "Non-nil means Org displays descriptive links.
  103. E.g. [[https://orgmode.org][Org website]] is be displayed as
  104. \"Org Website\", hiding the link itself and just displaying its
  105. description. When set to nil, Org displays the full links
  106. literally.
  107. You can interactively set the value of this variable by calling
  108. `org-toggle-link-display' or from the \"Org > Hyperlinks\" menu."
  109. :group 'org-link
  110. :type 'boolean
  111. :safe #'booleanp)
  112. (defcustom org-link-make-description-function nil
  113. "Function to use for generating link descriptions from links.
  114. This function must take two parameters: the first one is the
  115. link, the second one is the description generated by
  116. `org-insert-link'. The function should return the description to
  117. use."
  118. :group 'org-link
  119. :type '(choice (const nil) (function))
  120. :safe #'null)
  121. (defcustom org-link-file-path-type 'adaptive
  122. "How the path name in file links should be stored.
  123. Valid values are:
  124. relative Relative to the current directory, i.e. the directory of the file
  125. into which the link is being inserted.
  126. absolute Absolute path, if possible with ~ for home directory.
  127. noabbrev Absolute path, no abbreviation of home directory.
  128. adaptive Use relative path for files in the current directory and sub-
  129. directories of it. For other files, use an absolute path."
  130. :group 'org-link
  131. :type '(choice
  132. (const relative)
  133. (const absolute)
  134. (const noabbrev)
  135. (const adaptive))
  136. :safe #'symbolp)
  137. (defcustom org-link-abbrev-alist nil
  138. "Alist of link abbreviations.
  139. The car of each element is a string, to be replaced at the start of a link.
  140. The cdrs are replacement values, like (\"linkkey\" . REPLACE). Abbreviated
  141. links in Org buffers can have an optional tag after a double colon, e.g.,
  142. [[linkkey:tag][description]]
  143. The `linkkey' must be a single word, starting with a letter, followed
  144. by letters, numbers, `-' or `_'.
  145. If REPLACE is a string, the tag will simply be appended to create the link.
  146. If the string contains \"%s\", the tag will be inserted there. If the string
  147. contains \"%h\", it will cause a url-encoded version of the tag to be inserted
  148. at that point (see the function `url-hexify-string'). If the string contains
  149. the specifier \"%(my-function)\", then the custom function `my-function' will
  150. be invoked: this function takes the tag as its only argument and must return
  151. a string.
  152. REPLACE may also be a function that will be called with the tag as the
  153. only argument to create the link, which should be returned as a string.
  154. See the manual for examples."
  155. :group 'org-link
  156. :type '(repeat
  157. (cons (string :tag "Protocol")
  158. (choice
  159. (string :tag "Format")
  160. (function))))
  161. :safe (lambda (val)
  162. (pcase val
  163. (`(,(pred stringp) . ,(pred stringp)) t)
  164. (_ nil))))
  165. (defgroup org-link-follow nil
  166. "Options concerning following links in Org mode."
  167. :tag "Org Follow Link"
  168. :group 'org-link)
  169. (defcustom org-link-translation-function nil
  170. "Function to translate links with different syntax to Org syntax.
  171. This can be used to translate links created for example by the Planner
  172. or emacs-wiki packages to Org syntax.
  173. The function must accept two parameters, a TYPE containing the link
  174. protocol name like \"rmail\" or \"gnus\" as a string, and the linked path,
  175. which is everything after the link protocol. It should return a cons
  176. with possibly modified values of type and path.
  177. Org contains a function for this, so if you set this variable to
  178. `org-translate-link-from-planner', you should be able follow many
  179. links created by planner."
  180. :group 'org-link-follow
  181. :type '(choice (const nil) (function))
  182. :safe #'null)
  183. (defcustom org-link-doi-server-url "http://dx.doi.org/"
  184. "The URL of the DOI server."
  185. :group 'org-link-follow
  186. :version "24.3"
  187. :type 'string
  188. :safe #'stringp)
  189. (defcustom org-link-frame-setup
  190. '((vm . vm-visit-folder-other-frame)
  191. (vm-imap . vm-visit-imap-folder-other-frame)
  192. (gnus . org-gnus-no-new-news)
  193. (file . find-file-other-window)
  194. (wl . wl-other-frame))
  195. "Setup the frame configuration for following links.
  196. When following a link with Emacs, it may often be useful to display
  197. this link in another window or frame. This variable can be used to
  198. set this up for the different types of links.
  199. For VM, use any of
  200. `vm-visit-folder'
  201. `vm-visit-folder-other-window'
  202. `vm-visit-folder-other-frame'
  203. For Gnus, use any of
  204. `gnus'
  205. `gnus-other-frame'
  206. `org-gnus-no-new-news'
  207. For FILE, use any of
  208. `find-file'
  209. `find-file-other-window'
  210. `find-file-other-frame'
  211. For Wanderlust use any of
  212. `wl'
  213. `wl-other-frame'
  214. For the calendar, use the variable `calendar-setup'.
  215. For BBDB, it is currently only possible to display the matches in
  216. another window."
  217. :group 'org-link-follow
  218. :type '(list
  219. (cons (const vm)
  220. (choice
  221. (const vm-visit-folder)
  222. (const vm-visit-folder-other-window)
  223. (const vm-visit-folder-other-frame)))
  224. (cons (const vm-imap)
  225. (choice
  226. (const vm-visit-imap-folder)
  227. (const vm-visit-imap-folder-other-window)
  228. (const vm-visit-imap-folder-other-frame)))
  229. (cons (const gnus)
  230. (choice
  231. (const gnus)
  232. (const gnus-other-frame)
  233. (const org-gnus-no-new-news)))
  234. (cons (const file)
  235. (choice
  236. (const find-file)
  237. (const find-file-other-window)
  238. (const find-file-other-frame)))
  239. (cons (const wl)
  240. (choice
  241. (const wl)
  242. (const wl-other-frame))))
  243. :safe nil)
  244. (defcustom org-link-search-must-match-exact-headline 'query-to-create
  245. "Non-nil means internal fuzzy links can only match headlines.
  246. When nil, the a fuzzy link may point to a target or a named
  247. construct in the document. When set to the special value
  248. `query-to-create', offer to create a new headline when none
  249. matched.
  250. Spaces and statistics cookies are ignored during heading searches."
  251. :group 'org-link-follow
  252. :version "24.1"
  253. :type '(choice
  254. (const :tag "Use fuzzy text search" nil)
  255. (const :tag "Match only exact headline" t)
  256. (const :tag "Match exact headline or query to create it"
  257. query-to-create))
  258. :safe #'symbolp)
  259. (defcustom org-link-use-indirect-buffer-for-internals nil
  260. "Non-nil means use indirect buffer to display infile links.
  261. Activating internal links (from one location in a file to another location
  262. in the same file) normally just jumps to the location. When the link is
  263. activated with a `\\[universal-argument]' prefix (or with mouse-3), the link \
  264. is displayed in
  265. another window. When this option is set, the other window actually displays
  266. an indirect buffer clone of the current buffer, to avoid any visibility
  267. changes to the current buffer."
  268. :group 'org-link-follow
  269. :type 'boolean
  270. :safe #'booleanp)
  271. (defcustom org-link-shell-confirm-function 'yes-or-no-p
  272. "Non-nil means ask for confirmation before executing shell links.
  273. Shell links can be dangerous: just think about a link
  274. [[shell:rm -rf ~/*][Google Search]]
  275. This link would show up in your Org document as \"Google Search\",
  276. but really it would remove your entire home directory.
  277. Therefore we advise against setting this variable to nil.
  278. Just change it to `y-or-n-p' if you want to confirm with a
  279. single keystroke rather than having to type \"yes\"."
  280. :group 'org-link-follow
  281. :type '(choice
  282. (const :tag "with yes-or-no (safer)" yes-or-no-p)
  283. (const :tag "with y-or-n (faster)" y-or-n-p)
  284. (const :tag "no confirmation (dangerous)" nil))
  285. :safe nil)
  286. (defcustom org-link-shell-skip-confirm-regexp ""
  287. "Regexp to skip confirmation for shell links."
  288. :group 'org-link-follow
  289. :version "24.1"
  290. :type 'regexp
  291. :safe nil)
  292. (defcustom org-link-elisp-confirm-function 'yes-or-no-p
  293. "Non-nil means ask for confirmation before executing Emacs Lisp links.
  294. Elisp links can be dangerous: just think about a link
  295. [[elisp:(shell-command \"rm -rf ~/*\")][Google Search]]
  296. This link would show up in your Org document as \"Google Search\",
  297. but really it would remove your entire home directory.
  298. Therefore we advise against setting this variable to nil.
  299. Just change it to `y-or-n-p' if you want to confirm with a
  300. single keystroke rather than having to type \"yes\"."
  301. :group 'org-link-follow
  302. :type '(choice
  303. (const :tag "with yes-or-no (safer)" yes-or-no-p)
  304. (const :tag "with y-or-n (faster)" y-or-n-p)
  305. (const :tag "no confirmation (dangerous)" nil))
  306. :safe nil)
  307. (defcustom org-link-elisp-skip-confirm-regexp ""
  308. "A regexp to skip confirmation for Elisp links."
  309. :group 'org-link-follow
  310. :version "24.1"
  311. :type 'regexp
  312. :safe nil)
  313. (defgroup org-link-store nil
  314. "Options concerning storing links in Org mode."
  315. :tag "Org Store Link"
  316. :group 'org-link)
  317. (defcustom org-link-context-for-files t
  318. "Non-nil means file links from `org-store-link' contain context.
  319. \\<org-mode-map>
  320. A search string is added to the file name with \"::\" as separator
  321. and used to find the context when the link is activated by the command
  322. `org-open-at-point'. When this option is t, the entire active region
  323. is be placed in the search string of the file link. If set to a
  324. positive integer N, only the first N lines of context are stored.
  325. Using a prefix argument to the command `org-store-link' \
  326. \(`\\[universal-argument] \\[org-store-link]')
  327. negates this setting for the duration of the command."
  328. :group 'org-link-store
  329. :type '(choice boolean integer)
  330. :safe (lambda (val) (or (booleanp val) (integerp val))))
  331. (defcustom org-link-email-description-format "Email %c: %s"
  332. "Format of the description part of a link to an email or usenet message.
  333. The following %-escapes will be replaced by corresponding information:
  334. %F full \"From\" field
  335. %f name, taken from \"From\" field, address if no name
  336. %T full \"To\" field
  337. %t first name in \"To\" field, address if no name
  338. %c correspondent. Usually \"from NAME\", but if you sent it yourself, it
  339. will be \"to NAME\". See also the variable `org-from-is-user-regexp'.
  340. %s subject
  341. %d date
  342. %m message-id.
  343. You may use normal field width specification between the % and the letter.
  344. This is for example useful to limit the length of the subject.
  345. Examples: \"%f on: %.30s\", \"Email from %f\", \"Email %c\""
  346. :group 'org-link-store
  347. :package-version '(Org . 9.3)
  348. :type 'string
  349. :safe #'stringp)
  350. (defcustom org-link-from-user-regexp
  351. (let ((mail (and (org-string-nw-p user-mail-address)
  352. (format "\\<%s\\>" (regexp-quote user-mail-address))))
  353. (name (and (org-string-nw-p user-full-name)
  354. (format "\\<%s\\>" (regexp-quote user-full-name)))))
  355. (if (and mail name) (concat mail "\\|" name) (or mail name)))
  356. "Regexp matched against the \"From:\" header of an email or Usenet message.
  357. It should match if the message is from the user him/herself."
  358. :group 'org-link-store
  359. :type 'regexp
  360. :safe #'stringp)
  361. (defcustom org-link-keep-stored-after-insertion nil
  362. "Non-nil means keep link in list for entire session.
  363. \\<org-mode-map>
  364. The command `org-store-link' adds a link pointing to the current
  365. location to an internal list. These links accumulate during a session.
  366. The command `org-insert-link' can be used to insert links into any
  367. Org file (offering completion for all stored links).
  368. When this option is nil, every link which has been inserted once using
  369. `\\[org-insert-link]' will be removed from the list, to make completing the \
  370. unused
  371. links more efficient."
  372. :group 'org-link-store
  373. :type 'boolean
  374. :safe #'booleanp)
  375. ;;; Public variables
  376. (defconst org-target-regexp (let ((border "[^<>\n\r \t]"))
  377. (format "<<\\(%s\\|%s[^<>\n\r]*%s\\)>>"
  378. border border border))
  379. "Regular expression matching a link target.")
  380. (defconst org-radio-target-regexp (format "<%s>" org-target-regexp)
  381. "Regular expression matching a radio target.")
  382. (defvar-local org-target-link-regexp nil
  383. "Regular expression matching radio targets in plain text.")
  384. (defvar org-link-types-re nil
  385. "Matches a link that has a url-like prefix like \"http:\"")
  386. (defvar org-link-angle-re nil
  387. "Matches link with angular brackets, spaces are allowed.")
  388. (defvar org-link-plain-re nil
  389. "Matches plain link, without spaces.")
  390. (defvar org-link-bracket-re nil
  391. "Matches a link in double brackets.")
  392. (defvar org-link-any-re nil
  393. "Regular expression matching any link.")
  394. (defvar-local org-link-abbrev-alist-local nil
  395. "Buffer-local version of `org-link-abbrev-alist', which see.
  396. The value of this is taken from the LINK keywords.")
  397. (defvar org-stored-links nil
  398. "Contains the links stored with `org-store-link'.")
  399. (defvar org-store-link-plist nil
  400. "Plist with info about the most recently link created with `org-store-link'.")
  401. (defvar org-create-file-search-functions nil
  402. "List of functions to construct the right search string for a file link.
  403. These functions are called in turn with point at the location to
  404. which the link should point.
  405. A function in the hook should first test if it would like to
  406. handle this file type, for example by checking the `major-mode'
  407. or the file extension. If it decides not to handle this file, it
  408. should just return nil to give other functions a chance. If it
  409. does handle the file, it must return the search string to be used
  410. when following the link. The search string will be part of the
  411. file link, given after a double colon, and `org-open-at-point'
  412. will automatically search for it. If special measures must be
  413. taken to make the search successful, another function should be
  414. added to the companion hook `org-execute-file-search-functions',
  415. which see.
  416. A function in this hook may also use `setq' to set the variable
  417. `description' to provide a suggestion for the descriptive text to
  418. be used for this link when it gets inserted into an Org buffer
  419. with \\[org-insert-link].")
  420. (defvar org-execute-file-search-functions nil
  421. "List of functions to execute a file search triggered by a link.
  422. Functions added to this hook must accept a single argument, the
  423. search string that was part of the file link, the part after the
  424. double colon. The function must first check if it would like to
  425. handle this search, for example by checking the `major-mode' or
  426. the file extension. If it decides not to handle this search, it
  427. should just return nil to give other functions a chance. If it
  428. does handle the search, it must return a non-nil value to keep
  429. other functions from trying.
  430. Each function can access the current prefix argument through the
  431. variable `current-prefix-arg'. Note that a single prefix is used
  432. to force opening a link in Emacs, so it may be good to only use a
  433. numeric or double prefix to guide the search function.
  434. In case this is needed, a function in this hook can also restore
  435. the window configuration before `org-open-at-point' was called using:
  436. (set-window-configuration org-window-config-before-follow-link)")
  437. (defvar org-open-link-functions nil
  438. "Hook for functions finding a plain text link.
  439. These functions must take a single argument, the link content.
  440. They will be called for links that look like [[link text][description]]
  441. when LINK TEXT does not have a protocol like \"http:\" and does not look
  442. like a filename (e.g. \"./blue.png\").
  443. These functions will be called *before* Org attempts to resolve the
  444. link by doing text searches in the current buffer - so if you want a
  445. link \"[[target]]\" to still find \"<<target>>\", your function should
  446. handle this as a special case.
  447. When the function does handle the link, it must return a non-nil value.
  448. If it decides that it is not responsible for this link, it must return
  449. nil to indicate that that Org can continue with other options like
  450. exact and fuzzy text search.")
  451. ;;; Internal Variables
  452. (defconst org-link--forbidden-chars "]\t\n\r<>"
  453. "Characters forbidden within a link, as a string.")
  454. (defvar org-link--history nil
  455. "History for inserted links.")
  456. (defvar org-link--insert-history nil
  457. "Minibuffer history for links inserted with `org-insert-link'.")
  458. (defvar org-link--search-failed nil
  459. "Non-nil when last link search failed.")
  460. ;;; Internal Functions
  461. (defun org-link--try-special-completion (type)
  462. "If there is completion support for link type TYPE, offer it."
  463. (let ((fun (org-link-get-parameter type :complete)))
  464. (if (functionp fun)
  465. (funcall fun)
  466. (read-string "Link (no completion support): " (concat type ":")))))
  467. (defun org-link--prettify (link)
  468. "Return a human-readable representation of LINK.
  469. The car of LINK must be a raw link. The cdr of LINK must be
  470. either a link description or nil."
  471. (let ((desc (or (cadr link) "<no description>")))
  472. (concat (format "%-45s" (substring desc 0 (min (length desc) 40)))
  473. "<" (car link) ">")))
  474. (defun org-link--decode-compound (hex)
  475. "Unhexify Unicode hex-chars HEX.
  476. E.g. \"%C3%B6\" is the German o-Umlaut. Note: this function also
  477. decodes single byte encodings like \"%E1\" (a-acute) if not
  478. followed by another \"%[A-F0-9]{2}\" group."
  479. (save-match-data
  480. (let* ((bytes (cdr (split-string hex "%")))
  481. (ret "")
  482. (eat 0)
  483. (sum 0))
  484. (while bytes
  485. (let* ((val (string-to-number (pop bytes) 16))
  486. (shift-xor
  487. (if (= 0 eat)
  488. (cond
  489. ((>= val 252) (cons 6 252))
  490. ((>= val 248) (cons 5 248))
  491. ((>= val 240) (cons 4 240))
  492. ((>= val 224) (cons 3 224))
  493. ((>= val 192) (cons 2 192))
  494. (t (cons 0 0)))
  495. (cons 6 128))))
  496. (when (>= val 192) (setq eat (car shift-xor)))
  497. (setq val (logxor val (cdr shift-xor)))
  498. (setq sum (+ (lsh sum (car shift-xor)) val))
  499. (when (> eat 0) (setq eat (- eat 1)))
  500. (cond
  501. ((= 0 eat) ;multi byte
  502. (setq ret (concat ret (char-to-string sum)))
  503. (setq sum 0))
  504. ((not bytes) ; single byte(s)
  505. (setq ret (org-link--decode-single-byte-sequence hex))))))
  506. ret)))
  507. (defun org-link--decode-single-byte-sequence (hex)
  508. "Unhexify hex-encoded single byte character sequence HEX."
  509. (mapconcat (lambda (byte)
  510. (char-to-string (string-to-number byte 16)))
  511. (cdr (split-string hex "%"))
  512. ""))
  513. (defun org-link--fontify-links-to-this-file ()
  514. "Fontify links to the current file in `org-stored-links'."
  515. (let ((f (buffer-file-name)) a b)
  516. (setq a (mapcar (lambda(l)
  517. (let ((ll (car l)))
  518. (when (and (string-match "^file:\\(.+\\)::" ll)
  519. (equal f (expand-file-name (match-string 1 ll))))
  520. ll)))
  521. org-stored-links))
  522. (when (featurep 'org-id)
  523. (setq b (mapcar (lambda(l)
  524. (let ((ll (car l)))
  525. (when (and (string-match "^id:\\(.+\\)$" ll)
  526. (equal f (expand-file-name
  527. (or (org-id-find-id-file
  528. (match-string 1 ll)) ""))))
  529. ll)))
  530. org-stored-links)))
  531. (mapcar (lambda(l)
  532. (put-text-property 0 (length l) 'face 'font-lock-comment-face l))
  533. (delq nil (append a b)))))
  534. (defun org-link--buffer-for-internals ()
  535. "Return buffer used for displaying the target of internal links."
  536. (cond
  537. ((not org-link-use-indirect-buffer-for-internals) (current-buffer))
  538. ((string-suffix-p "(Clone)" (buffer-name))
  539. (message "Buffer is already a clone, not making another one")
  540. ;; We also do not modify visibility in this case.
  541. (current-buffer))
  542. (t ;make a new indirect buffer for displaying the link
  543. (let* ((indirect-buffer-name (concat (buffer-name) "(Clone)"))
  544. (indirect-buffer
  545. (or (get-buffer indirect-buffer-name)
  546. (make-indirect-buffer (current-buffer)
  547. indirect-buffer-name
  548. 'clone))))
  549. (with-current-buffer indirect-buffer (org-overview))
  550. indirect-buffer))))
  551. (defun org-link--search-radio-target (target)
  552. "Search a radio target matching TARGET in current buffer.
  553. White spaces are not significant."
  554. (let ((re (format "<<<%s>>>"
  555. (mapconcat #'regexp-quote
  556. (split-string target)
  557. "[ \t]+\\(?:\n[ \t]*\\)?")))
  558. (origin (point)))
  559. (goto-char (point-min))
  560. (catch :radio-match
  561. (while (re-search-forward re nil t)
  562. (forward-char -1)
  563. (let ((object (org-element-context)))
  564. (when (eq (org-element-type object) 'radio-target)
  565. (goto-char (org-element-property :begin object))
  566. (org-show-context 'link-search)
  567. (throw :radio-match nil))))
  568. (goto-char origin)
  569. (user-error "No match for radio target: %s" target))))
  570. ;;; Public API
  571. (defun org-link-types ()
  572. "Return a list of known link types."
  573. (mapcar #'car org-link-parameters))
  574. (defun org-link-get-parameter (type key)
  575. "Get TYPE link property for KEY.
  576. TYPE is a string and KEY is a plist keyword. See
  577. `org-link-parameters' for supported keywords."
  578. (plist-get (cdr (assoc type org-link-parameters))
  579. key))
  580. (defun org-link-set-parameters (type &rest parameters)
  581. "Set link TYPE properties to PARAMETERS.
  582. PARAMETERS should be keyword value pairs. See
  583. `org-link-parameters' for supported keys."
  584. (let ((data (assoc type org-link-parameters)))
  585. (if data (setcdr data (org-combine-plists (cdr data) parameters))
  586. (push (cons type parameters) org-link-parameters)
  587. (org-link-make-regexps)
  588. (when (featurep 'org-element) (org-element-update-syntax)))))
  589. (defun org-link-make-regexps ()
  590. "Update the link regular expressions.
  591. This should be called after the variable `org-link-parameters' has changed."
  592. (let ((types-re (regexp-opt (org-link-types) t)))
  593. (setq org-link-types-re
  594. (concat "\\`" types-re ":")
  595. org-link-angle-re
  596. (format "<%s:\\([^>\n]*\\(?:\n[ \t]*[^> \t\n][^>\n]*\\)*\\)>"
  597. types-re)
  598. org-link-plain-re
  599. (concat
  600. "\\<" types-re ":"
  601. "\\([^][ \t\n()<>]+\\(?:([[:word:]0-9_]+)\\|\\([^[:punct:] \t\n]\\|/\\)\\)\\)")
  602. ;; "\\([^]\t\n\r<>() ]+[^]\t\n\r<>,.;() ]\\)")
  603. org-link-bracket-re
  604. (rx (seq "[["
  605. ;; URI part: match group 1.
  606. (group
  607. (*? anything)
  608. ;; Allow an even number of backslashes right
  609. ;; before the closing bracket.
  610. (not (any "\\"))
  611. (zero-or-more "\\\\"))
  612. "]"
  613. ;; Description (optional): match group 2.
  614. (opt "[" (group (+? anything)) "]")
  615. "]"))
  616. org-link-any-re
  617. (concat "\\(" org-link-bracket-re "\\)\\|\\("
  618. org-link-angle-re "\\)\\|\\("
  619. org-link-plain-re "\\)"))))
  620. (defun org-link-complete-file (&optional arg)
  621. "Create a file link using completion."
  622. (let ((file (read-file-name "File: "))
  623. (pwd (file-name-as-directory (expand-file-name ".")))
  624. (pwd1 (file-name-as-directory (abbreviate-file-name
  625. (expand-file-name ".")))))
  626. (cond ((equal arg '(16))
  627. (concat "file:"
  628. (abbreviate-file-name (expand-file-name file))))
  629. ((string-match
  630. (concat "^" (regexp-quote pwd1) "\\(.+\\)") file)
  631. (concat "file:" (match-string 1 file)))
  632. ((string-match
  633. (concat "^" (regexp-quote pwd) "\\(.+\\)")
  634. (expand-file-name file))
  635. (concat "file:"
  636. (match-string 1 (expand-file-name file))))
  637. (t (concat "file:" file)))))
  638. (defun org-link-email-description (&optional fmt)
  639. "Return the description part of an email link.
  640. This takes information from `org-store-link-plist' and formats it
  641. according to FMT (default from `org-link-email-description-format')."
  642. (setq fmt (or fmt org-link-email-description-format))
  643. (let* ((p org-store-link-plist)
  644. (to (plist-get p :toaddress))
  645. (from (plist-get p :fromaddress))
  646. (table
  647. (list
  648. (cons "%c" (plist-get p :fromto))
  649. (cons "%F" (plist-get p :from))
  650. (cons "%f" (or (plist-get p :fromname) (plist-get p :fromaddress) "?"))
  651. (cons "%T" (plist-get p :to))
  652. (cons "%t" (or (plist-get p :toname) (plist-get p :toaddress) "?"))
  653. (cons "%s" (plist-get p :subject))
  654. (cons "%d" (plist-get p :date))
  655. (cons "%m" (plist-get p :message-id)))))
  656. (when (string-match "%c" fmt)
  657. ;; Check if the user wrote this message
  658. (if (and org-link-from-user-regexp from to
  659. (save-match-data (string-match org-link-from-user-regexp from)))
  660. (setq fmt (replace-match "to %t" t t fmt))
  661. (setq fmt (replace-match "from %f" t t fmt))))
  662. (org-replace-escapes fmt table)))
  663. (defun org-link-store-props (&rest plist)
  664. "Store link properties.
  665. The properties are pre-processed by extracting names, addresses
  666. and dates."
  667. (let ((x (plist-get plist :from)))
  668. (when x
  669. (let ((adr (mail-extract-address-components x)))
  670. (setq plist (plist-put plist :fromname (car adr)))
  671. (setq plist (plist-put plist :fromaddress (nth 1 adr))))))
  672. (let ((x (plist-get plist :to)))
  673. (when x
  674. (let ((adr (mail-extract-address-components x)))
  675. (setq plist (plist-put plist :toname (car adr)))
  676. (setq plist (plist-put plist :toaddress (nth 1 adr))))))
  677. (let ((x (ignore-errors (date-to-time (plist-get plist :date)))))
  678. (when x
  679. (setq plist (plist-put plist :date-timestamp
  680. (format-time-string
  681. (org-time-stamp-format t) x)))
  682. (setq plist (plist-put plist :date-timestamp-inactive
  683. (format-time-string
  684. (org-time-stamp-format t t) x)))))
  685. (let ((from (plist-get plist :from))
  686. (to (plist-get plist :to)))
  687. (when (and from to org-link-from-user-regexp)
  688. (setq plist
  689. (plist-put plist :fromto
  690. (if (string-match org-link-from-user-regexp from)
  691. (concat "to %t")
  692. (concat "from %f"))))))
  693. (setq org-store-link-plist plist))
  694. (defun org-link-add-props (&rest plist)
  695. "Add these properties to the link property list."
  696. (let (key value)
  697. (while plist
  698. (setq key (pop plist) value (pop plist))
  699. (setq org-store-link-plist
  700. (plist-put org-store-link-plist key value)))))
  701. (defun org-link-encode (text table)
  702. "Return percent escaped representation of string TEXT.
  703. TEXT is a string with the text to escape. TABLE is a list of
  704. characters that should be escaped."
  705. (mapconcat
  706. (lambda (c)
  707. (if (memq c table)
  708. (mapconcat (lambda (e) (format "%%%.2X" e))
  709. (or (encode-coding-char c 'utf-8)
  710. (error "Unable to percent escape character: %c" c))
  711. "")
  712. (char-to-string c)))
  713. text ""))
  714. (defun org-link-decode (s)
  715. "Decode percent-encoded parts in string S.
  716. E.g. \"%C3%B6\" becomes the german o-Umlaut."
  717. (replace-regexp-in-string "\\(%[0-9A-Za-z]\\{2\\}\\)+"
  718. #'org-link--decode-compound s t t))
  719. (defun org-link-escape (link)
  720. "Backslash-escape sensitive characters in string LINK."
  721. ;; Escape closing square brackets followed by another square bracket
  722. ;; or at the end of the link. Also escape final backslashes so that
  723. ;; we do not escape inadvertently URI's closing bracket.
  724. (with-temp-buffer
  725. (insert link)
  726. (insert (make-string (- (skip-chars-backward "\\\\"))
  727. ?\\))
  728. (while (search-backward "\]" nil t)
  729. (when (looking-at-p "\\]\\(?:[][]\\|\\'\\)")
  730. (insert (make-string (1+ (- (skip-chars-backward "\\\\")))
  731. ?\\))))
  732. (buffer-string)))
  733. (defun org-link-unescape (link)
  734. "Remove escaping backslash characters from string LINK."
  735. (with-temp-buffer
  736. (save-excursion (insert link))
  737. (while (re-search-forward "\\(\\\\+\\)\\]\\(?:[][]\\|\\'\\)" nil t)
  738. (replace-match (make-string (/ (- (match-end 1) (match-beginning 1)) 2)
  739. ?\\)
  740. nil t nil 1))
  741. (goto-char (point-max))
  742. (delete-char (/ (- (skip-chars-backward "\\\\")) 2))
  743. (buffer-string)))
  744. (defun org-link-make-string (link &optional description)
  745. "Make a bracket link, consisting of LINK and DESCRIPTION.
  746. LINK is escaped with backslashes for inclusion in buffer."
  747. (unless (org-string-nw-p link) (error "Empty link"))
  748. (let* ((uri (org-link-escape link))
  749. (zero-width-space (string ?\x200B))
  750. (description
  751. (and (org-string-nw-p description)
  752. ;; Description cannot contain two consecutive square
  753. ;; brackets, or end with a square bracket. To prevent
  754. ;; this, insert a zero width space character between
  755. ;; the brackets, or at the end of the description.
  756. (replace-regexp-in-string
  757. "\\(]\\)\\(]\\)"
  758. (concat "\\1" zero-width-space "\\2")
  759. (replace-regexp-in-string "]\\'"
  760. (concat "\\&" zero-width-space)
  761. (org-trim description))))))
  762. (format "[[%s]%s]"
  763. uri
  764. (if description (format "[%s]" description) ""))))
  765. (defun org-store-link-functions ()
  766. "List of functions that are called to create and store a link.
  767. The functions are defined in the `:store' property of
  768. `org-link-parameters'.
  769. Each function will be called in turn until one returns a non-nil
  770. value. Each function should check if it is responsible for
  771. creating this link (for example by looking at the major mode).
  772. If not, it must exit and return nil. If yes, it should return
  773. a non-nil value after calling `org-link-store-props' with a list
  774. of properties and values. Special properties are:
  775. :type The link prefix, like \"http\". This must be given.
  776. :link The link, like \"http://www.astro.uva.nl/~dominik\".
  777. This is obligatory as well.
  778. :description Optional default description for the second pair
  779. of brackets in an Org mode link. The user can still change
  780. this when inserting this link into an Org mode buffer.
  781. In addition to these, any additional properties can be specified
  782. and then used in capture templates."
  783. (cl-loop for link in org-link-parameters
  784. with store-func
  785. do (setq store-func (org-link-get-parameter (car link) :store))
  786. if store-func
  787. collect store-func))
  788. (defun org-link-expand-abbrev (link)
  789. "Replace link abbreviations in LINK string.
  790. Abbreviations are defined in `org-link-abbrev-alist'."
  791. (if (not (string-match "^\\([^:]*\\)\\(::?\\(.*\\)\\)?$" link)) link
  792. (let* ((key (match-string 1 link))
  793. (as (or (assoc key org-link-abbrev-alist-local)
  794. (assoc key org-link-abbrev-alist)))
  795. (tag (and (match-end 2) (match-string 3 link)))
  796. rpl)
  797. (if (not as)
  798. link
  799. (setq rpl (cdr as))
  800. (cond
  801. ((symbolp rpl) (funcall rpl tag))
  802. ((string-match "%(\\([^)]+\\))" rpl)
  803. (replace-match
  804. (save-match-data
  805. (funcall (intern-soft (match-string 1 rpl)) tag)) t t rpl))
  806. ((string-match "%s" rpl) (replace-match (or tag "") t t rpl))
  807. ((string-match "%h" rpl)
  808. (replace-match (url-hexify-string (or tag "")) t t rpl))
  809. (t (concat rpl tag)))))))
  810. (defun org-link-open (link &optional arg)
  811. "Open a link object LINK.
  812. Optional argument is passed to `org-open-file' when S is
  813. a \"file\" link."
  814. (let ((type (org-element-property :type link))
  815. (path (org-element-property :path link)))
  816. (cond
  817. ((equal type "file")
  818. (if (string-match "[*?{]" (file-name-nondirectory path))
  819. (dired path)
  820. ;; Look into `org-link-parameters' in order to find
  821. ;; a DEDICATED-FUNCTION to open file. The function will be
  822. ;; applied on raw link instead of parsed link due to the
  823. ;; limitation in `org-add-link-type' ("open" function called
  824. ;; with a single argument). If no such function is found,
  825. ;; fallback to `org-open-file'.
  826. (let* ((option (org-element-property :search-option link))
  827. (app (org-element-property :application link))
  828. (dedicated-function
  829. (org-link-get-parameter (if app (concat type "+" app) type)
  830. :follow)))
  831. (if dedicated-function
  832. (funcall dedicated-function
  833. (concat path
  834. (and option (concat "::" option))))
  835. (apply #'org-open-file
  836. path
  837. (cond (arg)
  838. ((equal app "emacs") 'emacs)
  839. ((equal app "sys") 'system))
  840. (cond ((not option) nil)
  841. ((string-match-p "\\`[0-9]+\\'" option)
  842. (list (string-to-number option)))
  843. (t (list nil option))))))))
  844. ((functionp (org-link-get-parameter type :follow))
  845. (funcall (org-link-get-parameter type :follow) path))
  846. ((member type '("coderef" "custom-id" "fuzzy" "radio"))
  847. (unless (run-hook-with-args-until-success 'org-open-link-functions path)
  848. (if (not arg) (org-mark-ring-push)
  849. (switch-to-buffer-other-window (org-link--buffer-for-internals)))
  850. (let ((destination
  851. (org-with-wide-buffer
  852. (if (equal type "radio")
  853. (org-link--search-radio-target
  854. (org-element-property :path link))
  855. (org-link-search
  856. (pcase type
  857. ("custom-id" (concat "#" path))
  858. ("coderef" (format "(%s)" path))
  859. (_ path))
  860. ;; Prevent fuzzy links from matching themselves.
  861. (and (equal type "fuzzy")
  862. (+ 2 (org-element-property :begin link)))))
  863. (point))))
  864. (unless (and (<= (point-min) destination)
  865. (>= (point-max) destination))
  866. (widen))
  867. (goto-char destination))))
  868. (t (browse-url-at-point)))))
  869. (defun org-link-open-from-string (s &optional arg)
  870. "Open a link in the string S, as if it was in Org mode.
  871. Optional argument is passed to `org-open-file' when S is
  872. a \"file\" link."
  873. (interactive "sLink: \nP")
  874. (pcase (with-temp-buffer
  875. (let ((org-inhibit-startup nil))
  876. (insert s)
  877. (org-mode)
  878. (goto-char (point-min))
  879. (org-element-link-parser)))
  880. (`nil (user-error "No valid link in %S" s))
  881. (link (org-link-open link arg))))
  882. (defun org-link-search (s &optional avoid-pos stealth)
  883. "Search for a search string S.
  884. If S starts with \"#\", it triggers a custom ID search.
  885. If S is enclosed within parenthesis, it initiates a coderef
  886. search.
  887. If S is surrounded by forward slashes, it is interpreted as
  888. a regular expression. In Org mode files, this will create an
  889. `org-occur' sparse tree. In ordinary files, `occur' will be used
  890. to list matches. If the current buffer is in `dired-mode', grep
  891. will be used to search in all files.
  892. When AVOID-POS is given, ignore matches near that position.
  893. When optional argument STEALTH is non-nil, do not modify
  894. visibility around point, thus ignoring `org-show-context-detail'
  895. variable.
  896. Search is case-insensitive and ignores white spaces. Return type
  897. of matched result, which is either `dedicated' or `fuzzy'."
  898. (unless (org-string-nw-p s) (error "Invalid search string \"%s\"" s))
  899. (let* ((case-fold-search t)
  900. (origin (point))
  901. (normalized (replace-regexp-in-string "\n[ \t]*" " " s))
  902. (starred (eq (string-to-char normalized) ?*))
  903. (words (split-string (if starred (substring s 1) s)))
  904. (s-multi-re (mapconcat #'regexp-quote words "\\(?:[ \t\n]+\\)"))
  905. (s-single-re (mapconcat #'regexp-quote words "[ \t]+"))
  906. type)
  907. (cond
  908. ;; Check if there are any special search functions.
  909. ((run-hook-with-args-until-success 'org-execute-file-search-functions s))
  910. ((eq (string-to-char s) ?#)
  911. ;; Look for a custom ID S if S starts with "#".
  912. (let* ((id (substring normalized 1))
  913. (match (org-find-property "CUSTOM_ID" id)))
  914. (if match (progn (goto-char match) (setf type 'dedicated))
  915. (error "No match for custom ID: %s" id))))
  916. ((string-match "\\`(\\(.*\\))\\'" normalized)
  917. ;; Look for coderef targets if S is enclosed within parenthesis.
  918. (let ((coderef (match-string-no-properties 1 normalized))
  919. (re (substring s-single-re 1 -1)))
  920. (goto-char (point-min))
  921. (catch :coderef-match
  922. (while (re-search-forward re nil t)
  923. (let ((element (org-element-at-point)))
  924. (when (and (memq (org-element-type element)
  925. '(example-block src-block))
  926. (org-match-line
  927. (concat ".*?" (org-src-coderef-regexp
  928. (org-src-coderef-format element)
  929. coderef))))
  930. (setq type 'dedicated)
  931. (goto-char (match-beginning 2))
  932. (throw :coderef-match nil))))
  933. (goto-char origin)
  934. (error "No match for coderef: %s" coderef))))
  935. ((string-match "\\`/\\(.*\\)/\\'" normalized)
  936. ;; Look for a regular expression.
  937. (funcall (if (derived-mode-p 'org-mode) #'org-occur #'org-do-occur)
  938. (match-string 1 s)))
  939. ;; From here, we handle fuzzy links.
  940. ;;
  941. ;; Look for targets, only if not in a headline search.
  942. ((and (not starred)
  943. (let ((target (format "<<%s>>" s-multi-re)))
  944. (catch :target-match
  945. (goto-char (point-min))
  946. (while (re-search-forward target nil t)
  947. (backward-char)
  948. (let ((context (org-element-context)))
  949. (when (eq (org-element-type context) 'target)
  950. (setq type 'dedicated)
  951. (goto-char (org-element-property :begin context))
  952. (throw :target-match t))))
  953. nil))))
  954. ;; Look for elements named after S, only if not in a headline
  955. ;; search.
  956. ((and (not starred)
  957. (let ((name (format "^[ \t]*#\\+NAME: +%s[ \t]*$" s-single-re)))
  958. (catch :name-match
  959. (goto-char (point-min))
  960. (while (re-search-forward name nil t)
  961. (let ((element (org-element-at-point)))
  962. (when (equal words
  963. (split-string
  964. (org-element-property :name element)))
  965. (setq type 'dedicated)
  966. (beginning-of-line)
  967. (throw :name-match t))))
  968. nil))))
  969. ;; Regular text search. Prefer headlines in Org mode buffers.
  970. ;; Ignore COMMENT keyword, TODO keywords, priority cookies,
  971. ;; statistics cookies and tags.
  972. ((and (derived-mode-p 'org-mode)
  973. (let ((title-re
  974. (format "%s.*\\(?:%s[ \t]\\)?.*%s"
  975. org-outline-regexp-bol
  976. org-comment-string
  977. (mapconcat #'regexp-quote words ".+")))
  978. (cookie-re "\\[[0-9]*\\(?:%\\|/[0-9]*\\)\\]")
  979. (comment-re (format "\\`%s[ \t]+" org-comment-string)))
  980. (goto-char (point-min))
  981. (catch :found
  982. (while (re-search-forward title-re nil t)
  983. (when (equal words
  984. (split-string
  985. (replace-regexp-in-string
  986. cookie-re ""
  987. (replace-regexp-in-string
  988. comment-re "" (org-get-heading t t t)))))
  989. (throw :found t)))
  990. nil)))
  991. (beginning-of-line)
  992. (setq type 'dedicated))
  993. ;; Offer to create non-existent headline depending on
  994. ;; `org-link-search-must-match-exact-headline'.
  995. ((and (derived-mode-p 'org-mode)
  996. (eq org-link-search-must-match-exact-headline 'query-to-create)
  997. (yes-or-no-p "No match - create this as a new heading? "))
  998. (goto-char (point-max))
  999. (unless (bolp) (newline))
  1000. (org-insert-heading nil t t)
  1001. (insert s "\n")
  1002. (beginning-of-line 0))
  1003. ;; Only headlines are looked after. No need to process
  1004. ;; further: throw an error.
  1005. ((and (derived-mode-p 'org-mode)
  1006. (or starred org-link-search-must-match-exact-headline))
  1007. (goto-char origin)
  1008. (error "No match for fuzzy expression: %s" normalized))
  1009. ;; Regular text search.
  1010. ((catch :fuzzy-match
  1011. (goto-char (point-min))
  1012. (while (re-search-forward s-multi-re nil t)
  1013. ;; Skip match if it contains AVOID-POS or it is included in
  1014. ;; a link with a description but outside the description.
  1015. (unless (or (and avoid-pos
  1016. (<= (match-beginning 0) avoid-pos)
  1017. (> (match-end 0) avoid-pos))
  1018. (and (save-match-data
  1019. (org-in-regexp org-link-bracket-re))
  1020. (match-beginning 3)
  1021. (or (> (match-beginning 3) (point))
  1022. (<= (match-end 3) (point)))
  1023. (org-element-lineage
  1024. (save-match-data (org-element-context))
  1025. '(link) t)))
  1026. (goto-char (match-beginning 0))
  1027. (setq type 'fuzzy)
  1028. (throw :fuzzy-match t)))
  1029. nil))
  1030. ;; All failed. Throw an error.
  1031. (t (goto-char origin)
  1032. (error "No match for fuzzy expression: %s" normalized)))
  1033. ;; Disclose surroundings of match, if appropriate.
  1034. (when (and (derived-mode-p 'org-mode) (not stealth))
  1035. (org-show-context 'link-search))
  1036. type))
  1037. (defun org-link-heading-search-string (&optional string)
  1038. "Make search string for the current headline or STRING."
  1039. (let ((s (or string
  1040. (and (derived-mode-p 'org-mode)
  1041. (save-excursion
  1042. (org-back-to-heading t)
  1043. (org-element-property :raw-value
  1044. (org-element-at-point))))))
  1045. (lines org-link-context-for-files))
  1046. (unless string (setq s (concat "*" s))) ;Add * for headlines
  1047. (setq s (replace-regexp-in-string "\\[[0-9]+%\\]\\|\\[[0-9]+/[0-9]+\\]" "" s))
  1048. (when (and string (integerp lines) (> lines 0))
  1049. (let ((slines (org-split-string s "\n")))
  1050. (when (< lines (length slines))
  1051. (setq s (mapconcat
  1052. #'identity
  1053. (reverse (nthcdr (- (length slines) lines)
  1054. (reverse slines))) "\n")))))
  1055. (mapconcat #'identity (split-string s) " ")))
  1056. (defun org-link-display-format (s)
  1057. "Replace links in string S with their description.
  1058. If there is no description, use the link target."
  1059. (save-match-data
  1060. (replace-regexp-in-string
  1061. org-link-bracket-re
  1062. (lambda (m) (or (match-string 2 m) (match-string 1 m)))
  1063. s nil t)))
  1064. (defun org-link-add-angle-brackets (s)
  1065. "Wrap string S within angle brackets."
  1066. (unless (equal (substring s 0 1) "<") (setq s (concat "<" s)))
  1067. (unless (equal (substring s -1) ">") (setq s (concat s ">")))
  1068. s)
  1069. ;;; Built-in link types
  1070. ;;;; "doi" link type
  1071. (defun org-link--open-doi (path)
  1072. "Open a \"doi\" type link.
  1073. PATH is a the path to search for, as a string."
  1074. (browse-url (url-encode-url (concat org-link-doi-server-url path))))
  1075. (org-link-set-parameters "doi" :follow #'org-link--open-doi)
  1076. ;;;; "elisp" link type
  1077. (defun org-link--open-elisp (path)
  1078. "Open a \"elisp\" type link.
  1079. PATH is the sexp to evaluate, as a string."
  1080. (if (or (and (org-string-nw-p org-link-elisp-skip-confirm-regexp)
  1081. (string-match-p org-link-elisp-skip-confirm-regexp path))
  1082. (not org-link-elisp-confirm-function)
  1083. (funcall org-link-elisp-confirm-function
  1084. (format "Execute %S as Elisp? "
  1085. (org-add-props path nil 'face 'org-warning))))
  1086. (message "%s => %s" path
  1087. (if (eq ?\( (string-to-char path))
  1088. (eval (read path))
  1089. (call-interactively (read path))))
  1090. (user-error "Abort")))
  1091. (org-link-set-parameters "elisp" :follow #'org-link--open-elisp)
  1092. ;;;; "file" link type
  1093. (org-link-set-parameters "file" :complete #'org-link-complete-file)
  1094. ;;;; "help" link type
  1095. (defun org-link--open-help (path)
  1096. "Open a \"help\" type link.
  1097. PATH is a symbol name, as a string."
  1098. (pcase (intern path)
  1099. ((and (pred fboundp) variable) (describe-function variable))
  1100. ((and (pred boundp) function) (describe-variable function))
  1101. (name (user-error "Unknown function or variable: %s" name))))
  1102. (org-link-set-parameters "help" :follow #'org-link--open-elisp)
  1103. ;;;; "http", "https", "mailto", "ftp", and "news" link types
  1104. (dolist (scheme '("ftp" "http" "https" "mailto" "news"))
  1105. (org-link-set-parameters scheme
  1106. :follow
  1107. (lambda (url) (browse-url (concat scheme ":" url)))))
  1108. ;;;; "shell" link type
  1109. (defun org-link--open-shell (path)
  1110. "Open a \"shell\" type link.
  1111. PATH is the command to execute, as a string."
  1112. (if (or (and (org-string-nw-p org-link-shell-skip-confirm-regexp)
  1113. (string-match-p org-link-shell-skip-confirm-regexp path))
  1114. (not org-link-shell-confirm-function)
  1115. (funcall org-link-shell-confirm-function
  1116. (format "Execute %S in shell? "
  1117. (org-add-props path nil 'face 'org-warning))))
  1118. (let ((buf (generate-new-buffer "*Org Shell Output*")))
  1119. (message "Executing %s" path)
  1120. (shell-command path buf)
  1121. (when (featurep 'midnight)
  1122. (setq clean-buffer-list-kill-buffer-names
  1123. (cons (buffer-name buf)
  1124. clean-buffer-list-kill-buffer-names))))
  1125. (user-error "Abort")))
  1126. (org-link-set-parameters "shell" :follow #'org-link--open-shell)
  1127. ;;; Interactive Functions
  1128. ;;;###autoload
  1129. (defun org-next-link (&optional search-backward)
  1130. "Move forward to the next link.
  1131. If the link is in hidden text, expose it. When SEARCH-BACKWARD
  1132. is non-nil, move backward."
  1133. (interactive)
  1134. (let ((pos (point))
  1135. (search-fun (if search-backward #'re-search-backward
  1136. #'re-search-forward)))
  1137. ;; Tweak initial position. If last search failed, wrap around.
  1138. ;; Otherwise, make sure we do not match current link.
  1139. (cond
  1140. ((not (and org-link--search-failed (eq this-command last-command)))
  1141. (cond
  1142. ((and (not search-backward) (looking-at org-link-any-re))
  1143. (goto-char (match-end 0)))
  1144. (search-backward
  1145. (pcase (org-in-regexp org-link-any-re nil t)
  1146. (`(,beg . ,_) (goto-char beg))
  1147. (_ nil)))
  1148. (t nil)))
  1149. (search-backward
  1150. (goto-char (point-max))
  1151. (message "Link search wrapped back to end of buffer"))
  1152. (t
  1153. (goto-char (point-min))
  1154. (message "Link search wrapped back to beginning of buffer")))
  1155. (setq org-link--search-failed nil)
  1156. (catch :found
  1157. (while (funcall search-fun org-link-any-re nil t)
  1158. (let ((context (save-excursion
  1159. (unless search-backward (forward-char -1))
  1160. (org-element-context))))
  1161. (pcase (org-element-lineage context '(link) t)
  1162. (`nil nil)
  1163. (link
  1164. (goto-char (org-element-property :begin link))
  1165. (when (org-invisible-p) (org-show-context))
  1166. (throw :found t)))))
  1167. (goto-char pos)
  1168. (setq org-link--search-failed t)
  1169. (message "No further link found"))))
  1170. ;;;###autoload
  1171. (defun org-previous-link ()
  1172. "Move backward to the previous link.
  1173. If the link is in hidden text, expose it."
  1174. (interactive)
  1175. (org-next-link t))
  1176. ;;;###autoload
  1177. (defun org-toggle-link-display ()
  1178. "Toggle the literal or descriptive display of links."
  1179. (interactive)
  1180. (if org-link-descriptive (remove-from-invisibility-spec '(org-link))
  1181. (add-to-invisibility-spec '(org-link)))
  1182. (org-restart-font-lock)
  1183. (setq org-link-descriptive (not org-link-descriptive)))
  1184. ;;;###autoload
  1185. (defun org-store-link (arg &optional interactive?)
  1186. "Store a link to the current location.
  1187. \\<org-mode-map>
  1188. This link is added to `org-stored-links' and can later be inserted
  1189. into an Org buffer with `org-insert-link' (`\\[org-insert-link]').
  1190. For some link types, a `\\[universal-argument]' prefix ARG is interpreted. \
  1191. A single
  1192. `\\[universal-argument]' negates `org-context-in-file-links' for file links or
  1193. `org-gnus-prefer-web-links' for links to Usenet articles.
  1194. A `\\[universal-argument] \\[universal-argument]' prefix ARG forces \
  1195. skipping storing functions that are not
  1196. part of Org core.
  1197. A `\\[universal-argument] \\[universal-argument] \\[universal-argument]' \
  1198. prefix ARG forces storing a link for each line in the
  1199. active region.
  1200. Assume the function is called interactively if INTERACTIVE? is
  1201. non-nil."
  1202. (interactive "P\np")
  1203. (org-load-modules-maybe)
  1204. (if (and (equal arg '(64)) (org-region-active-p))
  1205. (save-excursion
  1206. (let ((end (region-end)))
  1207. (goto-char (region-beginning))
  1208. (set-mark (point))
  1209. (while (< (point-at-eol) end)
  1210. (move-end-of-line 1) (activate-mark)
  1211. (let (current-prefix-arg)
  1212. (call-interactively 'org-store-link))
  1213. (move-beginning-of-line 2)
  1214. (set-mark (point)))))
  1215. (setq org-store-link-plist nil)
  1216. (let (link cpltxt desc description search txt custom-id agenda-link)
  1217. (cond
  1218. ;; Store a link using an external link type, if any function is
  1219. ;; available. If more than one can generate a link from current
  1220. ;; location, ask which one to use.
  1221. ((and (not (equal arg '(16)))
  1222. (let ((results-alist nil))
  1223. (dolist (f (org-store-link-functions))
  1224. (when (funcall f)
  1225. ;; XXX: return value is not link's plist, so we
  1226. ;; store the new value before it is modified. It
  1227. ;; would be cleaner to ask store link functions to
  1228. ;; return the plist instead.
  1229. (push (cons f (copy-sequence org-store-link-plist))
  1230. results-alist)))
  1231. (pcase results-alist
  1232. (`nil nil)
  1233. (`((,_ . ,_)) t) ;single choice: nothing to do
  1234. (`((,name . ,_) . ,_)
  1235. ;; Reinstate link plist associated to the chosen
  1236. ;; function.
  1237. (apply #'org-link-store-props
  1238. (cdr (assoc-string
  1239. (completing-read
  1240. "Which function for creating the link? "
  1241. (mapcar #'car results-alist)
  1242. nil t (symbol-name name))
  1243. results-alist)))
  1244. t))))
  1245. (setq link (plist-get org-store-link-plist :link))
  1246. (setq desc (or (plist-get org-store-link-plist :description)
  1247. link)))
  1248. ;; Store a link from a remote editing buffer.
  1249. ((org-src-edit-buffer-p)
  1250. (let ((coderef-format (org-src-coderef-format))
  1251. (format-link
  1252. (lambda (label)
  1253. (if org-src-source-file-name
  1254. (format "file:%s::(%s)" org-src-source-file-name label)
  1255. (format "(%s)" label)))))
  1256. (cond
  1257. ;; Code references do not exist in this type of buffer.
  1258. ;; Pretend we're linking from the source buffer directly.
  1259. ((not (memq (org-src-source-type) '(example-block src-block)))
  1260. (with-current-buffer (org-src-source-buffer)
  1261. (org-store-link arg interactive?))
  1262. (setq link nil))
  1263. ;; A code reference exists. Use it.
  1264. ((save-excursion
  1265. (beginning-of-line)
  1266. (re-search-forward (org-src-coderef-regexp coderef-format)
  1267. (line-end-position)
  1268. t))
  1269. (setq link (funcall format-link (match-string-no-properties 3))))
  1270. ;; No code reference. Create a new one then store the link
  1271. ;; to it, but only in the function is called interactively.
  1272. (interactive?
  1273. (end-of-line)
  1274. (let* ((label (read-string "Code line label: "))
  1275. (reference (format coderef-format label))
  1276. (gc (- 79 (length reference))))
  1277. (if (< (current-column) gc)
  1278. (org-move-to-column gc t)
  1279. (insert " "))
  1280. (insert reference)
  1281. (setq link (funcall format-link label))))
  1282. ;; No code reference, and non-interactive call. Don't know
  1283. ;; what to do. Give up.
  1284. (t (setq link nil)))))
  1285. ;; We are in the agenda, link to referenced location
  1286. ((equal (bound-and-true-p org-agenda-buffer-name) (buffer-name))
  1287. (let ((m (or (get-text-property (point) 'org-hd-marker)
  1288. (get-text-property (point) 'org-marker))))
  1289. (when m
  1290. (org-with-point-at m
  1291. (setq agenda-link (org-store-link nil interactive?))))))
  1292. ((eq major-mode 'calendar-mode)
  1293. (let ((cd (calendar-cursor-to-date)))
  1294. (setq link
  1295. (format-time-string
  1296. (car org-time-stamp-formats)
  1297. (apply 'encode-time
  1298. (list 0 0 0 (nth 1 cd) (nth 0 cd) (nth 2 cd)
  1299. nil nil nil))))
  1300. (org-link-store-props :type "calendar" :date cd)))
  1301. ((eq major-mode 'help-mode)
  1302. (setq link (concat "help:" (save-excursion
  1303. (goto-char (point-min))
  1304. (looking-at "^[^ ]+")
  1305. (match-string 0))))
  1306. (org-link-store-props :type "help"))
  1307. ((eq major-mode 'w3-mode)
  1308. (setq cpltxt (if (and (buffer-name)
  1309. (not (string-match "Untitled" (buffer-name))))
  1310. (buffer-name)
  1311. (url-view-url t))
  1312. link (url-view-url t))
  1313. (org-link-store-props :type "w3" :url (url-view-url t)))
  1314. ((eq major-mode 'image-mode)
  1315. (setq cpltxt (concat "file:"
  1316. (abbreviate-file-name buffer-file-name))
  1317. link cpltxt)
  1318. (org-link-store-props :type "image" :file buffer-file-name))
  1319. ;; In dired, store a link to the file of the current line
  1320. ((derived-mode-p 'dired-mode)
  1321. (let ((file (dired-get-filename nil t)))
  1322. (setq file (if file
  1323. (abbreviate-file-name
  1324. (expand-file-name (dired-get-filename nil t)))
  1325. ;; otherwise, no file so use current directory.
  1326. default-directory))
  1327. (setq cpltxt (concat "file:" file)
  1328. link cpltxt)))
  1329. ((setq search (run-hook-with-args-until-success
  1330. 'org-create-file-search-functions))
  1331. (setq link (concat "file:" (abbreviate-file-name buffer-file-name)
  1332. "::" search))
  1333. (setq cpltxt (or description link)))
  1334. ((and (buffer-file-name (buffer-base-buffer)) (derived-mode-p 'org-mode))
  1335. (org-with-limited-levels
  1336. (setq custom-id (org-entry-get nil "CUSTOM_ID"))
  1337. (cond
  1338. ;; Store a link using the target at point
  1339. ((org-in-regexp "[^<]<<\\([^<>]+\\)>>[^>]" 1)
  1340. (setq cpltxt
  1341. (concat "file:"
  1342. (abbreviate-file-name
  1343. (buffer-file-name (buffer-base-buffer)))
  1344. "::" (match-string 1))
  1345. link cpltxt))
  1346. ((and (featurep 'org-id)
  1347. (or (eq org-id-link-to-org-use-id t)
  1348. (and interactive?
  1349. (or (eq org-id-link-to-org-use-id 'create-if-interactive)
  1350. (and (eq org-id-link-to-org-use-id
  1351. 'create-if-interactive-and-no-custom-id)
  1352. (not custom-id))))
  1353. (and org-id-link-to-org-use-id (org-entry-get nil "ID"))))
  1354. ;; Store a link using the ID at point
  1355. (setq link (condition-case nil
  1356. (prog1 (org-id-store-link)
  1357. (setq desc (or (plist-get org-store-link-plist
  1358. :description)
  1359. "")))
  1360. (error
  1361. ;; Probably before first headline, link only to file
  1362. (concat "file:"
  1363. (abbreviate-file-name
  1364. (buffer-file-name (buffer-base-buffer))))))))
  1365. (t
  1366. ;; Just link to current headline
  1367. (setq cpltxt (concat "file:"
  1368. (abbreviate-file-name
  1369. (buffer-file-name (buffer-base-buffer)))))
  1370. ;; Add a context search string
  1371. (when (org-xor org-link-context-for-files (equal arg '(4)))
  1372. (let* ((element (org-element-at-point))
  1373. (name (org-element-property :name element)))
  1374. (setq txt (cond
  1375. ((org-at-heading-p) nil)
  1376. (name)
  1377. ((org-region-active-p)
  1378. (buffer-substring (region-beginning) (region-end)))))
  1379. (when (or (null txt) (string-match "\\S-" txt))
  1380. (setq cpltxt
  1381. (concat cpltxt "::"
  1382. (condition-case nil
  1383. (org-link-heading-search-string txt)
  1384. (error "")))
  1385. desc (or name
  1386. (nth 4 (ignore-errors (org-heading-components)))
  1387. "NONE")))))
  1388. (when (string-match "::\\'" cpltxt)
  1389. (setq cpltxt (substring cpltxt 0 -2)))
  1390. (setq link cpltxt)))))
  1391. ((buffer-file-name (buffer-base-buffer))
  1392. ;; Just link to this file here.
  1393. (setq cpltxt (concat "file:"
  1394. (abbreviate-file-name
  1395. (buffer-file-name (buffer-base-buffer)))))
  1396. ;; Add a context string.
  1397. (when (org-xor org-link-context-for-files (equal arg '(4)))
  1398. (setq txt (if (org-region-active-p)
  1399. (buffer-substring (region-beginning) (region-end))
  1400. (buffer-substring (point-at-bol) (point-at-eol))))
  1401. ;; Only use search option if there is some text.
  1402. (when (string-match "\\S-" txt)
  1403. (setq cpltxt
  1404. (concat cpltxt "::" (org-link-heading-search-string txt))
  1405. desc "NONE")))
  1406. (setq link cpltxt))
  1407. (interactive?
  1408. (user-error "No method for storing a link from this buffer"))
  1409. (t (setq link nil)))
  1410. ;; We're done setting link and desc, clean up
  1411. (when (consp link) (setq cpltxt (car link) link (cdr link)))
  1412. (setq link (or link cpltxt)
  1413. desc (or desc cpltxt))
  1414. (cond ((not desc))
  1415. ((equal desc "NONE") (setq desc nil))
  1416. (t (setq desc (org-link-display-format desc))))
  1417. ;; Return the link
  1418. (if (not (and interactive? link))
  1419. (or agenda-link (and link (org-link-make-string link desc)))
  1420. (push (list link desc) org-stored-links)
  1421. (message "Stored: %s" (or desc link))
  1422. (when custom-id
  1423. (setq link (concat "file:" (abbreviate-file-name
  1424. (buffer-file-name)) "::#" custom-id))
  1425. (push (list link desc) org-stored-links))
  1426. (car org-stored-links)))))
  1427. ;;;###autoload
  1428. (defun org-insert-link (&optional complete-file link-location description)
  1429. "Insert a link. At the prompt, enter the link.
  1430. Completion can be used to insert any of the link protocol prefixes in use.
  1431. The history can be used to select a link previously stored with
  1432. `org-store-link'. When the empty string is entered (i.e. if you just
  1433. press `RET' at the prompt), the link defaults to the most recently
  1434. stored link. As `SPC' triggers completion in the minibuffer, you need to
  1435. use `M-SPC' or `C-q SPC' to force the insertion of a space character.
  1436. You will also be prompted for a description, and if one is given, it will
  1437. be displayed in the buffer instead of the link.
  1438. If there is already a link at point, this command will allow you to edit
  1439. link and description parts.
  1440. With a `\\[universal-argument]' prefix, prompts for a file to link to. The \
  1441. file name can be
  1442. selected using completion. The path to the file will be relative to the
  1443. current directory if the file is in the current directory or a subdirectory.
  1444. Otherwise, the link will be the absolute path as completed in the minibuffer
  1445. \(i.e. normally ~/path/to/file). You can configure this behavior using the
  1446. option `org-link-file-path-type'.
  1447. With a `\\[universal-argument] \\[universal-argument]' prefix, enforce an \
  1448. absolute path even if the file is in
  1449. the current directory or below.
  1450. A `\\[universal-argument] \\[universal-argument] \\[universal-argument]' \
  1451. prefix negates `org-link-keep-stored-after-insertion'.
  1452. If the LINK-LOCATION parameter is non-nil, this value will be used as
  1453. the link location instead of reading one interactively.
  1454. If the DESCRIPTION parameter is non-nil, this value will be used as the
  1455. default description. Otherwise, if `org-link-make-description-function'
  1456. is non-nil, this function will be called with the link target, and the
  1457. result will be the default link description. When called non-interactively,
  1458. don't allow to edit the default description."
  1459. (interactive "P")
  1460. (let* ((wcf (current-window-configuration))
  1461. (origbuf (current-buffer))
  1462. (region (when (org-region-active-p)
  1463. (buffer-substring (region-beginning) (region-end))))
  1464. (remove (and region (list (region-beginning) (region-end))))
  1465. (desc region)
  1466. (link link-location)
  1467. (abbrevs org-link-abbrev-alist-local)
  1468. entry all-prefixes auto-desc)
  1469. (cond
  1470. (link-location) ; specified by arg, just use it.
  1471. ((org-in-regexp org-link-bracket-re 1)
  1472. ;; We do have a link at point, and we are going to edit it.
  1473. (setq remove (list (match-beginning 0) (match-end 0)))
  1474. (setq desc (when (match-end 2) (match-string-no-properties 2)))
  1475. (setq link (read-string "Link: "
  1476. (org-link-unescape
  1477. (match-string-no-properties 1)))))
  1478. ((or (org-in-regexp org-link-angle-re)
  1479. (org-in-regexp org-link-plain-re))
  1480. ;; Convert to bracket link
  1481. (setq remove (list (match-beginning 0) (match-end 0))
  1482. link (read-string "Link: "
  1483. (org-unbracket-string "<" ">" (match-string 0)))))
  1484. ((member complete-file '((4) (16)))
  1485. ;; Completing read for file names.
  1486. (setq link (org-link-complete-file complete-file)))
  1487. (t
  1488. ;; Read link, with completion for stored links.
  1489. (org-link--fontify-links-to-this-file)
  1490. (org-switch-to-buffer-other-window "*Org Links*")
  1491. (with-current-buffer "*Org Links*"
  1492. (erase-buffer)
  1493. (insert "Insert a link.
  1494. Use TAB to complete link prefixes, then RET for type-specific completion support\n")
  1495. (when org-stored-links
  1496. (insert "\nStored links are available with <up>/<down> or M-p/n \
  1497. \(most recent with RET):\n\n")
  1498. (insert (mapconcat #'org-link--prettify
  1499. (reverse org-stored-links)
  1500. "\n")))
  1501. (goto-char (point-min)))
  1502. (let ((cw (selected-window)))
  1503. (select-window (get-buffer-window "*Org Links*" 'visible))
  1504. (with-current-buffer "*Org Links*" (setq truncate-lines t))
  1505. (unless (pos-visible-in-window-p (point-max))
  1506. (org-fit-window-to-buffer))
  1507. (and (window-live-p cw) (select-window cw)))
  1508. (setq all-prefixes (append (mapcar #'car abbrevs)
  1509. (mapcar #'car org-link-abbrev-alist)
  1510. (org-link-types)))
  1511. (unwind-protect
  1512. ;; Fake a link history, containing the stored links.
  1513. (let ((org-link--history
  1514. (append (mapcar #'car org-stored-links)
  1515. org-link--insert-history)))
  1516. (setq link
  1517. (org-completing-read
  1518. "Link: "
  1519. (append
  1520. (mapcar (lambda (x) (concat x ":")) all-prefixes)
  1521. (mapcar #'car org-stored-links))
  1522. nil nil nil
  1523. 'org-link--history
  1524. (caar org-stored-links)))
  1525. (unless (org-string-nw-p link) (user-error "No link selected"))
  1526. (dolist (l org-stored-links)
  1527. (when (equal link (cadr l))
  1528. (setq link (car l))
  1529. (setq auto-desc t)))
  1530. (when (or (member link all-prefixes)
  1531. (and (equal ":" (substring link -1))
  1532. (member (substring link 0 -1) all-prefixes)
  1533. (setq link (substring link 0 -1))))
  1534. (setq link (with-current-buffer origbuf
  1535. (org-link--try-special-completion link)))))
  1536. (set-window-configuration wcf)
  1537. (kill-buffer "*Org Links*"))
  1538. (setq entry (assoc link org-stored-links))
  1539. (or entry (push link org-link--insert-history))
  1540. (setq desc (or desc (nth 1 entry)))))
  1541. (when (funcall (if (equal complete-file '(64)) 'not 'identity)
  1542. (not org-link-keep-stored-after-insertion))
  1543. (setq org-stored-links (delq (assoc link org-stored-links)
  1544. org-stored-links)))
  1545. (when (and (string-match org-link-plain-re link)
  1546. (not (string-match org-ts-regexp link)))
  1547. ;; URL-like link, normalize the use of angular brackets.
  1548. (setq link (org-unbracket-string "<" ">" link)))
  1549. ;; Check if we are linking to the current file with a search
  1550. ;; option If yes, simplify the link by using only the search
  1551. ;; option.
  1552. (when (and buffer-file-name
  1553. (let ((case-fold-search nil))
  1554. (string-match "\\`file:\\(.+?\\)::" link)))
  1555. (let ((path (match-string-no-properties 1 link))
  1556. (search (substring-no-properties link (match-end 0))))
  1557. (save-match-data
  1558. (when (equal (file-truename buffer-file-name) (file-truename path))
  1559. ;; We are linking to this same file, with a search option
  1560. (setq link search)))))
  1561. ;; Check if we can/should use a relative path. If yes, simplify
  1562. ;; the link.
  1563. (let ((case-fold-search nil))
  1564. (when (string-match "\\`\\(file\\|docview\\):" link)
  1565. (let* ((type (match-string-no-properties 0 link))
  1566. (path-start (match-end 0))
  1567. (search (and (string-match "::\\(.*\\)\\'" link)
  1568. (match-string 1 link)))
  1569. (path
  1570. (if search
  1571. (substring-no-properties
  1572. link path-start (match-beginning 0))
  1573. (substring-no-properties link (match-end 0))))
  1574. (origpath path))
  1575. (cond
  1576. ((or (eq org-link-file-path-type 'absolute)
  1577. (equal complete-file '(16)))
  1578. (setq path (abbreviate-file-name (expand-file-name path))))
  1579. ((eq org-link-file-path-type 'noabbrev)
  1580. (setq path (expand-file-name path)))
  1581. ((eq org-link-file-path-type 'relative)
  1582. (setq path (file-relative-name path)))
  1583. (t
  1584. (save-match-data
  1585. (if (string-match (concat "^" (regexp-quote
  1586. (expand-file-name
  1587. (file-name-as-directory
  1588. default-directory))))
  1589. (expand-file-name path))
  1590. ;; We are linking a file with relative path name.
  1591. (setq path (substring (expand-file-name path)
  1592. (match-end 0)))
  1593. (setq path (abbreviate-file-name (expand-file-name path)))))))
  1594. (setq link (concat type path (and search (concat "::" search))))
  1595. (when (equal desc origpath)
  1596. (setq desc path)))))
  1597. (unless auto-desc
  1598. (let ((initial-input
  1599. (cond
  1600. (description)
  1601. ((not org-link-make-description-function) desc)
  1602. (t (condition-case nil
  1603. (funcall org-link-make-description-function link desc)
  1604. (error
  1605. (message "Can't get link description from %S"
  1606. (symbol-name org-link-make-description-function))
  1607. (sit-for 2)
  1608. nil))))))
  1609. (setq desc (if (called-interactively-p 'any)
  1610. (read-string "Description: " initial-input)
  1611. initial-input))))
  1612. (unless (org-string-nw-p desc) (setq desc nil))
  1613. (when remove (apply #'delete-region remove))
  1614. (insert (org-link-make-string link desc))
  1615. ;; Redisplay so as the new link has proper invisible characters.
  1616. (sit-for 0)))
  1617. ;;;###autoload
  1618. (defun org-insert-all-links (arg &optional pre post)
  1619. "Insert all links in `org-stored-links'.
  1620. When a universal prefix, do not delete the links from `org-stored-links'.
  1621. When `ARG' is a number, insert the last N link(s).
  1622. `PRE' and `POST' are optional arguments to define a string to
  1623. prepend or to append."
  1624. (interactive "P")
  1625. (let ((org-link-keep-stored-after-insertion (equal arg '(4)))
  1626. (links (copy-sequence org-stored-links))
  1627. (pr (or pre "- "))
  1628. (po (or post "\n"))
  1629. (cnt 1) l)
  1630. (if (null org-stored-links)
  1631. (message "No link to insert")
  1632. (while (and (or (listp arg) (>= arg cnt))
  1633. (setq l (if (listp arg)
  1634. (pop links)
  1635. (pop org-stored-links))))
  1636. (setq cnt (1+ cnt))
  1637. (insert pr)
  1638. (org-insert-link nil (car l) (or (cadr l) "<no description>"))
  1639. (insert po)))))
  1640. ;;;###autoload
  1641. (defun org-insert-last-stored-link (arg)
  1642. "Insert the last link stored in `org-stored-links'."
  1643. (interactive "p")
  1644. (org-insert-all-links arg "" "\n"))
  1645. ;;;###autoload
  1646. (defun org-insert-link-global ()
  1647. "Insert a link like Org mode does.
  1648. This command can be called in any mode to insert a link in Org syntax."
  1649. (interactive)
  1650. (org-load-modules-maybe)
  1651. (org-run-like-in-org-mode 'org-insert-link))
  1652. ;;;###autoload
  1653. (defun org-update-radio-target-regexp ()
  1654. "Find all radio targets in this file and update the regular expression.
  1655. Also refresh fontification if needed."
  1656. (interactive)
  1657. (let ((old-regexp org-target-link-regexp)
  1658. ;; Some languages, e.g., Chinese, do not use spaces to
  1659. ;; separate words. Also allow to surround radio targets with
  1660. ;; line-breakable characters.
  1661. (before-re "\\(?:^\\|[^[:alnum:]]\\|\\c|\\)\\(")
  1662. (after-re "\\)\\(?:$\\|[^[:alnum:]]\\|\\c|\\)")
  1663. (targets
  1664. (org-with-wide-buffer
  1665. (goto-char (point-min))
  1666. (let (rtn)
  1667. (while (re-search-forward org-radio-target-regexp nil t)
  1668. ;; Make sure point is really within the object.
  1669. (backward-char)
  1670. (let ((obj (org-element-context)))
  1671. (when (eq (org-element-type obj) 'radio-target)
  1672. (cl-pushnew (org-element-property :value obj) rtn
  1673. :test #'equal))))
  1674. rtn))))
  1675. (setq org-target-link-regexp
  1676. (and targets
  1677. (concat before-re
  1678. (mapconcat
  1679. (lambda (x)
  1680. (replace-regexp-in-string
  1681. " +" "\\s-+" (regexp-quote x) t t))
  1682. targets
  1683. "\\|")
  1684. after-re)))
  1685. (unless (equal old-regexp org-target-link-regexp)
  1686. ;; Clean-up cache.
  1687. (let ((regexp (cond ((not old-regexp) org-target-link-regexp)
  1688. ((not org-target-link-regexp) old-regexp)
  1689. (t
  1690. (concat before-re
  1691. (mapconcat
  1692. (lambda (re)
  1693. (substring re (length before-re)
  1694. (- (length after-re))))
  1695. (list old-regexp org-target-link-regexp)
  1696. "\\|")
  1697. after-re)))))
  1698. (when (featurep 'org-element)
  1699. (org-with-point-at 1
  1700. (while (re-search-forward regexp nil t)
  1701. (org-element-cache-refresh (match-beginning 1))))))
  1702. ;; Re fontify buffer.
  1703. (when (memq 'radio org-highlight-links)
  1704. (org-restart-font-lock)))))
  1705. ;;; Initialize Regexps
  1706. (org-link-make-regexps)
  1707. (provide 'ol)
  1708. ;;; ol.el ends here