ol-irc.el 9.4 KB

123456789101112131415161718192021222324252627282930313233343536373839404142434445464748495051525354555657585960616263646566676869707172737475767778798081828384858687888990919293949596979899100101102103104105106107108109110111112113114115116117118119120121122123124125126127128129130131132133134135136137138139140141142143144145146147148149150151152153154155156157158159160161162163164165166167168169170171172173174175176177178179180181182183184185186187188189190191192193194195196197198199200201202203204205206207208209210211212213214215216217218219220221222223224225226227228229230231232233234235236237238239240241242243244245246247248249250251252253254255256257258259260261262263264265266267268269270
  1. ;;; ol-irc.el --- Links to IRC Sessions -*- lexical-binding: t; -*-
  2. ;;
  3. ;; Copyright (C) 2008-2019 Free Software Foundation, Inc.
  4. ;;
  5. ;; Author: Philip Jackson <emacs@shellarchive.co.uk>
  6. ;; Keywords: erc, irc, link, org
  7. ;;
  8. ;; This file is part of GNU Emacs.
  9. ;;
  10. ;; GNU Emacs is free software: you can redistribute it and/or modify
  11. ;; it under the terms of the GNU General Public License as published by
  12. ;; the Free Software Foundation, either version 3 of the License, or
  13. ;; (at your option) any later version.
  14. ;; GNU Emacs is distributed in the hope that it will be useful,
  15. ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  16. ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  17. ;; GNU General Public License for more details.
  18. ;; You should have received a copy of the GNU General Public License
  19. ;; along with GNU Emacs. If not, see <https://www.gnu.org/licenses/>.
  20. ;;; Commentary:
  21. ;; This file implements links to an IRC session from within Org mode.
  22. ;; Org mode loads this module by default - if this is not what you want,
  23. ;; configure the variable `org-modules'.
  24. ;;
  25. ;; Please customize the variable `org-modules' to select
  26. ;; extensions you would like to use, and to deselect those which you don't
  27. ;; want.
  28. ;;
  29. ;; Please note that at the moment only ERC is supported. Other clients
  30. ;; shouldn't be difficult to add though.
  31. ;;
  32. ;; Then set `org-irc-link-to-logs' to non-nil if you would like a
  33. ;; file:/ type link to be created to the current line in the logs or
  34. ;; to t if you would like to create an irc:/ style link.
  35. ;;
  36. ;; Links within an org buffer might look like this:
  37. ;;
  38. ;; [[irc:/irc.freenode.net/#emacs/bob][chat with bob in #emacs on freenode]]
  39. ;; [[irc:/irc.freenode.net/#emacs][#emacs on freenode]]
  40. ;; [[irc:/irc.freenode.net/]]
  41. ;;
  42. ;; If, when the resulting link is visited, there is no connection to a
  43. ;; requested server then one will be created.
  44. ;;; Code:
  45. (require 'ol)
  46. (declare-function erc-buffer-filter "erc" (predicate &optional proc))
  47. (declare-function erc-channel-p "erc" (channel))
  48. (declare-function erc-cmd-JOIN "erc" (channel &optional key))
  49. (declare-function erc-current-logfile "erc-log" (&optional buffer))
  50. (declare-function erc-default-target "erc" ())
  51. (declare-function erc-get-server-nickname-list "erc" ())
  52. (declare-function erc-logging-enabled "erc-log" (&optional buffer))
  53. (declare-function erc-prompt "erc" ())
  54. (declare-function erc-save-buffer-in-logs "erc-log" (&optional buffer))
  55. (declare-function erc-server-buffer "erc" ())
  56. (defvar org-irc-client 'erc
  57. "The IRC client to act on.")
  58. (defvar org-irc-link-to-logs nil
  59. "Non-nil will store a link to the logs, nil will store an irc: style link.")
  60. (defvar erc-default-port) ; dynamically scoped from erc.el
  61. (defvar erc-session-port) ; dynamically scoped form erc-backend.el
  62. (defvar erc-session-server) ; dynamically scoped form erc-backend.el
  63. ;; Generic functions/config (extend these for other clients)
  64. (org-link-set-parameters "irc"
  65. :follow #'org-irc-visit
  66. :store #'org-irc-store-link
  67. :export #'org-irc-export)
  68. (defun org-irc-visit (link)
  69. "Parse LINK and dispatch to the correct function based on the client found."
  70. (let ((link (org-irc-parse-link link)))
  71. (cond
  72. ((eq org-irc-client 'erc)
  73. (org-irc-visit-erc link))
  74. (t
  75. (error "ERC only known client")))))
  76. (defun org-irc-parse-link (link)
  77. "Parse an IRC LINK and return the attributes found.
  78. Parse a LINK that looks like server:port/chan/user (port, chan
  79. and user being optional) and return any of the port, channel or user
  80. attributes that are found."
  81. (let* ((parts (split-string link "/" t))
  82. (len (length parts)))
  83. (when (or (< len 1) (> len 3))
  84. (error "Failed to parse link needed 1-3 parts, got %d" len))
  85. (setcar parts (split-string (car parts) ":" t))
  86. parts))
  87. ;;;###autoload
  88. (defun org-irc-store-link ()
  89. "Dispatch to the appropriate function to store a link to an IRC session."
  90. (cond
  91. ((eq major-mode 'erc-mode)
  92. (org-irc-erc-store-link))))
  93. (defun org-irc-ellipsify-description (string &optional after)
  94. "Remove unnecessary white space from STRING and add ellipses if necessary.
  95. Strip starting and ending white space from STRING and replace any
  96. chars that the value AFTER with `...'"
  97. (let* ((after (number-to-string (or after 30)))
  98. (replace-map (list (cons "^[ \t]*" "")
  99. (cons "[ \t]*$" "")
  100. (cons (concat "^\\(.\\{" after
  101. "\\}\\).*") "\\1..."))))
  102. (dolist (x replace-map string)
  103. (when (string-match (car x) string)
  104. (setq string (replace-match (cdr x) nil nil string))))))
  105. ;; ERC specific functions
  106. (defun org-irc-erc-get-line-from-log (erc-line)
  107. "Find the best line to link to from the ERC logs given ERC-LINE as a start.
  108. If the user is on the ERC-prompt then search backward for the
  109. first non-blank line, otherwise return the current line. The
  110. result is a cons of the filename and search string."
  111. (erc-save-buffer-in-logs)
  112. (require 'erc-log)
  113. (with-current-buffer (find-file-noselect (erc-current-logfile))
  114. (goto-char (point-max))
  115. (list
  116. (abbreviate-file-name buffer-file-name)
  117. ;; can we get a '::' part?
  118. (if (string= erc-line (erc-prompt))
  119. (progn
  120. (goto-char (point-at-bol))
  121. (when (search-backward-regexp "^[^ ]" nil t)
  122. (buffer-substring-no-properties (point-at-bol)
  123. (point-at-eol))))
  124. (when (search-backward erc-line nil t)
  125. (buffer-substring-no-properties (point-at-bol)
  126. (point-at-eol)))))))
  127. (defun org-irc-erc-store-link ()
  128. "Store a link to the IRC log file or the session itself.
  129. Depending on the variable `org-irc-link-to-logs' store either a
  130. link to the log file for the current session or an irc: link to
  131. the session itself."
  132. (require 'erc-log)
  133. (if org-irc-link-to-logs
  134. (let* ((erc-line (buffer-substring-no-properties
  135. (point-at-bol) (point-at-eol)))
  136. (parsed-line (org-irc-erc-get-line-from-log erc-line)))
  137. (if (erc-logging-enabled nil)
  138. (progn
  139. (org-link-store-props
  140. :type "file"
  141. :description (concat "'" (org-irc-ellipsify-description
  142. (cadr parsed-line) 20)
  143. "' from an IRC conversation")
  144. :link (concat "file:" (car parsed-line) "::"
  145. (cadr parsed-line)))
  146. t)
  147. (error "This ERC session is not being logged")))
  148. (let* ((link-text (org-irc-get-erc-link))
  149. (link (org-irc-parse-link link-text)))
  150. (if link-text
  151. (progn
  152. (org-link-store-props
  153. :type "irc"
  154. :link (concat "irc:/" link-text)
  155. :description (concat "irc session `" link-text "'")
  156. :server (car (car link))
  157. :port (or (string-to-number (cadr (pop link))) erc-default-port)
  158. :nick (pop link))
  159. t)
  160. (error "Failed to create ('irc:/' style) ERC link")))))
  161. (defun org-irc-get-erc-link ()
  162. "Return an org compatible irc:/ link from an ERC buffer."
  163. (let* ((session-port (if (numberp erc-session-port)
  164. (number-to-string erc-session-port)
  165. erc-session-port))
  166. (link (concat erc-session-server ":" session-port)))
  167. (concat link "/"
  168. (if (and (erc-default-target)
  169. (erc-channel-p (erc-default-target))
  170. (car (get-text-property (point) 'erc-data)))
  171. ;; we can get a nick
  172. (let ((nick (car (get-text-property (point) 'erc-data))))
  173. (concat (erc-default-target) "/" nick))
  174. (erc-default-target)))))
  175. (defun org-irc-get-current-erc-port ()
  176. "Return the current port as a number.
  177. Return the current port number or, if none is set, return the ERC
  178. default."
  179. (cond
  180. ((stringp erc-session-port)
  181. (string-to-number erc-session-port))
  182. ((numberp erc-session-port)
  183. erc-session-port)
  184. (t
  185. erc-default-port)))
  186. (defun org-irc-visit-erc (link)
  187. "Visit an ERC buffer based on criteria found in LINK."
  188. (require 'erc)
  189. (require 'erc-log)
  190. (let* ((server (car (car link)))
  191. (port (let ((p (cadr (pop link))))
  192. (if p (string-to-number p) erc-default-port)))
  193. (server-buffer)
  194. (buffer-list
  195. (erc-buffer-filter
  196. (lambda nil
  197. (let ((tmp-server-buf (erc-server-buffer)))
  198. (and tmp-server-buf
  199. (with-current-buffer tmp-server-buf
  200. (and
  201. (eq (org-irc-get-current-erc-port) port)
  202. (string= erc-session-server server)
  203. (setq server-buffer tmp-server-buf)))))))))
  204. (if buffer-list
  205. (let ((chan-name (pop link)))
  206. ;; if we got a channel name then switch to it or join it
  207. (if chan-name
  208. (let ((chan-buf (catch 'found
  209. (dolist (x buffer-list)
  210. (if (string= (buffer-name x) chan-name)
  211. (throw 'found x))))))
  212. (if chan-buf
  213. (progn
  214. (pop-to-buffer-same-window chan-buf)
  215. ;; if we got a nick, and they're in the chan,
  216. ;; then start a chat with them
  217. (let ((nick (pop link)))
  218. (when nick
  219. (if (member nick (erc-get-server-nickname-list))
  220. (progn
  221. (goto-char (point-max))
  222. (insert (concat nick ": ")))
  223. (error "%s not found in %s" nick chan-name)))))
  224. (progn
  225. (pop-to-buffer-same-window server-buffer)
  226. (erc-cmd-JOIN chan-name))))
  227. (pop-to-buffer-same-window server-buffer)))
  228. ;; no server match, make new connection
  229. (erc-select :server server :port port))))
  230. (defun org-irc-export (link description format)
  231. "Export an IRC link.
  232. See `org-link-parameters' for details about LINK, DESCRIPTION and
  233. FORMAT."
  234. (let ((desc (or description link)))
  235. (pcase format
  236. (`html (format "<a href=\"irc:%s\">%s</a>" link desc))
  237. (`md (format "[%s](irc:%s)" desc link))
  238. (_ nil))))
  239. (provide 'ol-irc)
  240. ;; Local variables:
  241. ;; generated-autoload-file: "org-loaddefs.el"
  242. ;; End:
  243. ;;; ol-irc.el ends here