ox-publish.el 50 KB

123456789101112131415161718192021222324252627282930313233343536373839404142434445464748495051525354555657585960616263646566676869707172737475767778798081828384858687888990919293949596979899100101102103104105106107108109110111112113114115116117118119120121122123124125126127128129130131132133134135136137138139140141142143144145146147148149150151152153154155156157158159160161162163164165166167168169170171172173174175176177178179180181182183184185186187188189190191192193194195196197198199200201202203204205206207208209210211212213214215216217218219220221222223224225226227228229230231232233234235236237238239240241242243244245246247248249250251252253254255256257258259260261262263264265266267268269270271272273274275276277278279280281282283284285286287288289290291292293294295296297298299300301302303304305306307308309310311312313314315316317318319320321322323324325326327328329330331332333334335336337338339340341342343344345346347348349350351352353354355356357358359360361362363364365366367368369370371372373374375376377378379380381382383384385386387388389390391392393394395396397398399400401402403404405406407408409410411412413414415416417418419420421422423424425426427428429430431432433434435436437438439440441442443444445446447448449450451452453454455456457458459460461462463464465466467468469470471472473474475476477478479480481482483484485486487488489490491492493494495496497498499500501502503504505506507508509510511512513514515516517518519520521522523524525526527528529530531532533534535536537538539540541542543544545546547548549550551552553554555556557558559560561562563564565566567568569570571572573574575576577578579580581582583584585586587588589590591592593594595596597598599600601602603604605606607608609610611612613614615616617618619620621622623624625626627628629630631632633634635636637638639640641642643644645646647648649650651652653654655656657658659660661662663664665666667668669670671672673674675676677678679680681682683684685686687688689690691692693694695696697698699700701702703704705706707708709710711712713714715716717718719720721722723724725726727728729730731732733734735736737738739740741742743744745746747748749750751752753754755756757758759760761762763764765766767768769770771772773774775776777778779780781782783784785786787788789790791792793794795796797798799800801802803804805806807808809810811812813814815816817818819820821822823824825826827828829830831832833834835836837838839840841842843844845846847848849850851852853854855856857858859860861862863864865866867868869870871872873874875876877878879880881882883884885886887888889890891892893894895896897898899900901902903904905906907908909910911912913914915916917918919920921922923924925926927928929930931932933934935936937938939940941942943944945946947948949950951952953954955956957958959960961962963964965966967968969970971972973974975976977978979980981982983984985986987988989990991992993994995996997998999100010011002100310041005100610071008100910101011101210131014101510161017101810191020102110221023102410251026102710281029103010311032103310341035103610371038103910401041104210431044104510461047104810491050105110521053105410551056105710581059106010611062106310641065106610671068106910701071107210731074107510761077107810791080108110821083108410851086108710881089109010911092109310941095109610971098109911001101110211031104110511061107110811091110111111121113111411151116111711181119112011211122112311241125112611271128112911301131113211331134113511361137113811391140114111421143114411451146114711481149115011511152115311541155115611571158115911601161116211631164116511661167116811691170117111721173117411751176117711781179118011811182118311841185118611871188118911901191119211931194119511961197119811991200120112021203120412051206120712081209121012111212121312141215121612171218121912201221122212231224122512261227122812291230123112321233123412351236123712381239124012411242124312441245124612471248124912501251125212531254125512561257125812591260126112621263126412651266126712681269127012711272127312741275127612771278127912801281128212831284128512861287128812891290129112921293129412951296129712981299130013011302130313041305130613071308130913101311131213131314131513161317131813191320132113221323132413251326132713281329133013311332133313341335133613371338133913401341134213431344134513461347134813491350135113521353135413551356135713581359136013611362
  1. ;;; ox-publish.el --- Publish Related Org Mode Files as a Website -*- lexical-binding: t; -*-
  2. ;; Copyright (C) 2006-2017 Free Software Foundation, Inc.
  3. ;; Author: David O'Toole <dto@gnu.org>
  4. ;; Maintainer: Carsten Dominik <carsten DOT dominik AT gmail DOT com>
  5. ;; Keywords: hypermedia, outlines, wp
  6. ;; This file is part of GNU Emacs.
  7. ;;
  8. ;; GNU Emacs is free software: you can redistribute it and/or modify
  9. ;; it under the terms of the GNU General Public License as published by
  10. ;; the Free Software Foundation, either version 3 of the License, or
  11. ;; (at your option) any later version.
  12. ;; GNU Emacs is distributed in the hope that it will be useful,
  13. ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  14. ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  15. ;; GNU General Public License for more details.
  16. ;; You should have received a copy of the GNU General Public License
  17. ;; along with GNU Emacs. If not, see <https://www.gnu.org/licenses/>.
  18. ;;; Commentary:
  19. ;; This program allow configurable publishing of related sets of
  20. ;; Org mode files as a complete website.
  21. ;;
  22. ;; ox-publish.el can do the following:
  23. ;;
  24. ;; + Publish all one's Org files to a given export back-end
  25. ;; + Upload HTML, images, attachments and other files to a web server
  26. ;; + Exclude selected private pages from publishing
  27. ;; + Publish a clickable sitemap of pages
  28. ;; + Manage local timestamps for publishing only changed files
  29. ;; + Accept plugin functions to extend range of publishable content
  30. ;;
  31. ;; Documentation for publishing is in the manual.
  32. ;;; Code:
  33. (require 'cl-lib)
  34. (require 'format-spec)
  35. (require 'ox)
  36. ;;; Variables
  37. ;; Here, so you find the variable right before it's used the first time:
  38. (defvar org-publish-cache nil
  39. "This will cache timestamps and titles for files in publishing projects.
  40. Blocks could hash sha1 values here.")
  41. (defvar org-publish-after-publishing-hook nil
  42. "Hook run each time a file is published.
  43. Every function in this hook will be called with two arguments:
  44. the name of the original file and the name of the file
  45. produced.")
  46. (defgroup org-publish nil
  47. "Options for publishing a set of files."
  48. :tag "Org Publishing"
  49. :group 'org)
  50. (defcustom org-publish-project-alist nil
  51. "Association list to control publishing behavior.
  52. \\<org-mode-map>
  53. Each element of the alist is a publishing project. The car of
  54. each element is a string, uniquely identifying the project. The
  55. cdr of each element is in one of the following forms:
  56. 1. A well-formed property list with an even number of elements,
  57. alternating keys and values, specifying parameters for the
  58. publishing process.
  59. (:property value :property value ... )
  60. 2. A meta-project definition, specifying of a list of
  61. sub-projects:
  62. (:components (\"project-1\" \"project-2\" ...))
  63. When the CDR of an element of org-publish-project-alist is in
  64. this second form, the elements of the list after `:components'
  65. are taken to be components of the project, which group together
  66. files requiring different publishing options. When you publish
  67. such a project with `\\[org-publish]', the components all publish.
  68. When a property is given a value in `org-publish-project-alist',
  69. its setting overrides the value of the corresponding user
  70. variable (if any) during publishing. However, options set within
  71. a file override everything.
  72. Most properties are optional, but some should always be set:
  73. `:base-directory'
  74. Directory containing publishing source files.
  75. `:base-extension'
  76. Extension (without the dot!) of source files. This can be
  77. a regular expression. If not given, \"org\" will be used as
  78. default extension. If it is `any', include all the files,
  79. even without extension.
  80. `:publishing-directory'
  81. Directory (possibly remote) where output files will be
  82. published.
  83. If `:recursive' is non-nil files in sub-directories of
  84. `:base-directory' are considered.
  85. The `:exclude' property may be used to prevent certain files from
  86. being published. Its value may be a string or regexp matching
  87. file names you don't want to be published.
  88. The `:include' property may be used to include extra files. Its
  89. value may be a list of filenames to include. The filenames are
  90. considered relative to the base directory.
  91. When both `:include' and `:exclude' properties are given values,
  92. the exclusion step happens first.
  93. One special property controls which back-end function to use for
  94. publishing files in the project. This can be used to extend the
  95. set of file types publishable by `org-publish', as well as the
  96. set of output formats.
  97. `:publishing-function'
  98. Function to publish file. Each back-end may define its
  99. own (i.e. `org-latex-publish-to-pdf',
  100. `org-html-publish-to-html'). May be a list of functions, in
  101. which case each function in the list is invoked in turn.
  102. Another property allows you to insert code that prepares
  103. a project for publishing. For example, you could call GNU Make
  104. on a certain makefile, to ensure published files are built up to
  105. date.
  106. `:preparation-function'
  107. Function to be called before publishing this project. This
  108. may also be a list of functions. Preparation functions are
  109. called with the project properties list as their sole
  110. argument.
  111. `:completion-function'
  112. Function to be called after publishing this project. This
  113. may also be a list of functions. Completion functions are
  114. called with the project properties list as their sole
  115. argument.
  116. Some properties control details of the Org publishing process,
  117. and are equivalent to the corresponding user variables listed in
  118. the right column. Back-end specific properties may also be
  119. included. See the back-end documentation for more information.
  120. :author `user-full-name'
  121. :creator `org-export-creator-string'
  122. :email `user-mail-address'
  123. :exclude-tags `org-export-exclude-tags'
  124. :headline-levels `org-export-headline-levels'
  125. :language `org-export-default-language'
  126. :preserve-breaks `org-export-preserve-breaks'
  127. :section-numbers `org-export-with-section-numbers'
  128. :select-tags `org-export-select-tags'
  129. :time-stamp-file `org-export-time-stamp-file'
  130. :with-archived-trees `org-export-with-archived-trees'
  131. :with-author `org-export-with-author'
  132. :with-creator `org-export-with-creator'
  133. :with-date `org-export-with-date'
  134. :with-drawers `org-export-with-drawers'
  135. :with-email `org-export-with-email'
  136. :with-emphasize `org-export-with-emphasize'
  137. :with-entities `org-export-with-entities'
  138. :with-fixed-width `org-export-with-fixed-width'
  139. :with-footnotes `org-export-with-footnotes'
  140. :with-inlinetasks `org-export-with-inlinetasks'
  141. :with-latex `org-export-with-latex'
  142. :with-planning `org-export-with-planning'
  143. :with-priority `org-export-with-priority'
  144. :with-properties `org-export-with-properties'
  145. :with-smart-quotes `org-export-with-smart-quotes'
  146. :with-special-strings `org-export-with-special-strings'
  147. :with-statistics-cookies' `org-export-with-statistics-cookies'
  148. :with-sub-superscript `org-export-with-sub-superscripts'
  149. :with-toc `org-export-with-toc'
  150. :with-tables `org-export-with-tables'
  151. :with-tags `org-export-with-tags'
  152. :with-tasks `org-export-with-tasks'
  153. :with-timestamps `org-export-with-timestamps'
  154. :with-title `org-export-with-title'
  155. :with-todo-keywords `org-export-with-todo-keywords'
  156. The following properties may be used to control publishing of
  157. a site-map of files or summary page for a given project.
  158. `:auto-sitemap'
  159. Whether to publish a site-map during
  160. `org-publish-current-project' or `org-publish-all'.
  161. `:sitemap-filename'
  162. Filename for output of site-map. Defaults to \"sitemap.org\".
  163. `:sitemap-title'
  164. Title of site-map page. Defaults to name of file.
  165. `:sitemap-style'
  166. Can be `list' (site-map is just an itemized list of the
  167. titles of the files involved) or `tree' (the directory
  168. structure of the source files is reflected in the site-map).
  169. Defaults to `tree'.
  170. `:sitemap-format-entry'
  171. Plugin function used to format entries in the site-map. It
  172. is called with three arguments: the file or directory name
  173. relative to base directory, the site map style and the
  174. current project. It has to return a string.
  175. Defaults to `org-publish-sitemap-default-entry', which turns
  176. file names into links and use document titles as
  177. descriptions. For specific formatting needs, one can use
  178. `org-publish-find-date', `org-publish-find-title' and
  179. `org-publish-find-property', to retrieve additional
  180. information about published documents.
  181. `:sitemap-function'
  182. Plugin function to use for generation of site-map. It is
  183. called with two arguments: the title of the site-map, as
  184. a string, and a representation of the files involved in the
  185. project, as returned by `org-list-to-lisp'. The latter can
  186. further be transformed using `org-list-to-generic',
  187. `org-list-to-subtree' and alike. It has to return a string.
  188. Defaults to `org-publish-sitemap-default', which generates
  189. a plain list of links to all files in the project.
  190. If you create a site-map file, adjust the sorting like this:
  191. `:sitemap-sort-folders'
  192. Where folders should appear in the site-map. Set this to
  193. `first' or `last' to display folders first or last,
  194. respectively. When set to `ignore' (default), folders are
  195. ignored altogether. Any other value will mix files and
  196. folders. This variable has no effect when site-map style is
  197. `tree'.
  198. `:sitemap-sort-files'
  199. The site map is normally sorted alphabetically. You can
  200. change this behavior setting this to `anti-chronologically',
  201. `chronologically', or nil.
  202. `:sitemap-ignore-case'
  203. Should sorting be case-sensitive? Default nil.
  204. The following property control the creation of a concept index.
  205. `:makeindex'
  206. Create a concept index. The file containing the index has to
  207. be called \"theindex.org\". If it doesn't exist in the
  208. project, it will be generated. Contents of the index are
  209. stored in the file \"theindex.inc\", which can be included in
  210. \"theindex.org\".
  211. Other properties affecting publication.
  212. `:body-only'
  213. Set this to t to publish only the body of the documents."
  214. :group 'org-export-publish
  215. :type 'alist)
  216. (defcustom org-publish-use-timestamps-flag t
  217. "Non-nil means use timestamp checking to publish only changed files.
  218. When nil, do no timestamp checking and always publish all files."
  219. :group 'org-export-publish
  220. :type 'boolean)
  221. (defcustom org-publish-timestamp-directory
  222. (convert-standard-filename "~/.org-timestamps/")
  223. "Name of directory in which to store publishing timestamps."
  224. :group 'org-export-publish
  225. :type 'directory)
  226. (defcustom org-publish-list-skipped-files t
  227. "Non-nil means show message about files *not* published."
  228. :group 'org-export-publish
  229. :type 'boolean)
  230. (defcustom org-publish-sitemap-sort-files 'alphabetically
  231. "Method to sort files in site-maps.
  232. Possible values are `alphabetically', `chronologically',
  233. `anti-chronologically' and nil.
  234. If `alphabetically', files will be sorted alphabetically. If
  235. `chronologically', files will be sorted with older modification
  236. time first. If `anti-chronologically', files will be sorted with
  237. newer modification time first. nil won't sort files.
  238. You can overwrite this default per project in your
  239. `org-publish-project-alist', using `:sitemap-sort-files'."
  240. :group 'org-export-publish
  241. :type 'symbol)
  242. (defcustom org-publish-sitemap-sort-folders 'ignore
  243. "A symbol, denoting if folders are sorted first in site-maps.
  244. Possible values are `first', `last', `ignore' and nil.
  245. If `first', folders will be sorted before files.
  246. If `last', folders are sorted to the end after the files.
  247. If `ignore', folders do not appear in the site-map.
  248. Any other value will mix files and folders.
  249. You can overwrite this default per project in your
  250. `org-publish-project-alist', using `:sitemap-sort-folders'.
  251. This variable is ignored when site-map style is `tree'."
  252. :group 'org-export-publish
  253. :type '(choice
  254. (const :tag "Folders before files" first)
  255. (const :tag "Folders after files" last)
  256. (const :tag "No folder in site-map" ignore)
  257. (const :tag "Mix folders and files" nil))
  258. :version "26.1"
  259. :package-version '(Org . "9.1")
  260. :safe #'symbolp)
  261. (defcustom org-publish-sitemap-sort-ignore-case nil
  262. "Non-nil when site-map sorting should ignore case.
  263. You can overwrite this default per project in your
  264. `org-publish-project-alist', using `:sitemap-ignore-case'."
  265. :group 'org-export-publish
  266. :type 'boolean)
  267. ;;; Timestamp-related functions
  268. (defun org-publish-timestamp-filename (filename &optional pub-dir pub-func)
  269. "Return path to timestamp file for filename FILENAME."
  270. (setq filename (concat filename "::" (or pub-dir "") "::"
  271. (format "%s" (or pub-func ""))))
  272. (concat "X" (if (fboundp 'sha1) (sha1 filename) (md5 filename))))
  273. (defun org-publish-needed-p
  274. (filename &optional pub-dir pub-func _true-pub-dir base-dir)
  275. "Non-nil if FILENAME should be published in PUB-DIR using PUB-FUNC.
  276. TRUE-PUB-DIR is where the file will truly end up. Currently we
  277. are not using this - maybe it can eventually be used to check if
  278. the file is present at the target location, and how old it is.
  279. Right now we cannot do this, because we do not know under what
  280. file name the file will be stored - the publishing function can
  281. still decide about that independently."
  282. (let ((rtn (if (not org-publish-use-timestamps-flag) t
  283. (org-publish-cache-file-needs-publishing
  284. filename pub-dir pub-func base-dir))))
  285. (if rtn (message "Publishing file %s using `%s'" filename pub-func)
  286. (when org-publish-list-skipped-files
  287. (message "Skipping unmodified file %s" filename)))
  288. rtn))
  289. (defun org-publish-update-timestamp
  290. (filename &optional pub-dir pub-func _base-dir)
  291. "Update publishing timestamp for file FILENAME.
  292. If there is no timestamp, create one."
  293. (let ((key (org-publish-timestamp-filename filename pub-dir pub-func))
  294. (stamp (org-publish-cache-ctime-of-src filename)))
  295. (org-publish-cache-set key stamp)))
  296. (defun org-publish-remove-all-timestamps ()
  297. "Remove all files in the timestamp directory."
  298. (let ((dir org-publish-timestamp-directory))
  299. (when (and (file-exists-p dir) (file-directory-p dir))
  300. (mapc #'delete-file (directory-files dir 'full "[^.]\\'"))
  301. (org-publish-reset-cache))))
  302. ;;; Getting project information out of `org-publish-project-alist'
  303. (defun org-publish-property (property project &optional default)
  304. "Return value PROPERTY, as a symbol, in PROJECT.
  305. DEFAULT is returned when PROPERTY is not actually set in PROJECT
  306. definition."
  307. (let ((properties (cdr project)))
  308. (if (plist-member properties property)
  309. (plist-get properties property)
  310. default)))
  311. (defun org-publish--expand-file-name (file project)
  312. "Return full file name for FILE in PROJECT.
  313. When FILE is a relative file name, it is expanded according to
  314. project base directory. Always return the true name of the file,
  315. ignoring symlinks."
  316. (file-truename
  317. (if (file-name-absolute-p file) file
  318. (expand-file-name file (org-publish-property :base-directory project)))))
  319. (defun org-publish-expand-projects (projects-alist)
  320. "Expand projects in PROJECTS-ALIST.
  321. This splices all the components into the list."
  322. (let ((rest projects-alist) rtn p components)
  323. (while (setq p (pop rest))
  324. (if (setq components (plist-get (cdr p) :components))
  325. (setq rest (append
  326. (mapcar
  327. (lambda (x)
  328. (or (assoc x org-publish-project-alist)
  329. (user-error "Unknown component %S in project %S"
  330. x (car p))))
  331. components)
  332. rest))
  333. (push p rtn)))
  334. (nreverse (delete-dups (delq nil rtn)))))
  335. (defun org-publish-get-base-files (project)
  336. "Return a list of all files in PROJECT."
  337. (let* ((base-dir (file-name-as-directory
  338. (org-publish-property :base-directory project)))
  339. (extension (or (org-publish-property :base-extension project) "org"))
  340. (match (if (eq extension 'any) ""
  341. (format "^[^\\.].*\\.\\(%s\\)$" extension)))
  342. (base-files
  343. (cl-remove-if #'file-directory-p
  344. (if (org-publish-property :recursive project)
  345. (directory-files-recursively base-dir match)
  346. (directory-files base-dir t match t)))))
  347. (org-uniquify
  348. (append
  349. ;; Files from BASE-DIR. Apply exclusion filter before adding
  350. ;; included files.
  351. (let ((exclude-regexp (org-publish-property :exclude project)))
  352. (if exclude-regexp
  353. (cl-remove-if
  354. (lambda (f)
  355. ;; Match against relative names, yet BASE-DIR file
  356. ;; names are absolute.
  357. (string-match exclude-regexp
  358. (file-relative-name f base-dir)))
  359. base-files)
  360. base-files))
  361. ;; Sitemap file.
  362. (and (org-publish-property :auto-sitemap project)
  363. (list (expand-file-name
  364. (or (org-publish-property :sitemap-filename project)
  365. "sitemap.org")
  366. base-dir)))
  367. ;; Included files.
  368. (mapcar (lambda (f) (expand-file-name f base-dir))
  369. (org-publish-property :include project))))))
  370. (defun org-publish-get-project-from-filename (filename &optional up)
  371. "Return a project that FILENAME belongs to.
  372. When UP is non-nil, return a meta-project (i.e., with a :components part)
  373. publishing FILENAME."
  374. (let* ((filename (file-truename filename))
  375. (project
  376. (cl-some
  377. (lambda (p)
  378. ;; Ignore meta-projects.
  379. (unless (org-publish-property :components p)
  380. (let ((base (file-truename
  381. (org-publish-property :base-directory p))))
  382. (cond
  383. ;; Check if FILENAME is explicitly included in one
  384. ;; project.
  385. ((cl-some (lambda (f) (file-equal-p f filename))
  386. (mapcar (lambda (f) (expand-file-name f base))
  387. (org-publish-property :include p)))
  388. p)
  389. ;; Exclude file names matching :exclude property.
  390. ((let ((exclude-re (org-publish-property :exclude p)))
  391. (and exclude-re
  392. (string-match-p exclude-re
  393. (file-relative-name filename base))))
  394. nil)
  395. ;; Check :extension. Handle special `any'
  396. ;; extension.
  397. ((let ((extension (org-publish-property :base-extension p)))
  398. (not (or (eq extension 'any)
  399. (string= (or extension "org")
  400. (file-name-extension filename)))))
  401. nil)
  402. ;; Check if FILENAME belong to project's base
  403. ;; directory, or some of its sub-directories
  404. ;; if :recursive in non-nil.
  405. ((org-publish-property :recursive p)
  406. (and (file-in-directory-p filename base) p))
  407. ((file-equal-p base (file-name-directory filename)) p)
  408. (t nil)))))
  409. org-publish-project-alist)))
  410. (cond
  411. ((not project) nil)
  412. ((not up) project)
  413. ;; When optional argument UP is non-nil, return the top-most
  414. ;; meta-project effectively publishing FILENAME.
  415. (t
  416. (letrec ((find-parent-project
  417. (lambda (project)
  418. (or (cl-some
  419. (lambda (p)
  420. (and (member (car project)
  421. (org-publish-property :components p))
  422. (funcall find-parent-project p)))
  423. org-publish-project-alist)
  424. project))))
  425. (funcall find-parent-project project))))))
  426. ;;; Tools for publishing functions in back-ends
  427. (defun org-publish-org-to (backend filename extension plist &optional pub-dir)
  428. "Publish an Org file to a specified back-end.
  429. BACKEND is a symbol representing the back-end used for
  430. transcoding. FILENAME is the filename of the Org file to be
  431. published. EXTENSION is the extension used for the output
  432. string, with the leading dot. PLIST is the property list for the
  433. given project.
  434. Optional argument PUB-DIR, when non-nil is the publishing
  435. directory.
  436. Return output file name."
  437. (unless (or (not pub-dir) (file-exists-p pub-dir)) (make-directory pub-dir t))
  438. ;; Check if a buffer visiting FILENAME is already open.
  439. (let* ((org-inhibit-startup t)
  440. (visiting (find-buffer-visiting filename))
  441. (work-buffer (or visiting (find-file-noselect filename))))
  442. (unwind-protect
  443. (with-current-buffer work-buffer
  444. (let ((output (org-export-output-file-name extension nil pub-dir)))
  445. (org-export-to-file backend output
  446. nil nil nil (plist-get plist :body-only)
  447. ;; Add `org-publish--store-crossrefs' and
  448. ;; `org-publish-collect-index' to final output filters.
  449. ;; The latter isn't dependent on `:makeindex', since we
  450. ;; want to keep it up-to-date in cache anyway.
  451. (org-combine-plists
  452. plist
  453. `(:crossrefs
  454. ,(org-publish-cache-get-file-property
  455. ;; Normalize file names in cache.
  456. (file-truename filename) :crossrefs nil t)
  457. :filter-final-output
  458. (org-publish--store-crossrefs
  459. org-publish-collect-index
  460. ,@(plist-get plist :filter-final-output)))))))
  461. ;; Remove opened buffer in the process.
  462. (unless visiting (kill-buffer work-buffer)))))
  463. (defun org-publish-attachment (_plist filename pub-dir)
  464. "Publish a file with no transformation of any kind.
  465. FILENAME is the filename of the Org file to be published. PLIST
  466. is the property list for the given project. PUB-DIR is the
  467. publishing directory.
  468. Return output file name."
  469. (unless (file-directory-p pub-dir)
  470. (make-directory pub-dir t))
  471. (let ((output (expand-file-name (file-name-nondirectory filename) pub-dir)))
  472. (unless (file-equal-p (expand-file-name (file-name-directory filename))
  473. (file-name-as-directory (expand-file-name pub-dir)))
  474. (copy-file filename output t))
  475. ;; Return file name.
  476. output))
  477. ;;; Publishing files, sets of files
  478. (defun org-publish-file (filename &optional project no-cache)
  479. "Publish file FILENAME from PROJECT.
  480. If NO-CACHE is not nil, do not initialize `org-publish-cache'.
  481. This is needed, since this function is used to publish single
  482. files, when entire projects are published (see
  483. `org-publish-projects')."
  484. (let* ((project
  485. (or project
  486. (org-publish-get-project-from-filename filename)
  487. (user-error "File %S is not part of any known project"
  488. (abbreviate-file-name filename))))
  489. (project-plist (cdr project))
  490. (publishing-function
  491. (pcase (org-publish-property :publishing-function project)
  492. (`nil (user-error "No publishing function chosen"))
  493. ((and f (pred listp)) f)
  494. (f (list f))))
  495. (base-dir
  496. (file-name-as-directory
  497. (or (org-publish-property :base-directory project)
  498. (user-error "Project %S does not have :base-directory defined"
  499. (car project)))))
  500. (pub-base-dir
  501. (file-name-as-directory
  502. (or (org-publish-property :publishing-directory project)
  503. (user-error
  504. "Project %S does not have :publishing-directory defined"
  505. (car project)))))
  506. (pub-dir
  507. (file-name-directory
  508. (expand-file-name (file-relative-name filename base-dir)
  509. pub-base-dir))))
  510. (unless no-cache (org-publish-initialize-cache (car project)))
  511. ;; Allow chain of publishing functions.
  512. (dolist (f publishing-function)
  513. (when (org-publish-needed-p filename pub-base-dir f pub-dir base-dir)
  514. (let ((output (funcall f project-plist filename pub-dir)))
  515. (org-publish-update-timestamp filename pub-base-dir f base-dir)
  516. (run-hook-with-args 'org-publish-after-publishing-hook
  517. filename
  518. output))))
  519. ;; Make sure to write cache to file after successfully publishing
  520. ;; a file, so as to minimize impact of a publishing failure.
  521. (org-publish-write-cache-file)))
  522. (defun org-publish-projects (projects)
  523. "Publish all files belonging to the PROJECTS alist.
  524. If `:auto-sitemap' is set, publish the sitemap too. If
  525. `:makeindex' is set, also produce a file \"theindex.org\"."
  526. (dolist (project (org-publish-expand-projects projects))
  527. (let ((plist (cdr project)))
  528. (let ((fun (org-publish-property :preparation-function project)))
  529. (cond
  530. ((consp fun) (dolist (f fun) (funcall f plist)))
  531. ((functionp fun) (funcall fun plist))))
  532. ;; Each project uses its own cache file.
  533. (org-publish-initialize-cache (car project))
  534. (when (org-publish-property :auto-sitemap project)
  535. (let ((sitemap-filename
  536. (or (org-publish-property :sitemap-filename project)
  537. "sitemap.org")))
  538. (org-publish-sitemap project sitemap-filename)))
  539. ;; Publish all files from PROJECT except "theindex.org". Its
  540. ;; publishing will be deferred until "theindex.inc" is
  541. ;; populated.
  542. (let ((theindex
  543. (expand-file-name "theindex.org"
  544. (org-publish-property :base-directory project))))
  545. (dolist (file (org-publish-get-base-files project))
  546. (unless (file-equal-p file theindex)
  547. (org-publish-file file project t)))
  548. ;; Populate "theindex.inc", if needed, and publish
  549. ;; "theindex.org".
  550. (when (org-publish-property :makeindex project)
  551. (org-publish-index-generate-theindex
  552. project (org-publish-property :base-directory project))
  553. (org-publish-file theindex project t)))
  554. (let ((fun (org-publish-property :completion-function project)))
  555. (cond
  556. ((consp fun) (dolist (f fun) (funcall f plist)))
  557. ((functionp fun) (funcall fun plist)))))
  558. (org-publish-write-cache-file)))
  559. ;;; Site map generation
  560. (defun org-publish--sitemap-files-to-lisp (files project style format-entry)
  561. "Represent FILES as a parsed plain list.
  562. FILES is the list of files in the site map. PROJECT is the
  563. current project. STYLE determines is either `list' or `tree'.
  564. FORMAT-ENTRY is a function called on each file which should
  565. return a string. Return value is a list as returned by
  566. `org-list-to-lisp'."
  567. (let ((root (expand-file-name
  568. (file-name-as-directory
  569. (org-publish-property :base-directory project)))))
  570. (pcase style
  571. (`list
  572. (cons 'unordered
  573. (mapcar
  574. (lambda (f)
  575. (list (funcall format-entry
  576. (file-relative-name f root)
  577. style
  578. project)))
  579. files)))
  580. (`tree
  581. (letrec ((files-only (cl-remove-if #'directory-name-p files))
  582. (directories (cl-remove-if-not #'directory-name-p files))
  583. (subtree-to-list
  584. (lambda (dir)
  585. (cons 'unordered
  586. (nconc
  587. ;; Files in DIR.
  588. (mapcar
  589. (lambda (f)
  590. (list (funcall format-entry
  591. (file-relative-name f root)
  592. style
  593. project)))
  594. (cl-remove-if-not
  595. (lambda (f) (string= dir (file-name-directory f)))
  596. files-only))
  597. ;; Direct sub-directories.
  598. (mapcar
  599. (lambda (sub)
  600. (list (funcall format-entry
  601. (file-relative-name sub root)
  602. style
  603. project)
  604. (funcall subtree-to-list sub)))
  605. (cl-remove-if-not
  606. (lambda (f)
  607. (string=
  608. dir
  609. ;; Parent directory.
  610. (file-name-directory (directory-file-name f))))
  611. directories)))))))
  612. (funcall subtree-to-list root)))
  613. (_ (user-error "Unknown site-map style: `%s'" style)))))
  614. (defun org-publish-sitemap (project &optional sitemap-filename)
  615. "Create a sitemap of pages in set defined by PROJECT.
  616. Optionally set the filename of the sitemap with SITEMAP-FILENAME.
  617. Default for SITEMAP-FILENAME is `sitemap.org'."
  618. (let* ((root (expand-file-name
  619. (file-name-as-directory
  620. (org-publish-property :base-directory project))))
  621. (sitemap-filename (concat root (or sitemap-filename "sitemap.org")))
  622. (title (or (org-publish-property :sitemap-title project)
  623. (concat "Sitemap for project " (car project))))
  624. (style (or (org-publish-property :sitemap-style project)
  625. 'tree))
  626. (sitemap-builder (or (org-publish-property :sitemap-function project)
  627. #'org-publish-sitemap-default))
  628. (format-entry (or (org-publish-property :sitemap-format-entry project)
  629. #'org-publish-sitemap-default-entry))
  630. (sort-folders
  631. (org-publish-property :sitemap-sort-folders project
  632. org-publish-sitemap-sort-folders))
  633. (sort-files
  634. (org-publish-property :sitemap-sort-files project
  635. org-publish-sitemap-sort-files))
  636. (ignore-case
  637. (org-publish-property :sitemap-ignore-case project
  638. org-publish-sitemap-sort-ignore-case))
  639. (org-file-p (lambda (f) (equal "org" (file-name-extension f))))
  640. (sort-predicate
  641. (lambda (a b)
  642. (let ((retval t))
  643. ;; First we sort files:
  644. (pcase sort-files
  645. (`alphabetically
  646. (let ((A (if (funcall org-file-p a)
  647. (concat (file-name-directory a)
  648. (org-publish-find-title a project))
  649. a))
  650. (B (if (funcall org-file-p b)
  651. (concat (file-name-directory b)
  652. (org-publish-find-title b project))
  653. b)))
  654. (setq retval
  655. (if ignore-case
  656. (not (string-lessp (upcase B) (upcase A)))
  657. (not (string-lessp B A))))))
  658. ((or `anti-chronologically `chronologically)
  659. (let* ((adate (org-publish-find-date a project))
  660. (bdate (org-publish-find-date b project))
  661. (A (+ (lsh (car adate) 16) (cadr adate)))
  662. (B (+ (lsh (car bdate) 16) (cadr bdate))))
  663. (setq retval
  664. (if (eq sort-files 'chronologically)
  665. (<= A B)
  666. (>= A B)))))
  667. (`nil nil)
  668. (_ (user-error "Invalid sort value %s" sort-files)))
  669. ;; Directory-wise wins:
  670. (when (memq sort-folders '(first last))
  671. ;; a is directory, b not:
  672. (cond
  673. ((and (file-directory-p a) (not (file-directory-p b)))
  674. (setq retval (eq sort-folders 'first)))
  675. ;; a is not a directory, but b is:
  676. ((and (not (file-directory-p a)) (file-directory-p b))
  677. (setq retval (eq sort-folders 'last)))))
  678. retval))))
  679. (message "Generating sitemap for %s" title)
  680. (with-temp-file sitemap-filename
  681. (insert
  682. (let ((files (remove sitemap-filename
  683. (org-publish-get-base-files project))))
  684. ;; Add directories, if applicable.
  685. (unless (and (eq style 'list) (eq sort-folders 'ignore))
  686. (setq files
  687. (nconc (remove root (org-uniquify
  688. (mapcar #'file-name-directory files)))
  689. files)))
  690. ;; Eventually sort all entries.
  691. (when (or sort-files (not (memq sort-folders 'ignore)))
  692. (setq files (sort files sort-predicate)))
  693. (funcall sitemap-builder
  694. title
  695. (org-publish--sitemap-files-to-lisp
  696. files project style format-entry)))))))
  697. (defun org-publish-find-property (file property project &optional backend)
  698. "Find the PROPERTY of FILE in project.
  699. PROPERTY is a keyword referring to an export option, as defined
  700. in `org-export-options-alist' or in export back-ends. In the
  701. latter case, optional argument BACKEND has to be set to the
  702. back-end where the option is defined, e.g.,
  703. (org-publish-find-property file :subtitle 'latex)
  704. Return value may be a string or a list, depending on the type of
  705. PROPERTY, i.e. \"behavior\" parameter from `org-export-options-alist'."
  706. (let ((file (org-publish--expand-file-name file project)))
  707. (when (and (file-readable-p file) (not (directory-name-p file)))
  708. (let* ((org-inhibit-startup t)
  709. (visiting (find-buffer-visiting file))
  710. (buffer (or visiting (find-file-noselect file))))
  711. (unwind-protect
  712. (plist-get (with-current-buffer buffer
  713. (if (not visiting) (org-export-get-environment backend)
  714. ;; Protect local variables in open buffers.
  715. (org-export-with-buffer-copy
  716. (org-export-get-environment backend))))
  717. property)
  718. (unless visiting (kill-buffer buffer)))))))
  719. (defun org-publish-find-title (file project)
  720. "Find the title of FILE in PROJECT."
  721. (let ((file (org-publish--expand-file-name file project)))
  722. (or (org-publish-cache-get-file-property file :title nil t)
  723. (let* ((parsed-title (org-publish-find-property file :title project))
  724. (title
  725. (if parsed-title
  726. ;; Remove property so that the return value is
  727. ;; cache-able (i.e., it can be `read' back).
  728. (org-no-properties
  729. (org-element-interpret-data parsed-title))
  730. (file-name-nondirectory (file-name-sans-extension file)))))
  731. (org-publish-cache-set-file-property file :title title)
  732. title))))
  733. (defun org-publish-find-date (file project)
  734. "Find the date of FILE in PROJECT.
  735. This function assumes FILE is either a directory or an Org file.
  736. If FILE is an Org file and provides a DATE keyword use it. In
  737. any other case use the file system's modification time. Return
  738. time in `current-time' format."
  739. (let ((file (org-publish--expand-file-name file project)))
  740. (if (file-directory-p file) (nth 5 (file-attributes file))
  741. (let ((date (org-publish-find-property file :date project)))
  742. ;; DATE is a secondary string. If it contains a time-stamp,
  743. ;; convert it to internal format. Otherwise, use FILE
  744. ;; modification time.
  745. (cond ((let ((ts (and (consp date) (assq 'timestamp date))))
  746. (and ts
  747. (let ((value (org-element-interpret-data ts)))
  748. (and (org-string-nw-p value)
  749. (org-time-string-to-time value))))))
  750. ((file-exists-p file) (nth 5 (file-attributes file)))
  751. (t (error "No such file: \"%s\"" file)))))))
  752. (defun org-publish-sitemap-default-entry (entry style project)
  753. "Default format for site map ENTRY, as a string.
  754. ENTRY is a file name. STYLE is the style of the sitemap.
  755. PROJECT is the current project."
  756. (cond ((not (directory-name-p entry))
  757. (format "[[file:%s][%s]]"
  758. entry
  759. (org-publish-find-title entry project)))
  760. ((eq style 'tree)
  761. ;; Return only last subdir.
  762. (file-name-nondirectory (directory-file-name entry)))
  763. (t entry)))
  764. (defun org-publish-sitemap-default (title list)
  765. "Default site map, as a string.
  766. TITLE is the the title of the site map. LIST is an internal
  767. representation for the files to include, as returned by
  768. `org-list-to-lisp'. PROJECT is the current project."
  769. (concat "#+TITLE: " title "\n\n"
  770. (org-list-to-org list)))
  771. ;;; Interactive publishing functions
  772. ;;;###autoload
  773. (defalias 'org-publish-project 'org-publish)
  774. ;;;###autoload
  775. (defun org-publish (project &optional force async)
  776. "Publish PROJECT.
  777. PROJECT is either a project name, as a string, or a project
  778. alist (see `org-publish-project-alist' variable).
  779. When optional argument FORCE is non-nil, force publishing all
  780. files in PROJECT. With a non-nil optional argument ASYNC,
  781. publishing will be done asynchronously, in another process."
  782. (interactive
  783. (list (assoc (completing-read "Publish project: "
  784. org-publish-project-alist nil t)
  785. org-publish-project-alist)
  786. current-prefix-arg))
  787. (let ((project (if (not (stringp project)) project
  788. ;; If this function is called in batch mode,
  789. ;; PROJECT is still a string here.
  790. (assoc project org-publish-project-alist))))
  791. (cond
  792. ((not project))
  793. (async
  794. (org-export-async-start (lambda (_) nil)
  795. `(let ((org-publish-use-timestamps-flag
  796. ,(and (not force) org-publish-use-timestamps-flag)))
  797. ;; Expand components right now as external process may not
  798. ;; be aware of complete `org-publish-project-alist'.
  799. (org-publish-projects
  800. ',(org-publish-expand-projects (list project))))))
  801. (t (save-window-excursion
  802. (let ((org-publish-use-timestamps-flag
  803. (and (not force) org-publish-use-timestamps-flag)))
  804. (org-publish-projects (list project))))))))
  805. ;;;###autoload
  806. (defun org-publish-all (&optional force async)
  807. "Publish all projects.
  808. With prefix argument FORCE, remove all files in the timestamp
  809. directory and force publishing all projects. With a non-nil
  810. optional argument ASYNC, publishing will be done asynchronously,
  811. in another process."
  812. (interactive "P")
  813. (if async
  814. (org-export-async-start (lambda (_) nil)
  815. `(progn
  816. (when ',force (org-publish-remove-all-timestamps))
  817. (let ((org-publish-use-timestamps-flag
  818. (if ',force nil ,org-publish-use-timestamps-flag)))
  819. (org-publish-projects ',org-publish-project-alist))))
  820. (when force (org-publish-remove-all-timestamps))
  821. (save-window-excursion
  822. (let ((org-publish-use-timestamps-flag
  823. (if force nil org-publish-use-timestamps-flag)))
  824. (org-publish-projects org-publish-project-alist)))))
  825. ;;;###autoload
  826. (defun org-publish-current-file (&optional force async)
  827. "Publish the current file.
  828. With prefix argument FORCE, force publish the file. When
  829. optional argument ASYNC is non-nil, publishing will be done
  830. asynchronously, in another process."
  831. (interactive "P")
  832. (let ((file (buffer-file-name (buffer-base-buffer))))
  833. (if async
  834. (org-export-async-start (lambda (_) nil)
  835. `(let ((org-publish-use-timestamps-flag
  836. (if ',force nil ,org-publish-use-timestamps-flag)))
  837. (org-publish-file ,file)))
  838. (save-window-excursion
  839. (let ((org-publish-use-timestamps-flag
  840. (if force nil org-publish-use-timestamps-flag)))
  841. (org-publish-file file))))))
  842. ;;;###autoload
  843. (defun org-publish-current-project (&optional force async)
  844. "Publish the project associated with the current file.
  845. With a prefix argument, force publishing of all files in
  846. the project."
  847. (interactive "P")
  848. (save-window-excursion
  849. (let ((project (org-publish-get-project-from-filename
  850. (buffer-file-name (buffer-base-buffer)) 'up)))
  851. (if project (org-publish project force async)
  852. (error "File %s is not part of any known project"
  853. (buffer-file-name (buffer-base-buffer)))))))
  854. ;;; Index generation
  855. (defun org-publish-collect-index (output _backend info)
  856. "Update index for a file in cache.
  857. OUTPUT is the output from transcoding current file. BACKEND is
  858. the back-end that was used for transcoding. INFO is a plist
  859. containing publishing and export options.
  860. The index relative to current file is stored as an alist. An
  861. association has the following shape: (TERM FILE-NAME PARENT),
  862. where TERM is the indexed term, as a string, FILE-NAME is the
  863. original full path of the file where the term in encountered, and
  864. PARENT is a reference to the headline, if any, containing the
  865. original index keyword. When non-nil, this reference is a cons
  866. cell. Its CAR is a symbol among `id', `custom-id' and `name' and
  867. its CDR is a string."
  868. (let ((file (file-truename (plist-get info :input-file))))
  869. (org-publish-cache-set-file-property
  870. file :index
  871. (delete-dups
  872. (org-element-map (plist-get info :parse-tree) 'keyword
  873. (lambda (k)
  874. (when (equal (org-element-property :key k) "INDEX")
  875. (let ((parent (org-export-get-parent-headline k)))
  876. (list (org-element-property :value k)
  877. file
  878. (cond
  879. ((not parent) nil)
  880. ((let ((id (org-element-property :ID parent)))
  881. (and id (cons 'id id))))
  882. ((let ((id (org-element-property :CUSTOM_ID parent)))
  883. (and id (cons 'custom-id id))))
  884. (t (cons 'name
  885. ;; Remove statistics cookie.
  886. (replace-regexp-in-string
  887. "\\[[0-9]+%\\]\\|\\[[0-9]+/[0-9]+\\]" ""
  888. (org-element-property :raw-value parent)))))))))
  889. info))))
  890. ;; Return output unchanged.
  891. output)
  892. (defun org-publish-index-generate-theindex (project directory)
  893. "Retrieve full index from cache and build \"theindex.org\".
  894. PROJECT is the project the index relates to. DIRECTORY is the
  895. publishing directory."
  896. (let ((all-files (org-publish-get-base-files project))
  897. full-index)
  898. ;; Compile full index and sort it alphabetically.
  899. (dolist (file all-files
  900. (setq full-index
  901. (sort (nreverse full-index)
  902. (lambda (a b) (string< (downcase (car a))
  903. (downcase (car b)))))))
  904. (let ((index (org-publish-cache-get-file-property file :index)))
  905. (dolist (term index)
  906. (unless (member term full-index) (push term full-index)))))
  907. ;; Write "theindex.inc" in DIRECTORY.
  908. (with-temp-file (expand-file-name "theindex.inc" directory)
  909. (let ((current-letter nil) (last-entry nil))
  910. (dolist (idx full-index)
  911. (let* ((entry (org-split-string (car idx) "!"))
  912. (letter (upcase (substring (car entry) 0 1)))
  913. ;; Transform file into a path relative to publishing
  914. ;; directory.
  915. (file (file-relative-name
  916. (nth 1 idx)
  917. (plist-get (cdr project) :base-directory))))
  918. ;; Check if another letter has to be inserted.
  919. (unless (string= letter current-letter)
  920. (insert (format "* %s\n" letter)))
  921. ;; Compute the first difference between last entry and
  922. ;; current one: it tells the level at which new items
  923. ;; should be added.
  924. (let* ((rank
  925. (if (equal entry last-entry) (1- (length entry))
  926. (cl-loop for n from 0 to (length entry)
  927. unless (equal (nth n entry) (nth n last-entry))
  928. return n)))
  929. (len (length (nthcdr rank entry))))
  930. ;; For each term after the first difference, create
  931. ;; a new sub-list with the term as body. Moreover,
  932. ;; linkify the last term.
  933. (dotimes (n len)
  934. (insert
  935. (concat
  936. (make-string (* (+ rank n) 2) ?\s) " - "
  937. (if (not (= (1- len) n)) (nth (+ rank n) entry)
  938. ;; Last term: Link it to TARGET, if possible.
  939. (let ((target (nth 2 idx)))
  940. (format
  941. "[[%s][%s]]"
  942. ;; Destination.
  943. (pcase (car target)
  944. (`nil (format "file:%s" file))
  945. (`id (format "id:%s" (cdr target)))
  946. (`custom-id (format "file:%s::#%s" file (cdr target)))
  947. (_ (format "file:%s::*%s" file (cdr target))))
  948. ;; Description.
  949. (car (last entry)))))
  950. "\n"))))
  951. (setq current-letter letter last-entry entry))))
  952. ;; Create "theindex.org", if it doesn't exist yet, and provide
  953. ;; a default index file.
  954. (let ((index.org (expand-file-name "theindex.org" directory)))
  955. (unless (file-exists-p index.org)
  956. (with-temp-file index.org
  957. (insert "#+TITLE: Index\n\n#+INCLUDE: \"theindex.inc\"\n\n")))))))
  958. ;;; External Fuzzy Links Resolution
  959. ;;
  960. ;; This part implements tools to resolve [[file.org::*Some headline]]
  961. ;; links, where "file.org" belongs to the current project.
  962. (defun org-publish--store-crossrefs (output _backend info)
  963. "Store cross-references for current published file.
  964. OUTPUT is the produced output, as a string. BACKEND is the export
  965. back-end used, as a symbol. INFO is the final export state, as
  966. a plist.
  967. This function is meant to be used as a final output filter. See
  968. `org-publish-org-to'."
  969. (org-publish-cache-set-file-property
  970. (file-truename (plist-get info :input-file))
  971. :crossrefs
  972. ;; Update `:crossrefs' so as to remove unused references and search
  973. ;; cells. Actually used references are extracted from
  974. ;; `:internal-references', with references as strings removed. See
  975. ;; `org-export-get-reference' for details.
  976. (cl-remove-if (lambda (pair) (stringp (car pair)))
  977. (plist-get info :internal-references)))
  978. ;; Return output unchanged.
  979. output)
  980. (defun org-publish-resolve-external-link (search file &optional prefer-custom)
  981. "Return reference for element matching string SEARCH in FILE.
  982. Return value is an internal reference, as a string.
  983. This function allows resolving external links with a search
  984. option, e.g.,
  985. [[file:file.org::*heading][description]]
  986. [[file:file.org::#custom-id][description]]
  987. [[file:file.org::fuzzy][description]]
  988. When PREFER-CUSTOM is non-nil, and SEARCH targets a headline in
  989. FILE, return its custom ID, if any.
  990. It only makes sense to use this if export back-end builds
  991. references with `org-export-get-reference'."
  992. (cond
  993. ((and prefer-custom
  994. (if (string-prefix-p "#" search)
  995. (substring search 1)
  996. (with-current-buffer (find-file-noselect file)
  997. (org-with-point-at 1
  998. (let ((org-link-search-must-match-exact-headline t))
  999. (org-link-search (org-link-unescape search) nil t))
  1000. (and (org-at-heading-p)
  1001. (org-string-nw-p (org-entry-get (point) "CUSTOM_ID"))))))))
  1002. ((not org-publish-cache)
  1003. (progn
  1004. (message "Reference %S in file %S cannot be resolved without publishing"
  1005. search
  1006. file)
  1007. "MissingReference"))
  1008. (t
  1009. (let* ((filename (file-truename file))
  1010. (crossrefs
  1011. (org-publish-cache-get-file-property filename :crossrefs nil t))
  1012. (cells
  1013. (org-export-string-to-search-cell (org-link-unescape search))))
  1014. (or
  1015. ;; Look for reference associated to search cells triggered by
  1016. ;; LINK. It can match when targeted file has been published
  1017. ;; already.
  1018. (let ((known (cdr (cl-some (lambda (c) (assoc c crossrefs)) cells))))
  1019. (and known (org-export-format-reference known)))
  1020. ;; Search cell is unknown so far. Generate a new internal
  1021. ;; reference that will be used when the targeted file will be
  1022. ;; published.
  1023. (let ((new (org-export-new-reference crossrefs)))
  1024. (dolist (cell cells) (push (cons cell new) crossrefs))
  1025. (org-publish-cache-set-file-property filename :crossrefs crossrefs)
  1026. (org-export-format-reference new)))))))
  1027. (defun org-publish-file-relative-name (filename info)
  1028. "Convert FILENAME to be relative to current project's base directory.
  1029. INFO is the plist containing the current export state. The
  1030. function does not change relative file names."
  1031. (let ((base (plist-get info :base-directory)))
  1032. (if (and base
  1033. (file-name-absolute-p filename)
  1034. (file-in-directory-p filename base))
  1035. (file-relative-name filename base)
  1036. filename)))
  1037. ;;; Caching functions
  1038. (defun org-publish-write-cache-file (&optional free-cache)
  1039. "Write `org-publish-cache' to file.
  1040. If FREE-CACHE, empty the cache."
  1041. (unless org-publish-cache
  1042. (error "`org-publish-write-cache-file' called, but no cache present"))
  1043. (let ((cache-file (org-publish-cache-get ":cache-file:")))
  1044. (unless cache-file
  1045. (error "Cannot find cache-file name in `org-publish-write-cache-file'"))
  1046. (with-temp-file cache-file
  1047. (let (print-level print-length)
  1048. (insert "(setq org-publish-cache \
  1049. \(make-hash-table :test 'equal :weakness nil :size 100))\n")
  1050. (maphash (lambda (k v)
  1051. (insert
  1052. (format "(puthash %S %s%S org-publish-cache)\n"
  1053. k (if (or (listp v) (symbolp v)) "'" "") v)))
  1054. org-publish-cache)))
  1055. (when free-cache (org-publish-reset-cache))))
  1056. (defun org-publish-initialize-cache (project-name)
  1057. "Initialize the projects cache if not initialized yet and return it."
  1058. (unless project-name
  1059. (error "Cannot initialize `org-publish-cache' without projects name in \
  1060. `org-publish-initialize-cache'"))
  1061. (unless (file-exists-p org-publish-timestamp-directory)
  1062. (make-directory org-publish-timestamp-directory t))
  1063. (unless (file-directory-p org-publish-timestamp-directory)
  1064. (error "Org publish timestamp: %s is not a directory"
  1065. org-publish-timestamp-directory))
  1066. (unless (and org-publish-cache
  1067. (string= (org-publish-cache-get ":project:") project-name))
  1068. (let* ((cache-file
  1069. (concat
  1070. (expand-file-name org-publish-timestamp-directory)
  1071. project-name ".cache"))
  1072. (cexists (file-exists-p cache-file)))
  1073. (when org-publish-cache (org-publish-reset-cache))
  1074. (if cexists (load-file cache-file)
  1075. (setq org-publish-cache
  1076. (make-hash-table :test 'equal :weakness nil :size 100))
  1077. (org-publish-cache-set ":project:" project-name)
  1078. (org-publish-cache-set ":cache-file:" cache-file))
  1079. (unless cexists (org-publish-write-cache-file nil))))
  1080. org-publish-cache)
  1081. (defun org-publish-reset-cache ()
  1082. "Empty org-publish-cache and reset it nil."
  1083. (message "%s" "Resetting org-publish-cache")
  1084. (when (hash-table-p org-publish-cache)
  1085. (clrhash org-publish-cache))
  1086. (setq org-publish-cache nil))
  1087. (defun org-publish-cache-file-needs-publishing
  1088. (filename &optional pub-dir pub-func _base-dir)
  1089. "Check the timestamp of the last publishing of FILENAME.
  1090. Return non-nil if the file needs publishing. Also check if
  1091. any included files have been more recently published, so that
  1092. the file including them will be republished as well."
  1093. (unless org-publish-cache
  1094. (error
  1095. "`org-publish-cache-file-needs-publishing' called, but no cache present"))
  1096. (let* ((key (org-publish-timestamp-filename filename pub-dir pub-func))
  1097. (pstamp (org-publish-cache-get key))
  1098. (org-inhibit-startup t)
  1099. included-files-ctime)
  1100. (when (equal (file-name-extension filename) "org")
  1101. (let ((visiting (find-buffer-visiting filename))
  1102. (buf (find-file-noselect filename))
  1103. (case-fold-search t))
  1104. (unwind-protect
  1105. (with-current-buffer buf
  1106. (goto-char (point-min))
  1107. (while (re-search-forward "^[ \t]*#\\+INCLUDE:" nil t)
  1108. (let* ((element (org-element-at-point))
  1109. (included-file
  1110. (and (eq (org-element-type element) 'keyword)
  1111. (let ((value (org-element-property :value element)))
  1112. (and value
  1113. (string-match
  1114. "\\`\\(\".+?\"\\|\\S-+\\)\\(?:\\s-+\\|$\\)"
  1115. value)
  1116. (let ((m (match-string 1 value)))
  1117. (org-unbracket-string
  1118. "\"" "\""
  1119. ;; Ignore search suffix.
  1120. (if (string-match "::.*?\"?\\'" m)
  1121. (substring m 0 (match-beginning 0))
  1122. m))))))))
  1123. (when included-file
  1124. (push (org-publish-cache-ctime-of-src
  1125. (expand-file-name included-file))
  1126. included-files-ctime)))))
  1127. (unless visiting (kill-buffer buf)))))
  1128. (or (null pstamp)
  1129. (let ((ctime (org-publish-cache-ctime-of-src filename)))
  1130. (or (< pstamp ctime)
  1131. (cl-some (lambda (ct) (< ctime ct)) included-files-ctime))))))
  1132. (defun org-publish-cache-set-file-property
  1133. (filename property value &optional project-name)
  1134. "Set the VALUE for a PROPERTY of file FILENAME in publishing cache to VALUE.
  1135. Use cache file of PROJECT-NAME. If the entry does not exist, it
  1136. will be created. Return VALUE."
  1137. ;; Evtl. load the requested cache file:
  1138. (if project-name (org-publish-initialize-cache project-name))
  1139. (let ((pl (org-publish-cache-get filename)))
  1140. (if pl (progn (plist-put pl property value) value)
  1141. (org-publish-cache-get-file-property
  1142. filename property value nil project-name))))
  1143. (defun org-publish-cache-get-file-property
  1144. (filename property &optional default no-create project-name)
  1145. "Return the value for a PROPERTY of file FILENAME in publishing cache.
  1146. Use cache file of PROJECT-NAME. Return the value of that PROPERTY,
  1147. or DEFAULT, if the value does not yet exist. Create the entry,
  1148. if necessary, unless NO-CREATE is non-nil."
  1149. (when project-name (org-publish-initialize-cache project-name))
  1150. (let ((properties (org-publish-cache-get filename)))
  1151. (cond ((null properties)
  1152. (unless no-create
  1153. (org-publish-cache-set filename (list property default)))
  1154. default)
  1155. ((plist-member properties property) (plist-get properties property))
  1156. (t default))))
  1157. (defun org-publish-cache-get (key)
  1158. "Return the value stored in `org-publish-cache' for key KEY.
  1159. Return nil, if no value or nil is found. Raise an error if the
  1160. cache does not exist."
  1161. (unless org-publish-cache
  1162. (error "`org-publish-cache-get' called, but no cache present"))
  1163. (gethash key org-publish-cache))
  1164. (defun org-publish-cache-set (key value)
  1165. "Store KEY VALUE pair in `org-publish-cache'.
  1166. Returns value on success, else nil. Raise an error if the cache
  1167. does not exist."
  1168. (unless org-publish-cache
  1169. (error "`org-publish-cache-set' called, but no cache present"))
  1170. (puthash key value org-publish-cache))
  1171. (defun org-publish-cache-ctime-of-src (file)
  1172. "Get the ctime of FILE as an integer."
  1173. (let ((attr (file-attributes
  1174. (expand-file-name (or (file-symlink-p file) file)
  1175. (file-name-directory file)))))
  1176. (if (not attr) (error "No such file: \"%s\"" file)
  1177. (+ (lsh (car (nth 5 attr)) 16)
  1178. (cadr (nth 5 attr))))))
  1179. (provide 'ox-publish)
  1180. ;; Local variables:
  1181. ;; generated-autoload-file: "org-loaddefs.el"
  1182. ;; End:
  1183. ;;; ox-publish.el ends here