org-protocol.el 27 KB

123456789101112131415161718192021222324252627282930313233343536373839404142434445464748495051525354555657585960616263646566676869707172737475767778798081828384858687888990919293949596979899100101102103104105106107108109110111112113114115116117118119120121122123124125126127128129130131132133134135136137138139140141142143144145146147148149150151152153154155156157158159160161162163164165166167168169170171172173174175176177178179180181182183184185186187188189190191192193194195196197198199200201202203204205206207208209210211212213214215216217218219220221222223224225226227228229230231232233234235236237238239240241242243244245246247248249250251252253254255256257258259260261262263264265266267268269270271272273274275276277278279280281282283284285286287288289290291292293294295296297298299300301302303304305306307308309310311312313314315316317318319320321322323324325326327328329330331332333334335336337338339340341342343344345346347348349350351352353354355356357358359360361362363364365366367368369370371372373374375376377378379380381382383384385386387388389390391392393394395396397398399400401402403404405406407408409410411412413414415416417418419420421422423424425426427428429430431432433434435436437438439440441442443444445446447448449450451452453454455456457458459460461462463464465466467468469470471472473474475476477478479480481482483484485486487488489490491492493494495496497498499500501502503504505506507508509510511512513514515516517518519520521522523524525526527528529530531532533534535536537538539540541542543544545546547548549550551552553554555556557558559560561562563564565566567568569570571572573574575576577578579580581582583584585586587588589590591592593594595596597598599600601602603604605606607608609610611612613614615616617618619620621622623624625626627628629630631632633634635636637638639640641642643644645646647648649650651652653654655656657658659660661662663664665666667668669670671672673674675676677678679680681682683684685686687688689690691692693694695696697698699700701702703704705706707
  1. ;;; org-protocol.el --- Intercept calls from emacsclient to trigger custom actions.
  2. ;;
  3. ;; Copyright (C) 2008, 2009, 2010
  4. ;; Free Software Foundation, Inc.
  5. ;;
  6. ;; Author: Bastien Guerry <bzg AT altern DOT org>
  7. ;; Author: Daniel M German <dmg AT uvic DOT org>
  8. ;; Author: Sebastian Rose <sebastian_rose AT gmx DOT de>
  9. ;; Author: Ross Patterson <me AT rpatterson DOT net>
  10. ;; Maintainer: Sebastian Rose <sebastian_rose AT gmx DOT de>
  11. ;; Keywords: org, emacsclient, wp
  12. ;; Version: 6.36trans
  13. ;; This file is part of GNU Emacs.
  14. ;;
  15. ;; GNU Emacs is free software: you can redistribute it and/or modify
  16. ;; it under the terms of the GNU General Public License as published by
  17. ;; the Free Software Foundation, either version 3 of the License, or
  18. ;; (at your option) any later version.
  19. ;; GNU Emacs is distributed in the hope that it will be useful,
  20. ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  21. ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  22. ;; GNU General Public License for more details.
  23. ;; You should have received a copy of the GNU General Public License
  24. ;; along with GNU Emacs. If not, see <http://www.gnu.org/licenses/>.
  25. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  26. ;;; Commentary:
  27. ;;
  28. ;; Intercept calls from emacsclient to trigger custom actions.
  29. ;;
  30. ;; This is done by advising `server-visit-files' to scann the list of filenames
  31. ;; for `org-protocol-the-protocol' and sub-procols defined in
  32. ;; `org-protocol-protocol-alist' and `org-protocol-protocol-alist-default'.
  33. ;;
  34. ;; Any application that supports calling external programs with an URL
  35. ;; as argument may be used with this functionality.
  36. ;;
  37. ;;
  38. ;; Usage:
  39. ;; ------
  40. ;;
  41. ;; 1.) Add this to your init file (.emacs probably):
  42. ;;
  43. ;; (add-to-list 'load-path "/path/to/org-protocol/")
  44. ;; (require 'org-protocol)
  45. ;;
  46. ;; 3.) Ensure emacs-server is up and running.
  47. ;; 4.) Try this from the command line (adjust the URL as needed):
  48. ;;
  49. ;; $ emacsclient \
  50. ;; org-protocol://store-link://http:%2F%2Flocalhost%2Findex.html/The%20title
  51. ;;
  52. ;; 5.) Optionally add custom sub-protocols and handlers:
  53. ;;
  54. ;; (setq org-protocol-protocol-alist
  55. ;; '(("my-protocol"
  56. ;; :protocol "my-protocol"
  57. ;; :function my-protocol-handler-fuction)))
  58. ;;
  59. ;; A "sub-protocol" will be found in URLs like this:
  60. ;;
  61. ;; org-protocol://sub-protocol://data
  62. ;;
  63. ;; If it works, you can now setup other applications for using this feature.
  64. ;;
  65. ;;
  66. ;; As of March 2009 Firefox users follow the steps documented on
  67. ;; http://kb.mozillazine.org/Register_protocol, Opera setup is described here:
  68. ;; http://www.opera.com/support/kb/view/535/
  69. ;;
  70. ;;
  71. ;; Documentation
  72. ;; -------------
  73. ;;
  74. ;; org-protocol.el comes with and installs handlers to open sources of published
  75. ;; online content, store and insert the browser's URLs and cite online content
  76. ;; by clicking on a bookmark in Firefox, Opera and probably other browsers and
  77. ;; applications:
  78. ;;
  79. ;; * `org-protocol-open-source' uses the sub-protocol \"open-source\" and maps
  80. ;; URLs to local filenames defined in `org-protocol-project-alist'.
  81. ;;
  82. ;; * `org-protocol-store-link' stores an Org-link (if Org-mode is present) and
  83. ;; pushes the browsers URL to the `kill-ring' for yanking. This handler is
  84. ;; triggered through the sub-protocol \"store-link\".
  85. ;;
  86. ;; * Call `org-protocol-capture' by using the sub-protocol \"capture\". If
  87. ;; Org-mode is loaded, emacs will pop-up a capture buffer and fill the
  88. ;; template with the data provided. I.e. the browser's URL is inserted as an
  89. ;; Org-link of which the page title will be the description part. If text
  90. ;; was select in the browser, that text will be the body of the entry.
  91. ;;
  92. ;; * Call `org-protocol-remember' by using the sub-protocol \"remember\".
  93. ;; This is provided for backward compatibility.
  94. ;; You may read `org-capture' as `org-remember' throughout this file if
  95. ;; you still use `org-remember'.
  96. ;;
  97. ;; You may use the same bookmark URL for all those standard handlers and just
  98. ;; adjust the sub-protocol used:
  99. ;;
  100. ;; location.href='org-protocol://sub-protocol://'+
  101. ;; encodeURIComponent(location.href)+'/'+
  102. ;; encodeURIComponent(document.title)+'/'+
  103. ;; encodeURIComponent(window.getSelection())
  104. ;;
  105. ;; The handler for the sub-protocol \"capture\" detects an optional template
  106. ;; char that, if present, triggers the use of a special template.
  107. ;; Example:
  108. ;;
  109. ;; location.href='org-protocol://sub-protocol://x/'+ ...
  110. ;;
  111. ;; use template ?x.
  112. ;;
  113. ;; Note, that using double slashes is optional from org-protocol.el's point of
  114. ;; view because emacsclient squashes the slashes to one.
  115. ;;
  116. ;;
  117. ;; provides: 'org-protocol
  118. ;;
  119. ;;; Code:
  120. (require 'org)
  121. (eval-when-compile
  122. (require 'cl))
  123. (declare-function org-publish-initialize-files-alist "org-publish"
  124. (&optional refresh))
  125. (declare-function org-publish-get-project-from-filename "org-publish"
  126. (filename &optional up))
  127. (declare-function server-edit "server" (&optional arg))
  128. (defgroup org-protocol nil
  129. "Intercept calls from emacsclient to trigger custom actions.
  130. This is done by advising `server-visit-files' to scann the list of filenames
  131. for `org-protocol-the-protocol' and sub-procols defined in
  132. `org-protocol-protocol-alist' and `org-protocol-protocol-alist-default'."
  133. :version "22.1"
  134. :group 'convenience
  135. :group 'org)
  136. ;;; Variables:
  137. (defconst org-protocol-protocol-alist-default
  138. '(("org-remember" :protocol "remember" :function org-protocol-remember :kill-client t)
  139. ("org-capture" :protocol "capture" :function org-protocol-capture :kill-client t)
  140. ("org-store-link" :protocol "store-link" :function org-protocol-store-link)
  141. ("org-open-source" :protocol "open-source" :function org-protocol-open-source))
  142. "Default protocols to use.
  143. See `org-protocol-protocol-alist' for a description of this variable.")
  144. (defconst org-protocol-the-protocol "org-protocol"
  145. "This is the protocol to detect if org-protocol.el is loaded.
  146. `org-protocol-protocol-alist-default' and `org-protocol-protocol-alist' hold the
  147. sub-protocols that trigger the required action. You will have to define just one
  148. protocol handler OS-wide (MS-Windows) or per application (Linux). That protocol
  149. handler should call emacsclient.")
  150. ;;; User variables:
  151. (defcustom org-protocol-reverse-list-of-files t
  152. "* The filenames passed on the commandline are passed to the emacs-server in
  153. reversed order. Set to `t' (default) to re-reverse the list, i.e. use the
  154. sequence on the command line. If nil, the sequence of the filenames is
  155. unchanged."
  156. :group 'org-protocol
  157. :type 'boolean)
  158. (defcustom org-protocol-project-alist nil
  159. "* Map URLs to local filenames for `org-protocol-open-source' (open-source).
  160. Each element of this list must be of the form:
  161. (module-name :property value property: value ...)
  162. where module-name is an arbitrary name. All the values are strings.
  163. Possible properties are:
  164. :online-suffix - the suffix to strip from the published URLs
  165. :working-suffix - the replacement for online-suffix
  166. :base-url - the base URL, e.g. http://www.example.com/project/
  167. Last slash required.
  168. :working-directory - the local working directory. This is, what base-url will
  169. be replaced with.
  170. :redirects - A list of cons cells, each of which maps a regular
  171. expression to match to a path relative to :working-directory.
  172. Example:
  173. (setq org-protocol-project-alist
  174. '((\"http://orgmode.org/worg/\"
  175. :online-suffix \".php\"
  176. :working-suffix \".org\"
  177. :base-url \"http://orgmode.org/worg/\"
  178. :working-directory \"/home/user/org/Worg/\")
  179. (\"http://localhost/org-notes/\"
  180. :online-suffix \".html\"
  181. :working-suffix \".org\"
  182. :base-url \"http://localhost/org/\"
  183. :working-directory \"/home/user/org/\"
  184. :rewrites ((\"org/?$\" . \"index.php\")))))
  185. The last line tells `org-protocol-open-source' to open
  186. /home/user/org/index.php, if the URL cannot be mapped to an existing
  187. file, and ends with either \"org\" or \"org/\".
  188. Consider using the interactive functions `org-protocol-create' and
  189. `org-protocol-create-for-org' to help you filling this variable with valid contents."
  190. :group 'org-protocol
  191. :type 'alist)
  192. (defcustom org-protocol-protocol-alist nil
  193. "* Register custom handlers for org-protocol.
  194. Each element of this list must be of the form:
  195. (module-name :protocol protocol :function func :kill-client nil)
  196. protocol - protocol to detect in a filename without trailing colon and slashes.
  197. See rfc1738 section 2.1 for more on this.
  198. If you define a protocol \"my-protocol\", `org-protocol-check-filename-for-protocol'
  199. will search filenames for \"org-protocol:/my-protocol:/\"
  200. and trigger your action for every match. `org-protocol' is defined in
  201. `org-protocol-the-protocol'. Double and tripple slashes are compressed
  202. to one by emacsclient.
  203. function - function that handles requests with protocol and takes exactly one
  204. argument: the filename with all protocols stripped. If the function
  205. returns nil, emacsclient and -server do nothing. Any non-nil return
  206. value is considered a valid filename and thus passed to the server.
  207. `org-protocol.el provides some support for handling those filenames,
  208. if you stay with the conventions used for the standard handlers in
  209. `org-protocol-protocol-alist-default'. See `org-protocol-split-data'.
  210. kill-client - If t, kill the client immediately, once the sub-protocol is
  211. detected. This is necessary for actions that can be interrupted by
  212. `C-g' to avoid dangeling emacsclients. Note, that all other command
  213. line arguments but the this one will be discarded, greedy handlers
  214. still receive the whole list of arguments though.
  215. Here is an example:
  216. (setq org-protocol-protocol-alist
  217. '((\"my-protocol\"
  218. :protocol \"my-protocol\"
  219. :function my-protocol-handler-fuction)
  220. (\"your-protocol\"
  221. :protocol \"your-protocol\"
  222. :function your-protocol-handler-fuction)))"
  223. :group 'org-protocol
  224. :type '(alist))
  225. (defcustom org-protocol-default-template-key "w"
  226. "The default org-remember-templates key to use."
  227. :group 'org-protocol
  228. :type 'string)
  229. ;;; Helper functions:
  230. (defun org-protocol-sanitize-uri (uri)
  231. "emacsclient compresses double and tripple slashes.
  232. Slashes are sanitized to double slashes here."
  233. (when (string-match "^\\([a-z]+\\):/" uri)
  234. (let* ((splitparts (split-string uri "/+")))
  235. (setq uri (concat (car splitparts) "//" (mapconcat 'identity (cdr splitparts) "/")))))
  236. uri)
  237. (defun org-protocol-split-data(data &optional unhexify separator)
  238. "Split, what a org-protocol handler function gets as only argument.
  239. data is that one argument. Data is splitted at each occurrence of separator
  240. (regexp). If no separator is specified or separator is nil, assume \"/+\".
  241. The results of that splitting are return as a list. If unhexify is non-nil,
  242. hex-decode each split part. If unhexify is a function, use that function to
  243. decode each split part."
  244. (let* ((sep (or separator "/+"))
  245. (split-parts (split-string data sep)))
  246. (if unhexify
  247. (if (fboundp unhexify)
  248. (mapcar unhexify split-parts)
  249. (mapcar 'org-protocol-unhex-string split-parts))
  250. split-parts)))
  251. ;; This inline function is needed in org-protocol-unhex-compound to do
  252. ;; the right thing to decode UTF-8 char integer values.
  253. (eval-when-compile
  254. (if (>= emacs-major-version 23)
  255. (defsubst org-protocol-char-to-string(c)
  256. "Defsubst to decode UTF-8 character values in emacs 23 and beyond."
  257. (char-to-string c))
  258. (defsubst org-protocol-char-to-string (c)
  259. "Defsubst to decode UTF-8 character values in emacs 22."
  260. (string (decode-char 'ucs c)))))
  261. (defun org-protocol-unhex-string(str)
  262. "Unhex hexified unicode strings as returned from the JavaScript function
  263. encodeURIComponent. E.g. `%C3%B6' is the german Umlaut `ü'."
  264. (setq str (or str ""))
  265. (let ((tmp "")
  266. (case-fold-search t))
  267. (while (string-match "\\(%[0-9a-f][0-9a-f]\\)+" str)
  268. (let* ((start (match-beginning 0))
  269. (end (match-end 0))
  270. (hex (match-string 0 str))
  271. (replacement (org-protocol-unhex-compound hex)))
  272. (setq tmp (concat tmp (substring str 0 start) replacement))
  273. (setq str (substring str end))))
  274. (setq tmp (concat tmp str))
  275. tmp))
  276. (defun org-protocol-unhex-compound (hex)
  277. "Unhexify unicode hex-chars. E.g. `%C3%B6' is the german Umlaut `ü'."
  278. (let* ((bytes (remove "" (split-string hex "%")))
  279. (ret "")
  280. (eat 0)
  281. (sum 0))
  282. (while bytes
  283. (let* ((b (pop bytes))
  284. (a (elt b 0))
  285. (b (elt b 1))
  286. (c1 (if (> a ?9) (+ 10 (- a ?A)) (- a ?0)))
  287. (c2 (if (> b ?9) (+ 10 (- b ?A)) (- b ?0)))
  288. (val (+ (lsh c1 4) c2))
  289. (shift
  290. (if (= 0 eat) ;; new byte
  291. (if (>= val 252) 6
  292. (if (>= val 248) 5
  293. (if (>= val 240) 4
  294. (if (>= val 224) 3
  295. (if (>= val 192) 2 0)))))
  296. 6))
  297. (xor
  298. (if (= 0 eat) ;; new byte
  299. (if (>= val 252) 252
  300. (if (>= val 248) 248
  301. (if (>= val 240) 240
  302. (if (>= val 224) 224
  303. (if (>= val 192) 192 0)))))
  304. 128)))
  305. (if (>= val 192) (setq eat shift))
  306. (setq val (logxor val xor))
  307. (setq sum (+ (lsh sum shift) val))
  308. (if (> eat 0) (setq eat (- eat 1)))
  309. (when (= 0 eat)
  310. (setq ret (concat ret (org-protocol-char-to-string sum)))
  311. (setq sum 0))
  312. )) ;; end (while bytes
  313. ret ))
  314. (defun org-protocol-flatten-greedy (param-list &optional strip-path replacement)
  315. "Greedy handlers might receive a list like this from emacsclient:
  316. '( (\"/dir/org-protocol:/greedy:/~/path1\" (23 . 12)) (\"/dir/param\")
  317. where \"/dir/\" is the absolute path to emacsclients working directory. This
  318. function transforms it into a flat list utilizing `org-protocol-flatten' and
  319. transforms the elements of that list as follows:
  320. If strip-path is non-nil, remove the \"/dir/\" prefix from all members of
  321. param-list.
  322. If replacement is string, replace the \"/dir/\" prefix with it.
  323. The first parameter, the one that contains the protocols, is always changed.
  324. Everything up to the end of the protocols is stripped.
  325. Note, that this function will always behave as if
  326. `org-protocol-reverse-list-of-files' was set to t and the returned list will
  327. reflect that. I.e. emacsclients first parameter will be the first one in the
  328. returned list."
  329. (let* ((l (org-protocol-flatten (if org-protocol-reverse-list-of-files
  330. param-list
  331. (reverse param-list))))
  332. (trigger (car l))
  333. (len 0)
  334. dir
  335. ret)
  336. (when (string-match "^\\(.*\\)\\(org-protocol:/+[a-zA-z0-9][-_a-zA-z0-9]*:/+\\)\\(.*\\)" trigger)
  337. (setq dir (match-string 1 trigger))
  338. (setq len (length dir))
  339. (setcar l (concat dir (match-string 3 trigger))))
  340. (if strip-path
  341. (progn
  342. (dolist (e l ret)
  343. (setq ret
  344. (append ret
  345. (list
  346. (if (stringp e)
  347. (if (stringp replacement)
  348. (setq e (concat replacement (substring e len)))
  349. (setq e (substring e len)))
  350. e)))))
  351. ret)
  352. l)))
  353. (defun org-protocol-flatten (l)
  354. "Greedy handlers might receive a list like this from emacsclient:
  355. '( (\"/dir/org-protocol:/greedy:/~/path1\" (23 . 12)) (\"/dir/param\")
  356. where \"/dir/\" is the absolute path to emacsclients working directory.
  357. This function transforms it into a flat list."
  358. (if (null l) ()
  359. (if (listp l)
  360. (append (org-protocol-flatten (car l)) (org-protocol-flatten (cdr l)))
  361. (list l))))
  362. ;;; Standard protocol handlers:
  363. (defun org-protocol-store-link (fname)
  364. "Process an org-protocol://store-link:// style url
  365. and store a browser URL as an org link. Also pushes the links URL to the
  366. `kill-ring'.
  367. The location for a browser's bookmark has to look like this:
  368. javascript:location.href='org-protocol://store-link://'+ \\
  369. encodeURIComponent(location.href)
  370. encodeURIComponent(document.title)+'/'+ \\
  371. Don't use `escape()'! Use `encodeURIComponent()' instead. The title of the page
  372. could contain slashes and the location definitely will.
  373. The sub-protocol used to reach this function is set in
  374. `org-protocol-protocol-alist'."
  375. (let* ((splitparts (org-protocol-split-data fname t))
  376. (uri (org-protocol-sanitize-uri (car splitparts)))
  377. (title (cadr splitparts))
  378. orglink)
  379. (if (boundp 'org-stored-links)
  380. (setq org-stored-links (cons (list uri title) org-stored-links)))
  381. (kill-new uri)
  382. (message "`%s' to insert new org-link, `%s' to insert `%s'"
  383. (substitute-command-keys"\\[org-insert-link]")
  384. (substitute-command-keys"\\[yank]")
  385. uri))
  386. nil)
  387. (defun org-protocol-remember (info)
  388. "Process an org-protocol://remember:// style url.
  389. The location for a browser's bookmark has to look like this:
  390. javascript:location.href='org-protocol://remember://'+ \\
  391. encodeURIComponent(location.href)+'/' \\
  392. encodeURIComponent(document.title)+'/'+ \\
  393. encodeURIComponent(window.getSelection())
  394. See the docs for `org-protocol-capture' for more information."
  395. (if (and (boundp 'org-stored-links)
  396. (or (fboundp 'org-capture))
  397. (org-protocol-do-capture info 'org-remember))
  398. (message "Org-mode not loaded."))
  399. nil)
  400. (defun org-protocol-capture (info)
  401. "Process an org-protocol://capture:// style url.
  402. The sub-protocol used to reach this function is set in
  403. `org-protocol-protocol-alist'.
  404. This function detects an URL, title and optional text, separated by '/'
  405. The location for a browser's bookmark has to look like this:
  406. javascript:location.href='org-protocol://capture://'+ \\
  407. encodeURIComponent(location.href)+'/' \\
  408. encodeURIComponent(document.title)+'/'+ \\
  409. encodeURIComponent(window.getSelection())
  410. By default, it uses the character `org-protocol-default-template-key',
  411. which should be associated with a template in `org-capture-templates'.
  412. But you may prepend the encoded URL with a character and a slash like so:
  413. javascript:location.href='org-protocol://capture://b/'+ ...
  414. Now template ?b will be used."
  415. (if (and (boundp 'org-stored-links)
  416. (or (fboundp 'org-capture))
  417. (org-protocol-do-capture info 'org-capture))
  418. (message "Org-mode not loaded."))
  419. nil)
  420. (defun org-protocol-do-capture (info capture-func)
  421. "Support `org-capture' and `org-remember' alike.
  422. CAPTURE-FUNC is either the symbol `org-remember' or `org-capture'."
  423. (let* ((parts (org-protocol-split-data info t))
  424. (template (or (and (= 1 (length (car parts))) (pop parts))
  425. org-protocol-default-template-key))
  426. (url (org-protocol-sanitize-uri (car parts)))
  427. (type (if (string-match "^\\([a-z]+\\):" url)
  428. (match-string 1 url)))
  429. (title(or (cadr parts) ""))
  430. (region (or (caddr parts) ""))
  431. (orglink (org-make-link-string
  432. url (if (string-match "[^[:space:]]" title) title url)))
  433. remember-annotation-functions)
  434. (setq org-stored-links
  435. (cons (list url title) org-stored-links))
  436. (kill-new orglink)
  437. (org-store-link-props :type type
  438. :link url
  439. :description title
  440. :initial region)
  441. (raise-frame)
  442. (funcall capture-func nil template)))
  443. (defun org-protocol-open-source (fname)
  444. "Process an org-protocol://open-source:// style url.
  445. Change a filename by mapping URLs to local filenames as set
  446. in `org-protocol-project-alist'.
  447. The location for a browser's bookmark should look like this:
  448. javascript:location.href='org-protocol://open-source://'+ \\
  449. encodeURIComponent(location.href)"
  450. ;; As we enter this function for a match on our protocol, the return value
  451. ;; defaults to nil.
  452. (let ((result nil)
  453. (f (org-protocol-unhex-string fname)))
  454. (catch 'result
  455. (dolist (prolist org-protocol-project-alist)
  456. (let* ((base-url (plist-get (cdr prolist) :base-url))
  457. (wsearch (regexp-quote base-url)))
  458. (when (string-match wsearch f)
  459. (let* ((wdir (plist-get (cdr prolist) :working-directory))
  460. (strip-suffix (plist-get (cdr prolist) :online-suffix))
  461. (add-suffix (plist-get (cdr prolist) :working-suffix))
  462. ;; Strip "[?#].*$" if `f' is a redirect with another
  463. ;; ending than strip-suffix here:
  464. (f1 (substring f 0 (string-match "\\([\\?#].*\\)?$" f)))
  465. (start-pos (+ (string-match wsearch f1) (length base-url)))
  466. (end-pos (string-match
  467. (regexp-quote strip-suffix) f1))
  468. ;; We have to compare redirects without suffix below:
  469. (f2 (concat wdir (substring f1 start-pos end-pos)))
  470. (the-file (concat f2 add-suffix)))
  471. ;; Note: the-file may still contain `%C3' et al here because browsers
  472. ;; tend to encode `&auml;' in URLs to `%25C3' - `%25' being `%'.
  473. ;; So the results may vary.
  474. ;; -- start redirects --
  475. (unless (file-exists-p the-file)
  476. (message "File %s does not exist.\nTesting for rewritten URLs." the-file)
  477. (let ((rewrites (plist-get (cdr prolist) :rewrites)))
  478. (when rewrites
  479. (message "Rewrites found: %S" rewrites)
  480. (mapc
  481. (lambda (rewrite)
  482. "Try to match a rewritten URL and map it to a real file."
  483. ;; Compare redirects without suffix:
  484. (if (string-match (car rewrite) f2)
  485. (throw 'result (concat wdir (cdr rewrite)))))
  486. rewrites))))
  487. ;; -- end of redirects --
  488. (if (file-readable-p the-file)
  489. (throw 'result the-file))
  490. (if (file-exists-p the-file)
  491. (message "%s: permission denied!" the-file)
  492. (message "%s: no such file or directory." the-file))))))
  493. result)))
  494. ;;; Core functions:
  495. (defun org-protocol-check-filename-for-protocol (fname restoffiles client)
  496. "Detect if `org-protocol-the-protocol' and a known sub-protocol is used in fname.
  497. Sub-protocols are registered in `org-protocol-protocol-alist' and
  498. `org-protocol-protocol-alist-default'.
  499. This is, how the matching is done:
  500. (string-match \"protocol:/+sub-protocol:/+\" ...)
  501. protocol and sub-protocol are regexp-quoted.
  502. If a matching protcol is found, the protcol is stripped from fname and the
  503. result is passed to the protocols function as the only parameter. If the
  504. function returns nil, the filename is removed from the list of filenames
  505. passed from emacsclient to the server.
  506. If the function returns a non nil value, that value is passed to the server
  507. as filename."
  508. (let ((sub-protocols (append org-protocol-protocol-alist org-protocol-protocol-alist-default)))
  509. (catch 'fname
  510. (let ((the-protocol (concat (regexp-quote org-protocol-the-protocol) ":/+")))
  511. (when (string-match the-protocol fname)
  512. (dolist (prolist sub-protocols)
  513. (let ((proto (concat the-protocol (regexp-quote (plist-get (cdr prolist) :protocol)) ":/+")))
  514. (when (string-match proto fname)
  515. (let* ((func (plist-get (cdr prolist) :function))
  516. (greedy (plist-get (cdr prolist) :greedy))
  517. (splitted (split-string fname proto))
  518. (result (if greedy restoffiles (cadr splitted))))
  519. (when (plist-get (cdr prolist) :kill-client)
  520. (message "Greedy org-protocol handler. Killing client.")
  521. (server-edit))
  522. (when (fboundp func)
  523. (unless greedy
  524. (throw 'fname (funcall func result)))
  525. (funcall func result)
  526. (throw 'fname t))))))))
  527. ;; (message "fname: %s" fname)
  528. fname)))
  529. (defadvice server-visit-files (before org-protocol-detect-protocol-server activate)
  530. "Advice server-visit-flist to call `org-protocol-modify-filename-for-protocol'."
  531. (let ((flist (if org-protocol-reverse-list-of-files
  532. (reverse (ad-get-arg 0))
  533. (ad-get-arg 0)))
  534. (client (ad-get-arg 1)))
  535. (catch 'greedy
  536. (dolist (var flist)
  537. (let ((fname (expand-file-name (car var)))) ;; `\' to `/' on windows. FIXME: could this be done any better?
  538. (setq fname (org-protocol-check-filename-for-protocol fname (member var flist) client))
  539. (if (eq fname t) ;; greedy? We need the `t' return value.
  540. (progn
  541. (ad-set-arg 0 nil)
  542. (throw 'greedy t))
  543. (if (stringp fname) ;; probably filename
  544. (setcar var fname)
  545. (ad-set-arg 0 (delq var (ad-get-arg 0))))))
  546. ))))
  547. ;;; Org specific functions:
  548. (defun org-protocol-create-for-org ()
  549. "Create a org-protocol project for the current file's Org-mode project.
  550. This works, if the file visited is part of a publishing project in
  551. `org-publish-project-alist'. This functions calls `org-protocol-create' to do
  552. most of the work."
  553. (interactive)
  554. (require 'org-publish)
  555. (org-publish-initialize-files-alist)
  556. (let ((all (or (org-publish-get-project-from-filename buffer-file-name))))
  557. (if all (org-protocol-create (cdr all))
  558. (message "Not in an org-project. Did mean %s?"
  559. (substitute-command-keys"\\[org-protocol-create]")))))
  560. (defun org-protocol-create(&optional project-plist)
  561. "Create a new org-protocol project interactively.
  562. An org-protocol project is an entry in `org-protocol-project-alist'
  563. which is used by `org-protocol-open-source'.
  564. Optionally use project-plist to initialize the defaults for this project. If
  565. project-plist is the CDR of an element in `org-publish-project-alist', reuse
  566. :base-directory, :html-extension and :base-extension."
  567. (interactive)
  568. (let ((working-dir (expand-file-name(or (plist-get project-plist :base-directory) default-directory)))
  569. (base-url "http://orgmode.org/worg/")
  570. (strip-suffix (or (plist-get project-plist :html-extension) ".html"))
  571. (working-suffix (if (plist-get project-plist :base-extension)
  572. (concat "." (plist-get project-plist :base-extension))
  573. ".org"))
  574. (worglet-buffer nil)
  575. (insert-default-directory t)
  576. (minibuffer-allow-text-properties nil))
  577. (setq base-url (read-string "Base URL of published content: " base-url nil base-url t))
  578. (if (not (string-match "\\/$" base-url))
  579. (setq base-url (concat base-url "/")))
  580. (setq working-dir
  581. (expand-file-name
  582. (read-directory-name "Local working directory: " working-dir working-dir t)))
  583. (if (not (string-match "\\/$" working-dir))
  584. (setq working-dir (concat working-dir "/")))
  585. (setq strip-suffix
  586. (read-string
  587. (concat "Extension to strip from published URLs ("strip-suffix"): ")
  588. strip-suffix nil strip-suffix t))
  589. (setq working-suffix
  590. (read-string
  591. (concat "Extension of editable files ("working-suffix"): ")
  592. working-suffix nil working-suffix t))
  593. (when (yes-or-no-p "Save the new org-protocol-project to your init file? ")
  594. (setq org-protocol-project-alist
  595. (cons `(,base-url . (:base-url ,base-url
  596. :working-directory ,working-dir
  597. :online-suffix ,strip-suffix
  598. :working-suffix ,working-suffix))
  599. org-protocol-project-alist))
  600. (customize-save-variable 'org-protocol-project-alist org-protocol-project-alist))))
  601. (provide 'org-protocol)
  602. ;; arch-tag: b5c5c2ac-77cf-4a94-a649-2163dff95846
  603. ;;; org-protocol.el ends here