ox-confluence.el 8.9 KB

123456789101112131415161718192021222324252627282930313233343536373839404142434445464748495051525354555657585960616263646566676869707172737475767778798081828384858687888990919293949596979899100101102103104105106107108109110111112113114115116117118119120121122123124125126127128129130131132133134135136137138139140141142143144145146147148149150151152153154155156157158159160161162163164165166167168169170171172173174175176177178179180181182183184185186187188189190191192193194195196197198199200201202203204205206207208209210211212213214215216217218219220221222223224225226227228229230231232233234235236237238239240241242243244245246247248249250251252253254
  1. ;;; ox-confluence --- Confluence Wiki Back-End for Org Export Engine
  2. ;; Copyright (C) 2012, 2014 Sébastien Delafond
  3. ;; Author: Sébastien Delafond <sdelafond@gmail.com>
  4. ;; Keywords: outlines, confluence, wiki
  5. ;; This file is not part of GNU Emacs.
  6. ;; This program is free software: you can redistribute it and/or modify
  7. ;; it under the terms of the GNU General Public License as published by
  8. ;; the Free Software Foundation, either version 3 of the License, or
  9. ;; (at your option) any later version.
  10. ;; This program is distributed in the hope that it will be useful,
  11. ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  12. ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  13. ;; GNU General Public License for more details.
  14. ;; You should have received a copy of the GNU General Public License
  15. ;; along with GNU Emacs. If not, see <http://www.gnu.org/licenses/>.
  16. ;;; Commentary:
  17. ;;
  18. ;; ox-confluence.el lets you convert Org files to confluence files
  19. ;; using the ox.el export engine.
  20. ;;
  21. ;; Put this file into your load-path and the following into your ~/.emacs:
  22. ;; (require 'ox-confluence)
  23. ;;
  24. ;; Export Org files to confluence:
  25. ;; M-x org-confluence-export-as-confluence RET
  26. ;;
  27. ;;; Code:
  28. (require 'ox)
  29. (require 'ox-ascii)
  30. ;; Define the backend itself
  31. (org-export-define-derived-backend 'confluence 'ascii
  32. :translate-alist '((bold . org-confluence-bold)
  33. (code . org-confluence-code)
  34. (example-block . org-confluence-example-block)
  35. (fixed-width . org-confluence-fixed-width)
  36. (footnote-definition . org-confluence-empty)
  37. (footnote-reference . org-confluence-empty)
  38. (headline . org-confluence-headline)
  39. (italic . org-confluence-italic)
  40. (item . org-confluence-item)
  41. (link . org-confluence-link)
  42. (paragraph . org-confluence-paragraph)
  43. (property-drawer . org-confluence-property-drawer)
  44. (quote-block . org-confluence-quote-block)
  45. (section . org-confluence-section)
  46. (src-block . org-confluence-src-block)
  47. (strike-through . org-confluence-strike-through)
  48. (table . org-confluence-table)
  49. (table-cell . org-confluence-table-cell)
  50. (table-row . org-confluence-table-row)
  51. (template . org-confluence-template)
  52. (timestamp . org-confluence-timestamp)
  53. (underline . org-confluence-underline)
  54. (verbatim . org-confluence-verbatim)))
  55. (defcustom org-confluence-lang-alist
  56. '(("sh" . "bash"))
  57. "Map from org-babel language name to confluence wiki language name"
  58. :type '(alist :key-type string :value-type string))
  59. ;; All the functions we use
  60. (defun org-confluence-bold (bold contents info)
  61. (format "*%s*" contents))
  62. (defun org-confluence-empty (empty contents info)
  63. "")
  64. (defun org-confluence-example-block (example-block contents info)
  65. ;; FIXME: provide a user-controlled variable for theme
  66. (let ((content (org-export-format-code-default example-block info)))
  67. (org-confluence--block "none" "Confluence" content)))
  68. (defun org-confluence-italic (italic contents info)
  69. (format "_%s_" contents))
  70. (defun org-confluence-item (item contents info)
  71. (let ((list-type (org-element-property :type (org-export-get-parent item))))
  72. (concat
  73. (make-string (1+ (org-confluence--li-depth item))
  74. (if (eq list-type 'ordered) ?\# ?\-))
  75. " "
  76. (pcase (org-element-property :checkbox item)
  77. (`on "*{{(X)}}* ")
  78. (`off "*{{( )}}* ")
  79. (`trans "*{{(\\-)}}* "))
  80. (when (eq list-type 'descriptive)
  81. (concat "*"
  82. (org-export-data (org-element-property :tag item) info)
  83. "* - "))
  84. (org-trim contents))))
  85. (defun org-confluence-fixed-width (fixed-width contents info)
  86. (org-confluence--block
  87. "none"
  88. "Confluence"
  89. (org-trim (org-element-property :value fixed-width))))
  90. (defun org-confluence-verbatim (verbatim contents info)
  91. (format "\{\{%s\}\}" (org-element-property :value verbatim)))
  92. (defun org-confluence-code (code contents info)
  93. (format "\{\{%s\}\}" (org-element-property :value code)))
  94. (defun org-confluence-headline (headline contents info)
  95. (let* ((low-level-rank (org-export-low-level-p headline info))
  96. (text (org-export-data (org-element-property :title headline)
  97. info))
  98. (todo (org-export-data (org-element-property :todo-keyword headline)
  99. info))
  100. (level (org-export-get-relative-level headline info))
  101. (todo-text (if (or (not (plist-get info :with-todo-keywords))
  102. (string= todo ""))
  103. ""
  104. (format "*{{%s}}* " todo))))
  105. (format "h%s. %s%s\n%s" level todo-text text
  106. (if (org-string-nw-p contents) contents ""))))
  107. (defun org-confluence-link (link desc info)
  108. (let ((raw-link (org-element-property :raw-link link)))
  109. (concat "["
  110. (when (org-string-nw-p desc) (format "%s|" desc))
  111. (cond
  112. ((string-match "^confluence:" raw-link)
  113. (replace-regexp-in-string "^confluence:" "" raw-link))
  114. (t
  115. raw-link))
  116. "]")))
  117. (defun org-confluence-paragraph (paragraph contents info)
  118. "Transcode PARAGRAPH element for Confluence.
  119. CONTENTS is the paragraph contents. INFO is a plist used as
  120. a communication channel."
  121. contents)
  122. (defun org-confluence-property-drawer (property-drawer contents info)
  123. (and (org-string-nw-p contents)
  124. (format "\{\{%s\}\}" contents)))
  125. (defun org-confluence-quote-block (quote-block contents info)
  126. (format "{quote}\n%s{quote}" contents))
  127. (defun org-confluence-section (section contents info)
  128. contents)
  129. (defun org-confluence-src-block (src-block contents info)
  130. ;; FIXME: provide a user-controlled variable for theme
  131. (let* ((lang (org-element-property :language src-block))
  132. (language (or (cdr (assoc lang org-confluence-lang-alist)) lang))
  133. (content (org-export-format-code-default src-block info)))
  134. (org-confluence--block language "Emacs" content)))
  135. (defun org-confluence-strike-through (strike-through contents info)
  136. (format "-%s-" contents))
  137. (defun org-confluence-table (table contents info)
  138. contents)
  139. (defun org-confluence-table-row (table-row contents info)
  140. (concat
  141. (if (org-string-nw-p contents) (format "|%s" contents)
  142. "")
  143. (when (org-export-table-row-ends-header-p table-row info)
  144. "|")))
  145. (defun org-confluence-table-cell (table-cell contents info)
  146. (let ((table-row (org-export-get-parent table-cell)))
  147. (concat (and (org-export-table-row-starts-header-p table-row info) "|")
  148. (if (= (length contents) 0) " " contents)
  149. "|")))
  150. (defun org-confluence-template (contents info)
  151. (let ((depth (plist-get info :with-toc)))
  152. (concat (when depth "\{toc\}\n\n") contents)))
  153. (defun org-confluence-timestamp (timestamp _contents _info)
  154. "Transcode a TIMESTAMP object from Org to Confluence.
  155. CONTENTS and INFO are ignored."
  156. (let ((translated (org-trim (org-timestamp-translate timestamp))))
  157. (if (string-prefix-p "[" translated)
  158. (concat "(" (substring translated 1 -1) ")")
  159. translated)))
  160. (defun org-confluence-underline (underline contents info)
  161. (format "+%s+" contents))
  162. (defun org-confluence--block (language theme contents)
  163. (concat "\{code:theme=" theme
  164. (when language (format "|language=%s" language))
  165. "}\n"
  166. contents
  167. "\{code\}\n"))
  168. (defun org-confluence--li-depth (item)
  169. "Return depth of a list item; -1 means not a list item"
  170. ;; FIXME check whether it's worth it to cache depth
  171. ;; (it gets recalculated quite a few times while
  172. ;; traversing a list)
  173. (let ((depth -1)
  174. (tag))
  175. (while (and item
  176. (setq tag (car item))
  177. (or (eq tag 'item) ; list items interleave with plain-list
  178. (eq tag 'plain-list)))
  179. (when (eq tag 'item)
  180. (cl-incf depth))
  181. (setq item (org-export-get-parent item)))
  182. depth))
  183. ;; main interactive entrypoint
  184. (defun org-confluence-export-as-confluence
  185. (&optional async subtreep visible-only body-only ext-plist)
  186. "Export current buffer to a text buffer.
  187. If narrowing is active in the current buffer, only export its
  188. narrowed part.
  189. If a region is active, export that region.
  190. A non-nil optional argument ASYNC means the process should happen
  191. asynchronously. The resulting buffer should be accessible
  192. through the `org-export-stack' interface.
  193. When optional argument SUBTREEP is non-nil, export the sub-tree
  194. at point, extracting information from the headline properties
  195. first.
  196. When optional argument VISIBLE-ONLY is non-nil, don't export
  197. contents of hidden elements.
  198. When optional argument BODY-ONLY is non-nil, strip title, table
  199. of contents and footnote definitions from output.
  200. EXT-PLIST, when provided, is a property list with external
  201. parameters overriding Org default settings, but still inferior to
  202. file-local settings.
  203. Export is done in a buffer named \"*Org CONFLUENCE Export*\", which
  204. will be displayed when `org-export-show-temporary-export-buffer'
  205. is non-nil."
  206. (interactive)
  207. (org-export-to-buffer 'confluence "*org CONFLUENCE Export*"
  208. async subtreep visible-only body-only ext-plist (lambda () (text-mode))))
  209. (provide 'ox-confluence)