org-protocol.el 28 KB

123456789101112131415161718192021222324252627282930313233343536373839404142434445464748495051525354555657585960616263646566676869707172737475767778798081828384858687888990919293949596979899100101102103104105106107108109110111112113114115116117118119120121122123124125126127128129130131132133134135136137138139140141142143144145146147148149150151152153154155156157158159160161162163164165166167168169170171172173174175176177178179180181182183184185186187188189190191192193194195196197198199200201202203204205206207208209210211212213214215216217218219220221222223224225226227228229230231232233234235236237238239240241242243244245246247248249250251252253254255256257258259260261262263264265266267268269270271272273274275276277278279280281282283284285286287288289290291292293294295296297298299300301302303304305306307308309310311312313314315316317318319320321322323324325326327328329330331332333334335336337338339340341342343344345346347348349350351352353354355356357358359360361362363364365366367368369370371372373374375376377378379380381382383384385386387388389390391392393394395396397398399400401402403404405406407408409410411412413414415416417418419420421422423424425426427428429430431432433434435436437438439440441442443444445446447448449450451452453454455456457458459460461462463464465466467468469470471472473474475476477478479480481482483484485486487488489490491492493494495496497498499500501502503504505506507508509510511512513514515516517518519520521522523524525526527528529530531532533534535536537538539540541542543544545546547548549550551552553554555556557558559560561562563564565566567568569570571572573574575576577578579580581582583584585586587588589590591592593594595596597598599600601602603604605606607608609610611612613614615616617618619620621622623624625626627628629630631632633634635636637638639640641642643644645646647648649650651652653654655656657658659660661662663664665666667668669670671672673674675676677678679680681682683684685686687688689690691692693694695696697698699700701702703704705706707708709710711712713714715716717718719720721722723724725726727728729730731
  1. ;;; org-protocol.el --- Intercept Calls from Emacsclient to Trigger Custom Actions -*- lexical-binding: t; -*-
  2. ;;
  3. ;; Copyright (C) 2008-2017 Free Software Foundation, Inc.
  4. ;;
  5. ;; Authors: Bastien Guerry <bzg@gnu.org>
  6. ;; Daniel M German <dmg AT uvic DOT org>
  7. ;; Sebastian Rose <sebastian_rose AT gmx DOT de>
  8. ;; Ross Patterson <me AT rpatterson DOT net>
  9. ;; Maintainer: Sebastian Rose <sebastian_rose AT gmx DOT de>
  10. ;; Keywords: org, emacsclient, wp
  11. ;; This file is part of GNU Emacs.
  12. ;;
  13. ;; GNU Emacs is free software: you can redistribute it and/or modify
  14. ;; it under the terms of the GNU General Public License as published by
  15. ;; the Free Software Foundation, either version 3 of the License, or
  16. ;; (at your option) any later version.
  17. ;; GNU Emacs is distributed in the hope that it will be useful,
  18. ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  19. ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  20. ;; GNU General Public License for more details.
  21. ;; You should have received a copy of the GNU General Public License
  22. ;; along with GNU Emacs. If not, see <https://www.gnu.org/licenses/>.
  23. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  24. ;;; Commentary:
  25. ;;
  26. ;; Intercept calls from emacsclient to trigger custom actions.
  27. ;;
  28. ;; This is done by advising `server-visit-files' to scan the list of filenames
  29. ;; for `org-protocol-the-protocol' and sub-protocols defined in
  30. ;; `org-protocol-protocol-alist' and `org-protocol-protocol-alist-default'.
  31. ;;
  32. ;; Any application that supports calling external programs with an URL
  33. ;; as argument may be used with this functionality.
  34. ;;
  35. ;;
  36. ;; Usage:
  37. ;; ------
  38. ;;
  39. ;; 1.) Add this to your init file (.emacs probably):
  40. ;;
  41. ;; (add-to-list 'load-path "/path/to/org-protocol/")
  42. ;; (require 'org-protocol)
  43. ;;
  44. ;; 3.) Ensure emacs-server is up and running.
  45. ;; 4.) Try this from the command line (adjust the URL as needed):
  46. ;;
  47. ;; $ emacsclient \
  48. ;; org-protocol://store-link?url=http:%2F%2Flocalhost%2Findex.html&title=The%20title
  49. ;;
  50. ;; 5.) Optionally add custom sub-protocols and handlers:
  51. ;;
  52. ;; (setq org-protocol-protocol-alist
  53. ;; '(("my-protocol"
  54. ;; :protocol "my-protocol"
  55. ;; :function my-protocol-handler-function)))
  56. ;;
  57. ;; A "sub-protocol" will be found in URLs like this:
  58. ;;
  59. ;; org-protocol://sub-protocol?key=val&key2=val2
  60. ;;
  61. ;; If it works, you can now setup other applications for using this feature.
  62. ;;
  63. ;;
  64. ;; As of March 2009 Firefox users follow the steps documented on
  65. ;; http://kb.mozillazine.org/Register_protocol, Opera setup is described here:
  66. ;; http://www.opera.com/support/kb/view/535/
  67. ;;
  68. ;;
  69. ;; Documentation
  70. ;; -------------
  71. ;;
  72. ;; org-protocol.el comes with and installs handlers to open sources of published
  73. ;; online content, store and insert the browser's URLs and cite online content
  74. ;; by clicking on a bookmark in Firefox, Opera and probably other browsers and
  75. ;; applications:
  76. ;;
  77. ;; * `org-protocol-open-source' uses the sub-protocol \"open-source\" and maps
  78. ;; URLs to local filenames defined in `org-protocol-project-alist'.
  79. ;;
  80. ;; * `org-protocol-store-link' stores an Org link (if Org is present) and
  81. ;; pushes the browsers URL to the `kill-ring' for yanking. This handler is
  82. ;; triggered through the sub-protocol \"store-link\".
  83. ;;
  84. ;; * Call `org-protocol-capture' by using the sub-protocol \"capture\". If
  85. ;; Org is loaded, Emacs will pop-up a capture buffer and fill the
  86. ;; template with the data provided. I.e. the browser's URL is inserted as an
  87. ;; Org-link of which the page title will be the description part. If text
  88. ;; was select in the browser, that text will be the body of the entry.
  89. ;;
  90. ;; You may use the same bookmark URL for all those standard handlers and just
  91. ;; adjust the sub-protocol used:
  92. ;;
  93. ;; location.href='org-protocol://sub-protocol?url='+
  94. ;; encodeURIComponent(location.href)+'&title='+
  95. ;; encodeURIComponent(document.title)+'&body='+
  96. ;; encodeURIComponent(window.getSelection())
  97. ;;
  98. ;; The handler for the sub-protocol \"capture\" detects an optional template
  99. ;; char that, if present, triggers the use of a special template.
  100. ;; Example:
  101. ;;
  102. ;; location.href='org-protocol://capture?template=x'+ ...
  103. ;;
  104. ;; uses template ?x.
  105. ;;
  106. ;; Note that using double slashes is optional from org-protocol.el's point of
  107. ;; view because emacsclient squashes the slashes to one.
  108. ;;
  109. ;;
  110. ;; provides: 'org-protocol
  111. ;;
  112. ;;; Code:
  113. (require 'org)
  114. (declare-function org-publish-get-project-from-filename "ox-publish"
  115. (filename &optional up))
  116. (declare-function server-edit "server" (&optional arg))
  117. (defvar org-capture-link-is-already-stored)
  118. (defgroup org-protocol nil
  119. "Intercept calls from emacsclient to trigger custom actions.
  120. This is done by advising `server-visit-files' to scan the list of filenames
  121. for `org-protocol-the-protocol' and sub-protocols defined in
  122. `org-protocol-protocol-alist' and `org-protocol-protocol-alist-default'."
  123. :version "22.1"
  124. :group 'convenience
  125. :group 'org)
  126. ;;; Variables:
  127. (defconst org-protocol-protocol-alist-default
  128. '(("org-capture" :protocol "capture" :function org-protocol-capture :kill-client t)
  129. ("org-store-link" :protocol "store-link" :function org-protocol-store-link)
  130. ("org-open-source" :protocol "open-source" :function org-protocol-open-source))
  131. "Default protocols to use.
  132. See `org-protocol-protocol-alist' for a description of this variable.")
  133. (defconst org-protocol-the-protocol "org-protocol"
  134. "This is the protocol to detect if org-protocol.el is loaded.
  135. `org-protocol-protocol-alist-default' and `org-protocol-protocol-alist' hold
  136. the sub-protocols that trigger the required action. You will have to define
  137. just one protocol handler OS-wide (MS-Windows) or per application (Linux).
  138. That protocol handler should call emacsclient.")
  139. ;;; User variables:
  140. (defcustom org-protocol-reverse-list-of-files t
  141. "Non-nil means re-reverse the list of filenames passed on the command line.
  142. The filenames passed on the command line are passed to the emacs-server in
  143. reverse order. Set to t (default) to re-reverse the list, i.e. use the
  144. sequence on the command line. If nil, the sequence of the filenames is
  145. unchanged."
  146. :group 'org-protocol
  147. :type 'boolean)
  148. (defcustom org-protocol-project-alist nil
  149. "Map URLs to local filenames for `org-protocol-open-source' (open-source).
  150. Each element of this list must be of the form:
  151. (module-name :property value property: value ...)
  152. where module-name is an arbitrary name. All the values are strings.
  153. Possible properties are:
  154. :online-suffix - the suffix to strip from the published URLs
  155. :working-suffix - the replacement for online-suffix
  156. :base-url - the base URL, e.g. http://www.example.com/project/
  157. Last slash required.
  158. :working-directory - the local working directory. This is, what base-url will
  159. be replaced with.
  160. :redirects - A list of cons cells, each of which maps a regular
  161. expression to match to a path relative to :working-directory.
  162. Example:
  163. (setq org-protocol-project-alist
  164. \\='((\"http://orgmode.org/worg/\"
  165. :online-suffix \".php\"
  166. :working-suffix \".org\"
  167. :base-url \"http://orgmode.org/worg/\"
  168. :working-directory \"/home/user/org/Worg/\")
  169. (\"http://localhost/org-notes/\"
  170. :online-suffix \".html\"
  171. :working-suffix \".org\"
  172. :base-url \"http://localhost/org/\"
  173. :working-directory \"/home/user/org/\"
  174. :rewrites ((\"org/?$\" . \"index.php\")))
  175. (\"Hugo based blog\"
  176. :base-url \"https://www.site.com/\"
  177. :working-directory \"~/site/content/post/\"
  178. :online-suffix \".html\"
  179. :working-suffix \".md\"
  180. :rewrites ((\"\\(https://site.com/[0-9]+/[0-9]+/[0-9]+/\\)\" . \".md\")))))
  181. The last line tells `org-protocol-open-source' to open
  182. /home/user/org/index.php, if the URL cannot be mapped to an existing
  183. file, and ends with either \"org\" or \"org/\".
  184. Consider using the interactive functions `org-protocol-create' and
  185. `org-protocol-create-for-org' to help you filling this variable with valid contents."
  186. :group 'org-protocol
  187. :type 'alist)
  188. (defcustom org-protocol-protocol-alist nil
  189. "Register custom handlers for org-protocol.
  190. Each element of this list must be of the form:
  191. (module-name :protocol protocol :function func :kill-client nil)
  192. protocol - protocol to detect in a filename without trailing
  193. colon and slashes. See rfc1738 section 2.1 for more
  194. on this. If you define a protocol \"my-protocol\",
  195. `org-protocol-check-filename-for-protocol' will search
  196. filenames for \"org-protocol:/my-protocol\" and
  197. trigger your action for every match. `org-protocol'
  198. is defined in `org-protocol-the-protocol'. Double and
  199. triple slashes are compressed to one by emacsclient.
  200. function - function that handles requests with protocol and takes
  201. one argument. If a new-style link (key=val&key2=val2)
  202. is given, the argument will be a property list with
  203. the values from the link. If an old-style link is
  204. given (val1/val2), the argument will be the filename
  205. with all protocols stripped.
  206. If the function returns nil, emacsclient and -server
  207. do nothing. Any non-nil return value is considered a
  208. valid filename and thus passed to the server.
  209. `org-protocol.el' provides some support for handling
  210. old-style filenames, if you follow the conventions
  211. used for the standard handlers in
  212. `org-protocol-protocol-alist-default'. See
  213. `org-protocol-parse-parameters'.
  214. kill-client - If t, kill the client immediately, once the sub-protocol is
  215. detected. This is necessary for actions that can be interrupted by
  216. `C-g' to avoid dangling emacsclients. Note that all other command
  217. line arguments but the this one will be discarded. Greedy handlers
  218. still receive the whole list of arguments though.
  219. Here is an example:
  220. (setq org-protocol-protocol-alist
  221. \\='((\"my-protocol\"
  222. :protocol \"my-protocol\"
  223. :function my-protocol-handler-function)
  224. (\"your-protocol\"
  225. :protocol \"your-protocol\"
  226. :function your-protocol-handler-function)))"
  227. :group 'org-protocol
  228. :type '(alist))
  229. (defcustom org-protocol-default-template-key nil
  230. "The default template key to use.
  231. This is usually a single character string but can also be a
  232. string with two characters."
  233. :group 'org-protocol
  234. :type '(choice (const nil) (string)))
  235. (defcustom org-protocol-data-separator "/+\\|\\?"
  236. "The default data separator to use.
  237. This should be a single regexp string."
  238. :group 'org-protocol
  239. :version "24.4"
  240. :package-version '(Org . "8.0")
  241. :type 'string)
  242. ;;; Helper functions:
  243. (defun org-protocol-sanitize-uri (uri)
  244. "Sanitize slashes to double-slashes in URI.
  245. Emacsclient compresses double and triple slashes."
  246. (when (string-match "^\\([a-z]+\\):/" uri)
  247. (let* ((splitparts (split-string uri "/+")))
  248. (setq uri (concat (car splitparts) "//" (mapconcat 'identity (cdr splitparts) "/")))))
  249. uri)
  250. (defun org-protocol-split-data (data &optional unhexify separator)
  251. "Split the DATA argument for an org-protocol handler function.
  252. If UNHEXIFY is non-nil, hex-decode each split part. If UNHEXIFY
  253. is a function, use that function to decode each split part. The
  254. string is split at each occurrence of SEPARATOR (regexp). If no
  255. SEPARATOR is specified or SEPARATOR is nil, assume \"/+\". The
  256. results of that splitting are returned as a list."
  257. (let* ((sep (or separator "/+\\|\\?"))
  258. (split-parts (split-string data sep)))
  259. (if unhexify
  260. (if (fboundp unhexify)
  261. (mapcar unhexify split-parts)
  262. (mapcar 'org-link-unescape split-parts))
  263. split-parts)))
  264. (defun org-protocol-flatten-greedy (param-list &optional strip-path replacement)
  265. "Transform PARAM-LIST into a flat list for greedy handlers.
  266. Greedy handlers might receive a list like this from emacsclient:
  267. \((\"/dir/org-protocol:/greedy:/~/path1\" (23 . 12)) (\"/dir/param\"))
  268. where \"/dir/\" is the absolute path to emacsclient's working directory. This
  269. function transforms it into a flat list using `org-protocol-flatten' and
  270. transforms the elements of that list as follows:
  271. If STRIP-PATH is non-nil, remove the \"/dir/\" prefix from all members of
  272. param-list.
  273. If REPLACEMENT is string, replace the \"/dir/\" prefix with it.
  274. The first parameter, the one that contains the protocols, is always changed.
  275. Everything up to the end of the protocols is stripped.
  276. Note, that this function will always behave as if
  277. `org-protocol-reverse-list-of-files' was set to t and the returned list will
  278. reflect that. emacsclient's first parameter will be the first one in the
  279. returned list."
  280. (let* ((l (org-protocol-flatten (if org-protocol-reverse-list-of-files
  281. param-list
  282. (reverse param-list))))
  283. (trigger (car l))
  284. (len 0)
  285. dir
  286. ret)
  287. (when (string-match "^\\(.*\\)\\(org-protocol:/+[a-zA-z0-9][-_a-zA-z0-9]*:/+\\)\\(.*\\)" trigger)
  288. (setq dir (match-string 1 trigger))
  289. (setq len (length dir))
  290. (setcar l (concat dir (match-string 3 trigger))))
  291. (if strip-path
  292. (progn
  293. (dolist (e l ret)
  294. (setq ret
  295. (append ret
  296. (list
  297. (if (stringp e)
  298. (if (stringp replacement)
  299. (setq e (concat replacement (substring e len)))
  300. (setq e (substring e len)))
  301. e)))))
  302. ret)
  303. l)))
  304. (defun org-protocol-flatten (list)
  305. "Transform LIST into a flat list.
  306. Greedy handlers might receive a list like this from emacsclient:
  307. \((\"/dir/org-protocol:/greedy:/~/path1\" (23 . 12)) (\"/dir/param\"))
  308. where \"/dir/\" is the absolute path to emacsclients working directory.
  309. This function transforms it into a flat list."
  310. (if (null list) ()
  311. (if (listp list)
  312. (append (org-protocol-flatten (car list)) (org-protocol-flatten (cdr list)))
  313. (list list))))
  314. (defun org-protocol-parse-parameters (info &optional new-style default-order)
  315. "Return a property list of parameters from INFO.
  316. If NEW-STYLE is non-nil, treat INFO as a query string (ex:
  317. url=URL&title=TITLE). If old-style links are used (ex:
  318. org-protocol://store-link/url/title), assign them to attributes
  319. following DEFAULT-ORDER.
  320. If no DEFAULT-ORDER is specified, return the list of values.
  321. If INFO is already a property list, return it unchanged."
  322. (if (listp info)
  323. info
  324. (if new-style
  325. (let ((data (org-protocol-convert-query-to-plist info))
  326. result)
  327. (while data
  328. (setq result
  329. (append
  330. result
  331. (list
  332. (pop data)
  333. (org-link-unescape (pop data))))))
  334. result)
  335. (let ((data (org-protocol-split-data info t org-protocol-data-separator)))
  336. (if default-order
  337. (org-protocol-assign-parameters data default-order)
  338. data)))))
  339. (defun org-protocol-assign-parameters (data default-order)
  340. "Return a property list of parameters from DATA.
  341. Key names are taken from DEFAULT-ORDER, which should be a list of
  342. symbols. If DEFAULT-ORDER is shorter than the number of values
  343. specified, the rest of the values are treated as :key value pairs."
  344. (let (result)
  345. (while default-order
  346. (setq result
  347. (append result
  348. (list (pop default-order)
  349. (pop data)))))
  350. (while data
  351. (setq result
  352. (append result
  353. (list (intern (concat ":" (pop data)))
  354. (pop data)))))
  355. result))
  356. ;;; Standard protocol handlers:
  357. (defun org-protocol-store-link (fname)
  358. "Process an org-protocol://store-link style url.
  359. Additionally store a browser URL as an org link. Also pushes the
  360. link's URL to the `kill-ring'.
  361. Parameters: url, title (optional), body (optional)
  362. Old-style links such as org-protocol://store-link://URL/TITLE are
  363. also recognized.
  364. The location for a browser's bookmark has to look like this:
  365. javascript:location.href = \\
  366. \\='org-protocol://store-link?url=\\=' + \\
  367. encodeURIComponent(location.href) + \\='&title=\\=' + \\
  368. encodeURIComponent(document.title);
  369. Don't use `escape()'! Use `encodeURIComponent()' instead. The
  370. title of the page could contain slashes and the location
  371. definitely will.
  372. The sub-protocol used to reach this function is set in
  373. `org-protocol-protocol-alist'.
  374. FNAME should be a property list. If not, an old-style link of the
  375. form URL/TITLE can also be used."
  376. (let* ((splitparts (org-protocol-parse-parameters fname nil '(:url :title)))
  377. (uri (org-protocol-sanitize-uri (plist-get splitparts :url)))
  378. (title (plist-get splitparts :title)))
  379. (when (boundp 'org-stored-links)
  380. (push (list uri title) org-stored-links))
  381. (kill-new uri)
  382. (message "`%s' to insert new org-link, `%s' to insert `%s'"
  383. (substitute-command-keys "`\\[org-insert-link]'")
  384. (substitute-command-keys "`\\[yank]'")
  385. uri))
  386. nil)
  387. (defun org-protocol-capture (info)
  388. "Process an org-protocol://capture style url with INFO.
  389. The sub-protocol used to reach this function is set in
  390. `org-protocol-protocol-alist'.
  391. This function detects an URL, title and optional text, separated
  392. by `/'. The location for a browser's bookmark looks like this:
  393. javascript:location.href = \\='org-protocol://capture?url=\\='+ \\
  394. encodeURIComponent(location.href) + \\='&title=\\=' \\
  395. encodeURIComponent(document.title) + \\='&body=\\=' + \\
  396. encodeURIComponent(window.getSelection())
  397. By default, it uses the character `org-protocol-default-template-key',
  398. which should be associated with a template in `org-capture-templates'.
  399. You may specify the template with a template= query parameter, like this:
  400. javascript:location.href = \\='org-protocol://capture?template=b\\='+ ...
  401. Now template ?b will be used."
  402. (if (and (boundp 'org-stored-links)
  403. (org-protocol-do-capture info))
  404. (message "Item captured."))
  405. nil)
  406. (defun org-protocol-convert-query-to-plist (query)
  407. "Convert QUERY key=value pairs in the URL to a property list."
  408. (if query
  409. (apply 'append (mapcar (lambda (x)
  410. (let ((c (split-string x "=")))
  411. (list (intern (concat ":" (car c))) (cadr c))))
  412. (split-string query "&")))))
  413. (defun org-protocol-do-capture (info)
  414. "Perform the actual capture based on INFO."
  415. (let* ((temp-parts (org-protocol-parse-parameters info))
  416. (parts
  417. (cond
  418. ((and (listp info) (symbolp (car info))) info)
  419. ((= (length (car temp-parts)) 1) ;; First parameter is exactly one character long
  420. (org-protocol-assign-parameters temp-parts '(:template :url :title :body)))
  421. (t
  422. (org-protocol-assign-parameters temp-parts '(:url :title :body)))))
  423. (template (or (plist-get parts :template)
  424. org-protocol-default-template-key))
  425. (url (and (plist-get parts :url) (org-protocol-sanitize-uri (plist-get parts :url))))
  426. (type (and url (if (string-match "^\\([a-z]+\\):" url)
  427. (match-string 1 url))))
  428. (title (or (plist-get parts :title) ""))
  429. (region (or (plist-get parts :body) ""))
  430. (orglink (if url
  431. (org-make-link-string
  432. url (if (string-match "[^[:space:]]" title) title url))
  433. title))
  434. (org-capture-link-is-already-stored t)) ;; avoid call to org-store-link
  435. (setq org-stored-links
  436. (cons (list url title) org-stored-links))
  437. (org-store-link-props :type type
  438. :link url
  439. :description title
  440. :annotation orglink
  441. :initial region
  442. :query parts)
  443. (raise-frame)
  444. (funcall 'org-capture nil template)))
  445. (defun org-protocol-open-source (fname)
  446. "Process an org-protocol://open-source?url= style URL with FNAME.
  447. Change a filename by mapping URLs to local filenames as set
  448. in `org-protocol-project-alist'.
  449. The location for a browser's bookmark should look like this:
  450. javascript:location.href = \\='org-protocol://open-source?url=\\=' + \\
  451. encodeURIComponent(location.href)"
  452. ;; As we enter this function for a match on our protocol, the return value
  453. ;; defaults to nil.
  454. (let ((result nil)
  455. (f (org-protocol-sanitize-uri
  456. (plist-get (org-protocol-parse-parameters fname nil '(:url))
  457. :url))))
  458. (catch 'result
  459. (dolist (prolist org-protocol-project-alist)
  460. (let* ((base-url (plist-get (cdr prolist) :base-url))
  461. (wsearch (regexp-quote base-url)))
  462. (when (string-match wsearch f)
  463. (let* ((wdir (plist-get (cdr prolist) :working-directory))
  464. (strip-suffix (plist-get (cdr prolist) :online-suffix))
  465. (add-suffix (plist-get (cdr prolist) :working-suffix))
  466. ;; Strip "[?#].*$" if `f' is a redirect with another
  467. ;; ending than strip-suffix here:
  468. (f1 (substring f 0 (string-match "\\([\\?#].*\\)?$" f)))
  469. (start-pos (+ (string-match wsearch f1) (length base-url)))
  470. (end-pos (string-match
  471. (regexp-quote strip-suffix) f1))
  472. ;; We have to compare redirects without suffix below:
  473. (f2 (concat wdir (substring f1 start-pos end-pos)))
  474. (the-file (concat f2 add-suffix)))
  475. ;; Note: the-file may still contain `%C3' et al here because browsers
  476. ;; tend to encode `&auml;' in URLs to `%25C3' - `%25' being `%'.
  477. ;; So the results may vary.
  478. ;; -- start redirects --
  479. (unless (file-exists-p the-file)
  480. (message "File %s does not exist.\nTesting for rewritten URLs." the-file)
  481. (let ((rewrites (plist-get (cdr prolist) :rewrites)))
  482. (when rewrites
  483. (message "Rewrites found: %S" rewrites)
  484. (dolist (rewrite rewrites)
  485. ;; Try to match a rewritten URL and map it to
  486. ;; a real file. Compare redirects without
  487. ;; suffix.
  488. (when (string-match (car rewrite) f1)
  489. (let ((replacement
  490. (concat (directory-file-name
  491. (replace-match "" nil nil f1 1))
  492. (cdr rewrite))))
  493. (throw 'result (concat wdir replacement))))))))
  494. ;; -- end of redirects --
  495. (if (file-readable-p the-file)
  496. (throw 'result the-file))
  497. (if (file-exists-p the-file)
  498. (message "%s: permission denied!" the-file)
  499. (message "%s: no such file or directory." the-file))))))
  500. result)))
  501. ;;; Core functions:
  502. (defun org-protocol-check-filename-for-protocol (fname restoffiles _client)
  503. "Check if `org-protocol-the-protocol' and a valid protocol are used in FNAME.
  504. Sub-protocols are registered in `org-protocol-protocol-alist' and
  505. `org-protocol-protocol-alist-default'. This is how the matching is done:
  506. (string-match \"protocol:/+sub-protocol\\\\(://\\\\|\\\\?\\\\)\" ...)
  507. protocol and sub-protocol are regexp-quoted.
  508. Old-style links such as \"protocol://sub-protocol://param1/param2\" are
  509. also recognized.
  510. If a matching protocol is found, the protocol is stripped from
  511. fname and the result is passed to the protocol function as the
  512. first parameter. The second parameter will be non-nil if FNAME
  513. uses key=val&key2=val2-type arguments, or nil if FNAME uses
  514. val/val2-type arguments. If the function returns nil, the
  515. filename is removed from the list of filenames passed from
  516. emacsclient to the server. If the function returns a non-nil
  517. value, that value is passed to the server as filename.
  518. If the handler function is greedy, RESTOFFILES will also be passed to it.
  519. CLIENT is ignored."
  520. (let ((sub-protocols (append org-protocol-protocol-alist
  521. org-protocol-protocol-alist-default)))
  522. (catch 'fname
  523. (let ((the-protocol (concat (regexp-quote org-protocol-the-protocol)
  524. ":/+")))
  525. (when (string-match the-protocol fname)
  526. (dolist (prolist sub-protocols)
  527. (let ((proto
  528. (concat the-protocol
  529. (regexp-quote (plist-get (cdr prolist) :protocol))
  530. "\\(:/+\\|\\?\\)")))
  531. (when (string-match proto fname)
  532. (let* ((func (plist-get (cdr prolist) :function))
  533. (greedy (plist-get (cdr prolist) :greedy))
  534. (split (split-string fname proto))
  535. (result (if greedy restoffiles (cadr split)))
  536. (new-style (string= (match-string 1 fname) "?")))
  537. (when (plist-get (cdr prolist) :kill-client)
  538. (message "Greedy org-protocol handler. Killing client.")
  539. (server-edit))
  540. (when (fboundp func)
  541. (unless greedy
  542. (throw 'fname
  543. (if new-style
  544. (funcall func (org-protocol-parse-parameters
  545. result new-style))
  546. (warn "Please update your Org Protocol handler \
  547. to deal with new-style links.")
  548. (funcall func result))))
  549. ;; Greedy protocol handlers are responsible for
  550. ;; parsing their own filenames.
  551. (funcall func result)
  552. (throw 'fname t))))))))
  553. fname)))
  554. (defadvice server-visit-files (before org-protocol-detect-protocol-server activate)
  555. "Advice server-visit-flist to call `org-protocol-modify-filename-for-protocol'."
  556. (let ((flist (if org-protocol-reverse-list-of-files
  557. (reverse (ad-get-arg 0))
  558. (ad-get-arg 0)))
  559. (client (ad-get-arg 1)))
  560. (catch 'greedy
  561. (dolist (var flist)
  562. ;; `\' to `/' on windows. FIXME: could this be done any better?
  563. (let ((fname (expand-file-name (car var))))
  564. (setq fname (org-protocol-check-filename-for-protocol
  565. fname (member var flist) client))
  566. (if (eq fname t) ;; greedy? We need the t return value.
  567. (progn
  568. (ad-set-arg 0 nil)
  569. (throw 'greedy t))
  570. (if (stringp fname) ;; probably filename
  571. (setcar var fname)
  572. (ad-set-arg 0 (delq var (ad-get-arg 0))))))))))
  573. ;;; Org specific functions:
  574. (defun org-protocol-create-for-org ()
  575. "Create a Org protocol project for the current file's project.
  576. The visited file needs to be part of a publishing project in
  577. `org-publish-project-alist' for this to work. The function
  578. delegates most of the work to `org-protocol-create'."
  579. (interactive)
  580. (require 'ox-publish)
  581. (let ((all (or (org-publish-get-project-from-filename buffer-file-name))))
  582. (if all (org-protocol-create (cdr all))
  583. (message "%s"
  584. (substitute-command-keys
  585. "Not in an Org project. \
  586. Did you mean `\\[org-protocol-create]'?")))))
  587. (defun org-protocol-create (&optional project-plist)
  588. "Create a new org-protocol project interactively.
  589. An org-protocol project is an entry in
  590. `org-protocol-project-alist' which is used by
  591. `org-protocol-open-source'. Optionally use PROJECT-PLIST to
  592. initialize the defaults for this project. If PROJECT-PLIST is
  593. the cdr of an element in `org-publish-project-alist', reuse
  594. :base-directory, :html-extension and :base-extension."
  595. (interactive)
  596. (let ((working-dir (expand-file-name
  597. (or (plist-get project-plist :base-directory)
  598. default-directory)))
  599. (base-url "http://orgmode.org/worg/")
  600. (strip-suffix (or (plist-get project-plist :html-extension) ".html"))
  601. (working-suffix (if (plist-get project-plist :base-extension)
  602. (concat "." (plist-get project-plist :base-extension))
  603. ".org"))
  604. (insert-default-directory t)
  605. (minibuffer-allow-text-properties nil))
  606. (setq base-url (read-string "Base URL of published content: " base-url nil base-url t))
  607. (or (string-suffix-p "/" base-url)
  608. (setq base-url (concat base-url "/")))
  609. (setq working-dir
  610. (expand-file-name
  611. (read-directory-name "Local working directory: " working-dir working-dir t)))
  612. (or (string-suffix-p "/" working-dir)
  613. (setq working-dir (concat working-dir "/")))
  614. (setq strip-suffix
  615. (read-string
  616. (concat "Extension to strip from published URLs (" strip-suffix "): ")
  617. strip-suffix nil strip-suffix t))
  618. (setq working-suffix
  619. (read-string
  620. (concat "Extension of editable files (" working-suffix "): ")
  621. working-suffix nil working-suffix t))
  622. (when (yes-or-no-p "Save the new org-protocol-project to your init file? ")
  623. (setq org-protocol-project-alist
  624. (cons `(,base-url . (:base-url ,base-url
  625. :working-directory ,working-dir
  626. :online-suffix ,strip-suffix
  627. :working-suffix ,working-suffix))
  628. org-protocol-project-alist))
  629. (customize-save-variable 'org-protocol-project-alist org-protocol-project-alist))))
  630. (provide 'org-protocol)
  631. ;;; org-protocol.el ends here