ox-beamer.el 43 KB

12345678910111213141516171819202122232425262728293031323334353637383940414243444546474849505152535455565758596061626364656667686970717273747576777879808182838485868788899091929394959697989910010110210310410510610710810911011111211311411511611711811912012112212312412512612712812913013113213313413513613713813914014114214314414514614714814915015115215315415515615715815916016116216316416516616716816917017117217317417517617717817918018118218318418518618718818919019119219319419519619719819920020120220320420520620720820921021121221321421521621721821922022122222322422522622722822923023123223323423523623723823924024124224324424524624724824925025125225325425525625725825926026126226326426526626726826927027127227327427527627727827928028128228328428528628728828929029129229329429529629729829930030130230330430530630730830931031131231331431531631731831932032132232332432532632732832933033133233333433533633733833934034134234334434534634734834935035135235335435535635735835936036136236336436536636736836937037137237337437537637737837938038138238338438538638738838939039139239339439539639739839940040140240340440540640740840941041141241341441541641741841942042142242342442542642742842943043143243343443543643743843944044144244344444544644744844945045145245345445545645745845946046146246346446546646746846947047147247347447547647747847948048148248348448548648748848949049149249349449549649749849950050150250350450550650750850951051151251351451551651751851952052152252352452552652752852953053153253353453553653753853954054154254354454554654754854955055155255355455555655755855956056156256356456556656756856957057157257357457557657757857958058158258358458558658758858959059159259359459559659759859960060160260360460560660760860961061161261361461561661761861962062162262362462562662762862963063163263363463563663763863964064164264364464564664764864965065165265365465565665765865966066166266366466566666766866967067167267367467567667767867968068168268368468568668768868969069169269369469569669769869970070170270370470570670770870971071171271371471571671771871972072172272372472572672772872973073173273373473573673773873974074174274374474574674774874975075175275375475575675775875976076176276376476576676776876977077177277377477577677777877978078178278378478578678778878979079179279379479579679779879980080180280380480580680780880981081181281381481581681781881982082182282382482582682782882983083183283383483583683783883984084184284384484584684784884985085185285385485585685785885986086186286386486586686786886987087187287387487587687787887988088188288388488588688788888989089189289389489589689789889990090190290390490590690790890991091191291391491591691791891992092192292392492592692792892993093193293393493593693793893994094194294394494594694794894995095195295395495595695795895996096196296396496596696796896997097197297397497597697797897998098198298398498598698798898999099199299399499599699799899910001001100210031004100510061007100810091010101110121013101410151016101710181019102010211022102310241025102610271028102910301031103210331034103510361037103810391040104110421043104410451046104710481049105010511052105310541055105610571058105910601061106210631064106510661067106810691070107110721073107410751076107710781079108010811082108310841085108610871088108910901091109210931094109510961097109810991100110111021103110411051106110711081109111011111112111311141115111611171118111911201121112211231124112511261127112811291130113111321133113411351136113711381139114011411142114311441145114611471148114911501151115211531154115511561157115811591160116111621163116411651166116711681169117011711172117311741175117611771178
  1. ;;; ox-beamer.el --- Beamer Back-End for Org Export Engine -*- lexical-binding: t; -*-
  2. ;; Copyright (C) 2007-2016 Free Software Foundation, Inc.
  3. ;; Author: Carsten Dominik <carsten.dominik AT gmail DOT com>
  4. ;; Nicolas Goaziou <n.goaziou AT gmail DOT com>
  5. ;; Keywords: org, wp, tex
  6. ;; This file is part of GNU Emacs.
  7. ;; GNU Emacs is free software: you can redistribute it and/or modify
  8. ;; it under the terms of the GNU General Public License as published by
  9. ;; the Free Software Foundation, either version 3 of the License, or
  10. ;; (at your option) any later version.
  11. ;; GNU Emacs is distributed in the hope that it will be useful,
  12. ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  13. ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  14. ;; GNU General Public License for more details.
  15. ;; You should have received a copy of the GNU General Public License
  16. ;; along with GNU Emacs. If not, see <http://www.gnu.org/licenses/>.
  17. ;;; Commentary:
  18. ;;
  19. ;; This library implements both a Beamer back-end, derived from the
  20. ;; LaTeX one and a minor mode easing structure edition of the
  21. ;; document. See Org manual for more information.
  22. ;;; Code:
  23. (require 'cl-lib)
  24. (require 'ox-latex)
  25. ;; Install a default set-up for Beamer export.
  26. (unless (assoc "beamer" org-latex-classes)
  27. (add-to-list 'org-latex-classes
  28. '("beamer"
  29. "\\documentclass[presentation]{beamer}"
  30. ("\\section{%s}" . "\\section*{%s}")
  31. ("\\subsection{%s}" . "\\subsection*{%s}")
  32. ("\\subsubsection{%s}" . "\\subsubsection*{%s}"))))
  33. ;;; User-Configurable Variables
  34. (defgroup org-export-beamer nil
  35. "Options specific for using the beamer class in LaTeX export."
  36. :tag "Org Beamer"
  37. :group 'org-export
  38. :version "24.2")
  39. (defcustom org-beamer-frame-level 1
  40. "The level at which headlines become frames.
  41. Headlines at a lower level will be translated into a sectioning
  42. structure. At a higher level, they will be translated into
  43. blocks.
  44. If a headline with a \"BEAMER_env\" property set to \"frame\" is
  45. found within a tree, its level locally overrides this number.
  46. This variable has no effect on headlines with the \"BEAMER_env\"
  47. property set to either \"ignoreheading\", \"appendix\", or
  48. \"note\", which will respectively, be invisible, become an
  49. appendix or a note.
  50. This integer is relative to the minimal level of a headline
  51. within the parse tree, defined as 1."
  52. :group 'org-export-beamer
  53. :type 'integer)
  54. (defcustom org-beamer-frame-default-options ""
  55. "Default options string to use for frames.
  56. For example, it could be set to \"allowframebreaks\"."
  57. :group 'org-export-beamer
  58. :type '(string :tag "[options]"))
  59. (defcustom org-beamer-column-view-format
  60. "%45ITEM %10BEAMER_env(Env) %10BEAMER_act(Act) %4BEAMER_col(Col) %8BEAMER_opt(Opt)"
  61. "Column view format that should be used to fill the template."
  62. :group 'org-export-beamer
  63. :version "24.4"
  64. :package-version '(Org . "8.0")
  65. :type '(choice
  66. (const :tag "Do not insert Beamer column view format" nil)
  67. (string :tag "Beamer column view format")))
  68. (defcustom org-beamer-theme "default"
  69. "Default theme used in Beamer presentations."
  70. :group 'org-export-beamer
  71. :version "24.4"
  72. :package-version '(Org . "8.0")
  73. :type '(choice
  74. (const :tag "Do not insert a Beamer theme" nil)
  75. (string :tag "Beamer theme")))
  76. (defcustom org-beamer-environments-extra nil
  77. "Environments triggered by tags in Beamer export.
  78. Each entry has 4 elements:
  79. name Name of the environment
  80. key Selection key for `org-beamer-select-environment'
  81. open The opening template for the environment, with the following escapes
  82. %a the action/overlay specification
  83. %A the default action/overlay specification
  84. %R the raw BEAMER_act value
  85. %o the options argument, with square brackets
  86. %O the raw BEAMER_opt value
  87. %h the headline text
  88. %r the raw headline text (i.e. without any processing)
  89. %H if there is headline text, that raw text in {} braces
  90. %U if there is headline text, that raw text in [] brackets
  91. close The closing string of the environment."
  92. :group 'org-export-beamer
  93. :version "24.4"
  94. :package-version '(Org . "8.1")
  95. :type '(repeat
  96. (list
  97. (string :tag "Environment")
  98. (string :tag "Selection key")
  99. (string :tag "Begin")
  100. (string :tag "End"))))
  101. (defcustom org-beamer-outline-frame-title "Outline"
  102. "Default title of a frame containing an outline."
  103. :group 'org-export-beamer
  104. :type '(string :tag "Outline frame title"))
  105. (defcustom org-beamer-outline-frame-options ""
  106. "Outline frame options appended after \\begin{frame}.
  107. You might want to put e.g. \"allowframebreaks=0.9\" here."
  108. :group 'org-export-beamer
  109. :type '(string :tag "Outline frame options"))
  110. (defcustom org-beamer-subtitle-format "\\subtitle{%s}"
  111. "Format string used for transcoded subtitle.
  112. The format string should have at most one \"%s\"-expression,
  113. which is replaced with the subtitle."
  114. :group 'org-export-beamer
  115. :version "25.2"
  116. :package-version '(Org . "8.3")
  117. :type '(string :tag "Format string"))
  118. ;;; Internal Variables
  119. (defconst org-beamer-column-widths
  120. "0.1 0.2 0.3 0.4 0.5 0.6 0.7 0.8 0.9 0.0 :ETC"
  121. "The column widths that should be installed as allowed property values.")
  122. (defconst org-beamer-environments-special
  123. '(("againframe" "A")
  124. ("appendix" "x")
  125. ("column" "c")
  126. ("columns" "C")
  127. ("frame" "f")
  128. ("fullframe" "F")
  129. ("ignoreheading" "i")
  130. ("note" "n")
  131. ("noteNH" "N"))
  132. "Alist of environments treated in a special way by the back-end.
  133. Keys are environment names, as strings, values are bindings used
  134. in `org-beamer-select-environment'. Environments listed here,
  135. along with their binding, are hard coded and cannot be modified
  136. through `org-beamer-environments-extra' variable.")
  137. (defconst org-beamer-environments-default
  138. '(("block" "b" "\\begin{block}%a{%h}" "\\end{block}")
  139. ("alertblock" "a" "\\begin{alertblock}%a{%h}" "\\end{alertblock}")
  140. ("verse" "v" "\\begin{verse}%a %% %h" "\\end{verse}")
  141. ("quotation" "q" "\\begin{quotation}%a %% %h" "\\end{quotation}")
  142. ("quote" "Q" "\\begin{quote}%a %% %h" "\\end{quote}")
  143. ("structureenv" "s" "\\begin{structureenv}%a %% %h" "\\end{structureenv}")
  144. ("theorem" "t" "\\begin{theorem}%a%U" "\\end{theorem}")
  145. ("definition" "d" "\\begin{definition}%a%U" "\\end{definition}")
  146. ("example" "e" "\\begin{example}%a%U" "\\end{example}")
  147. ("exampleblock" "E" "\\begin{exampleblock}%a{%h}" "\\end{exampleblock}")
  148. ("proof" "p" "\\begin{proof}%a%U" "\\end{proof}")
  149. ("beamercolorbox" "o" "\\begin{beamercolorbox}%o{%h}" "\\end{beamercolorbox}"))
  150. "Environments triggered by properties in Beamer export.
  151. These are the defaults - for user definitions, see
  152. `org-beamer-environments-extra'.")
  153. (defconst org-beamer-verbatim-elements
  154. '(code example-block fixed-width inline-src-block src-block verbatim)
  155. "List of element or object types producing verbatim text.
  156. This is used internally to determine when a frame should have the
  157. \"fragile\" option.")
  158. ;;; Internal functions
  159. (defun org-beamer--normalize-argument (argument type)
  160. "Return ARGUMENT string with proper boundaries.
  161. TYPE is a symbol among the following:
  162. `action' Return ARGUMENT within angular brackets.
  163. `defaction' Return ARGUMENT within both square and angular brackets.
  164. `option' Return ARGUMENT within square brackets."
  165. (if (not (string-match "\\S-" argument)) ""
  166. (cl-case type
  167. (action (format "<%s>" (org-unbracket-string "<" ">" argument)))
  168. (defaction
  169. (format "[<%s>]"
  170. (org-unbracket-string "<" ">" (org-unbracket-string "[" "]" argument))))
  171. (option (format "[%s]" (org-unbracket-string "[" "]" argument)))
  172. (otherwise (error "Invalid `type' argument to `org-beamer--normalize-argument': %s"
  173. type)))))
  174. (defun org-beamer--element-has-overlay-p (element)
  175. "Non-nil when ELEMENT has an overlay specified.
  176. An element has an overlay specification when it starts with an
  177. `beamer' export-snippet whose value is between angular brackets.
  178. Return overlay specification, as a string, or nil."
  179. (let ((first-object (car (org-element-contents element))))
  180. (when (eq (org-element-type first-object) 'export-snippet)
  181. (let ((value (org-element-property :value first-object)))
  182. (and (string-prefix-p "<" value) (string-suffix-p ">" value)
  183. value)))))
  184. ;;; Define Back-End
  185. (org-export-define-derived-backend 'beamer 'latex
  186. :menu-entry
  187. '(?l 1
  188. ((?B "As LaTeX buffer (Beamer)" org-beamer-export-as-latex)
  189. (?b "As LaTeX file (Beamer)" org-beamer-export-to-latex)
  190. (?P "As PDF file (Beamer)" org-beamer-export-to-pdf)
  191. (?O "As PDF file and open (Beamer)"
  192. (lambda (a s v b)
  193. (if a (org-beamer-export-to-pdf t s v b)
  194. (org-open-file (org-beamer-export-to-pdf nil s v b)))))))
  195. :options-alist
  196. '((:headline-levels nil "H" org-beamer-frame-level)
  197. (:latex-class "LATEX_CLASS" nil "beamer" t)
  198. (:beamer-subtitle-format nil nil org-beamer-subtitle-format)
  199. (:beamer-column-view-format "COLUMNS" nil org-beamer-column-view-format)
  200. (:beamer-theme "BEAMER_THEME" nil org-beamer-theme)
  201. (:beamer-color-theme "BEAMER_COLOR_THEME" nil nil t)
  202. (:beamer-font-theme "BEAMER_FONT_THEME" nil nil t)
  203. (:beamer-inner-theme "BEAMER_INNER_THEME" nil nil t)
  204. (:beamer-outer-theme "BEAMER_OUTER_THEME" nil nil t)
  205. (:beamer-header "BEAMER_HEADER" nil nil newline)
  206. (:beamer-environments-extra nil nil org-beamer-environments-extra)
  207. (:beamer-frame-default-options nil nil org-beamer-frame-default-options)
  208. (:beamer-outline-frame-options nil nil org-beamer-outline-frame-options)
  209. (:beamer-outline-frame-title nil nil org-beamer-outline-frame-title))
  210. :translate-alist '((bold . org-beamer-bold)
  211. (export-block . org-beamer-export-block)
  212. (export-snippet . org-beamer-export-snippet)
  213. (headline . org-beamer-headline)
  214. (item . org-beamer-item)
  215. (keyword . org-beamer-keyword)
  216. (link . org-beamer-link)
  217. (plain-list . org-beamer-plain-list)
  218. (radio-target . org-beamer-radio-target)
  219. (target . org-beamer-target)
  220. (template . org-beamer-template)))
  221. ;;; Transcode Functions
  222. ;;;; Bold
  223. (defun org-beamer-bold (bold contents _info)
  224. "Transcode BLOCK object into Beamer code.
  225. CONTENTS is the text being bold. INFO is a plist used as
  226. a communication channel."
  227. (format "\\alert%s{%s}"
  228. (or (org-beamer--element-has-overlay-p bold) "")
  229. contents))
  230. ;;;; Export Block
  231. (defun org-beamer-export-block (export-block _contents _info)
  232. "Transcode an EXPORT-BLOCK element into Beamer code.
  233. CONTENTS is nil. INFO is a plist used as a communication
  234. channel."
  235. (when (member (org-element-property :type export-block) '("BEAMER" "LATEX"))
  236. (org-remove-indentation (org-element-property :value export-block))))
  237. ;;;; Export Snippet
  238. (defun org-beamer-export-snippet (export-snippet _contents info)
  239. "Transcode an EXPORT-SNIPPET object into Beamer code.
  240. CONTENTS is nil. INFO is a plist used as a communication
  241. channel."
  242. (let ((backend (org-export-snippet-backend export-snippet))
  243. (value (org-element-property :value export-snippet)))
  244. ;; Only "latex" and "beamer" snippets are retained.
  245. (cond ((eq backend 'latex) value)
  246. ;; Ignore "beamer" snippets specifying overlays.
  247. ((and (eq backend 'beamer)
  248. (or (org-export-get-previous-element export-snippet info)
  249. (not (string-match "\\`<.*>\\'" value))))
  250. value))))
  251. ;;;; Headline
  252. ;;
  253. ;; The main function to translate a headline is
  254. ;; `org-beamer-headline'.
  255. ;;
  256. ;; Depending on the level at which a headline is considered as
  257. ;; a frame (given by `org-beamer--frame-level'), the headline is
  258. ;; either a section (`org-beamer--format-section'), a frame
  259. ;; (`org-beamer--format-frame') or a block
  260. ;; (`org-beamer--format-block').
  261. ;;
  262. ;; `org-beamer-headline' also takes care of special environments
  263. ;; like "ignoreheading", "note", "noteNH", "appendix" and
  264. ;; "againframe".
  265. (defun org-beamer--get-label (headline info)
  266. "Return label for HEADLINE, as a string.
  267. INFO is a plist used as a communication channel.
  268. The value is either the label specified in \"BEAMER_opt\"
  269. property, the custom ID, if there is one and
  270. `:latex-prefer-user-labels' property has a non nil value, or
  271. a unique internal label. This function assumes HEADLINE will be
  272. treated as a frame."
  273. (cond
  274. ((let ((opt (org-element-property :BEAMER_OPT headline)))
  275. (and (stringp opt)
  276. (string-match "\\(?:^\\|,\\)label=\\(.*?\\)\\(?:$\\|,\\)" opt)
  277. (let ((label (match-string 1 opt)))
  278. (if (string-match-p "\\`{.*}\\'" label)
  279. (substring label 1 -1)
  280. label)))))
  281. ((and (plist-get info :latex-prefer-user-labels)
  282. (org-element-property :CUSTOM_ID headline)))
  283. (t (format "sec:%s" (org-export-get-reference headline info)))))
  284. (defun org-beamer--frame-level (headline info)
  285. "Return frame level in subtree containing HEADLINE.
  286. INFO is a plist used as a communication channel."
  287. (or
  288. ;; 1. Look for "frame" environment in parents, starting from the
  289. ;; farthest.
  290. (catch 'exit
  291. (dolist (parent (nreverse (org-element-lineage headline)))
  292. (let ((env (org-element-property :BEAMER_ENV parent)))
  293. (when (and env (member-ignore-case env '("frame" "fullframe")))
  294. (throw 'exit (org-export-get-relative-level parent info))))))
  295. ;; 2. Look for "frame" environment in HEADLINE.
  296. (let ((env (org-element-property :BEAMER_ENV headline)))
  297. (and env (member-ignore-case env '("frame" "fullframe"))
  298. (org-export-get-relative-level headline info)))
  299. ;; 3. Look for "frame" environment in sub-tree.
  300. (org-element-map headline 'headline
  301. (lambda (hl)
  302. (let ((env (org-element-property :BEAMER_ENV hl)))
  303. (when (and env (member-ignore-case env '("frame" "fullframe")))
  304. (org-export-get-relative-level hl info))))
  305. info 'first-match)
  306. ;; 4. No "frame" environment in tree: use default value.
  307. (plist-get info :headline-levels)))
  308. (defun org-beamer--format-section (headline contents info)
  309. "Format HEADLINE as a sectioning part.
  310. CONTENTS holds the contents of the headline. INFO is a plist
  311. used as a communication channel."
  312. (let ((latex-headline
  313. (org-export-with-backend
  314. ;; We create a temporary export back-end which behaves the
  315. ;; same as current one, but adds "\protect" in front of the
  316. ;; output of some objects.
  317. (org-export-create-backend
  318. :parent 'latex
  319. :transcoders
  320. (let ((protected-output
  321. (function
  322. (lambda (object contents info)
  323. (let ((code (org-export-with-backend
  324. 'beamer object contents info)))
  325. (if (org-string-nw-p code) (concat "\\protect" code)
  326. code))))))
  327. (mapcar #'(lambda (type) (cons type protected-output))
  328. '(bold footnote-reference italic strike-through timestamp
  329. underline))))
  330. headline
  331. contents
  332. info))
  333. (mode-specs (org-element-property :BEAMER_ACT headline)))
  334. (if (and mode-specs
  335. (string-match "\\`\\\\\\(.*?\\)\\(?:\\*\\|\\[.*\\]\\)?{"
  336. latex-headline))
  337. ;; Insert overlay specifications.
  338. (replace-match (concat (match-string 1 latex-headline)
  339. (format "<%s>" mode-specs))
  340. nil nil latex-headline 1)
  341. latex-headline)))
  342. (defun org-beamer--format-frame (headline contents info)
  343. "Format HEADLINE as a frame.
  344. CONTENTS holds the contents of the headline. INFO is a plist
  345. used as a communication channel."
  346. (let ((fragilep
  347. ;; FRAGILEP is non-nil when HEADLINE contains an element
  348. ;; among `org-beamer-verbatim-elements'.
  349. (org-element-map headline org-beamer-verbatim-elements 'identity
  350. info 'first-match)))
  351. (concat "\\begin{frame}"
  352. ;; Overlay specification, if any. When surrounded by
  353. ;; square brackets, consider it as a default
  354. ;; specification.
  355. (let ((action (org-element-property :BEAMER_ACT headline)))
  356. (cond
  357. ((not action) "")
  358. ((string-match "\\`\\[.*\\]\\'" action )
  359. (org-beamer--normalize-argument action 'defaction))
  360. (t (org-beamer--normalize-argument action 'action))))
  361. ;; Options, if any.
  362. (let* ((beamer-opt (org-element-property :BEAMER_OPT headline))
  363. (options
  364. ;; Collect options from default value and headline's
  365. ;; properties. Also add a label for links.
  366. (append
  367. (org-split-string
  368. (plist-get info :beamer-frame-default-options) ",")
  369. (and beamer-opt
  370. (org-split-string
  371. ;; Remove square brackets if user provided
  372. ;; them.
  373. (and (string-match "^\\[?\\(.*\\)\\]?$" beamer-opt)
  374. (match-string 1 beamer-opt))
  375. ","))
  376. ;; Provide an automatic label for the frame
  377. ;; unless the user specified one. Also refrain
  378. ;; from labeling `allowframebreaks' frames; this
  379. ;; is not allowed by beamer.
  380. (unless (and beamer-opt
  381. (or (string-match "\\(^\\|,\\)label=" beamer-opt)
  382. (string-match "allowframebreaks" beamer-opt)))
  383. (list
  384. (let ((label (org-beamer--get-label headline info)))
  385. ;; Labels containing colons need to be
  386. ;; wrapped within braces.
  387. (format (if (string-match-p ":" label)
  388. "label={%s}"
  389. "label=%s")
  390. label)))))))
  391. ;; Change options list into a string.
  392. (org-beamer--normalize-argument
  393. (mapconcat
  394. 'identity
  395. (if (or (not fragilep) (member "fragile" options)) options
  396. (cons "fragile" options))
  397. ",")
  398. 'option))
  399. ;; Title.
  400. (let ((env (org-element-property :BEAMER_ENV headline)))
  401. (format "{%s}"
  402. (if (and env (equal (downcase env) "fullframe")) ""
  403. (org-export-data
  404. (org-element-property :title headline) info))))
  405. "\n"
  406. ;; The following workaround is required in fragile frames
  407. ;; as Beamer will append "\par" to the beginning of the
  408. ;; contents. So we need to make sure the command is
  409. ;; separated from the contents by at least one space. If
  410. ;; it isn't, it will create "\parfirst-word" command and
  411. ;; remove the first word from the contents in the PDF
  412. ;; output.
  413. (if (not fragilep) contents
  414. (replace-regexp-in-string "\\`\n*" "\\& " (or contents "")))
  415. "\\end{frame}")))
  416. (defun org-beamer--format-block (headline contents info)
  417. "Format HEADLINE as a block.
  418. CONTENTS holds the contents of the headline. INFO is a plist
  419. used as a communication channel."
  420. (let* ((column-width (org-element-property :BEAMER_COL headline))
  421. ;; ENVIRONMENT defaults to "block" if none is specified and
  422. ;; there is no column specification. If there is a column
  423. ;; specified but still no explicit environment, ENVIRONMENT
  424. ;; is "column".
  425. (environment (let ((env (org-element-property :BEAMER_ENV headline)))
  426. (cond
  427. ;; "block" is the fallback environment.
  428. ((and (not env) (not column-width)) "block")
  429. ;; "column" only.
  430. ((not env) "column")
  431. ;; Use specified environment.
  432. (t env))))
  433. (raw-title (org-element-property :raw-value headline))
  434. (env-format
  435. (cond ((member environment '("column" "columns")) nil)
  436. ((assoc environment
  437. (append (plist-get info :beamer-environments-extra)
  438. org-beamer-environments-default)))
  439. (t (user-error "Wrong block type at a headline named \"%s\""
  440. raw-title))))
  441. (title (org-export-data (org-element-property :title headline) info))
  442. (raw-options (org-element-property :BEAMER_OPT headline))
  443. (options (if raw-options
  444. (org-beamer--normalize-argument raw-options 'option)
  445. ""))
  446. ;; Start a "columns" environment when explicitly requested or
  447. ;; when there is no previous headline or the previous
  448. ;; headline do not have a BEAMER_column property.
  449. (parent-env (org-element-property
  450. :BEAMER_ENV (org-export-get-parent-headline headline)))
  451. (start-columns-p
  452. (or (equal environment "columns")
  453. (and column-width
  454. (not (and parent-env
  455. (equal (downcase parent-env) "columns")))
  456. (or (org-export-first-sibling-p headline info)
  457. (not (org-element-property
  458. :BEAMER_COL
  459. (org-export-get-previous-element
  460. headline info)))))))
  461. ;; End the "columns" environment when explicitly requested or
  462. ;; when there is no next headline or the next headline do not
  463. ;; have a BEAMER_column property.
  464. (end-columns-p
  465. (or (equal environment "columns")
  466. (and column-width
  467. (not (and parent-env
  468. (equal (downcase parent-env) "columns")))
  469. (or (org-export-last-sibling-p headline info)
  470. (not (org-element-property
  471. :BEAMER_COL
  472. (org-export-get-next-element headline info))))))))
  473. (concat
  474. (when start-columns-p
  475. ;; Column can accept options only when the environment is
  476. ;; explicitly defined.
  477. (if (not (equal environment "columns")) "\\begin{columns}\n"
  478. (format "\\begin{columns}%s\n" options)))
  479. (when column-width
  480. (format "\\begin{column}%s{%s}\n"
  481. ;; One can specify placement for column only when
  482. ;; HEADLINE stands for a column on its own.
  483. (if (equal environment "column") options "")
  484. (format "%s\\columnwidth" column-width)))
  485. ;; Block's opening string.
  486. (when (nth 2 env-format)
  487. (concat
  488. (org-fill-template
  489. (nth 2 env-format)
  490. (nconc
  491. ;; If BEAMER_act property has its value enclosed in square
  492. ;; brackets, it is a default overlay specification and
  493. ;; overlay specification is empty. Otherwise, it is an
  494. ;; overlay specification and the default one is nil.
  495. (let ((action (org-element-property :BEAMER_ACT headline)))
  496. (cond
  497. ((not action) (list (cons "a" "") (cons "A" "") (cons "R" "")))
  498. ((and (string-prefix-p "[" action)
  499. (string-suffix-p "]" action))
  500. (list
  501. (cons "A" (org-beamer--normalize-argument action 'defaction))
  502. (cons "a" "")
  503. (cons "R" action)))
  504. (t
  505. (list (cons "a" (org-beamer--normalize-argument action 'action))
  506. (cons "A" "")
  507. (cons "R" action)))))
  508. (list (cons "o" options)
  509. (cons "O" (or raw-options ""))
  510. (cons "h" title)
  511. (cons "r" raw-title)
  512. (cons "H" (if (equal raw-title "") ""
  513. (format "{%s}" raw-title)))
  514. (cons "U" (if (equal raw-title "") ""
  515. (format "[%s]" raw-title))))))
  516. "\n"))
  517. contents
  518. ;; Block's closing string, if any.
  519. (and (nth 3 env-format) (concat (nth 3 env-format) "\n"))
  520. (when column-width "\\end{column}\n")
  521. (when end-columns-p "\\end{columns}"))))
  522. (defun org-beamer-headline (headline contents info)
  523. "Transcode HEADLINE element into Beamer code.
  524. CONTENTS is the contents of the headline. INFO is a plist used
  525. as a communication channel."
  526. (unless (org-element-property :footnote-section-p headline)
  527. (let ((level (org-export-get-relative-level headline info))
  528. (frame-level (org-beamer--frame-level headline info))
  529. (environment (let ((env (org-element-property :BEAMER_ENV headline)))
  530. (or (org-string-nw-p env) "block"))))
  531. (cond
  532. ;; Case 1: Resume frame specified by "BEAMER_ref" property.
  533. ((equal environment "againframe")
  534. (let ((ref (org-element-property :BEAMER_REF headline)))
  535. ;; Reference to frame being resumed is mandatory. Ignore
  536. ;; the whole headline if it isn't provided.
  537. (when (org-string-nw-p ref)
  538. (concat "\\againframe"
  539. ;; Overlay specification.
  540. (let ((overlay (org-element-property :BEAMER_ACT headline)))
  541. (when overlay
  542. (org-beamer--normalize-argument
  543. overlay
  544. (if (string-match "\\`\\[.*\\]\\'" overlay) 'defaction
  545. 'action))))
  546. ;; Options.
  547. (let ((options (org-element-property :BEAMER_OPT headline)))
  548. (when options
  549. (org-beamer--normalize-argument options 'option)))
  550. ;; Resolve reference provided by "BEAMER_ref"
  551. ;; property. This is done by building a minimal
  552. ;; fake link and calling the appropriate resolve
  553. ;; function, depending on the reference syntax.
  554. (let ((target
  555. (if (string-match "\\`\\(id:\\|#\\)" ref)
  556. (org-export-resolve-id-link
  557. `(link (:path ,(substring ref (match-end 0))))
  558. info)
  559. (org-export-resolve-fuzzy-link
  560. `(link (:path
  561. ;; Look for headlines only.
  562. ,(if (eq (string-to-char ref) ?*) ref
  563. (concat "*" ref))))
  564. info))))
  565. ;; Now use user-defined label provided in TARGET
  566. ;; headline, or fallback to standard one.
  567. (format "{%s}" (org-beamer--get-label target info)))))))
  568. ;; Case 2: Creation of an appendix is requested.
  569. ((equal environment "appendix")
  570. (concat "\\appendix"
  571. (org-element-property :BEAMER_ACT headline)
  572. "\n"
  573. (make-string (org-element-property :pre-blank headline) ?\n)
  574. contents))
  575. ;; Case 3: Ignore heading.
  576. ((equal environment "ignoreheading")
  577. (concat (make-string (org-element-property :pre-blank headline) ?\n)
  578. contents))
  579. ;; Case 4: HEADLINE is a note.
  580. ((member environment '("note" "noteNH"))
  581. (format "\\note{%s}"
  582. (concat (and (equal environment "note")
  583. (concat
  584. (org-export-data
  585. (org-element-property :title headline) info)
  586. "\n"))
  587. (org-trim contents))))
  588. ;; Case 5: HEADLINE is a frame.
  589. ((= level frame-level)
  590. (org-beamer--format-frame headline contents info))
  591. ;; Case 6: Regular section, extracted from
  592. ;; `org-latex-classes'.
  593. ((< level frame-level)
  594. (org-beamer--format-section headline contents info))
  595. ;; Case 7: Otherwise, HEADLINE is a block.
  596. (t (org-beamer--format-block headline contents info))))))
  597. ;;;; Item
  598. (defun org-beamer-item (item contents info)
  599. "Transcode an ITEM element into Beamer code.
  600. CONTENTS holds the contents of the item. INFO is a plist holding
  601. contextual information."
  602. (org-export-with-backend
  603. ;; Delegate item export to `latex'. However, we use `beamer'
  604. ;; transcoders for objects in the description tag.
  605. (org-export-create-backend
  606. :parent 'beamer
  607. :transcoders
  608. (list
  609. (cons
  610. 'item
  611. (lambda (item _c _i)
  612. (let ((action
  613. (let ((first (car (org-element-contents item))))
  614. (and (eq (org-element-type first) 'paragraph)
  615. (org-beamer--element-has-overlay-p first))))
  616. (output (org-latex-item item contents info)))
  617. (if (not (and action (string-match "\\\\item" output))) output
  618. ;; If the item starts with a paragraph and that paragraph
  619. ;; starts with an export snippet specifying an overlay,
  620. ;; append it to the \item command.
  621. (replace-match (concat "\\\\item" action) nil nil output)))))))
  622. item contents info))
  623. ;;;; Keyword
  624. (defun org-beamer-keyword (keyword contents info)
  625. "Transcode a KEYWORD element into Beamer code.
  626. CONTENTS is nil. INFO is a plist used as a communication
  627. channel."
  628. (let ((key (org-element-property :key keyword))
  629. (value (org-element-property :value keyword)))
  630. ;; Handle specifically BEAMER and TOC (headlines only) keywords.
  631. ;; Otherwise, fallback to `latex' back-end.
  632. (cond
  633. ((equal key "BEAMER") value)
  634. ((and (equal key "TOC") (string-match "\\<headlines\\>" value))
  635. (let ((depth (or (and (string-match "[0-9]+" value)
  636. (string-to-number (match-string 0 value)))
  637. (plist-get info :with-toc)))
  638. (options (and (string-match "\\[.*?\\]" value)
  639. (match-string 0 value))))
  640. (concat
  641. (when (wholenump depth) (format "\\setcounter{tocdepth}{%s}\n" depth))
  642. "\\tableofcontents" options)))
  643. (t (org-export-with-backend 'latex keyword contents info)))))
  644. ;;;; Link
  645. (defun org-beamer-link (link contents info)
  646. "Transcode a LINK object into Beamer code.
  647. CONTENTS is the description part of the link. INFO is a plist
  648. used as a communication channel."
  649. (let ((type (org-element-property :type link)))
  650. (cond
  651. ;; Link type is handled by a special function.
  652. ((org-export-custom-protocol-maybe link contents 'beamer))
  653. ;; Use \hyperlink command for all internal links.
  654. ((equal type "radio")
  655. (let ((destination (org-export-resolve-radio-link link info)))
  656. (if (not destination) contents
  657. (format "\\hyperlink%s{%s}{%s}"
  658. (or (org-beamer--element-has-overlay-p link) "")
  659. (org-export-get-reference destination info)
  660. contents))))
  661. ((and (member type '("custom-id" "fuzzy" "id"))
  662. (let ((destination (if (string= type "fuzzy")
  663. (org-export-resolve-fuzzy-link link info)
  664. (org-export-resolve-id-link link info))))
  665. (cl-case (org-element-type destination)
  666. (headline
  667. (let ((label
  668. (format "sec-%s"
  669. (mapconcat
  670. 'number-to-string
  671. (org-export-get-headline-number
  672. destination info)
  673. "-"))))
  674. (if (and (plist-get info :section-numbers) (not contents))
  675. (format "\\ref{%s}" label)
  676. (format "\\hyperlink%s{%s}{%s}"
  677. (or (org-beamer--element-has-overlay-p link) "")
  678. label
  679. contents))))
  680. (target
  681. (let ((ref (org-export-get-reference destination info)))
  682. (if (not contents) (format "\\ref{%s}" ref)
  683. (format "\\hyperlink%s{%s}{%s}"
  684. (or (org-beamer--element-has-overlay-p link) "")
  685. ref
  686. contents))))))))
  687. ;; Otherwise, use `latex' back-end.
  688. (t (org-export-with-backend 'latex link contents info)))))
  689. ;;;; Plain List
  690. ;;
  691. ;; Plain lists support `:environment', `:overlay' and `:options'
  692. ;; attributes.
  693. (defun org-beamer-plain-list (plain-list contents info)
  694. "Transcode a PLAIN-LIST element into Beamer code.
  695. CONTENTS is the contents of the list. INFO is a plist holding
  696. contextual information."
  697. (let* ((type (org-element-property :type plain-list))
  698. (attributes (org-combine-plists
  699. (org-export-read-attribute :attr_latex plain-list)
  700. (org-export-read-attribute :attr_beamer plain-list)))
  701. (latex-type (let ((env (plist-get attributes :environment)))
  702. (cond (env)
  703. ((eq type 'ordered) "enumerate")
  704. ((eq type 'descriptive) "description")
  705. (t "itemize")))))
  706. (org-latex--wrap-label
  707. plain-list
  708. (format "\\begin{%s}%s%s\n%s\\end{%s}"
  709. latex-type
  710. ;; Default overlay specification, if any.
  711. (org-beamer--normalize-argument
  712. (or (plist-get attributes :overlay) "")
  713. 'defaction)
  714. ;; Second optional argument depends on the list type.
  715. (org-beamer--normalize-argument
  716. (or (plist-get attributes :options) "")
  717. 'option)
  718. ;; Eventually insert contents and close environment.
  719. contents
  720. latex-type)
  721. info)))
  722. ;;;; Radio Target
  723. (defun org-beamer-radio-target (radio-target text info)
  724. "Transcode a RADIO-TARGET object into Beamer code.
  725. TEXT is the text of the target. INFO is a plist holding
  726. contextual information."
  727. (format "\\hypertarget%s{%s}{%s}"
  728. (or (org-beamer--element-has-overlay-p radio-target) "")
  729. (org-export-get-reference radio-target info)
  730. text))
  731. ;;;; Target
  732. (defun org-beamer-target (target _contents info)
  733. "Transcode a TARGET object into Beamer code.
  734. CONTENTS is nil. INFO is a plist holding contextual
  735. information."
  736. (format "\\label{%s}" (org-export-get-reference target info)))
  737. ;;;; Template
  738. ;;
  739. ;; Template used is similar to the one used in `latex' back-end,
  740. ;; excepted for the table of contents and Beamer themes.
  741. (defun org-beamer-template (contents info)
  742. "Return complete document string after Beamer conversion.
  743. CONTENTS is the transcoded contents string. INFO is a plist
  744. holding export options."
  745. (let ((title (org-export-data (plist-get info :title) info))
  746. (subtitle (org-export-data (plist-get info :subtitle) info)))
  747. (concat
  748. ;; Time-stamp.
  749. (and (plist-get info :time-stamp-file)
  750. (format-time-string "%% Created %Y-%m-%d %a %H:%M\n"))
  751. ;; LaTeX compiler
  752. (org-latex--insert-compiler info)
  753. ;; Document class and packages.
  754. (org-latex--make-preamble info)
  755. ;; Insert themes.
  756. (let ((format-theme
  757. (function
  758. (lambda (prop command)
  759. (let ((theme (plist-get info prop)))
  760. (when theme
  761. (concat command
  762. (if (not (string-match "\\[.*\\]" theme))
  763. (format "{%s}\n" theme)
  764. (format "%s{%s}\n"
  765. (match-string 0 theme)
  766. (org-trim
  767. (replace-match "" nil nil theme)))))))))))
  768. (mapconcat (lambda (args) (apply format-theme args))
  769. '((:beamer-theme "\\usetheme")
  770. (:beamer-color-theme "\\usecolortheme")
  771. (:beamer-font-theme "\\usefonttheme")
  772. (:beamer-inner-theme "\\useinnertheme")
  773. (:beamer-outer-theme "\\useoutertheme"))
  774. ""))
  775. ;; Possibly limit depth for headline numbering.
  776. (let ((sec-num (plist-get info :section-numbers)))
  777. (when (integerp sec-num)
  778. (format "\\setcounter{secnumdepth}{%d}\n" sec-num)))
  779. ;; Author.
  780. (let ((author (and (plist-get info :with-author)
  781. (let ((auth (plist-get info :author)))
  782. (and auth (org-export-data auth info)))))
  783. (email (and (plist-get info :with-email)
  784. (org-export-data (plist-get info :email) info))))
  785. (cond ((and author email (not (string= "" email)))
  786. (format "\\author{%s\\thanks{%s}}\n" author email))
  787. ((or author email) (format "\\author{%s}\n" (or author email)))))
  788. ;; Date.
  789. (let ((date (and (plist-get info :with-date) (org-export-get-date info))))
  790. (format "\\date{%s}\n" (org-export-data date info)))
  791. ;; Title
  792. (format "\\title{%s}\n" title)
  793. (when (org-string-nw-p subtitle)
  794. (concat (format (plist-get info :beamer-subtitle-format) subtitle) "\n"))
  795. ;; Beamer-header
  796. (let ((beamer-header (plist-get info :beamer-header)))
  797. (when beamer-header
  798. (format "%s\n" (plist-get info :beamer-header))))
  799. ;; 9. Hyperref options.
  800. (let ((template (plist-get info :latex-hyperref-template)))
  801. (and (stringp template)
  802. (format-spec template (org-latex--format-spec info))))
  803. ;; Document start.
  804. "\\begin{document}\n\n"
  805. ;; Title command.
  806. (org-element-normalize-string
  807. (cond ((not (plist-get info :with-title)) nil)
  808. ((string= "" title) nil)
  809. ((not (stringp org-latex-title-command)) nil)
  810. ((string-match "\\(?:[^%]\\|^\\)%s"
  811. org-latex-title-command)
  812. (format org-latex-title-command title))
  813. (t org-latex-title-command)))
  814. ;; Table of contents.
  815. (let ((depth (plist-get info :with-toc)))
  816. (when depth
  817. (concat
  818. (format "\\begin{frame}%s{%s}\n"
  819. (org-beamer--normalize-argument
  820. (plist-get info :beamer-outline-frame-options) 'option)
  821. (plist-get info :beamer-outline-frame-title))
  822. (when (wholenump depth)
  823. (format "\\setcounter{tocdepth}{%d}\n" depth))
  824. "\\tableofcontents\n"
  825. "\\end{frame}\n\n")))
  826. ;; Document's body.
  827. contents
  828. ;; Creator.
  829. (if (plist-get info :with-creator)
  830. (concat (plist-get info :creator) "\n")
  831. "")
  832. ;; Document end.
  833. "\\end{document}")))
  834. ;;; Minor Mode
  835. (defvar org-beamer-mode-map (make-sparse-keymap)
  836. "The keymap for `org-beamer-mode'.")
  837. (define-key org-beamer-mode-map "\C-c\C-b" 'org-beamer-select-environment)
  838. ;;;###autoload
  839. (define-minor-mode org-beamer-mode
  840. "Support for editing Beamer oriented Org mode files."
  841. nil " Bm" 'org-beamer-mode-map)
  842. (when (fboundp 'font-lock-add-keywords)
  843. (font-lock-add-keywords
  844. 'org-mode
  845. '((":\\(B_[a-z]+\\|BMCOL\\):" 1 'org-beamer-tag prepend))
  846. 'prepend))
  847. (defface org-beamer-tag '((t (:box (:line-width 1 :color grey40))))
  848. "The special face for beamer tags."
  849. :group 'org-export-beamer)
  850. (defun org-beamer-property-changed (property value)
  851. "Track the BEAMER_env property with tags.
  852. PROPERTY is the name of the modified property. VALUE is its new
  853. value."
  854. (cond
  855. ((equal property "BEAMER_env")
  856. (save-excursion
  857. (org-back-to-heading t)
  858. ;; Filter out Beamer-related tags and install environment tag.
  859. (let ((tags (cl-remove-if (lambda (x) (string-match "^B_" x))
  860. (org-get-tags)))
  861. (env-tag (and (org-string-nw-p value) (concat "B_" value))))
  862. (org-set-tags-to (if env-tag (cons env-tag tags) tags))
  863. (when env-tag (org-toggle-tag env-tag 'on)))))
  864. ((equal property "BEAMER_col")
  865. (org-toggle-tag "BMCOL" (if (org-string-nw-p value) 'on 'off)))))
  866. (add-hook 'org-property-changed-functions 'org-beamer-property-changed)
  867. (defun org-beamer-allowed-property-values (property)
  868. "Supply allowed values for PROPERTY."
  869. (cond
  870. ((and (equal property "BEAMER_env")
  871. (not (org-entry-get nil (concat property "_ALL") 'inherit)))
  872. ;; If no allowed values for BEAMER_env have been defined,
  873. ;; supply all defined environments
  874. (mapcar 'car (append org-beamer-environments-special
  875. org-beamer-environments-extra
  876. org-beamer-environments-default)))
  877. ((and (equal property "BEAMER_col")
  878. (not (org-entry-get nil (concat property "_ALL") 'inherit)))
  879. ;; If no allowed values for BEAMER_col have been defined,
  880. ;; supply some
  881. (org-split-string org-beamer-column-widths " "))))
  882. (add-hook 'org-property-allowed-value-functions
  883. 'org-beamer-allowed-property-values)
  884. ;;; Commands
  885. ;;;###autoload
  886. (defun org-beamer-export-as-latex
  887. (&optional async subtreep visible-only body-only ext-plist)
  888. "Export current buffer as a Beamer buffer.
  889. If narrowing is active in the current buffer, only export its
  890. narrowed part.
  891. If a region is active, export that region.
  892. A non-nil optional argument ASYNC means the process should happen
  893. asynchronously. The resulting buffer should be accessible
  894. through the `org-export-stack' interface.
  895. When optional argument SUBTREEP is non-nil, export the sub-tree
  896. at point, extracting information from the headline properties
  897. first.
  898. When optional argument VISIBLE-ONLY is non-nil, don't export
  899. contents of hidden elements.
  900. When optional argument BODY-ONLY is non-nil, only write code
  901. between \"\\begin{document}\" and \"\\end{document}\".
  902. EXT-PLIST, when provided, is a property list with external
  903. parameters overriding Org default settings, but still inferior to
  904. file-local settings.
  905. Export is done in a buffer named \"*Org BEAMER Export*\", which
  906. will be displayed when `org-export-show-temporary-export-buffer'
  907. is non-nil."
  908. (interactive)
  909. (org-export-to-buffer 'beamer "*Org BEAMER Export*"
  910. async subtreep visible-only body-only ext-plist (lambda () (LaTeX-mode))))
  911. ;;;###autoload
  912. (defun org-beamer-export-to-latex
  913. (&optional async subtreep visible-only body-only ext-plist)
  914. "Export current buffer as a Beamer presentation (tex).
  915. If narrowing is active in the current buffer, only export its
  916. narrowed part.
  917. If a region is active, export that region.
  918. A non-nil optional argument ASYNC means the process should happen
  919. asynchronously. The resulting file should be accessible through
  920. the `org-export-stack' interface.
  921. When optional argument SUBTREEP is non-nil, export the sub-tree
  922. at point, extracting information from the headline properties
  923. first.
  924. When optional argument VISIBLE-ONLY is non-nil, don't export
  925. contents of hidden elements.
  926. When optional argument BODY-ONLY is non-nil, only write code
  927. between \"\\begin{document}\" and \"\\end{document}\".
  928. EXT-PLIST, when provided, is a property list with external
  929. parameters overriding Org default settings, but still inferior to
  930. file-local settings.
  931. Return output file's name."
  932. (interactive)
  933. (let ((file (org-export-output-file-name ".tex" subtreep)))
  934. (org-export-to-file 'beamer file
  935. async subtreep visible-only body-only ext-plist)))
  936. ;;;###autoload
  937. (defun org-beamer-export-to-pdf
  938. (&optional async subtreep visible-only body-only ext-plist)
  939. "Export current buffer as a Beamer presentation (PDF).
  940. If narrowing is active in the current buffer, only export its
  941. narrowed part.
  942. If a region is active, export that region.
  943. A non-nil optional argument ASYNC means the process should happen
  944. asynchronously. The resulting file should be accessible through
  945. the `org-export-stack' interface.
  946. When optional argument SUBTREEP is non-nil, export the sub-tree
  947. at point, extracting information from the headline properties
  948. first.
  949. When optional argument VISIBLE-ONLY is non-nil, don't export
  950. contents of hidden elements.
  951. When optional argument BODY-ONLY is non-nil, only write code
  952. between \"\\begin{document}\" and \"\\end{document}\".
  953. EXT-PLIST, when provided, is a property list with external
  954. parameters overriding Org default settings, but still inferior to
  955. file-local settings.
  956. Return PDF file's name."
  957. (interactive)
  958. (let ((file (org-export-output-file-name ".tex" subtreep)))
  959. (org-export-to-file 'beamer file
  960. async subtreep visible-only body-only ext-plist
  961. (lambda (file) (org-latex-compile file)))))
  962. ;;;###autoload
  963. (defun org-beamer-select-environment ()
  964. "Select the environment to be used by beamer for this entry.
  965. While this uses (for convenience) a tag selection interface, the
  966. result of this command will be that the BEAMER_env *property* of
  967. the entry is set.
  968. In addition to this, the command will also set a tag as a visual
  969. aid, but the tag does not have any semantic meaning."
  970. (interactive)
  971. ;; Make sure `org-beamer-environments-special' has a higher
  972. ;; priority than `org-beamer-environments-extra'.
  973. (let* ((envs (append org-beamer-environments-special
  974. org-beamer-environments-extra
  975. org-beamer-environments-default))
  976. (org-current-tag-alist
  977. (append '((:startgroup))
  978. (mapcar (lambda (e) (cons (concat "B_" (car e))
  979. (string-to-char (nth 1 e))))
  980. envs)
  981. '((:endgroup))
  982. '(("BMCOL" . ?|))))
  983. (org-tag-persistent-alist nil)
  984. (org-use-fast-tag-selection t)
  985. (org-fast-tag-selection-single-key t))
  986. (org-set-tags)
  987. (let ((tags (or (ignore-errors (org-get-tags-string)) "")))
  988. (cond
  989. ;; For a column, automatically ask for its width.
  990. ((eq org-last-tag-selection-key ?|)
  991. (if (string-match ":BMCOL:" tags)
  992. (org-set-property "BEAMER_col" (read-string "Column width: "))
  993. (org-delete-property "BEAMER_col")))
  994. ;; For an "againframe" section, automatically ask for reference
  995. ;; to resumed frame and overlay specifications.
  996. ((eq org-last-tag-selection-key ?A)
  997. (if (equal (org-entry-get nil "BEAMER_env") "againframe")
  998. (progn (org-entry-delete nil "BEAMER_env")
  999. (org-entry-delete nil "BEAMER_ref")
  1000. (org-entry-delete nil "BEAMER_act"))
  1001. (org-entry-put nil "BEAMER_env" "againframe")
  1002. (org-set-property
  1003. "BEAMER_ref"
  1004. (read-string "Frame reference (*Title, #custom-id, id:...): "))
  1005. (org-set-property "BEAMER_act"
  1006. (read-string "Overlay specification: "))))
  1007. ((string-match (concat ":B_\\(" (mapconcat 'car envs "\\|") "\\):") tags)
  1008. (org-entry-put nil "BEAMER_env" (match-string 1 tags)))
  1009. (t (org-entry-delete nil "BEAMER_env"))))))
  1010. ;;;###autoload
  1011. (defun org-beamer-publish-to-latex (plist filename pub-dir)
  1012. "Publish an Org file to a Beamer presentation (LaTeX).
  1013. FILENAME is the filename of the Org file to be published. PLIST
  1014. is the property list for the given project. PUB-DIR is the
  1015. publishing directory.
  1016. Return output file name."
  1017. (org-publish-org-to 'beamer filename ".tex" plist pub-dir))
  1018. ;;;###autoload
  1019. (defun org-beamer-publish-to-pdf (plist filename pub-dir)
  1020. "Publish an Org file to a Beamer presentation (PDF, via LaTeX).
  1021. FILENAME is the filename of the Org file to be published. PLIST
  1022. is the property list for the given project. PUB-DIR is the
  1023. publishing directory.
  1024. Return output file name."
  1025. ;; Unlike to `org-beamer-publish-to-latex', PDF file is generated in
  1026. ;; working directory and then moved to publishing directory.
  1027. (org-publish-attachment
  1028. plist
  1029. (org-latex-compile
  1030. (org-publish-org-to
  1031. 'beamer filename ".tex" plist (file-name-directory filename)))
  1032. pub-dir))
  1033. (provide 'ox-beamer)
  1034. ;; Local variables:
  1035. ;; generated-autoload-file: "org-loaddefs.el"
  1036. ;; End:
  1037. ;;; ox-beamer.el ends here