org-inlinetask.el 13 KB

123456789101112131415161718192021222324252627282930313233343536373839404142434445464748495051525354555657585960616263646566676869707172737475767778798081828384858687888990919293949596979899100101102103104105106107108109110111112113114115116117118119120121122123124125126127128129130131132133134135136137138139140141142143144145146147148149150151152153154155156157158159160161162163164165166167168169170171172173174175176177178179180181182183184185186187188189190191192193194195196197198199200201202203204205206207208209210211212213214215216217218219220221222223224225226227228229230231232233234235236237238239240241242243244245246247248249250251252253254255256257258259260261262263264265266267268269270271272273274275276277278279280281282283284285286287288289290291292293294295296297298299300301302303304305306307308309310311312313314315316317318319320321322323324325326327328329330331332333334335336337338339340341342343344345346347348349350351352353354355356
  1. ;;; org-inlinetask.el --- Tasks Independent of Outline Hierarchy -*- lexical-binding: t; -*-
  2. ;; Copyright (C) 2009-2017 Free Software Foundation, Inc.
  3. ;;
  4. ;; Author: Carsten Dominik <carsten at orgmode dot org>
  5. ;; Keywords: outlines, hypermedia, calendar, wp
  6. ;; Homepage: http://orgmode.org
  7. ;; This file is part of GNU Emacs.
  8. ;; GNU Emacs is free software: you can redistribute it and/or modify
  9. ;; it under the terms of the GNU General Public License as published by
  10. ;; the Free Software Foundation, either version 3 of the License, or
  11. ;; (at your option) any later version.
  12. ;; GNU Emacs is distributed in the hope that it will be useful,
  13. ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  14. ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  15. ;; GNU General Public License for more details.
  16. ;; You should have received a copy of the GNU General Public License
  17. ;; along with GNU Emacs. If not, see <https://www.gnu.org/licenses/>.
  18. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  19. ;;
  20. ;;; Commentary:
  21. ;;
  22. ;; This module implements inline tasks in Org mode. Inline tasks are
  23. ;; tasks that have all the properties of normal outline nodes,
  24. ;; including the ability to store meta data like scheduling dates,
  25. ;; TODO state, tags and properties. However, these nodes are treated
  26. ;; specially by the visibility cycling.
  27. ;;
  28. ;; Visibility cycling exempts these nodes from cycling. So whenever
  29. ;; their parent is opened, so are these tasks. This will only work
  30. ;; with `org-cycle', so if you are also using other commands to
  31. ;; show/hide entries, you will occasionally find these tasks to behave
  32. ;; like all other outline nodes, seemingly splitting the text of the
  33. ;; parent into children.
  34. ;;
  35. ;; Special fontification of inline tasks, so that they can be
  36. ;; immediately recognized. From the stars of the headline, only the
  37. ;; first and the last two will be visible, the others will be hidden
  38. ;; using the `org-hide' face.
  39. ;;
  40. ;; An inline task is identified solely by a minimum outline level,
  41. ;; given by the variable `org-inlinetask-min-level', default 15.
  42. ;;
  43. ;; If you need to have a time planning line (DEADLINE etc), drawers,
  44. ;; for example LOGBOOK of PROPERTIES, or even normal text as part of
  45. ;; the inline task, you must add an "END" headline with the same
  46. ;; number of stars.
  47. ;;
  48. ;; As an example, here are two valid inline tasks:
  49. ;;
  50. ;; **************** TODO a small task
  51. ;;
  52. ;; and
  53. ;;
  54. ;; **************** TODO another small task
  55. ;; DEADLINE: <2009-03-30 Mon>
  56. ;; :PROPERTIES:
  57. ;; :SOMETHING: or other
  58. ;; :END:
  59. ;; And here is some extra text
  60. ;; **************** END
  61. ;;
  62. ;; Also, if you want to use refiling and archiving for inline tasks,
  63. ;; The END line must be present to make things work properly.
  64. ;;
  65. ;; Note that you should not try to use inline tasks within plain list,
  66. ;; visibility cycling is known to be problematic when doing so.
  67. ;;
  68. ;; This package installs one new command:
  69. ;;
  70. ;; C-c C-x t Insert a new inline task with END line
  71. ;;; Code:
  72. (require 'org)
  73. (defgroup org-inlinetask nil
  74. "Options concerning inline tasks in Org mode."
  75. :tag "Org Inline Tasks"
  76. :group 'org-structure)
  77. (defcustom org-inlinetask-min-level 15
  78. "Minimum level a headline must have before it is treated as an inline task.
  79. Don't set it to something higher than `29' or clocking will break since this
  80. is the hardcoded maximum number of stars `org-clock-sum' will work with.
  81. It is strongly recommended that you set `org-cycle-max-level' not at all,
  82. or to a number smaller than this one. In fact, when `org-cycle-max-level' is
  83. not set, it will be assumed to be one less than the value of smaller than
  84. the value of this variable."
  85. :group 'org-inlinetask
  86. :type '(choice
  87. (const :tag "Off" nil)
  88. (integer)))
  89. (defcustom org-inlinetask-show-first-star nil
  90. "Non-nil means display the first star of an inline task as additional marker.
  91. When nil, the first star is not shown."
  92. :tag "Org Inline Tasks"
  93. :group 'org-structure
  94. :type 'boolean)
  95. (defvar org-odd-levels-only)
  96. (defvar org-keyword-time-regexp)
  97. (defvar org-complex-heading-regexp)
  98. (defvar org-property-end-re)
  99. (defcustom org-inlinetask-default-state nil
  100. "Non-nil means make inline tasks have a TODO keyword initially.
  101. This should be the state `org-inlinetask-insert-task' should use by
  102. default, or nil of no state should be assigned."
  103. :group 'org-inlinetask
  104. :version "24.1"
  105. :type '(choice
  106. (const :tag "No state" nil)
  107. (string :tag "Specific state")))
  108. (defun org-inlinetask-insert-task (&optional no-state)
  109. "Insert an inline task.
  110. If prefix arg NO-STATE is set, ignore `org-inlinetask-default-state'.
  111. If there is a region wrap it inside the inline task."
  112. (interactive "P")
  113. ;; Error when inside an inline task, except if point was at its very
  114. ;; beginning, in which case the new inline task will be inserted
  115. ;; before this one.
  116. (when (and (org-inlinetask-in-task-p)
  117. (not (and (org-inlinetask-at-task-p) (bolp))))
  118. (error "Cannot nest inline tasks"))
  119. (or (bolp) (newline))
  120. (let* ((indent (if org-odd-levels-only
  121. (1- (* 2 org-inlinetask-min-level))
  122. org-inlinetask-min-level))
  123. (indent-string (concat (make-string indent ?*) " "))
  124. (rbeg (if (org-region-active-p) (region-beginning) (point)))
  125. (rend (if (org-region-active-p) (region-end) (point))))
  126. (goto-char rend)
  127. (insert "\n" indent-string "END\n")
  128. (goto-char rbeg)
  129. (unless (bolp) (insert "\n"))
  130. (insert indent-string
  131. (if (or no-state (not org-inlinetask-default-state))
  132. ""
  133. (concat org-inlinetask-default-state " "))
  134. (if (= rend rbeg) "" "\n"))
  135. (unless (= rend rbeg) (end-of-line 0))))
  136. (define-key org-mode-map "\C-c\C-xt" 'org-inlinetask-insert-task)
  137. (defun org-inlinetask-outline-regexp ()
  138. "Return string matching an inline task heading.
  139. The number of levels is controlled by `org-inlinetask-min-level'."
  140. (let ((nstars (if org-odd-levels-only
  141. (1- (* org-inlinetask-min-level 2))
  142. org-inlinetask-min-level)))
  143. (format "^\\(\\*\\{%d,\\}\\)[ \t]+" nstars)))
  144. (defun org-inlinetask-at-task-p ()
  145. "Return true if point is at beginning of an inline task."
  146. (save-excursion
  147. (beginning-of-line)
  148. (and (looking-at (concat (org-inlinetask-outline-regexp) "\\(.*\\)"))
  149. (not (string-match "^end[ \t]*$" (downcase (match-string 2)))))))
  150. (defun org-inlinetask-in-task-p ()
  151. "Return true if point is inside an inline task."
  152. (save-excursion
  153. (beginning-of-line)
  154. (let* ((case-fold-search t)
  155. (stars-re (org-inlinetask-outline-regexp))
  156. (task-beg-re (concat stars-re "\\(?:.*\\)"))
  157. (task-end-re (concat stars-re "END[ \t]*$")))
  158. (or (looking-at-p task-beg-re)
  159. (and (re-search-forward "^\\*+[ \t]+" nil t)
  160. (progn (beginning-of-line) (looking-at-p task-end-re)))))))
  161. (defun org-inlinetask-goto-beginning ()
  162. "Go to the beginning of the inline task at point."
  163. (end-of-line)
  164. (let ((case-fold-search t)
  165. (inlinetask-re (org-inlinetask-outline-regexp)))
  166. (re-search-backward inlinetask-re nil t)
  167. (when (looking-at-p (concat inlinetask-re "END[ \t]*$"))
  168. (re-search-backward inlinetask-re nil t))))
  169. (defun org-inlinetask-goto-end ()
  170. "Go to the end of the inline task at point.
  171. Return point."
  172. (save-match-data
  173. (beginning-of-line)
  174. (let* ((case-fold-search t)
  175. (inlinetask-re (org-inlinetask-outline-regexp))
  176. (task-end-re (concat inlinetask-re "END[ \t]*$")))
  177. (cond
  178. ((looking-at task-end-re))
  179. ((looking-at inlinetask-re)
  180. (forward-line)
  181. (cond
  182. ((looking-at task-end-re))
  183. ((looking-at inlinetask-re))
  184. ((org-inlinetask-in-task-p)
  185. (re-search-forward inlinetask-re nil t))))
  186. (t (re-search-forward inlinetask-re nil t)))
  187. (end-of-line)
  188. (point))))
  189. (defun org-inlinetask-get-task-level ()
  190. "Get the level of the inline task around.
  191. This assumes the point is inside an inline task."
  192. (save-excursion
  193. (end-of-line)
  194. (re-search-backward (org-inlinetask-outline-regexp) nil t)
  195. (- (match-end 1) (match-beginning 1))))
  196. (defun org-inlinetask-promote ()
  197. "Promote the inline task at point.
  198. If the task has an end part, promote it. Also, prevents level from
  199. going below `org-inlinetask-min-level'."
  200. (interactive)
  201. (if (not (org-inlinetask-in-task-p))
  202. (error "Not in an inline task")
  203. (save-excursion
  204. (let* ((lvl (org-inlinetask-get-task-level))
  205. (next-lvl (org-get-valid-level lvl -1))
  206. (diff (- next-lvl lvl))
  207. (down-task (concat (make-string next-lvl ?*)))
  208. beg)
  209. (if (< next-lvl org-inlinetask-min-level)
  210. (error "Cannot promote an inline task at minimum level")
  211. (org-inlinetask-goto-beginning)
  212. (setq beg (point))
  213. (replace-match down-task nil t nil 1)
  214. (org-inlinetask-goto-end)
  215. (if (eobp) (beginning-of-line) (forward-line -1))
  216. (unless (= (point) beg)
  217. (replace-match down-task nil t nil 1)
  218. (when org-adapt-indentation
  219. (goto-char beg)
  220. (org-fixup-indentation diff))))))))
  221. (defun org-inlinetask-demote ()
  222. "Demote the inline task at point.
  223. If the task has an end part, also demote it."
  224. (interactive)
  225. (if (not (org-inlinetask-in-task-p))
  226. (error "Not in an inline task")
  227. (save-excursion
  228. (let* ((lvl (org-inlinetask-get-task-level))
  229. (next-lvl (org-get-valid-level lvl 1))
  230. (diff (- next-lvl lvl))
  231. (down-task (concat (make-string next-lvl ?*)))
  232. beg)
  233. (org-inlinetask-goto-beginning)
  234. (setq beg (point))
  235. (replace-match down-task nil t nil 1)
  236. (org-inlinetask-goto-end)
  237. (if (eobp) (beginning-of-line) (forward-line -1))
  238. (unless (= (point) beg)
  239. (replace-match down-task nil t nil 1)
  240. (when org-adapt-indentation
  241. (goto-char beg)
  242. (org-fixup-indentation diff)))))))
  243. (defun org-inlinetask-get-current-indentation ()
  244. "Get the indentation of the last non-while line above this one."
  245. (save-excursion
  246. (beginning-of-line 1)
  247. (skip-chars-backward " \t\n")
  248. (beginning-of-line 1)
  249. (or (org-at-item-p)
  250. (looking-at "[ \t]*"))
  251. (goto-char (match-end 0))
  252. (current-column)))
  253. (defvar org-indent-indentation-per-level) ; defined in org-indent.el
  254. (defface org-inlinetask '((t :inherit shadow))
  255. "Face for inlinetask headlines."
  256. :group 'org-faces)
  257. (defun org-inlinetask-fontify (limit)
  258. "Fontify the inline tasks down to LIMIT."
  259. (let* ((nstars (if org-odd-levels-only
  260. (1- (* 2 (or org-inlinetask-min-level 200)))
  261. (or org-inlinetask-min-level 200)))
  262. (re (concat "^\\(\\*\\)\\(\\*\\{"
  263. (format "%d" (- nstars 3))
  264. ",\\}\\)\\(\\*\\* .*\\)"))
  265. ;; Virtual indentation will add the warning face on the first
  266. ;; star. Thus, in that case, only hide it.
  267. (start-face (if (and (bound-and-true-p org-indent-mode)
  268. (> org-indent-indentation-per-level 1))
  269. 'org-hide
  270. 'org-warning)))
  271. (while (re-search-forward re limit t)
  272. (if org-inlinetask-show-first-star
  273. (add-text-properties (match-beginning 1) (match-end 1)
  274. `(face ,start-face font-lock-fontified t)))
  275. (add-text-properties (match-beginning
  276. (if org-inlinetask-show-first-star 2 1))
  277. (match-end 2)
  278. '(face org-hide font-lock-fontified t))
  279. (add-text-properties (match-beginning 3) (match-end 3)
  280. '(face org-inlinetask font-lock-fontified t)))))
  281. (defun org-inlinetask-toggle-visibility ()
  282. "Toggle visibility of inline task at point."
  283. (let ((end (save-excursion
  284. (org-inlinetask-goto-end)
  285. (if (bolp) (1- (point)) (point))))
  286. (start (save-excursion
  287. (org-inlinetask-goto-beginning)
  288. (point-at-eol))))
  289. (cond
  290. ;; Nothing to show/hide.
  291. ((= end start))
  292. ;; Inlinetask was folded: expand it.
  293. ((eq (get-char-property (1+ start) 'invisible) 'outline)
  294. (outline-flag-region start end nil)
  295. (org-cycle-hide-drawers 'children))
  296. (t (outline-flag-region start end t)))))
  297. (defun org-inlinetask-hide-tasks (state)
  298. "Hide inline tasks in buffer when STATE is `contents' or `children'.
  299. This function is meant to be used in `org-cycle-hook'."
  300. (pcase state
  301. (`contents
  302. (let ((regexp (org-inlinetask-outline-regexp)))
  303. (save-excursion
  304. (goto-char (point-min))
  305. (while (re-search-forward regexp nil t)
  306. (org-inlinetask-toggle-visibility)
  307. (org-inlinetask-goto-end)))))
  308. (`children
  309. (save-excursion
  310. (while (and (outline-next-heading) (org-inlinetask-at-task-p))
  311. (org-inlinetask-toggle-visibility)
  312. (org-inlinetask-goto-end))))))
  313. (defun org-inlinetask-remove-END-maybe ()
  314. "Remove an END line when present."
  315. (when (looking-at (format "\\([ \t]*\n\\)*\\*\\{%d,\\}[ \t]+END[ \t]*$"
  316. org-inlinetask-min-level))
  317. (replace-match "")))
  318. (add-hook 'org-font-lock-hook 'org-inlinetask-fontify)
  319. (add-hook 'org-cycle-hook 'org-inlinetask-hide-tasks)
  320. (provide 'org-inlinetask)
  321. ;;; org-inlinetask.el ends here