org-footnote.el 35 KB

123456789101112131415161718192021222324252627282930313233343536373839404142434445464748495051525354555657585960616263646566676869707172737475767778798081828384858687888990919293949596979899100101102103104105106107108109110111112113114115116117118119120121122123124125126127128129130131132133134135136137138139140141142143144145146147148149150151152153154155156157158159160161162163164165166167168169170171172173174175176177178179180181182183184185186187188189190191192193194195196197198199200201202203204205206207208209210211212213214215216217218219220221222223224225226227228229230231232233234235236237238239240241242243244245246247248249250251252253254255256257258259260261262263264265266267268269270271272273274275276277278279280281282283284285286287288289290291292293294295296297298299300301302303304305306307308309310311312313314315316317318319320321322323324325326327328329330331332333334335336337338339340341342343344345346347348349350351352353354355356357358359360361362363364365366367368369370371372373374375376377378379380381382383384385386387388389390391392393394395396397398399400401402403404405406407408409410411412413414415416417418419420421422423424425426427428429430431432433434435436437438439440441442443444445446447448449450451452453454455456457458459460461462463464465466467468469470471472473474475476477478479480481482483484485486487488489490491492493494495496497498499500501502503504505506507508509510511512513514515516517518519520521522523524525526527528529530531532533534535536537538539540541542543544545546547548549550551552553554555556557558559560561562563564565566567568569570571572573574575576577578579580581582583584585586587588589590591592593594595596597598599600601602603604605606607608609610611612613614615616617618619620621622623624625626627628629630631632633634635636637638639640641642643644645646647648649650651652653654655656657658659660661662663664665666667668669670671672673674675676677678679680681682683684685686687688689690691692693694695696697698699700701702703704705706707708709710711712713714715716717718719720721722723724725726727728729730731732733734735736737738739740741742743744745746747748749750751752753754755756757758759760761762763764765766767768769770771772773774775776777778779780781782783784785786787788789790791792793794795796797798799800801802803804805806807808809810811812813814815816817818819820821822823824825826827828829830831832833834835836837838839840841842843844845846847848849850851852853854855856857858859860861862863864865866867868869870871872873874875876877878879880881882883884885886887888889890891892893894895896897898899900901902903904905906907908909910911912913914915916917918919920921922923
  1. ;;; org-footnote.el --- Footnote support in Org and elsewhere
  2. ;;
  3. ;; Copyright (C) 2009-2011 Free Software Foundation, Inc.
  4. ;;
  5. ;; Author: Carsten Dominik <carsten at orgmode dot org>
  6. ;; Keywords: outlines, hypermedia, calendar, wp
  7. ;; Homepage: http://orgmode.org
  8. ;;
  9. ;; This file is part of GNU Emacs.
  10. ;;
  11. ;; GNU Emacs is free software: you can redistribute it and/or modify
  12. ;; it under the terms of the GNU General Public License as published by
  13. ;; the Free Software Foundation, either version 3 of the License, or
  14. ;; (at your option) any later version.
  15. ;; GNU Emacs is distributed in the hope that it will be useful,
  16. ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17. ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  18. ;; GNU General Public License for more details.
  19. ;; You should have received a copy of the GNU General Public License
  20. ;; along with GNU Emacs. If not, see <http://www.gnu.org/licenses/>.
  21. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  22. ;;
  23. ;;; Commentary:
  24. ;; This file contains the code dealing with footnotes in Org-mode.
  25. ;; The code can also be used in arbitrary text modes to provide
  26. ;; footnotes. Compared to Steven L Baur's footnote.el it provides
  27. ;; better support for resuming editing. It is less configurable than
  28. ;; Steve's code, though.
  29. ;;; Code:
  30. (eval-when-compile
  31. (require 'cl))
  32. (require 'org-macs)
  33. (require 'org-compat)
  34. (declare-function message-point-in-header-p "message" ())
  35. (declare-function org-back-over-empty-lines "org" ())
  36. (declare-function org-back-to-heading "org" (&optional invisible-ok))
  37. (declare-function org-combine-plists "org" (&rest plists))
  38. (declare-function org-end-of-subtree "org" (&optional invisible-ok to-heading))
  39. (declare-function org-export-preprocess-string "org-exp"
  40. (string &rest parameters))
  41. (declare-function org-fill-paragraph "org" (&optional justify))
  42. (declare-function org-icompleting-read "org" (&rest args))
  43. (declare-function org-id-uuid "org-id" ())
  44. (declare-function org-in-block-p "org" (names))
  45. (declare-function org-in-commented-line "org" ())
  46. (declare-function org-in-indented-comment-line "org" ())
  47. (declare-function org-in-regexp "org" (re &optional nlines visually))
  48. (declare-function org-in-verbatim-emphasis "org" ())
  49. (declare-function org-inside-LaTeX-fragment-p "org" ())
  50. (declare-function org-inside-latex-macro-p "org" ())
  51. (declare-function org-mark-ring-push "org" (&optional pos buffer))
  52. (declare-function org-show-context "org" (&optional key))
  53. (declare-function org-trim "org" (s))
  54. (declare-function outline-next-heading "outline")
  55. (defvar org-outline-regexp-bol) ; defined in org.el
  56. (defvar org-odd-levels-only) ; defined in org.el
  57. (defvar org-bracket-link-regexp) ; defined in org.el
  58. (defvar message-cite-prefix-regexp) ; defined in message.el
  59. (defvar message-signature-separator) ; defined in message.el
  60. (defconst org-footnote-re
  61. ;; Only [1]-like footnotes are closed in this regexp, as footnotes
  62. ;; from other types might contain square brackets (i.e. links) in
  63. ;; their definition.
  64. ;;
  65. ;; `org-re' is used for regexp compatibility with XEmacs.
  66. (concat "\\[\\(?:"
  67. ;; Match inline footnotes.
  68. (org-re "fn:\\([-_[:word:]]+\\)?:\\|")
  69. ;; Match other footnotes.
  70. "\\(?:\\([0-9]+\\)\\]\\)\\|"
  71. (org-re "\\(fn:[-_[:word:]]+\\)")
  72. "\\)")
  73. "Regular expression for matching footnotes.")
  74. (defconst org-footnote-definition-re
  75. (org-re "^\\[\\([0-9]+\\|fn:[-_[:word:]]+\\)\\]")
  76. "Regular expression matching the definition of a footnote.")
  77. (defvar org-footnote-forbidden-blocks '("example" "verse" "src" "ascii" "beamer"
  78. "docbook" "html" "latex" "odt")
  79. "Names of blocks where footnotes are not allowed.")
  80. (defgroup org-footnote nil
  81. "Footnotes in Org-mode."
  82. :tag "Org Footnote"
  83. :group 'org)
  84. (defcustom org-footnote-section "Footnotes"
  85. "Outline heading containing footnote definitions before export.
  86. This can be nil, to place footnotes locally at the end of the current
  87. outline node. If can also be the name of a special outline heading
  88. under which footnotes should be put.
  89. This variable defines the place where Org puts the definition
  90. automatically, i.e. when creating the footnote, and when sorting the notes.
  91. However, by hand you may place definitions *anywhere*.
  92. If this is a string, during export, all subtrees starting with this
  93. heading will be removed after extracting footnote definitions."
  94. :group 'org-footnote
  95. :type '(choice
  96. (string :tag "Collect footnotes under heading")
  97. (const :tag "Define footnotes locally" nil)))
  98. (defcustom org-footnote-tag-for-non-org-mode-files "Footnotes:"
  99. "Tag marking the beginning of footnote section.
  100. The Org footnote engine can be used in arbitrary text files as well
  101. as in Org-mode. Outside Org mode, new footnotes are always placed at
  102. the end of the file. When you normalize the notes, any line containing
  103. only this tag will be removed, a new one will be inserted at the end
  104. of the file, followed by the collected and normalized footnotes.
  105. If you don't want any tag in such buffers, set this variable to nil."
  106. :group 'org-footnote
  107. :type '(choice
  108. (string :tag "Collect footnotes under tag")
  109. (const :tag "Don't use a tag" nil)))
  110. (defcustom org-footnote-define-inline nil
  111. "Non-nil means define footnotes inline, at reference location.
  112. When nil, footnotes will be defined in a special section near
  113. the end of the document. When t, the [fn:label:definition] notation
  114. will be used to define the footnote at the reference position."
  115. :group 'org-footnote
  116. :type 'boolean)
  117. (defcustom org-footnote-auto-label t
  118. "Non-nil means define automatically new labels for footnotes.
  119. Possible values are:
  120. nil prompt the user for each label
  121. t create unique labels of the form [fn:1], [fn:2], ...
  122. confirm like t, but let the user edit the created value. In particular,
  123. the label can be removed from the minibuffer, to create
  124. an anonymous footnote.
  125. random Automatically generate a unique, random label.
  126. plain Automatically create plain number labels like [1]"
  127. :group 'org-footnote
  128. :type '(choice
  129. (const :tag "Prompt for label" nil)
  130. (const :tag "Create automatic [fn:N]" t)
  131. (const :tag "Offer automatic [fn:N] for editing" confirm)
  132. (const :tag "Create a random label" random)
  133. (const :tag "Create automatic [N]" plain)))
  134. (defcustom org-footnote-auto-adjust nil
  135. "Non-nil means automatically adjust footnotes after insert/delete.
  136. When this is t, after each insertion or deletion of a footnote,
  137. simple fn:N footnotes will be renumbered, and all footnotes will be sorted.
  138. If you want to have just sorting or just renumbering, set this variable
  139. to `sort' or `renumber'.
  140. The main values of this variable can be set with in-buffer options:
  141. #+STARTUP: fnadjust
  142. #+STARTUP: nofnadjust"
  143. :group 'org-footnote
  144. :type '(choice
  145. (const :tag "Renumber" renumber)
  146. (const :tag "Sort" sort)
  147. (const :tag "Renumber and Sort" t)))
  148. (defcustom org-footnote-fill-after-inline-note-extraction nil
  149. "Non-nil means fill paragraphs after extracting footnotes.
  150. When extracting inline footnotes, the lengths of lines can change a lot.
  151. When this option is set, paragraphs from which an inline footnote has been
  152. extracted will be filled again."
  153. :group 'org-footnote
  154. :type 'boolean)
  155. (defun org-footnote-in-valid-context-p ()
  156. "Is point in a context where footnotes are allowed?"
  157. (save-match-data
  158. (not (or (org-in-commented-line)
  159. (org-in-indented-comment-line)
  160. (org-inside-LaTeX-fragment-p)
  161. ;; Avoid protected environments (LaTeX export)
  162. (get-text-property (point) 'org-protected)
  163. ;; Avoid literal example.
  164. (org-in-verbatim-emphasis)
  165. (save-excursion
  166. (beginning-of-line)
  167. (looking-at "[ \t]*:[ \t]+"))
  168. ;; Avoid cited text and headers in message-mode.
  169. (and (derived-mode-p 'message-mode)
  170. (or (save-excursion
  171. (beginning-of-line)
  172. (looking-at message-cite-prefix-regexp))
  173. (message-point-in-header-p)))
  174. ;; Avoid forbidden blocks.
  175. (org-in-block-p org-footnote-forbidden-blocks)))))
  176. (defun org-footnote-at-reference-p ()
  177. "Is the cursor at a footnote reference?
  178. If so, return a list containing its label, beginning and ending
  179. positions, and the definition, when inlined."
  180. (when (and (org-footnote-in-valid-context-p)
  181. (or (looking-at org-footnote-re)
  182. (org-in-regexp org-footnote-re)
  183. (save-excursion (re-search-backward org-footnote-re nil t)))
  184. ;; Only inline footnotes can start at bol.
  185. (or (eq (char-before (match-end 0)) 58)
  186. (/= (match-beginning 0) (point-at-bol))))
  187. (let* ((beg (match-beginning 0))
  188. (label (or (match-string 2) (match-string 3)
  189. ;; Anonymous footnotes don't have labels
  190. (and (match-string 1) (concat "fn:" (match-string 1)))))
  191. ;; Inline footnotes don't end at (match-end 0) as
  192. ;; `org-footnote-re' stops just after the second colon.
  193. ;; Find the real ending with `scan-sexps', so Org doesn't
  194. ;; get fooled by unrelated closing square brackets.
  195. (end (ignore-errors (scan-sexps beg 1))))
  196. ;; Point is really at a reference if it's located before true
  197. ;; ending of the footnote.
  198. (when (and end (< (point) end)
  199. ;; Verify match isn't a part of a link.
  200. (not (save-excursion
  201. (goto-char beg)
  202. (let ((linkp
  203. (save-match-data
  204. (org-in-regexp org-bracket-link-regexp))))
  205. (and linkp (< (point) (cdr linkp))))))
  206. ;; Verify point doesn't belong to a LaTeX macro.
  207. ;; Beware though, when two footnotes are side by
  208. ;; side, once the first one is changed into LaTeX,
  209. ;; the second one might then be considered as an
  210. ;; optional argument of the command. Thus, check
  211. ;; the `org-protected' property of that command.
  212. (or (not (org-inside-latex-macro-p))
  213. (get-text-property (1- beg) 'org-protected)))
  214. (list label beg end
  215. ;; Definition: ensure this is an inline footnote first.
  216. (and (or (not label) (match-string 1))
  217. (org-trim (buffer-substring (match-end 0) (1- end)))))))))
  218. (defun org-footnote-at-definition-p ()
  219. "Is the cursor at a footnote definition?
  220. This matches only pure definitions like [1] or [fn:name] at the beginning
  221. of a line. It does not match references like [fn:name:definition], where the
  222. footnote text is included and defined locally.
  223. The return value will be nil if not at a footnote definition, and a list with
  224. label, start, end and definition of the footnote otherwise."
  225. (when (save-excursion (beginning-of-line) (org-footnote-in-valid-context-p))
  226. (save-excursion
  227. (end-of-line)
  228. (let ((lim (save-excursion (re-search-backward
  229. (concat org-outline-regexp-bol
  230. "\\|^[ \t]*$") nil t))))
  231. (when (re-search-backward org-footnote-definition-re lim t)
  232. (end-of-line)
  233. (list (match-string 1)
  234. (match-beginning 0)
  235. (save-match-data
  236. ;; In a message, limit search to signature.
  237. (let ((bound (and (derived-mode-p 'message-mode)
  238. (save-excursion
  239. (goto-char (point-max))
  240. (re-search-backward
  241. message-signature-separator nil t)))))
  242. (or (and (re-search-forward
  243. (concat org-outline-regexp-bol "\\|"
  244. org-footnote-definition-re "\\|"
  245. "^[ \t]*$")
  246. bound 'move)
  247. (progn (skip-chars-forward " \t\n") (point-at-bol)))
  248. (point))))
  249. (org-trim (buffer-substring (match-end 0) (point)))))))))
  250. (defun org-footnote-get-next-reference (&optional label backward limit)
  251. "Return complete reference of the next footnote.
  252. If LABEL is provided, get the next reference of that footnote. If
  253. BACKWARD is non-nil, find previous reference instead. LIMIT is
  254. the buffer position bounding the search.
  255. Return value is a list like those provided by `org-footnote-at-reference-p'.
  256. If no footnote is found, return nil."
  257. (save-excursion
  258. (let* ((label-fmt (if label (format "\\[%s[]:]" label) org-footnote-re)))
  259. (catch 'exit
  260. (while t
  261. (unless (funcall (if backward #'re-search-backward #'re-search-forward)
  262. label-fmt limit t)
  263. (throw 'exit nil))
  264. (unless backward (backward-char))
  265. (let ((ref (org-footnote-at-reference-p)))
  266. (when ref (throw 'exit ref))))))))
  267. (defun org-footnote-next-reference-or-definition (limit)
  268. "Move point to next footnote reference or definition.
  269. LIMIT is the buffer position bounding the search.
  270. Return value is a list like those provided by
  271. `org-footnote-at-reference-p' or `org-footnote-at-definition-p'.
  272. If no footnote is found, return nil."
  273. (let* (ref (origin (point)))
  274. (catch 'exit
  275. (while t
  276. (unless (re-search-forward org-footnote-re limit t)
  277. (goto-char origin)
  278. (throw 'exit nil))
  279. ;; Beware: with [1]-like footnotes point will be just after
  280. ;; the closing square bracket.
  281. (backward-char)
  282. (cond
  283. ((setq ref (org-footnote-at-reference-p))
  284. (throw 'exit ref))
  285. ;; Definition: also grab the last square bracket, only
  286. ;; matched in `org-footnote-re' for [1]-like footnotes.
  287. ((save-match-data (org-footnote-at-definition-p))
  288. (let ((end (match-end 0)))
  289. (throw 'exit
  290. (list nil (match-beginning 0)
  291. (if (eq (char-before end) 93) end (1+ end)))))))))))
  292. (defun org-footnote-get-definition (label)
  293. "Return label, boundaries and definition of the footnote LABEL."
  294. (let* ((label (regexp-quote (org-footnote-normalize-label label)))
  295. (re (format "^\\[%s\\]\\|.\\[%s:" label label))
  296. pos)
  297. (save-excursion
  298. (save-restriction
  299. (when (or (re-search-forward re nil t)
  300. (and (goto-char (point-min))
  301. (re-search-forward re nil t))
  302. (and (progn (widen) t)
  303. (goto-char (point-min))
  304. (re-search-forward re nil t)))
  305. (let ((refp (org-footnote-at-reference-p)))
  306. (cond
  307. ((and (nth 3 refp) refp))
  308. ((org-footnote-at-definition-p)))))))))
  309. (defun org-footnote-goto-definition (label)
  310. "Move point to the definition of the footnote LABEL.
  311. Return a non-nil value when a definition has been found."
  312. (interactive "sLabel: ")
  313. (org-mark-ring-push)
  314. (let ((def (org-footnote-get-definition label)))
  315. (if (not def)
  316. (error "Cannot find definition of footnote %s" label)
  317. (goto-char (nth 1 def))
  318. (looking-at (format "\\[%s\\]\\|\\[%s:" label label))
  319. (goto-char (match-end 0))
  320. (org-show-context 'link-search)
  321. (when (eq major-mode 'org-mode)
  322. (message "Edit definition and go back with `C-c &' or, if unique, with `C-c C-c'."))
  323. t)))
  324. (defun org-footnote-goto-previous-reference (label)
  325. "Find the first closest (to point) reference of footnote with label LABEL."
  326. (interactive "sLabel: ")
  327. (org-mark-ring-push)
  328. (let* ((label (org-footnote-normalize-label label)) ref)
  329. (save-excursion
  330. (setq ref (or (org-footnote-get-next-reference label t)
  331. (org-footnote-get-next-reference label)
  332. (save-restriction
  333. (widen)
  334. (or
  335. (org-footnote-get-next-reference label t)
  336. (org-footnote-get-next-reference label))))))
  337. (if (not ref)
  338. (error "Cannot find reference of footnote %s" label)
  339. (goto-char (nth 1 ref))
  340. (org-show-context 'link-search))))
  341. (defun org-footnote-normalize-label (label)
  342. "Return LABEL as an appropriate string."
  343. (cond
  344. ((numberp label) (number-to-string label))
  345. ((equal "" label) nil)
  346. ((not (string-match "^[0-9]+$\\|^fn:" label))
  347. (concat "fn:" label))
  348. (t label)))
  349. (defun org-footnote-all-labels (&optional with-defs)
  350. "Return list with all defined foot labels used in the buffer.
  351. If WITH-DEFS is non-nil, also associate the definition to each
  352. label. The function will then return an alist whose key is label
  353. and value definition."
  354. (let* (rtn
  355. (push-to-rtn
  356. (function
  357. ;; Depending on WITH-DEFS, store label or (label . def) of
  358. ;; footnote reference/definition given as argument in RTN.
  359. (lambda (el)
  360. (let ((lbl (car el)))
  361. (push (if with-defs (cons lbl (nth 3 el)) lbl) rtn))))))
  362. (save-excursion
  363. (save-restriction
  364. (widen)
  365. ;; Find all labels found in definitions.
  366. (goto-char (point-min))
  367. (let (def)
  368. (while (re-search-forward org-footnote-definition-re nil t)
  369. (when (setq def (org-footnote-at-definition-p))
  370. (funcall push-to-rtn def))))
  371. ;; Find all labels found in references.
  372. (goto-char (point-min))
  373. (let (ref)
  374. (while (setq ref (org-footnote-get-next-reference))
  375. (goto-char (nth 2 ref))
  376. (and (car ref) ; ignore anonymous footnotes
  377. (not (funcall (if with-defs #'assoc #'member) (car ref) rtn))
  378. (funcall push-to-rtn ref))))))
  379. rtn))
  380. (defun org-footnote-unique-label (&optional current)
  381. "Return a new unique footnote label.
  382. The function returns the first \"fn:N\" or \"N\" label that is
  383. currently not used.
  384. Optional argument CURRENT is the list of labels active in the
  385. buffer."
  386. (unless current (setq current (org-footnote-all-labels)))
  387. (let ((fmt (if (eq org-footnote-auto-label 'plain) "%d" "fn:%d"))
  388. (cnt 1))
  389. (while (member (format fmt cnt) current)
  390. (incf cnt))
  391. (format fmt cnt)))
  392. (defun org-footnote-new ()
  393. "Insert a new footnote.
  394. This command prompts for a label. If this is a label referencing an
  395. existing label, only insert the label. If the footnote label is empty
  396. or new, let the user edit the definition of the footnote."
  397. (interactive)
  398. (unless (org-footnote-in-valid-context-p)
  399. (error "Cannot insert a footnote here"))
  400. (let* ((lbls (and (not (equal org-footnote-auto-label 'random))
  401. (org-footnote-all-labels)))
  402. (propose (org-footnote-unique-label lbls))
  403. (label
  404. (org-footnote-normalize-label
  405. (cond
  406. ((member org-footnote-auto-label '(t plain))
  407. propose)
  408. ((equal org-footnote-auto-label 'random)
  409. (require 'org-id)
  410. (substring (org-id-uuid) 0 8))
  411. (t
  412. (org-icompleting-read
  413. "Label (leave empty for anonymous): "
  414. (mapcar 'list lbls) nil nil
  415. (if (eq org-footnote-auto-label 'confirm) propose nil)))))))
  416. (cond
  417. ((and label (bolp) (not org-footnote-define-inline))
  418. (error "Cannot create a non-inlined footnote at left margin"))
  419. ((not label)
  420. (insert "[fn:: ]")
  421. (backward-char 1))
  422. ((member label lbls)
  423. (insert "[" label "]")
  424. (message "New reference to existing note"))
  425. (org-footnote-define-inline
  426. (insert "[" label ": ]")
  427. (backward-char 1)
  428. (org-footnote-auto-adjust-maybe))
  429. (t
  430. (insert "[" label "]")
  431. (org-footnote-create-definition label)
  432. (org-footnote-auto-adjust-maybe)))))
  433. (defvar org-blank-before-new-entry nil) ; silence byte-compiler
  434. (defun org-footnote-create-definition (label)
  435. "Start the definition of a footnote with label LABEL."
  436. (interactive "sLabel: ")
  437. (let ((label (org-footnote-normalize-label label)))
  438. (cond
  439. ;; In an Org file.
  440. ((eq major-mode 'org-mode)
  441. ;; If `org-footnote-section' is defined, find it, or create it
  442. ;; at the end of the buffer.
  443. (when org-footnote-section
  444. (goto-char (point-min))
  445. (let ((re (concat "^\\*+[ \t]+" org-footnote-section "[ \t]*$")))
  446. (unless (or (re-search-forward re nil t)
  447. (and (progn (widen) t)
  448. (re-search-forward re nil t)))
  449. (goto-char (point-max))
  450. (skip-chars-backward " \t\r\n")
  451. (unless (bolp) (newline))
  452. ;; Insert new section. Separate it from the previous one
  453. ;; with a blank line, unless `org-blank-before-new-entry'
  454. ;; explicitly says no.
  455. (when (and (cdr (assq 'heading org-blank-before-new-entry))
  456. (zerop (save-excursion (org-back-over-empty-lines))))
  457. (insert "\n"))
  458. (insert "* " org-footnote-section "\n"))))
  459. ;; Move to the end of this entry (which may be
  460. ;; `org-footnote-section' or the current one).
  461. (org-footnote-goto-local-insertion-point)
  462. (org-show-context 'link-search))
  463. (t
  464. ;; In a non-Org file. Search for footnote tag, or create it if
  465. ;; specified (at the end of buffer, or before signature if in
  466. ;; Message mode). Set point after any definition already there.
  467. (let ((tag (and org-footnote-tag-for-non-org-mode-files
  468. (concat "^" (regexp-quote
  469. org-footnote-tag-for-non-org-mode-files)
  470. "[ \t]*$")))
  471. (max (if (and (derived-mode-p 'message-mode)
  472. (goto-char (point-max))
  473. (re-search-backward
  474. message-signature-separator nil t))
  475. (progn
  476. ;; Ensure one blank line separates last
  477. ;; footnote from signature.
  478. (beginning-of-line)
  479. (open-line 2)
  480. (point-marker))
  481. (point-max-marker))))
  482. (set-marker-insertion-type max t)
  483. (goto-char max)
  484. ;; Check if the footnote tag is defined but missing. In this
  485. ;; case, insert it, before any footnote or one blank line
  486. ;; after any previous text.
  487. (when (and tag (not (re-search-backward tag nil t)))
  488. (skip-chars-backward " \t\r\n")
  489. (while (re-search-backward org-footnote-definition-re nil t))
  490. (unless (bolp) (newline 2))
  491. (insert org-footnote-tag-for-non-org-mode-files "\n\n"))
  492. ;; Remove superfluous white space and clear marker.
  493. (goto-char max)
  494. (skip-chars-backward " \t\r\n")
  495. (delete-region (point) max)
  496. (unless (bolp) (newline))
  497. (set-marker max nil))))
  498. ;; Insert footnote label.
  499. (insert "\n[" label "] ")
  500. ;; Only notify user about next possible action when in an Org
  501. ;; buffer, as the bindings may have different meanings otherwise.
  502. (when (eq major-mode 'org-mode)
  503. (message
  504. "Edit definition and go back with `C-c &' or, if unique, with `C-c C-c'."))))
  505. ;;;###autoload
  506. (defun org-footnote-action (&optional special)
  507. "Do the right thing for footnotes.
  508. When at a footnote reference, jump to the definition.
  509. When at a definition, jump to the references if they exist, offer
  510. to create them otherwise.
  511. When neither at definition or reference, create a new footnote,
  512. interactively.
  513. With prefix arg SPECIAL, offer additional commands in a menu."
  514. (interactive "P")
  515. (let (tmp c)
  516. (cond
  517. (special
  518. (message "Footnotes: [s]ort | [r]enumber fn:N | [S]=r+s |->[n]umeric | [d]elete")
  519. (setq c (read-char-exclusive))
  520. (cond
  521. ((eq c ?s) (org-footnote-normalize 'sort))
  522. ((eq c ?r) (org-footnote-renumber-fn:N))
  523. ((eq c ?S)
  524. (org-footnote-renumber-fn:N)
  525. (org-footnote-normalize 'sort))
  526. ((eq c ?n) (org-footnote-normalize))
  527. ((eq c ?d) (org-footnote-delete))
  528. (t (error "No such footnote command %c" c))))
  529. ((setq tmp (org-footnote-at-reference-p))
  530. (cond
  531. ;; Anonymous footnote: move point at the beginning of its
  532. ;; definition.
  533. ((not (car tmp))
  534. (goto-char (nth 1 tmp))
  535. (forward-char 5))
  536. ;; A definition exists: move to it.
  537. ((ignore-errors (org-footnote-goto-definition (car tmp))))
  538. ;; No definition exists: offer to create it.
  539. ((yes-or-no-p (format "No definition for %s. Create one? " (car tmp)))
  540. (org-footnote-create-definition (car tmp)))))
  541. ((setq tmp (org-footnote-at-definition-p))
  542. (org-footnote-goto-previous-reference (car tmp)))
  543. (t (org-footnote-new)))))
  544. (defvar org-footnote-insert-pos-for-preprocessor 'point-max
  545. "See `org-footnote-normalize'.")
  546. (defvar org-export-footnotes-seen nil) ; silence byte-compiler
  547. (defvar org-export-footnotes-data nil) ; silence byte-compiler
  548. ;;;###autoload
  549. (defun org-footnote-normalize (&optional sort-only export-props)
  550. "Collect the footnotes in various formats and normalize them.
  551. This finds the different sorts of footnotes allowed in Org, and
  552. normalizes them to the usual [N] format that is understood by the
  553. Org-mode exporters.
  554. When SORT-ONLY is set, only sort the footnote definitions into the
  555. referenced sequence.
  556. If Org is amidst an export process, EXPORT-PROPS will hold the
  557. export properties of the buffer.
  558. When EXPORT-PROPS is non-nil, the default action is to insert
  559. normalized footnotes towards the end of the pre-processing
  560. buffer. Some exporters (docbook, odt...) expect footnote
  561. definitions to be available before any references to them. Such
  562. exporters can let bind `org-footnote-insert-pos-for-preprocessor'
  563. to symbol `point-min' to achieve the desired behaviour.
  564. Additional note on `org-footnote-insert-pos-for-preprocessor':
  565. 1. This variable has not effect when FOR-PREPROCESSOR is nil.
  566. 2. This variable (potentially) obviates the need for extra scan
  567. of pre-processor buffer as witnessed in
  568. `org-export-docbook-get-footnotes'."
  569. ;; This is based on Paul's function, but rewritten.
  570. ;;
  571. ;; Re-create `org-with-limited-levels', but not limited to Org
  572. ;; buffers.
  573. (let* ((limit-level
  574. (and (boundp 'org-inlinetask-min-level)
  575. org-inlinetask-min-level
  576. (1- org-inlinetask-min-level)))
  577. (nstars (and limit-level
  578. (if org-odd-levels-only
  579. (and limit-level (1- (* limit-level 2)))
  580. limit-level)))
  581. (org-outline-regexp
  582. (concat "\\*" (if nstars (format "\\{1,%d\\} " nstars) "+ ")))
  583. ;; Determine the highest marker used so far.
  584. (ref-table (when export-props org-export-footnotes-seen))
  585. (count (if (and export-props ref-table)
  586. (apply 'max (mapcar (lambda (e) (nth 1 e)) ref-table))
  587. 0))
  588. ins-point ref)
  589. (save-excursion
  590. ;; 1. Find every footnote reference, extract the definition, and
  591. ;; collect that data in REF-TABLE. If SORT-ONLY is nil, also
  592. ;; normalize references.
  593. (goto-char (point-min))
  594. (while (setq ref (org-footnote-get-next-reference))
  595. (let* ((lbl (car ref))
  596. ;; When footnote isn't anonymous, check if it's label
  597. ;; (REF) is already stored in REF-TABLE. In that case,
  598. ;; extract number used to identify it (MARKER). If
  599. ;; footnote is unknown, increment the global counter
  600. ;; (COUNT) to create an unused identifier.
  601. (a (and lbl (assoc lbl ref-table)))
  602. (marker (or (nth 1 a) (incf count)))
  603. ;; Is the reference inline or pointing to an inline
  604. ;; footnote?
  605. (inlinep (or (stringp (nth 3 ref)) (nth 3 a))))
  606. ;; Replace footnote reference with [MARKER]. Maybe fill
  607. ;; paragraph once done. If SORT-ONLY is non-nil, only move
  608. ;; to the end of reference found to avoid matching it twice.
  609. ;; If EXPORT-PROPS isn't nil, also add `org-footnote'
  610. ;; property to it, so it can be easily recognized by
  611. ;; exporters.
  612. (if sort-only
  613. (goto-char (nth 2 ref))
  614. (delete-region (nth 1 ref) (nth 2 ref))
  615. (goto-char (nth 1 ref))
  616. (let ((new-ref (format "[%d]" marker)))
  617. (when export-props (org-add-props new-ref '(org-footnote t)))
  618. (insert new-ref))
  619. (and inlinep
  620. org-footnote-fill-after-inline-note-extraction
  621. (org-fill-paragraph)))
  622. ;; Add label (REF), identifier (MARKER), definition (DEF)
  623. ;; and type (INLINEP) to REF-TABLE if data was unknown.
  624. (unless a
  625. (let ((def (or (nth 3 ref) ; inline
  626. (and export-props
  627. (cdr (assoc lbl org-export-footnotes-data)))
  628. (nth 3 (org-footnote-get-definition lbl)))))
  629. (push (list lbl marker
  630. ;; When exporting, each definition goes
  631. ;; through `org-export-preprocess-string' so
  632. ;; it is ready to insert in the
  633. ;; backend-specific buffer.
  634. (if (and export-props def)
  635. (let ((parameters
  636. (org-combine-plists
  637. export-props
  638. '(:todo-keywords t :tags t :priority t))))
  639. (org-export-preprocess-string def parameters))
  640. def)
  641. inlinep) ref-table)))))
  642. ;; 2. Find and remove the footnote section, if any. Also
  643. ;; determine where footnotes shall be inserted (INS-POINT).
  644. (goto-char (point-min))
  645. (cond
  646. ((and org-footnote-section
  647. (eq major-mode 'org-mode)
  648. (re-search-forward
  649. (concat "^\\*[ \t]+" (regexp-quote org-footnote-section)
  650. "[ \t]*$")
  651. nil t))
  652. (delete-region (match-beginning 0) (org-end-of-subtree t)))
  653. ((eq major-mode 'org-mode)
  654. (goto-char (point-max))
  655. (unless (bolp) (newline)))
  656. (t
  657. ;; Remove any left-over tag in the buffer, if one is set up.
  658. (when org-footnote-tag-for-non-org-mode-files
  659. (let ((tag (concat "^" (regexp-quote
  660. org-footnote-tag-for-non-org-mode-files)
  661. "[ \t]*$")))
  662. (while (re-search-forward tag nil t)
  663. (replace-match "")
  664. (delete-region (point) (progn (forward-line) (point))))))
  665. ;; In Message mode, ensure footnotes are inserted before the
  666. ;; signature.
  667. (if (and (derived-mode-p 'message-mode)
  668. (goto-char (point-max))
  669. (re-search-backward message-signature-separator nil t))
  670. (beginning-of-line)
  671. (goto-char (point-max)))))
  672. ;; During export, `org-footnote-insert-pos-for-preprocessor' has
  673. ;; precedence over previously found position.
  674. (setq ins-point
  675. (copy-marker
  676. (if (and export-props
  677. (eq org-footnote-insert-pos-for-preprocessor 'point-min))
  678. (point-min)
  679. (point))))
  680. ;; 3. Clean-up REF-TABLE.
  681. (setq ref-table
  682. (delq nil
  683. (mapcar
  684. (lambda (x)
  685. (cond
  686. ;; When only sorting, ignore inline footnotes.
  687. ((and sort-only (nth 3 x)) nil)
  688. ;; No definition available: provide one.
  689. ((not (nth 2 x))
  690. (append (butlast x 2)
  691. (list (format "DEFINITION NOT FOUND: %s" (car x))
  692. (nth 3 x))))
  693. (t x)))
  694. ref-table)))
  695. (setq ref-table (nreverse ref-table))
  696. ;; 4. Remove left-over definitions in the buffer.
  697. (mapc (lambda (x) (unless (nth 3 x)
  698. (org-footnote-delete-definitions (car x))))
  699. ref-table)
  700. ;; 5. Insert the footnotes again in the buffer, at the
  701. ;; appropriate spot.
  702. (goto-char ins-point)
  703. (cond
  704. ;; No footnote: exit.
  705. ((not ref-table))
  706. ;; Cases when footnotes should be inserted in one place.
  707. ((or (not (eq major-mode 'org-mode))
  708. org-footnote-section
  709. (not sort-only))
  710. ;; Insert again the section title, if any. Ensure that title,
  711. ;; or the subsequent footnotes, will be separated by a blank
  712. ;; lines from the rest of the document. In an Org buffer,
  713. ;; separate section with a blank line, unless explicitly
  714. ;; stated in `org-blank-before-new-entry'.
  715. (cond
  716. ((not (eq major-mode 'org-mode))
  717. (skip-chars-backward " \t\n\r")
  718. (delete-region (point) ins-point)
  719. (unless (bolp) (newline))
  720. ;; Keep one blank line between footnotes and signature.
  721. (when (and (derived-mode-p 'message-mode)
  722. (save-excursion
  723. (re-search-forward message-signature-separator nil t)))
  724. (open-line 1))
  725. (when org-footnote-tag-for-non-org-mode-files
  726. (insert "\n" org-footnote-tag-for-non-org-mode-files "\n")))
  727. ((and org-footnote-section (not export-props))
  728. (when (and (cdr (assq 'heading org-blank-before-new-entry))
  729. (zerop (save-excursion (org-back-over-empty-lines))))
  730. (insert "\n"))
  731. (insert "* " org-footnote-section "\n")))
  732. (set-marker ins-point nil)
  733. ;; Insert the footnotes, separated by a blank line.
  734. (insert (mapconcat (lambda (x) (format "\n[%s] %s"
  735. (nth (if sort-only 0 1) x) (nth 2 x)))
  736. ref-table "\n"))
  737. (unless (eobp) (insert "\n"))
  738. ;; When exporting, add newly inserted markers along with their
  739. ;; associated definition to `org-export-footnotes-seen'.
  740. (when export-props
  741. (setq org-export-footnotes-seen ref-table)))
  742. ;; Else, insert each definition at the end of the section
  743. ;; containing their first reference. Happens only in Org files
  744. ;; with no special footnote section, and only when doing
  745. ;; sorting.
  746. (t (mapc 'org-insert-footnote-reference-near-definition
  747. ref-table))))))
  748. (defun org-insert-footnote-reference-near-definition (entry)
  749. "Find first reference of footnote ENTRY and insert the definition there.
  750. ENTRY is (fn-label num-mark definition)."
  751. (when (car entry)
  752. (goto-char (point-min))
  753. (let ((ref (org-footnote-get-next-reference (car entry))))
  754. (when ref
  755. (goto-char (nth 2 ref))
  756. (org-footnote-goto-local-insertion-point)
  757. (insert (format "\n[%s] %s\n" (car entry) (nth 2 entry)))))))
  758. (defun org-footnote-goto-local-insertion-point ()
  759. "Find insertion point for footnote, just before next outline heading."
  760. (org-with-limited-levels (outline-next-heading))
  761. (or (bolp) (newline))
  762. (beginning-of-line 0)
  763. (while (and (not (bobp)) (= (char-after) ?#))
  764. (beginning-of-line 0))
  765. (if (looking-at "[ \t]*#\\+TBLFM:") (beginning-of-line 2))
  766. (end-of-line 1)
  767. (skip-chars-backward "\n\r\t ")
  768. (forward-line))
  769. (defun org-footnote-delete-references (label)
  770. "Delete every reference to footnote LABEL.
  771. Return the number of footnotes removed."
  772. (save-excursion
  773. (goto-char (point-min))
  774. (let (ref (nref 0))
  775. (while (setq ref (org-footnote-get-next-reference label))
  776. (goto-char (nth 1 ref))
  777. (delete-region (nth 1 ref) (nth 2 ref))
  778. (incf nref))
  779. nref)))
  780. (defun org-footnote-delete-definitions (label)
  781. "Delete every definition of the footnote LABEL.
  782. Return the number of footnotes removed."
  783. (save-excursion
  784. (goto-char (point-min))
  785. (let ((def-re (concat "^\\[" (regexp-quote label) "\\]"))
  786. (ndef 0))
  787. (while (re-search-forward def-re nil t)
  788. (let ((full-def (org-footnote-at-definition-p)))
  789. (delete-region (nth 1 full-def) (nth 2 full-def)))
  790. (incf ndef))
  791. ndef)))
  792. (defun org-footnote-delete (&optional label)
  793. "Delete the footnote at point.
  794. This will remove the definition (even multiple definitions if they exist)
  795. and all references of a footnote label.
  796. If LABEL is non-nil, delete that footnote instead."
  797. (catch 'done
  798. (let* ((nref 0) (ndef 0) x
  799. ;; 1. Determine LABEL of footnote at point.
  800. (label (cond
  801. ;; LABEL is provided as argument.
  802. (label)
  803. ;; Footnote reference at point. If the footnote is
  804. ;; anonymous, delete it and exit instead.
  805. ((setq x (org-footnote-at-reference-p))
  806. (or (car x)
  807. (progn
  808. (delete-region (nth 1 x) (nth 2 x))
  809. (message "Anonymous footnote removed")
  810. (throw 'done t))))
  811. ;; Footnote definition at point.
  812. ((setq x (org-footnote-at-definition-p))
  813. (car x))
  814. (t (error "Don't know which footnote to remove")))))
  815. ;; 2. Now that LABEL is non-nil, find every reference and every
  816. ;; definition, and delete them.
  817. (setq nref (org-footnote-delete-references label)
  818. ndef (org-footnote-delete-definitions label))
  819. ;; 3. Verify consistency of footnotes and notify user.
  820. (org-footnote-auto-adjust-maybe)
  821. (message "%d definition(s) of and %d reference(s) of footnote %s removed"
  822. ndef nref label))))
  823. (defun org-footnote-renumber-fn:N ()
  824. "Renumber the simple footnotes like fn:17 into a sequence in the document."
  825. (interactive)
  826. (let (map (n 0))
  827. (org-with-wide-buffer
  828. (goto-char (point-min))
  829. (while (re-search-forward "\\[fn:\\([0-9]+\\)[]:]" nil t)
  830. (save-excursion
  831. (goto-char (match-beginning 0))
  832. ;; Ensure match is a footnote reference or definition.
  833. (when (save-match-data (if (bolp)
  834. (org-footnote-at-definition-p)
  835. (org-footnote-at-reference-p)))
  836. (let ((new-val (or (cdr (assoc (match-string 1) map))
  837. (number-to-string (incf n)))))
  838. (unless (assoc (match-string 1) map)
  839. (push (cons (match-string 1) new-val) map))
  840. (replace-match new-val nil nil nil 1))))))))
  841. (defun org-footnote-auto-adjust-maybe ()
  842. "Renumber and/or sort footnotes according to user settings."
  843. (when (memq org-footnote-auto-adjust '(t renumber))
  844. (org-footnote-renumber-fn:N))
  845. (when (memq org-footnote-auto-adjust '(t sort))
  846. (let ((label (car (org-footnote-at-definition-p))))
  847. (org-footnote-normalize 'sort)
  848. (when label
  849. (goto-char (point-min))
  850. (and (re-search-forward (concat "^\\[" (regexp-quote label) "\\]")
  851. nil t)
  852. (progn (insert " ")
  853. (just-one-space)))))))
  854. (provide 'org-footnote)
  855. ;;; org-footnote.el ends here