ol-man.el 2.6 KB

1234567891011121314151617181920212223242526272829303132333435363738394041424344454647484950515253545556575859606162636465666768697071727374757677
  1. ;;; ol-man.el - Links to man pages
  2. ;;
  3. ;; Author: Carsten Dominik <carsten at orgmode dot org>
  4. ;; Keywords: outlines, hypermedia, calendar, wp
  5. ;; Homepage: https://orgmode.org
  6. ;; Version: 1.0
  7. ;;
  8. ;; This file is not yet part of GNU Emacs.
  9. ;;
  10. ;; This program is free software; you can redistribute it and/or modify
  11. ;; it under the terms of the GNU General Public License as published by
  12. ;; the Free Software Foundation; either version 3, or (at your option)
  13. ;; any later version.
  14. ;; This program is distributed in the hope that it will be useful,
  15. ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  16. ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  17. ;; GNU General Public License for more details.
  18. ;; You should have received a copy of the GNU General Public License
  19. ;; along with GNU Emacs. If not, see <http://www.gnu.org/licenses/>.
  20. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  21. ;;
  22. ;;; Commentary:
  23. (require 'ol)
  24. (require 'org)
  25. (org-link-set-parameters "man"
  26. :follow #'org-man-open
  27. :export #'org-man-export
  28. :store #'org-man-store-link)
  29. (defcustom org-man-command 'man
  30. "The Emacs command to be used to display a man page."
  31. :group 'org-link
  32. :type '(choice (const man) (const woman)))
  33. (defun org-man-open (path)
  34. "Visit the manpage on PATH.
  35. PATH should be a topic that can be thrown at the man command."
  36. (funcall org-man-command path))
  37. (defun org-man-store-link ()
  38. "Store a link to a README file."
  39. (when (memq major-mode '(Man-mode woman-mode))
  40. ;; This is a man page, we do make this link
  41. (let* ((page (org-man-get-page-name))
  42. (link (concat "man:" page))
  43. (description (format "Manpage for %s" page)))
  44. (org-store-link-props
  45. :type "man"
  46. :link link
  47. :description description))))
  48. (defun org-man-get-page-name ()
  49. "Extract the page name from the buffer name."
  50. ;; This works for both `Man-mode' and `woman-mode'.
  51. (if (string-match " \\(\\S-+\\)\\*" (buffer-name))
  52. (match-string 1 (buffer-name))
  53. (error "Cannot create link to this man page")))
  54. (defun org-man-export (link description format)
  55. "Export a man page link from Org files."
  56. (let ((path (format "http://man.he.net/?topic=%s&section=all" link))
  57. (desc (or description link)))
  58. (cond
  59. ((eq format 'html) (format "<a target=\"_blank\" href=\"%s\">%s</a>" path desc))
  60. ((eq format 'latex) (format "\\href{%s}{%s}" path desc))
  61. ((eq format 'texinfo) (format "@uref{%s,%s}" path desc))
  62. ((eq format 'ascii) (format "%s (%s)" desc path))
  63. (t path))))
  64. (provide 'ol-man)
  65. ;;; ol-man.el ends here