org-compat.el 35 KB

123456789101112131415161718192021222324252627282930313233343536373839404142434445464748495051525354555657585960616263646566676869707172737475767778798081828384858687888990919293949596979899100101102103104105106107108109110111112113114115116117118119120121122123124125126127128129130131132133134135136137138139140141142143144145146147148149150151152153154155156157158159160161162163164165166167168169170171172173174175176177178179180181182183184185186187188189190191192193194195196197198199200201202203204205206207208209210211212213214215216217218219220221222223224225226227228229230231232233234235236237238239240241242243244245246247248249250251252253254255256257258259260261262263264265266267268269270271272273274275276277278279280281282283284285286287288289290291292293294295296297298299300301302303304305306307308309310311312313314315316317318319320321322323324325326327328329330331332333334335336337338339340341342343344345346347348349350351352353354355356357358359360361362363364365366367368369370371372373374375376377378379380381382383384385386387388389390391392393394395396397398399400401402403404405406407408409410411412413414415416417418419420421422423424425426427428429430431432433434435436437438439440441442443444445446447448449450451452453454455456457458459460461462463464465466467468469470471472473474475476477478479480481482483484485486487488489490491492493494495496497498499500501502503504505506507508509510511512513514515516517518519520521522523524525526527528529530531532533534535536537538539540541542543544545546547548549550551552553554555556557558559560561562563564565566567568569570571572573574575576577578579580581582583584585586587588589590591592593594595596597598599600601602603604605606607608609610611612613614615616617618619620621622623624625626627628629630631632633634635636637638639640641642643644645646647648649650651652653654655656657658659660661662663664665666667668669670671672673674675676677678679680681682683684685686687688689690691692693694695696697698699700701702703704705706707708709710711712713714715716717718719720721722723724725726727728729730731732733734735736737738739740741742743744745746747748749750751752753754755756757758759760761762763764765766767768769770771772773774775776777778779780781782783784785786787788789790791792793794795796797798799800801802803804805806807808809810811812813814815816817818819820821822823824825826827828829830831832833834835836837838839840841842843844845846847848849850851852853854855856857858859860861862863864865866867868869870871872873874875876877878879880881882883884885886887
  1. ;;; org-compat.el --- Compatibility Code for Older Emacsen -*- lexical-binding: t; -*-
  2. ;; Copyright (C) 2004-2017 Free Software Foundation, Inc.
  3. ;; Author: Carsten Dominik <carsten at orgmode dot org>
  4. ;; Keywords: outlines, hypermedia, calendar, wp
  5. ;; Homepage: http://orgmode.org
  6. ;;
  7. ;; This file is part of GNU Emacs.
  8. ;;
  9. ;; GNU Emacs is free software: you can redistribute it and/or modify
  10. ;; it under the terms of the GNU General Public License as published by
  11. ;; the Free Software Foundation, either version 3 of the License, or
  12. ;; (at your option) any later version.
  13. ;; GNU Emacs is distributed in the hope that it will be useful,
  14. ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  15. ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  16. ;; GNU General Public License for more details.
  17. ;; You should have received a copy of the GNU General Public License
  18. ;; along with GNU Emacs. If not, see <https://www.gnu.org/licenses/>.
  19. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  20. ;;
  21. ;;; Commentary:
  22. ;; This file contains code needed for compatibility with older
  23. ;; versions of GNU Emacs.
  24. ;;; Code:
  25. (require 'cl-lib)
  26. (require 'org-macs)
  27. (declare-function org-agenda-maybe-redo "org-agenda" ())
  28. (declare-function org-at-heading-p "org" (&optional ignored))
  29. (declare-function org-at-table.el-p "org" (&optional table-type))
  30. (declare-function org-element-at-point "org-element" ())
  31. (declare-function org-element-context "org-element" (&optional element))
  32. (declare-function org-element-lineage "org-element" (blob &optional types with-self))
  33. (declare-function org-element-type "org-element" (element))
  34. (declare-function org-element-property "org-element" (property element))
  35. (declare-function org-end-of-subtree "org" (&optional invisible-ok to-heading))
  36. (declare-function org-invisible-p "org" (&optional pos))
  37. (declare-function org-link-display-format "org" (s))
  38. (declare-function org-link-set-parameters "org" (type &rest rest))
  39. (declare-function org-log-into-drawer "org" ())
  40. (declare-function org-reduced-level "org" (l))
  41. (declare-function org-show-context "org" (&optional key))
  42. (declare-function org-table-end (&optional table-type))
  43. (declare-function outline-next-heading "outline" ())
  44. (declare-function speedbar-line-directory "speedbar" (&optional depth))
  45. (declare-function table--at-cell-p "table" (position &optional object at-column))
  46. (defvar org-complex-heading-regexp)
  47. (defvar org-table-any-border-regexp)
  48. (defvar org-table-dataline-regexp)
  49. (defvar org-table-tab-recognizes-table.el)
  50. (defvar org-table1-hline-regexp)
  51. ;;; Emacs < 25.1 compatibility
  52. (when (< emacs-major-version 25)
  53. (defalias 'outline-hide-entry 'hide-entry)
  54. (defalias 'outline-hide-sublevels 'hide-sublevels)
  55. (defalias 'outline-hide-subtree 'hide-subtree)
  56. (defalias 'outline-show-all 'show-all)
  57. (defalias 'outline-show-branches 'show-branches)
  58. (defalias 'outline-show-children 'show-children)
  59. (defalias 'outline-show-entry 'show-entry)
  60. (defalias 'outline-show-subtree 'show-subtree)
  61. (defalias 'xref-find-definitions 'find-tag)
  62. (defalias 'format-message 'format)
  63. (defalias 'gui-get-selection 'x-get-selection))
  64. (defun org-decode-time (&optional time zone)
  65. "Backward-compatible function for `decode-time'."
  66. (if (< emacs-major-version 25)
  67. (decode-time time)
  68. (decode-time time zone)))
  69. (unless (fboundp 'directory-name-p)
  70. (defun directory-name-p (name)
  71. "Return non-nil if NAME ends with a directory separator character."
  72. (let ((len (length name))
  73. (lastc ?.))
  74. (if (> len 0)
  75. (setq lastc (aref name (1- len))))
  76. (or (= lastc ?/)
  77. (and (memq system-type '(windows-nt ms-dos))
  78. (= lastc ?\\))))))
  79. (unless (fboundp 'directory-files-recursively)
  80. (defun directory-files-recursively (dir regexp &optional include-directories)
  81. "Return list of all files under DIR that have file names matching REGEXP.
  82. This function works recursively. Files are returned in \"depth first\"
  83. order, and files from each directory are sorted in alphabetical order.
  84. Each file name appears in the returned list in its absolute form.
  85. Optional argument INCLUDE-DIRECTORIES non-nil means also include in the
  86. output directories whose names match REGEXP."
  87. (let ((result nil)
  88. (files nil)
  89. ;; When DIR is "/", remote file names like "/method:" could
  90. ;; also be offered. We shall suppress them.
  91. (tramp-mode (and tramp-mode (file-remote-p (expand-file-name dir)))))
  92. (dolist (file (sort (file-name-all-completions "" dir)
  93. 'string<))
  94. (unless (member file '("./" "../"))
  95. (if (directory-name-p file)
  96. (let* ((leaf (substring file 0 (1- (length file))))
  97. (full-file (expand-file-name leaf dir)))
  98. ;; Don't follow symlinks to other directories.
  99. (unless (file-symlink-p full-file)
  100. (setq result
  101. (nconc result (directory-files-recursively
  102. full-file regexp include-directories))))
  103. (when (and include-directories
  104. (string-match regexp leaf))
  105. (setq result (nconc result (list full-file)))))
  106. (when (string-match regexp file)
  107. (push (expand-file-name file dir) files)))))
  108. (nconc result (nreverse files)))))
  109. ;;; Obsolete aliases (remove them after the next major release).
  110. ;;;; XEmacs compatibility, now removed.
  111. (define-obsolete-function-alias 'org-activate-mark 'activate-mark)
  112. (define-obsolete-function-alias 'org-add-hook 'add-hook "Org 9.0")
  113. (define-obsolete-function-alias 'org-bound-and-true-p 'bound-and-true-p "Org 9.0")
  114. (define-obsolete-function-alias 'org-decompose-region 'decompose-region "Org 9.0")
  115. (define-obsolete-function-alias 'org-defvaralias 'defvaralias "Org 9.0")
  116. (define-obsolete-function-alias 'org-detach-overlay 'delete-overlay "Org 9.0")
  117. (define-obsolete-function-alias 'org-file-equal-p 'file-equal-p "Org 9.0")
  118. (define-obsolete-function-alias 'org-float-time 'float-time "Org 9.0")
  119. (define-obsolete-function-alias 'org-indent-line-to 'indent-line-to "Org 9.0")
  120. (define-obsolete-function-alias 'org-indent-to-column 'indent-to-column "Org 9.0")
  121. (define-obsolete-function-alias 'org-looking-at-p 'looking-at-p "Org 9.0")
  122. (define-obsolete-function-alias 'org-looking-back 'looking-back "Org 9.0")
  123. (define-obsolete-function-alias 'org-match-string-no-properties 'match-string-no-properties "Org 9.0")
  124. (define-obsolete-function-alias 'org-propertize 'propertize "Org 9.0")
  125. (define-obsolete-function-alias 'org-select-frame-set-input-focus 'select-frame-set-input-focus "Org 9.0")
  126. (defmacro org-re (s)
  127. "Replace posix classes in regular expression S."
  128. (declare (debug (form))
  129. (obsolete "you can safely remove it." "Org 9.0"))
  130. s)
  131. ;;;; Functions from cl-lib that Org used to have its own implementation of.
  132. (define-obsolete-function-alias 'org-count 'cl-count "Org 9.0")
  133. (define-obsolete-function-alias 'org-every 'cl-every "Org 9.0")
  134. (define-obsolete-function-alias 'org-find-if 'cl-find-if "Org 9.0")
  135. (define-obsolete-function-alias 'org-reduce 'cl-reduce "Org 9.0")
  136. (define-obsolete-function-alias 'org-remove-if 'cl-remove-if "Org 9.0")
  137. (define-obsolete-function-alias 'org-remove-if-not 'cl-remove-if-not "Org 9.0")
  138. (define-obsolete-function-alias 'org-some 'cl-some "Org 9.0")
  139. (define-obsolete-function-alias 'org-floor* 'cl-floor "Org 9.0")
  140. (defun org-sublist (list start end)
  141. "Return a section of LIST, from START to END.
  142. Counting starts at 1."
  143. (cl-subseq list (1- start) end))
  144. (make-obsolete 'org-sublist
  145. "use cl-subseq (note the 0-based counting)."
  146. "Org 9.0")
  147. ;;;; Functions available since Emacs 24.3
  148. (define-obsolete-function-alias 'org-buffer-narrowed-p 'buffer-narrowed-p "Org 9.0")
  149. (define-obsolete-function-alias 'org-called-interactively-p 'called-interactively-p "Org 9.0")
  150. (define-obsolete-function-alias 'org-char-to-string 'char-to-string "Org 9.0")
  151. (define-obsolete-function-alias 'org-delete-directory 'delete-directory "Org 9.0")
  152. (define-obsolete-function-alias 'org-format-seconds 'format-seconds "Org 9.0")
  153. (define-obsolete-function-alias 'org-link-escape-browser 'url-encode-url "Org 9.0")
  154. (define-obsolete-function-alias 'org-no-warnings 'with-no-warnings "Org 9.0")
  155. (define-obsolete-function-alias 'org-number-sequence 'number-sequence "Org 9.0")
  156. (define-obsolete-function-alias 'org-pop-to-buffer-same-window 'pop-to-buffer-same-window "Org 9.0")
  157. (define-obsolete-function-alias 'org-string-match-p 'string-match-p "Org 9.0")
  158. ;;;; Functions and variables from previous releases now obsolete.
  159. (define-obsolete-function-alias 'org-element-remove-indentation
  160. 'org-remove-indentation "Org 9.0")
  161. (define-obsolete-variable-alias 'org-latex-create-formula-image-program
  162. 'org-preview-latex-default-process "Org 9.0")
  163. (define-obsolete-variable-alias 'org-latex-preview-ltxpng-directory
  164. 'org-preview-latex-image-directory "Org 9.0")
  165. (define-obsolete-function-alias 'org-table-p 'org-at-table-p "Org 9.0")
  166. (define-obsolete-function-alias 'org-on-heading-p 'org-at-heading-p "Org 9.0")
  167. (define-obsolete-function-alias 'org-at-regexp-p 'org-in-regexp "Org 8.3")
  168. (define-obsolete-function-alias 'org-image-file-name-regexp
  169. 'image-file-name-regexp "Org 9.0")
  170. (define-obsolete-function-alias 'org-completing-read-no-i
  171. 'completing-read "Org 9.0")
  172. (define-obsolete-function-alias 'org-icompleting-read
  173. 'completing-read "Org 9.0")
  174. (define-obsolete-function-alias 'org-iread-file-name 'read-file-name "Org 9.0")
  175. (define-obsolete-function-alias 'org-days-to-time
  176. 'org-time-stamp-to-now "Org 8.2")
  177. (define-obsolete-variable-alias 'org-agenda-ignore-drawer-properties
  178. 'org-agenda-ignore-properties "Org 9.0")
  179. (define-obsolete-function-alias 'org-preview-latex-fragment
  180. 'org-toggle-latex-fragment "Org 8.3")
  181. (define-obsolete-function-alias 'org-export-get-genealogy
  182. 'org-element-lineage "Org 9.0")
  183. (define-obsolete-variable-alias 'org-latex-with-hyperref
  184. 'org-latex-hyperref-template "Org 9.0")
  185. (define-obsolete-variable-alias 'hfy-optimisations 'hfy-optimizations "Org 9.0")
  186. (define-obsolete-variable-alias 'org-export-htmlized-org-css-url
  187. 'org-org-htmlized-css-url "Org 8.2")
  188. (define-obsolete-function-alias 'org-list-parse-list 'org-list-to-lisp "Org 9.0")
  189. (define-obsolete-function-alias 'org-agenda-todayp
  190. 'org-agenda-today-p "Org 9.0")
  191. (define-obsolete-function-alias 'org-babel-examplize-region
  192. 'org-babel-examplify-region "Org 9.0")
  193. (define-obsolete-variable-alias 'org-babel-capitalize-example-region-markers
  194. 'org-babel-uppercase-example-markers "Org 9.1")
  195. (define-obsolete-function-alias 'org-babel-trim 'org-trim "Org 9.0")
  196. (define-obsolete-variable-alias 'org-html-style 'org-html-head "24.4")
  197. (define-obsolete-function-alias 'org-insert-columns-dblock
  198. 'org-columns-insert-dblock "Org 9.0")
  199. (define-obsolete-variable-alias 'org-export-babel-evaluate
  200. 'org-export-use-babel "Org 9.1")
  201. (define-obsolete-function-alias 'org-activate-bracket-links
  202. 'org-activate-links "Org 9.0")
  203. (define-obsolete-function-alias 'org-activate-plain-links 'ignore "Org 9.0")
  204. (define-obsolete-function-alias 'org-activate-angle-links 'ignore "Org 9.0")
  205. (defun org-in-fixed-width-region-p ()
  206. "Non-nil if point in a fixed-width region."
  207. (save-match-data
  208. (eq 'fixed-width (org-element-type (org-element-at-point)))))
  209. (make-obsolete 'org-in-fixed-width-region-p
  210. "use `org-element' library"
  211. "Org 9.0")
  212. (defun org-compatible-face (inherits specs)
  213. "Make a compatible face specification.
  214. If INHERITS is an existing face and if the Emacs version supports
  215. it, just inherit the face. If INHERITS is not given and SPECS
  216. is, use SPECS to define the face."
  217. (declare (indent 1))
  218. (if (facep inherits)
  219. (list (list t :inherit inherits))
  220. specs))
  221. (make-obsolete 'org-compatible-face "you can remove it." "Org 9.0")
  222. (defun org-add-link-type (type &optional follow export)
  223. "Add a new TYPE link.
  224. FOLLOW and EXPORT are two functions.
  225. FOLLOW should take the link path as the single argument and do whatever
  226. is necessary to follow the link, for example find a file or display
  227. a mail message.
  228. EXPORT should format the link path for export to one of the export formats.
  229. It should be a function accepting three arguments:
  230. path the path of the link, the text after the prefix (like \"http:\")
  231. desc the description of the link, if any
  232. format the export format, a symbol like `html' or `latex' or `ascii'.
  233. The function may use the FORMAT information to return different values
  234. depending on the format. The return value will be put literally into
  235. the exported file. If the return value is nil, this means Org should
  236. do what it normally does with links which do not have EXPORT defined.
  237. Org mode has a built-in default for exporting links. If you are happy with
  238. this default, there is no need to define an export function for the link
  239. type. For a simple example of an export function, see `org-bbdb.el'.
  240. If TYPE already exists, update it with the arguments.
  241. See `org-link-parameters' for documentation on the other parameters."
  242. (org-link-set-parameters type :follow follow :export export)
  243. (message "Created %s link." type))
  244. (make-obsolete 'org-add-link-type "use `org-link-set-parameters' instead." "Org 9.0")
  245. (defun org-table-recognize-table.el ()
  246. "If there is a table.el table nearby, recognize it and move into it."
  247. (when (and org-table-tab-recognizes-table.el (org-at-table.el-p))
  248. (beginning-of-line)
  249. (unless (or (looking-at org-table-dataline-regexp)
  250. (not (looking-at org-table1-hline-regexp)))
  251. (forward-line)
  252. (when (looking-at org-table-any-border-regexp)
  253. (forward-line -2)))
  254. (if (re-search-forward "|" (org-table-end t) t)
  255. (progn
  256. (require 'table)
  257. (if (table--at-cell-p (point)) t
  258. (message "recognizing table.el table...")
  259. (table-recognize-table)
  260. (message "recognizing table.el table...done")))
  261. (error "This should not happen"))))
  262. ;; Not used by Org core since commit 6d1e3082, Feb 2010.
  263. (make-obsolete 'org-table-recognize-table.el
  264. "please notify the org mailing list if you use this function."
  265. "Org 9.0")
  266. (defun org-remove-angle-brackets (s)
  267. (org-unbracket-string "<" ">" s))
  268. (make-obsolete 'org-remove-angle-brackets 'org-unbracket-string "Org 9.0")
  269. (defun org-remove-double-quotes (s)
  270. (org-unbracket-string "\"" "\"" s))
  271. (make-obsolete 'org-remove-double-quotes 'org-unbracket-string "Org 9.0")
  272. (defcustom org-publish-sitemap-file-entry-format "%t"
  273. "Format string for site-map file entry.
  274. You could use brackets to delimit on what part the link will be.
  275. %t is the title.
  276. %a is the author.
  277. %d is the date formatted using `org-publish-sitemap-date-format'."
  278. :group 'org-export-publish
  279. :type 'string)
  280. (make-obsolete-variable
  281. 'org-publish-sitemap-file-entry-format
  282. "set `:sitemap-format-entry' in `org-publish-project-alist' instead."
  283. "Org 9.1")
  284. (defvar org-agenda-skip-regexp)
  285. (defun org-agenda-skip-entry-when-regexp-matches ()
  286. "Check if the current entry contains match for `org-agenda-skip-regexp'.
  287. If yes, it returns the end position of this entry, causing agenda commands
  288. to skip the entry but continuing the search in the subtree. This is a
  289. function that can be put into `org-agenda-skip-function' for the duration
  290. of a command."
  291. (declare (obsolete "use `org-agenda-skip-if' instead." "Org 9.1"))
  292. (let ((end (save-excursion (org-end-of-subtree t)))
  293. skip)
  294. (save-excursion
  295. (setq skip (re-search-forward org-agenda-skip-regexp end t)))
  296. (and skip end)))
  297. (defun org-agenda-skip-subtree-when-regexp-matches ()
  298. "Check if the current subtree contains match for `org-agenda-skip-regexp'.
  299. If yes, it returns the end position of this tree, causing agenda commands
  300. to skip this subtree. This is a function that can be put into
  301. `org-agenda-skip-function' for the duration of a command."
  302. (declare (obsolete "use `org-agenda-skip-if' instead." "Org 9.1"))
  303. (let ((end (save-excursion (org-end-of-subtree t)))
  304. skip)
  305. (save-excursion
  306. (setq skip (re-search-forward org-agenda-skip-regexp end t)))
  307. (and skip end)))
  308. (defun org-agenda-skip-entry-when-regexp-matches-in-subtree ()
  309. "Check if the current subtree contains match for `org-agenda-skip-regexp'.
  310. If yes, it returns the end position of the current entry (NOT the tree),
  311. causing agenda commands to skip the entry but continuing the search in
  312. the subtree. This is a function that can be put into
  313. `org-agenda-skip-function' for the duration of a command. An important
  314. use of this function is for the stuck project list."
  315. (declare (obsolete "use `org-agenda-skip-if' instead." "Org 9.1"))
  316. (let ((end (save-excursion (org-end-of-subtree t)))
  317. (entry-end (save-excursion (outline-next-heading) (1- (point))))
  318. skip)
  319. (save-excursion
  320. (setq skip (re-search-forward org-agenda-skip-regexp end t)))
  321. (and skip entry-end)))
  322. (define-obsolete-function-alias 'org-minutes-to-clocksum-string
  323. 'org-duration-from-minutes "Org 9.1")
  324. (define-obsolete-function-alias 'org-hh:mm-string-to-minutes
  325. 'org-duration-to-minutes "Org 9.1")
  326. (define-obsolete-function-alias 'org-duration-string-to-minutes
  327. 'org-duration-to-minutes "Org 9.1")
  328. (make-obsolete-variable 'org-time-clocksum-format
  329. "set `org-duration-format' instead." "Org 9.1")
  330. (make-obsolete-variable 'org-time-clocksum-use-fractional
  331. "set `org-duration-format' instead." "Org 9.1")
  332. (make-obsolete-variable 'org-time-clocksum-fractional-format
  333. "set `org-duration-format' instead." "Org 9.1")
  334. (make-obsolete-variable 'org-time-clocksum-use-effort-durations
  335. "set `org-duration-units' instead." "Org 9.1")
  336. (define-obsolete-function-alias 'org-babel-number-p
  337. 'org-babel--string-to-number "Org 9.0")
  338. (define-obsolete-variable-alias 'org-usenet-links-prefer-google
  339. 'org-gnus-prefer-web-links "Org 9.1")
  340. (define-obsolete-variable-alias 'org-texinfo-def-table-markup
  341. 'org-texinfo-table-default-markup "Org 9.1")
  342. ;;; The function was made obsolete by commit 65399674d5 of 2013-02-22.
  343. ;;; This make-obsolete call was added 2016-09-01.
  344. (make-obsolete 'org-capture-import-remember-templates
  345. "use the `org-capture-templates' variable instead."
  346. "Org 9.0")
  347. ;;;; Obsolete link types
  348. (eval-after-load 'org
  349. '(progn
  350. (org-link-set-parameters "file+emacs") ;since Org 9.0
  351. (org-link-set-parameters "file+sys"))) ;since Org 9.0
  352. ;;; Miscellaneous functions
  353. (defun org-version-check (version feature level)
  354. (let* ((v1 (mapcar 'string-to-number (split-string version "[.]")))
  355. (v2 (mapcar 'string-to-number (split-string emacs-version "[.]")))
  356. (rmaj (or (nth 0 v1) 99))
  357. (rmin (or (nth 1 v1) 99))
  358. (rbld (or (nth 2 v1) 99))
  359. (maj (or (nth 0 v2) 0))
  360. (min (or (nth 1 v2) 0))
  361. (bld (or (nth 2 v2) 0)))
  362. (if (or (< maj rmaj)
  363. (and (= maj rmaj)
  364. (< min rmin))
  365. (and (= maj rmaj)
  366. (= min rmin)
  367. (< bld rbld)))
  368. (if (eq level :predicate)
  369. ;; just return if we have the version
  370. nil
  371. (let ((msg (format "Emacs %s or greater is recommended for %s"
  372. version feature)))
  373. (display-warning 'org msg level)
  374. t))
  375. t)))
  376. (defun org-get-x-clipboard (value)
  377. "Get the value of the X or Windows clipboard."
  378. (cond ((and (eq window-system 'x)
  379. (fboundp 'gui-get-selection)) ;Silence byte-compiler.
  380. (org-no-properties
  381. (ignore-errors
  382. (or (gui-get-selection value 'UTF8_STRING)
  383. (gui-get-selection value 'COMPOUND_TEXT)
  384. (gui-get-selection value 'STRING)
  385. (gui-get-selection value 'TEXT)))))
  386. ((and (eq window-system 'w32) (fboundp 'w32-get-clipboard-data))
  387. (w32-get-clipboard-data))))
  388. (defun org-fit-window-to-buffer (&optional window max-height min-height
  389. shrink-only)
  390. "Fit WINDOW to the buffer, but only if it is not a side-by-side window.
  391. WINDOW defaults to the selected window. MAX-HEIGHT and MIN-HEIGHT are
  392. passed through to `fit-window-to-buffer'. If SHRINK-ONLY is set, call
  393. `shrink-window-if-larger-than-buffer' instead, the height limit is
  394. ignored in this case."
  395. (cond ((if (fboundp 'window-full-width-p)
  396. (not (window-full-width-p window))
  397. ;; do nothing if another window would suffer
  398. (> (frame-width) (window-width window))))
  399. ((and (fboundp 'fit-window-to-buffer) (not shrink-only))
  400. (fit-window-to-buffer window max-height min-height))
  401. ((fboundp 'shrink-window-if-larger-than-buffer)
  402. (shrink-window-if-larger-than-buffer window)))
  403. (or window (selected-window)))
  404. ;; `set-transient-map' is only in Emacs >= 24.4
  405. (defalias 'org-set-transient-map
  406. (if (fboundp 'set-transient-map)
  407. 'set-transient-map
  408. 'set-temporary-overlay-map))
  409. ;;; Region compatibility
  410. (defvar org-ignore-region nil
  411. "Non-nil means temporarily disable the active region.")
  412. (defun org-region-active-p ()
  413. "Non-nil when the region active.
  414. Unlike to `use-region-p', this function also checks
  415. `org-ignore-region'."
  416. (and (not org-ignore-region) (use-region-p)))
  417. (defun org-cursor-to-region-beginning ()
  418. (when (and (org-region-active-p)
  419. (> (point) (region-beginning)))
  420. (exchange-point-and-mark)))
  421. ;;; Invisibility compatibility
  422. (defun org-remove-from-invisibility-spec (arg)
  423. "Remove elements from `buffer-invisibility-spec'."
  424. (if (fboundp 'remove-from-invisibility-spec)
  425. (remove-from-invisibility-spec arg)
  426. (if (consp buffer-invisibility-spec)
  427. (setq buffer-invisibility-spec
  428. (delete arg buffer-invisibility-spec)))))
  429. (defun org-in-invisibility-spec-p (arg)
  430. "Is ARG a member of `buffer-invisibility-spec'?"
  431. (if (consp buffer-invisibility-spec)
  432. (member arg buffer-invisibility-spec)))
  433. (defun org-move-to-column (column &optional force _buffer)
  434. "Move to column COLUMN.
  435. Pass COLUMN and FORCE to `move-to-column'."
  436. (let ((buffer-invisibility-spec
  437. (if (listp buffer-invisibility-spec)
  438. (remove '(org-filtered) buffer-invisibility-spec)
  439. buffer-invisibility-spec)))
  440. (move-to-column column force)))
  441. (defmacro org-find-library-dir (library)
  442. `(file-name-directory (or (locate-library ,library) "")))
  443. (defun org-count-lines (s)
  444. "How many lines in string S?"
  445. (let ((start 0) (n 1))
  446. (while (string-match "\n" s start)
  447. (setq start (match-end 0) n (1+ n)))
  448. (if (and (> (length s) 0) (= (aref s (1- (length s))) ?\n))
  449. (setq n (1- n)))
  450. n))
  451. (defun org-kill-new (string &rest args)
  452. (remove-text-properties 0 (length string) '(line-prefix t wrap-prefix t)
  453. string)
  454. (apply 'kill-new string args))
  455. ;; `font-lock-ensure' is only available from 24.4.50 on
  456. (defalias 'org-font-lock-ensure
  457. (if (fboundp 'font-lock-ensure)
  458. #'font-lock-ensure
  459. (lambda (&optional _beg _end)
  460. (with-no-warnings (font-lock-fontify-buffer)))))
  461. ;; `file-local-name' was added in Emacs 26.1.
  462. (defalias 'org-babel-local-file-name
  463. (if (fboundp 'file-local-name)
  464. 'file-local-name
  465. (lambda (file)
  466. "Return the local name component of FILE."
  467. (or (file-remote-p file 'localname) file))))
  468. (defmacro org-no-popups (&rest body)
  469. "Suppress popup windows.
  470. Let-bind some variables to nil around BODY to achieve the desired
  471. effect, which variables to use depends on the Emacs version."
  472. (if (org-version-check "24.2.50" "" :predicate)
  473. `(let (pop-up-frames display-buffer-alist)
  474. ,@body)
  475. `(let (pop-up-frames special-display-buffer-names special-display-regexps special-display-function)
  476. ,@body)))
  477. ;;;###autoload
  478. (defmacro org-check-version ()
  479. "Try very hard to provide sensible version strings."
  480. (let* ((org-dir (org-find-library-dir "org"))
  481. (org-version.el (concat org-dir "org-version.el"))
  482. (org-fixup.el (concat org-dir "../mk/org-fixup.el")))
  483. (if (require 'org-version org-version.el 'noerror)
  484. '(progn
  485. (autoload 'org-release "org-version.el")
  486. (autoload 'org-git-version "org-version.el"))
  487. (if (require 'org-fixup org-fixup.el 'noerror)
  488. '(org-fixup)
  489. ;; provide fallback definitions and complain
  490. (warn "Could not define org version correctly. Check installation!")
  491. '(progn
  492. (defun org-release () "N/A")
  493. (defun org-git-version () "N/A !!check installation!!"))))))
  494. (defmacro org-with-silent-modifications (&rest body)
  495. (if (fboundp 'with-silent-modifications)
  496. `(with-silent-modifications ,@body)
  497. `(org-unmodified ,@body)))
  498. (def-edebug-spec org-with-silent-modifications (body))
  499. ;;; Functions for Emacs < 24.4 compatibility
  500. (defun org-define-error (name message)
  501. "Define NAME as a new error signal.
  502. MESSAGE is a string that will be output to the echo area if such
  503. an error is signaled without being caught by a `condition-case'.
  504. Implements `define-error' for older emacsen."
  505. (if (fboundp 'define-error) (define-error name message)
  506. (put name 'error-conditions
  507. (copy-sequence (cons name (get 'error 'error-conditions))))))
  508. (unless (fboundp 'string-suffix-p)
  509. ;; From Emacs subr.el.
  510. (defun string-suffix-p (suffix string &optional ignore-case)
  511. "Return non-nil if SUFFIX is a suffix of STRING.
  512. If IGNORE-CASE is non-nil, the comparison is done without paying
  513. attention to case differences."
  514. (let ((start-pos (- (length string) (length suffix))))
  515. (and (>= start-pos 0)
  516. (eq t (compare-strings suffix nil nil
  517. string start-pos nil ignore-case))))))
  518. ;;; Integration with and fixes for other packages
  519. (defgroup org-imenu-and-speedbar nil
  520. "Options concerning imenu and speedbar in Org mode."
  521. :tag "Org Imenu and Speedbar"
  522. :group 'org-structure)
  523. (defcustom org-imenu-depth 2
  524. "The maximum level for Imenu access to Org headlines.
  525. This also applied for speedbar access."
  526. :group 'org-imenu-and-speedbar
  527. :type 'integer)
  528. ;;;; Imenu
  529. (defvar-local org-imenu-markers nil
  530. "All markers currently used by Imenu.")
  531. (defun org-imenu-new-marker (&optional pos)
  532. "Return a new marker for use by Imenu, and remember the marker."
  533. (let ((m (make-marker)))
  534. (move-marker m (or pos (point)))
  535. (push m org-imenu-markers)
  536. m))
  537. (defun org-imenu-get-tree ()
  538. "Produce the index for Imenu."
  539. (dolist (x org-imenu-markers) (move-marker x nil))
  540. (setq org-imenu-markers nil)
  541. (let* ((case-fold-search nil)
  542. (n org-imenu-depth)
  543. (re (concat "^" (org-get-limited-outline-regexp)))
  544. (subs (make-vector (1+ n) nil))
  545. (last-level 0)
  546. m level head0 head)
  547. (org-with-wide-buffer
  548. (goto-char (point-max))
  549. (while (re-search-backward re nil t)
  550. (setq level (org-reduced-level (funcall outline-level)))
  551. (when (and (<= level n)
  552. (looking-at org-complex-heading-regexp)
  553. (setq head0 (match-string-no-properties 4)))
  554. (setq head (org-link-display-format head0)
  555. m (org-imenu-new-marker))
  556. (org-add-props head nil 'org-imenu-marker m 'org-imenu t)
  557. (if (>= level last-level)
  558. (push (cons head m) (aref subs level))
  559. (push (cons head (aref subs (1+ level))) (aref subs level))
  560. (cl-loop for i from (1+ level) to n do (aset subs i nil)))
  561. (setq last-level level))))
  562. (aref subs 1)))
  563. (eval-after-load "imenu"
  564. '(progn
  565. (add-hook 'imenu-after-jump-hook
  566. (lambda ()
  567. (when (derived-mode-p 'org-mode)
  568. (org-show-context 'org-goto))))))
  569. ;;;; Speedbar
  570. (defvar org-speedbar-restriction-lock-overlay (make-overlay 1 1)
  571. "Overlay marking the agenda restriction line in speedbar.")
  572. (overlay-put org-speedbar-restriction-lock-overlay
  573. 'face 'org-agenda-restriction-lock)
  574. (overlay-put org-speedbar-restriction-lock-overlay
  575. 'help-echo "Agendas are currently limited to this item.")
  576. (delete-overlay org-speedbar-restriction-lock-overlay)
  577. (defun org-speedbar-set-agenda-restriction ()
  578. "Restrict future agenda commands to the location at point in speedbar.
  579. To get rid of the restriction, use `\\[org-agenda-remove-restriction-lock]'."
  580. (interactive)
  581. (require 'org-agenda)
  582. (let (p m tp np dir txt)
  583. (cond
  584. ((setq p (text-property-any (point-at-bol) (point-at-eol)
  585. 'org-imenu t))
  586. (setq m (get-text-property p 'org-imenu-marker))
  587. (with-current-buffer (marker-buffer m)
  588. (goto-char m)
  589. (org-agenda-set-restriction-lock 'subtree)))
  590. ((setq p (text-property-any (point-at-bol) (point-at-eol)
  591. 'speedbar-function 'speedbar-find-file))
  592. (setq tp (previous-single-property-change
  593. (1+ p) 'speedbar-function)
  594. np (next-single-property-change
  595. tp 'speedbar-function)
  596. dir (speedbar-line-directory)
  597. txt (buffer-substring-no-properties (or tp (point-min))
  598. (or np (point-max))))
  599. (with-current-buffer (find-file-noselect
  600. (let ((default-directory dir))
  601. (expand-file-name txt)))
  602. (unless (derived-mode-p 'org-mode)
  603. (user-error "Cannot restrict to non-Org mode file"))
  604. (org-agenda-set-restriction-lock 'file)))
  605. (t (user-error "Don't know how to restrict Org mode agenda")))
  606. (move-overlay org-speedbar-restriction-lock-overlay
  607. (point-at-bol) (point-at-eol))
  608. (setq current-prefix-arg nil)
  609. (org-agenda-maybe-redo)))
  610. (defvar speedbar-file-key-map)
  611. (declare-function speedbar-add-supported-extension "speedbar" (extension))
  612. (eval-after-load "speedbar"
  613. '(progn
  614. (speedbar-add-supported-extension ".org")
  615. (define-key speedbar-file-key-map "<" 'org-speedbar-set-agenda-restriction)
  616. (define-key speedbar-file-key-map "\C-c\C-x<" 'org-speedbar-set-agenda-restriction)
  617. (define-key speedbar-file-key-map ">" 'org-agenda-remove-restriction-lock)
  618. (define-key speedbar-file-key-map "\C-c\C-x>" 'org-agenda-remove-restriction-lock)
  619. (add-hook 'speedbar-visiting-tag-hook
  620. (lambda () (and (derived-mode-p 'org-mode) (org-show-context 'org-goto))))))
  621. ;;;; Flyspell
  622. (defun org--flyspell-object-check-p (element)
  623. "Non-nil when Flyspell can check object at point.
  624. ELEMENT is the element at point."
  625. (let ((object (save-excursion
  626. (when (looking-at-p "\\>") (backward-char))
  627. (org-element-context element))))
  628. (cl-case (org-element-type object)
  629. ;; Prevent checks in links due to keybinding conflict with
  630. ;; Flyspell.
  631. ((code entity export-snippet inline-babel-call
  632. inline-src-block line-break latex-fragment link macro
  633. statistics-cookie target timestamp verbatim)
  634. nil)
  635. (footnote-reference
  636. ;; Only in inline footnotes, within the definition.
  637. (and (eq (org-element-property :type object) 'inline)
  638. (< (save-excursion
  639. (goto-char (org-element-property :begin object))
  640. (search-forward ":" nil t 2))
  641. (point))))
  642. (otherwise t))))
  643. (defun org-mode-flyspell-verify ()
  644. "Function used for `flyspell-generic-check-word-predicate'."
  645. (if (org-at-heading-p)
  646. ;; At a headline or an inlinetask, check title only. This is
  647. ;; faster than relying on `org-element-at-point'.
  648. (and (save-excursion (beginning-of-line)
  649. (and (let ((case-fold-search t))
  650. (not (looking-at-p "\\*+ END[ \t]*$")))
  651. (let ((case-fold-search nil))
  652. (looking-at org-complex-heading-regexp))))
  653. (match-beginning 4)
  654. (>= (point) (match-beginning 4))
  655. (or (not (match-beginning 5))
  656. (< (point) (match-beginning 5))))
  657. (let* ((element (org-element-at-point))
  658. (post-affiliated (org-element-property :post-affiliated element)))
  659. (cond
  660. ;; Ignore checks in all affiliated keywords but captions.
  661. ((< (point) post-affiliated)
  662. (and (save-excursion
  663. (beginning-of-line)
  664. (let ((case-fold-search t)) (looking-at "[ \t]*#\\+CAPTION:")))
  665. (> (point) (match-end 0))
  666. (org--flyspell-object-check-p element)))
  667. ;; Ignore checks in LOGBOOK (or equivalent) drawer.
  668. ((let ((log (org-log-into-drawer)))
  669. (and log
  670. (let ((drawer (org-element-lineage element '(drawer))))
  671. (and drawer
  672. (eq (compare-strings
  673. log nil nil
  674. (org-element-property :drawer-name drawer) nil nil t)
  675. t)))))
  676. nil)
  677. (t
  678. (cl-case (org-element-type element)
  679. ((comment quote-section) t)
  680. (comment-block
  681. ;; Allow checks between block markers, not on them.
  682. (and (> (line-beginning-position) post-affiliated)
  683. (save-excursion
  684. (end-of-line)
  685. (skip-chars-forward " \r\t\n")
  686. (< (point) (org-element-property :end element)))))
  687. ;; Arbitrary list of keywords where checks are meaningful.
  688. ;; Make sure point is on the value part of the element.
  689. (keyword
  690. (and (member (org-element-property :key element)
  691. '("DESCRIPTION" "TITLE"))
  692. (save-excursion
  693. (search-backward ":" (line-beginning-position) t))))
  694. ;; Check is globally allowed in paragraphs verse blocks and
  695. ;; table rows (after affiliated keywords) but some objects
  696. ;; must not be affected.
  697. ((paragraph table-row verse-block)
  698. (let ((cbeg (org-element-property :contents-begin element))
  699. (cend (org-element-property :contents-end element)))
  700. (and cbeg (>= (point) cbeg) (< (point) cend)
  701. (org--flyspell-object-check-p element))))))))))
  702. (put 'org-mode 'flyspell-mode-predicate 'org-mode-flyspell-verify)
  703. (defun org-remove-flyspell-overlays-in (beg end)
  704. "Remove flyspell overlays in region."
  705. (and (bound-and-true-p flyspell-mode)
  706. (fboundp 'flyspell-delete-region-overlays)
  707. (flyspell-delete-region-overlays beg end)))
  708. (defvar flyspell-delayed-commands)
  709. (eval-after-load "flyspell"
  710. '(add-to-list 'flyspell-delayed-commands 'org-self-insert-command))
  711. ;;;; Bookmark
  712. (defun org-bookmark-jump-unhide ()
  713. "Unhide the current position, to show the bookmark location."
  714. (and (derived-mode-p 'org-mode)
  715. (or (org-invisible-p)
  716. (save-excursion (goto-char (max (point-min) (1- (point))))
  717. (org-invisible-p)))
  718. (org-show-context 'bookmark-jump)))
  719. ;; Make `bookmark-jump' shows the jump location if it was hidden.
  720. (eval-after-load "bookmark"
  721. '(if (boundp 'bookmark-after-jump-hook)
  722. ;; We can use the hook
  723. (add-hook 'bookmark-after-jump-hook 'org-bookmark-jump-unhide)
  724. ;; Hook not available, use advice
  725. (defadvice bookmark-jump (after org-make-visible activate)
  726. "Make the position visible."
  727. (org-bookmark-jump-unhide))))
  728. ;;;; Saveplace
  729. ;; Make sure saveplace shows the location if it was hidden
  730. (eval-after-load "saveplace"
  731. '(defadvice save-place-find-file-hook (after org-make-visible activate)
  732. "Make the position visible."
  733. (org-bookmark-jump-unhide)))
  734. ;;;; Ecb
  735. ;; Make sure ecb shows the location if it was hidden
  736. (eval-after-load "ecb"
  737. '(defadvice ecb-method-clicked (after esf/org-show-context activate)
  738. "Make hierarchy visible when jumping into location from ECB tree buffer."
  739. (when (derived-mode-p 'org-mode)
  740. (org-show-context))))
  741. ;;;; Simple
  742. (defun org-mark-jump-unhide ()
  743. "Make the point visible with `org-show-context' after jumping to the mark."
  744. (when (and (derived-mode-p 'org-mode)
  745. (org-invisible-p))
  746. (org-show-context 'mark-goto)))
  747. (eval-after-load "simple"
  748. '(defadvice pop-to-mark-command (after org-make-visible activate)
  749. "Make the point visible with `org-show-context'."
  750. (org-mark-jump-unhide)))
  751. (eval-after-load "simple"
  752. '(defadvice exchange-point-and-mark (after org-make-visible activate)
  753. "Make the point visible with `org-show-context'."
  754. (org-mark-jump-unhide)))
  755. (eval-after-load "simple"
  756. '(defadvice pop-global-mark (after org-make-visible activate)
  757. "Make the point visible with `org-show-context'."
  758. (org-mark-jump-unhide)))
  759. ;;;; Session
  760. ;; Make "session.el" ignore our circular variable.
  761. (defvar session-globals-exclude)
  762. (eval-after-load "session"
  763. '(add-to-list 'session-globals-exclude 'org-mark-ring))
  764. (provide 'org-compat)
  765. ;;; org-compat.el ends here