ol-wl.el 11 KB

123456789101112131415161718192021222324252627282930313233343536373839404142434445464748495051525354555657585960616263646566676869707172737475767778798081828384858687888990919293949596979899100101102103104105106107108109110111112113114115116117118119120121122123124125126127128129130131132133134135136137138139140141142143144145146147148149150151152153154155156157158159160161162163164165166167168169170171172173174175176177178179180181182183184185186187188189190191192193194195196197198199200201202203204205206207208209210211212213214215216217218219220221222223224225226227228229230231232233234235236237238239240241242243244245246247248249250251252253254255256257258259260261262263264265266267268269270271272273274275276277278279280281282283284285286287288289290291292293294295296297298299300301302303304
  1. ;;; ol-wl.el --- Links to Wanderlust messages
  2. ;; Copyright (C) 2004-2018 Free Software Foundation, Inc.
  3. ;; Author: Tokuya Kameshima <kames at fa2 dot so-net dot ne dot jp>
  4. ;; David Maus <dmaus at ictsoc dot de>
  5. ;; Keywords: outlines, hypermedia, calendar, wp
  6. ;; Homepage: https://orgmode.org
  7. ;;
  8. ;; This file is not part of GNU Emacs.
  9. ;;
  10. ;; This program is free software: you can redistribute it and/or modify
  11. ;; it under the terms of the GNU General Public License as published by
  12. ;; the Free Software Foundation, either version 3 of the License, or
  13. ;; (at your option) any later version.
  14. ;; This program is distributed in the hope that it will be useful,
  15. ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  16. ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  17. ;; GNU General Public License for more details.
  18. ;; You should have received a copy of the GNU General Public License
  19. ;; along with GNU Emacs. If not, see <http://www.gnu.org/licenses/>.
  20. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  21. ;;
  22. ;;; Commentary:
  23. ;; This file implements links to Wanderlust messages from within Org-mode.
  24. ;; Org-mode loads this module by default - if this is not what you want,
  25. ;; configure the variable `org-modules'.
  26. ;;; Code:
  27. (require 'ol)
  28. (require 'org)
  29. (defgroup org-wl nil
  30. "Options concerning the Wanderlust link."
  31. :tag "Org Startup"
  32. :group 'org-link)
  33. (defcustom org-wl-link-to-refile-destination t
  34. "Create a link to the refile destination if the message is marked as refile."
  35. :group 'org-wl
  36. :type 'boolean)
  37. (defcustom org-wl-link-remove-filter nil
  38. "Remove filter condition if message is filter folder."
  39. :group 'org-wl
  40. :type 'boolean)
  41. (defcustom org-wl-shimbun-prefer-web-links nil
  42. "If non-nil create web links for shimbun messages."
  43. :group 'org-wl
  44. :type 'boolean)
  45. (defcustom org-wl-nntp-prefer-web-links nil
  46. "If non-nil create web links for nntp messages.
  47. When folder name contains string \"gmane\" link to gmane,
  48. googlegroups otherwise."
  49. :type 'boolean
  50. :group 'org-wl)
  51. (defcustom org-wl-disable-folder-check t
  52. "Disable check for new messages when open a link."
  53. :type 'boolean
  54. :group 'org-wl)
  55. (defcustom org-wl-namazu-default-index nil
  56. "Default namazu search index."
  57. :type '(choice (const nil) (directory))
  58. :group 'org-wl)
  59. ;; Declare external functions and variables
  60. (declare-function elmo-folder-exists-p "ext:elmo" (folder) t)
  61. (declare-function elmo-message-entity-field "ext:elmo-msgdb"
  62. (entity field &optional type))
  63. (declare-function elmo-message-field "ext:elmo"
  64. (folder number field &optional type) t)
  65. (declare-function elmo-msgdb-overview-get-entity "ext:elmo" (id msgdb) t)
  66. ;; Backward compatibility to old version of wl
  67. (declare-function wl "ext:wl" () t)
  68. (declare-function wl-summary-buffer-msgdb "ext:wl-folder" () t)
  69. (declare-function wl-summary-jump-to-msg-by-message-id "ext:wl-summary"
  70. (&optional id))
  71. (declare-function wl-summary-jump-to-msg "ext:wl-summary"
  72. (&optional number beg end))
  73. (declare-function wl-summary-line-from "ext:wl-summary" ())
  74. (declare-function wl-summary-line-subject "ext:wl-summary" ())
  75. (declare-function wl-summary-message-number "ext:wl-summary" ())
  76. (declare-function wl-summary-redisplay "ext:wl-summary" (&optional arg))
  77. (declare-function wl-summary-registered-temp-mark "ext:wl-action" (number))
  78. (declare-function wl-folder-goto-folder-subr "ext:wl-folder"
  79. (&optional folder sticky))
  80. (declare-function wl-folder-get-petname "ext:wl-folder" (name))
  81. (declare-function wl-folder-get-entity-from-buffer "ext:wl-folder"
  82. (&optional getid))
  83. (declare-function wl-folder-buffer-group-p "ext:wl-folder")
  84. (defvar wl-init)
  85. (defvar wl-summary-buffer-elmo-folder)
  86. (defvar wl-summary-buffer-folder-name)
  87. (defvar wl-folder-group-regexp)
  88. (defvar wl-auto-check-folder-name)
  89. (defvar elmo-nntp-default-server)
  90. (defconst org-wl-folder-types
  91. '(("%" . imap) ("-" . nntp) ("+" . mh) ("=" . spool)
  92. ("$" . archive) ("&" . pop) ("@" . shimbun) ("[" . search)
  93. ("*" . multi) ("/" . filter) ("|" . pipe) ("'" . internal))
  94. "List of folder indicators. See Wanderlust manual, section 3.")
  95. ;; Install the link type
  96. (org-link-set-parameters "wl" :follow #'org-wl-open :store #'org-wl-store-link)
  97. ;; Implementation
  98. (defun org-wl-folder-type (folder)
  99. "Return symbol that indicates the type of FOLDER.
  100. FOLDER is the wanderlust folder name. The first character of the
  101. folder name determines the folder type."
  102. (let* ((indicator (substring folder 0 1))
  103. (type (cdr (assoc indicator org-wl-folder-types))))
  104. ;; maybe access or file folder
  105. (when (not type)
  106. (setq type
  107. (cond
  108. ((and (>= (length folder) 5)
  109. (string= (substring folder 0 5) "file:"))
  110. 'file)
  111. ((and (>= (length folder) 7)
  112. (string= (substring folder 0 7) "access:"))
  113. 'access)
  114. (t
  115. nil))))
  116. type))
  117. (defun org-wl-message-field (field entity)
  118. "Return content of FIELD in ENTITY.
  119. FIELD is a symbol of a rfc822 message header field.
  120. ENTITY is a message entity."
  121. (let ((content (elmo-message-entity-field entity field 'string)))
  122. (if (listp content) (car content) content)))
  123. (defun org-wl-store-link ()
  124. "Store a link to a WL message or folder."
  125. (unless (eobp)
  126. (cond
  127. ((memq major-mode '(wl-summary-mode mime-view-mode))
  128. (org-wl-store-link-message))
  129. ((eq major-mode 'wl-folder-mode)
  130. (org-wl-store-link-folder))
  131. (t
  132. nil))))
  133. (defun org-wl-store-link-folder ()
  134. "Store a link to a WL folder."
  135. (let* ((folder (wl-folder-get-entity-from-buffer))
  136. (petname (wl-folder-get-petname folder))
  137. (link (concat "wl:" folder)))
  138. (save-excursion
  139. (beginning-of-line)
  140. (unless (and (wl-folder-buffer-group-p)
  141. (looking-at wl-folder-group-regexp))
  142. (org-store-link-props :type "wl" :description petname
  143. :link link)
  144. link))))
  145. (defun org-wl-store-link-message ()
  146. "Store a link to a WL message."
  147. (save-excursion
  148. (let ((buf (if (eq major-mode 'wl-summary-mode)
  149. (current-buffer)
  150. (and (boundp 'wl-message-buffer-cur-summary-buffer)
  151. wl-message-buffer-cur-summary-buffer))))
  152. (when buf
  153. (with-current-buffer buf
  154. (let* ((msgnum (wl-summary-message-number))
  155. (mark-info (wl-summary-registered-temp-mark msgnum))
  156. (folder-name
  157. (if (and org-wl-link-to-refile-destination
  158. mark-info
  159. (equal (nth 1 mark-info) "o")) ; marked as refile
  160. (nth 2 mark-info)
  161. wl-summary-buffer-folder-name))
  162. (folder-type (org-wl-folder-type folder-name))
  163. (wl-message-entity
  164. (if (fboundp 'elmo-message-entity)
  165. (elmo-message-entity
  166. wl-summary-buffer-elmo-folder msgnum)
  167. (elmo-msgdb-overview-get-entity
  168. msgnum (wl-summary-buffer-msgdb))))
  169. (message-id
  170. (org-wl-message-field 'message-id wl-message-entity))
  171. (message-id-no-brackets
  172. (org-unbracket-string "<" ">" message-id))
  173. (from (org-wl-message-field 'from wl-message-entity))
  174. (to (org-wl-message-field 'to wl-message-entity))
  175. (xref (org-wl-message-field 'xref wl-message-entity))
  176. (subject (org-wl-message-field 'subject wl-message-entity))
  177. (date (org-wl-message-field 'date wl-message-entity))
  178. desc link)
  179. ;; remove text properties of subject string to avoid possible bug
  180. ;; when formatting the subject
  181. ;; (Emacs bug #5306, fixed)
  182. (set-text-properties 0 (length subject) nil subject)
  183. ;; maybe remove filter condition
  184. (when (and (eq folder-type 'filter) org-wl-link-remove-filter)
  185. (while (eq (org-wl-folder-type folder-name) 'filter)
  186. (setq folder-name
  187. (replace-regexp-in-string "^/[^/]+/" "" folder-name))))
  188. ;; maybe create http link
  189. (cond
  190. ((and (eq folder-type 'shimbun)
  191. org-wl-shimbun-prefer-web-links xref)
  192. (org-store-link-props :type "http" :link xref :description subject
  193. :from from :to to :message-id message-id
  194. :message-id-no-brackets message-id-no-brackets
  195. :subject subject))
  196. ((and (eq folder-type 'nntp) org-wl-nntp-prefer-web-links)
  197. (setq link
  198. (format
  199. (if (string-match-p "gmane\\." folder-name)
  200. "http://mid.gmane.org/%s"
  201. "http://groups.google.com/groups/search?as_umsgid=%s")
  202. (url-encode-url message-id)))
  203. (org-store-link-props :type "http" :link link :description subject
  204. :from from :to to :message-id message-id
  205. :message-id-no-brackets message-id-no-brackets
  206. :subject subject))
  207. (t
  208. (org-store-link-props :type "wl" :from from :to to
  209. :subject subject :message-id message-id
  210. :message-id-no-brackets message-id-no-brackets)
  211. (setq desc (org-email-link-description))
  212. (setq link (concat "wl:" folder-name "#" message-id-no-brackets))
  213. (org-add-link-props :link link :description desc)))
  214. (org-add-link-props :date date)
  215. (or link xref)))))))
  216. (defun org-wl-open-nntp (path)
  217. "Follow the nntp: link specified by PATH."
  218. (let* ((spec (split-string path "/"))
  219. (server (split-string (nth 2 spec) "@"))
  220. (group (nth 3 spec))
  221. (article (nth 4 spec)))
  222. (org-wl-open
  223. (concat "-" group ":" (if (cdr server)
  224. (car (split-string (car server) ":"))
  225. "")
  226. (if (string= elmo-nntp-default-server (nth 2 spec))
  227. ""
  228. (concat "@" (or (cdr server) (car server))))
  229. (if article (concat "#" article) "")))))
  230. (defun org-wl-open (path)
  231. "Follow the WL message link specified by PATH.
  232. When called with one prefix, open message in namazu search folder
  233. with `org-wl-namazu-default-index' as search index. When called
  234. with two prefixes or `org-wl-namazu-default-index' is nil, ask
  235. for namazu index."
  236. (require 'wl)
  237. (let ((wl-auto-check-folder-name
  238. (if org-wl-disable-folder-check
  239. 'none
  240. wl-auto-check-folder-name)))
  241. (unless wl-init (wl))
  242. ;; XXX: The imap-uw's MH folder names start with "%#".
  243. (if (not (string-match "\\`\\(\\(?:%#\\)?[^#]+\\)\\(#\\(.*\\)\\)?" path))
  244. (error "Error in Wanderlust link"))
  245. (let ((folder (match-string 1 path))
  246. (article (match-string 3 path)))
  247. ;; maybe open message in namazu search folder
  248. (when current-prefix-arg
  249. (setq folder (concat "[" article "]"
  250. (if (and (equal current-prefix-arg '(4))
  251. org-wl-namazu-default-index)
  252. org-wl-namazu-default-index
  253. (read-directory-name "Namazu index: ")))))
  254. (if (not (elmo-folder-exists-p (with-no-warnings
  255. (wl-folder-get-elmo-folder folder))))
  256. (error "No such folder: %s" folder))
  257. (let ((old-buf (current-buffer))
  258. (old-point (point-marker)))
  259. (wl-folder-goto-folder-subr folder)
  260. (with-current-buffer old-buf
  261. ;; XXX: `wl-folder-goto-folder-subr' moves point to the
  262. ;; beginning of the current line. So, restore the point
  263. ;; in the old buffer.
  264. (goto-char old-point))
  265. (when article
  266. (if (string-match-p "@" article)
  267. (wl-summary-jump-to-msg-by-message-id (org-link-add-angle-brackets
  268. article))
  269. (or (wl-summary-jump-to-msg (string-to-number article))
  270. (error "No such message: %s" article)))
  271. (wl-summary-redisplay))))))
  272. (provide 'ol-wl)
  273. ;;; ol-wl.el ends here