org-feed.el 24 KB

123456789101112131415161718192021222324252627282930313233343536373839404142434445464748495051525354555657585960616263646566676869707172737475767778798081828384858687888990919293949596979899100101102103104105106107108109110111112113114115116117118119120121122123124125126127128129130131132133134135136137138139140141142143144145146147148149150151152153154155156157158159160161162163164165166167168169170171172173174175176177178179180181182183184185186187188189190191192193194195196197198199200201202203204205206207208209210211212213214215216217218219220221222223224225226227228229230231232233234235236237238239240241242243244245246247248249250251252253254255256257258259260261262263264265266267268269270271272273274275276277278279280281282283284285286287288289290291292293294295296297298299300301302303304305306307308309310311312313314315316317318319320321322323324325326327328329330331332333334335336337338339340341342343344345346347348349350351352353354355356357358359360361362363364365366367368369370371372373374375376377378379380381382383384385386387388389390391392393394395396397398399400401402403404405406407408409410411412413414415416417418419420421422423424425426427428429430431432433434435436437438439440441442443444445446447448449450451452453454455456457458459460461462463464465466467468469470471472473474475476477478479480481482483484485486487488489490491492493494495496497498499500501502503504505506507508509510511512513514515516517518519520521522523524525526527528529530531532533534535536537538539540541542543544545546547548549550551552553554555556557558559560561562563564565566567568569570571572573574575576577578579580581582583584585586587588589590591592593594595596597598599600601602603604605606607608609610611612613614615616617618619620621622623624625626627628629630631632633634635636637638639640641642643644645646647648649650651652653654655656657658659660661662663664665666667668669670671672673674675676677678679
  1. ;;; org-feed.el --- Add RSS feed items to Org files
  2. ;;
  3. ;; Copyright (C) 2009, 2010 Free Software Foundation, Inc.
  4. ;;
  5. ;; Author: Carsten Dominik <carsten at orgmode dot org>
  6. ;; Keywords: outlines, hypermedia, calendar, wp
  7. ;; Homepage: http://orgmode.org
  8. ;; Version: 7.5
  9. ;;
  10. ;; This file is part of GNU Emacs.
  11. ;;
  12. ;; GNU Emacs is free software: you can redistribute it and/or modify
  13. ;; it under the terms of the GNU General Public License as published by
  14. ;; the Free Software Foundation, either version 3 of the License, or
  15. ;; (at your option) any later version.
  16. ;; GNU Emacs is distributed in the hope that it will be useful,
  17. ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18. ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  19. ;; GNU General Public License for more details.
  20. ;; You should have received a copy of the GNU General Public License
  21. ;; along with GNU Emacs. If not, see <http://www.gnu.org/licenses/>.
  22. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  23. ;;
  24. ;;; Commentary:
  25. ;;
  26. ;; This module allows to create and change entries in an Org-mode
  27. ;; file triggered by items in an RSS feed. The basic functionality is
  28. ;; geared toward simply adding new items found in a feed as outline nodes
  29. ;; to an Org file. Using hooks, arbitrary actions can be triggered for
  30. ;; new or changed items.
  31. ;;
  32. ;; Selecting feeds and target locations
  33. ;; ------------------------------------
  34. ;;
  35. ;; This module is configured through a single variable, `org-feed-alist'.
  36. ;; Here is an example, using a notes/tasks feed from reQall.com.
  37. ;;
  38. ;; (setq org-feed-alist
  39. ;; '(("ReQall"
  40. ;; "http://www.reqall.com/user/feeds/rss/a1b2c3....."
  41. ;; "~/org/feeds.org" "ReQall Entries")
  42. ;;
  43. ;; With this setup, the command `M-x org-feed-update-all' will
  44. ;; collect new entries in the feed at the given URL and create
  45. ;; entries as subheadings under the "ReQall Entries" heading in the
  46. ;; file "~/org/feeds.org". Each feed should normally have its own
  47. ;; heading - however see the `:drawer' parameter.
  48. ;;
  49. ;; Besides these standard elements that need to be specified for each
  50. ;; feed, keyword-value pairs can set additional options. For example,
  51. ;; to de-select transitional entries with a title containing
  52. ;;
  53. ;; "reQall is typing what you said",
  54. ;;
  55. ;; you could use the `:filter' argument:
  56. ;;
  57. ;; (setq org-feed-alist
  58. ;; '(("ReQall"
  59. ;; "http://www.reqall.com/user/feeds/rss/a1b2c3....."
  60. ;; "~/org/feeds.org" "ReQall Entries"
  61. ;; :filter my-reqall-filter)))
  62. ;;
  63. ;; (defun my-reqall-filter (e)
  64. ;; (if (string-match "reQall is typing what you said"
  65. ;; (plist-get e :title))
  66. ;; nil
  67. ;; e))
  68. ;;
  69. ;; See the docstring for `org-feed-alist' for more details.
  70. ;;
  71. ;;
  72. ;; Keeping track of previously added entries
  73. ;; -----------------------------------------
  74. ;;
  75. ;; Since Org allows you to delete, archive, or move outline nodes,
  76. ;; org-feed.el needs to keep track of which feed items have been handled
  77. ;; before, so that they will not be handled again. For this, org-feed.el
  78. ;; stores information in a special drawer, FEEDSTATUS, under the heading
  79. ;; that received the input of the feed. You should add FEEDSTATUS
  80. ;; to your list of drawers in the files that receive feed input:
  81. ;;
  82. ;; #+DRAWERS: PROPERTIES LOGBOOK FEEDSTATUS
  83. ;;
  84. ;; Acknowledgments
  85. ;; ---------------
  86. ;;
  87. ;; org-feed.el is based on ideas by Brad Bozarth who implemented a
  88. ;; similar mechanism using shell and awk scripts.
  89. ;;; Code:
  90. (require 'org)
  91. (require 'sha1)
  92. (declare-function url-retrieve-synchronously "url" (url))
  93. (declare-function xml-node-children "xml" (node))
  94. (declare-function xml-get-children "xml" (node child-name))
  95. (declare-function xml-get-attribute "xml" (node attribute))
  96. (declare-function xml-get-attribute-or-nil "xml" (node attribute))
  97. (declare-function xml-substitute-special "xml" (string))
  98. (defgroup org-feed nil
  99. "Options concerning RSS feeds as inputs for Org files."
  100. :tag "Org Feed"
  101. :group 'org)
  102. (defcustom org-feed-alist nil
  103. "Alist specifying RSS feeds that should create inputs for Org.
  104. Each entry in this list specified an RSS feed tat should be queried
  105. to create inbox items in Org. Each entry is a list with the following items:
  106. name a custom name for this feed
  107. URL the Feed URL
  108. file the target Org file where entries should be listed
  109. headline the headline under which entries should be listed
  110. Additional arguments can be given using keyword-value pairs. Many of these
  111. specify functions that receive one or a list of \"entries\" as their single
  112. argument. An entry is a property list that describes a feed item. The
  113. property list has properties for each field in the item, for example `:title'
  114. for the `<title>' field and `:pubDate' for the publication date. In addition,
  115. it contains the following properties:
  116. `:item-full-text' the full text in the <item> tag
  117. `:guid-permalink' t when the guid property is a permalink
  118. Here are the keyword-value pair allows in `org-feed-alist'.
  119. :drawer drawer-name
  120. The name of the drawer for storing feed information. The default is
  121. \"FEEDSTATUS\". Using different drawers for different feeds allows
  122. several feeds to target the same inbox heading.
  123. :filter filter-function
  124. A function to select interesting entries in the feed. It gets a single
  125. entry as parameter. It should return the entry if it is relevant, or
  126. nil if it is not.
  127. :template template-string
  128. The default action on new items in the feed is to add them as children
  129. under the headline for the feed. The template describes how the entry
  130. should be formatted. If not given, it defaults to
  131. `org-feed-default-template'.
  132. :formatter formatter-function
  133. Instead of relying on a template, you may specify a function to format
  134. the outline node to be inserted as a child. This function gets passed
  135. a property list describing a single feed item, and it should return a
  136. string that is a properly formatted Org outline node of level 1.
  137. :new-handler function
  138. If adding new items as children to the outline is not what you want
  139. to do with new items, define a handler function that is called with
  140. a list of all new items in the feed, each one represented as a property
  141. list. The handler should do what needs to be done, and org-feed will
  142. mark all items given to this handler as \"handled\", i.e. they will not
  143. be passed to this handler again in future readings of the feed.
  144. When the handler is called, point will be at the feed headline.
  145. :changed-handler function
  146. This function gets passed a list of all entries that have been
  147. handled before, but are now still in the feed and have *changed*
  148. since last handled (as evidenced by a different sha1 hash).
  149. When the handler is called, point will be at the feed headline.
  150. :parse-feed function
  151. This function gets passed a buffer, and should return a list
  152. of entries, each being a property list containing the
  153. `:guid' and `:item-full-text' keys. The default is
  154. `org-feed-parse-rss-feed'; `org-feed-parse-atom-feed' is an
  155. alternative.
  156. :parse-entry function
  157. This function gets passed an entry as returned by the parse-feed
  158. function, and should return the entry with interesting properties added.
  159. The default is `org-feed-parse-rss-entry'; `org-feed-parse-atom-entry'
  160. is an alternative."
  161. :group 'org-feed
  162. :type '(repeat
  163. (list :value ("" "http://" "" "")
  164. (string :tag "Name")
  165. (string :tag "Feed URL")
  166. (file :tag "File for inbox")
  167. (string :tag "Headline for inbox")
  168. (repeat :inline t
  169. (choice
  170. (list :inline t :tag "Filter"
  171. (const :filter)
  172. (symbol :tag "Filter Function"))
  173. (list :inline t :tag "Template"
  174. (const :template)
  175. (string :tag "Template"))
  176. (list :inline t :tag "Formatter"
  177. (const :formatter)
  178. (symbol :tag "Formatter Function"))
  179. (list :inline t :tag "New items handler"
  180. (const :new-handler)
  181. (symbol :tag "Handler Function"))
  182. (list :inline t :tag "Changed items"
  183. (const :changed-handler)
  184. (symbol :tag "Handler Function"))
  185. (list :inline t :tag "Parse Feed"
  186. (const :parse-feed)
  187. (symbol :tag "Parse Feed Function"))
  188. (list :inline t :tag "Parse Entry"
  189. (const :parse-entry)
  190. (symbol :tag "Parse Entry Function"))
  191. )))))
  192. (defcustom org-feed-drawer "FEEDSTATUS"
  193. "The name of the drawer for feed status information.
  194. Each feed may also specify its own drawer name using the `:drawer'
  195. parameter in `org-feed-alist'.
  196. Note that in order to make these drawers behave like drawers, they must
  197. be added to the variable `org-drawers' or configured with a #+DRAWERS
  198. line."
  199. :group 'org-feed
  200. :type '(string :tag "Drawer Name"))
  201. (defcustom org-feed-default-template "\n* %h\n %U\n %description\n %a\n"
  202. "Template for the Org node created from RSS feed items.
  203. This is just the default, each feed can specify its own.
  204. Any fields from the feed item can be interpolated into the template with
  205. %name, for example %title, %description, %pubDate etc. In addition, the
  206. following special escapes are valid as well:
  207. %h the title, or the first line of the description
  208. %t the date as a stamp, either from <pubDate> (if present), or
  209. the current date.
  210. %T date and time
  211. %u,%U like %t,%T, but inactive time stamps
  212. %a A link, from <guid> if that is a permalink, else from <link>"
  213. :group 'org-feed
  214. :type '(string :tag "Template"))
  215. (defcustom org-feed-save-after-adding t
  216. "Non-nil means save buffer after adding new feed items."
  217. :group 'org-feed
  218. :type 'boolean)
  219. (defcustom org-feed-retrieve-method 'url-retrieve-synchronously
  220. "The method to be used to retrieve a feed URL.
  221. This can be `curl' or `wget' to call these external programs, or it can be
  222. an Emacs Lisp function that will return a buffer containing the content
  223. of the file pointed to by the URL."
  224. :group 'org-feed
  225. :type '(choice
  226. (const :tag "Internally with url.el" url-retrieve-synchronously)
  227. (const :tag "Externally with curl" curl)
  228. (const :tag "Externally with wget" wget)
  229. (function :tag "Function")))
  230. (defcustom org-feed-before-adding-hook nil
  231. "Hook that is run before adding new feed items to a file.
  232. You might want to commit the file in its current state to version control,
  233. for example."
  234. :group 'org-feed
  235. :type 'hook)
  236. (defcustom org-feed-after-adding-hook nil
  237. "Hook that is run after new items have been added to a file.
  238. Depending on `org-feed-save-after-adding', the buffer will already
  239. have been saved."
  240. :group 'org-feed
  241. :type 'hook)
  242. (defvar org-feed-buffer "*Org feed*"
  243. "The buffer used to retrieve a feed.")
  244. ;;;###autoload
  245. (defun org-feed-update-all ()
  246. "Get inbox items from all feeds in `org-feed-alist'."
  247. (interactive)
  248. (let ((nfeeds (length org-feed-alist))
  249. (nnew (apply '+ (mapcar 'org-feed-update org-feed-alist))))
  250. (message "%s from %d %s"
  251. (cond ((= nnew 0) "No new entries")
  252. ((= nnew 1) "1 new entry")
  253. (t (format "%d new entries" nnew)))
  254. nfeeds
  255. (if (= nfeeds 1) "feed" "feeds"))))
  256. ;;;###autoload
  257. (defun org-feed-update (feed &optional retrieve-only)
  258. "Get inbox items from FEED.
  259. FEED can be a string with an association in `org-feed-alist', or
  260. it can be a list structured like an entry in `org-feed-alist'."
  261. (interactive (list (org-completing-read "Feed name: " org-feed-alist)))
  262. (if (stringp feed) (setq feed (assoc feed org-feed-alist)))
  263. (unless feed
  264. (error "No such feed in `org-feed-alist"))
  265. (catch 'exit
  266. (let ((name (car feed))
  267. (url (nth 1 feed))
  268. (file (nth 2 feed))
  269. (headline (nth 3 feed))
  270. (filter (nth 1 (memq :filter feed)))
  271. (formatter (nth 1 (memq :formatter feed)))
  272. (new-handler (nth 1 (memq :new-handler feed)))
  273. (changed-handler (nth 1 (memq :changed-handler feed)))
  274. (template (or (nth 1 (memq :template feed))
  275. org-feed-default-template))
  276. (drawer (or (nth 1 (memq :drawer feed))
  277. org-feed-drawer))
  278. (parse-feed (or (nth 1 (memq :parse-feed feed))
  279. 'org-feed-parse-rss-feed))
  280. (parse-entry (or (nth 1 (memq :parse-entry feed))
  281. 'org-feed-parse-rss-entry))
  282. feed-buffer inbox-pos new-formatted
  283. entries old-status status new changed guid-alist e guid olds)
  284. (setq feed-buffer (org-feed-get-feed url))
  285. (unless (and feed-buffer (bufferp (get-buffer feed-buffer)))
  286. (error "Cannot get feed %s" name))
  287. (when retrieve-only
  288. (throw 'exit feed-buffer))
  289. (setq entries (funcall parse-feed feed-buffer))
  290. (ignore-errors (kill-buffer feed-buffer))
  291. (save-excursion
  292. (save-window-excursion
  293. (setq inbox-pos (org-feed-goto-inbox-internal file headline))
  294. (setq old-status (org-feed-read-previous-status inbox-pos drawer))
  295. ;; Add the "handled" status to the appropriate entries
  296. (setq entries (mapcar (lambda (e)
  297. (setq e
  298. (plist-put e :handled
  299. (nth 1 (assoc
  300. (plist-get e :guid)
  301. old-status)))))
  302. entries))
  303. ;; Find out which entries are new and which are changed
  304. (dolist (e entries)
  305. (if (not (plist-get e :handled))
  306. (push e new)
  307. (setq olds (nth 2 (assoc (plist-get e :guid) old-status)))
  308. (if (and olds
  309. (not (string= (sha1
  310. (plist-get e :item-full-text))
  311. olds)))
  312. (push e changed))))
  313. ;; Parse the relevant entries fully
  314. (setq new (mapcar parse-entry new)
  315. changed (mapcar parse-entry changed))
  316. ;; Run the filter
  317. (when filter
  318. (setq new (delq nil (mapcar filter new))
  319. changed (delq nil (mapcar filter new))))
  320. (when (not (or new changed))
  321. (message "No new items in feed %s" name)
  322. (throw 'exit 0))
  323. ;; Get alist based on guid, to look up entries
  324. (setq guid-alist
  325. (append
  326. (mapcar (lambda (e) (list (plist-get e :guid) e)) new)
  327. (mapcar (lambda (e) (list (plist-get e :guid) e)) changed)))
  328. ;; Construct the new status
  329. (setq status
  330. (mapcar
  331. (lambda (e)
  332. (setq guid (plist-get e :guid))
  333. (list guid
  334. ;; things count as handled if we handle them now,
  335. ;; or if they were handled previously
  336. (if (assoc guid guid-alist) t (plist-get e :handled))
  337. ;; A hash, to detect changes
  338. (sha1 (plist-get e :item-full-text))))
  339. entries))
  340. ;; Handle new items in the feed
  341. (when new
  342. (if new-handler
  343. (progn
  344. (goto-char inbox-pos)
  345. (funcall new-handler new))
  346. ;; No custom handler, do the default adding
  347. ;; Format the new entries into an alist with GUIDs in the car
  348. (setq new-formatted
  349. (mapcar
  350. (lambda (e) (org-feed-format-entry e template formatter))
  351. new)))
  352. ;; Insert the new items
  353. (org-feed-add-items inbox-pos new-formatted))
  354. ;; Handle changed items in the feed
  355. (when (and changed-handler changed)
  356. (goto-char inbox-pos)
  357. (funcall changed-handler changed))
  358. ;; Write the new status
  359. ;; We do this only now, in case something goes wrong above, so
  360. ;; that would would end up with a status that does not reflect
  361. ;; which items truely have been handled
  362. (org-feed-write-status inbox-pos drawer status)
  363. ;; Normalize the visibility of the inbox tree
  364. (goto-char inbox-pos)
  365. (hide-subtree)
  366. (show-children)
  367. (org-cycle-hide-drawers 'children)
  368. ;; Hooks and messages
  369. (when org-feed-save-after-adding (save-buffer))
  370. (message "Added %d new item%s from feed %s to file %s, heading %s"
  371. (length new) (if (> (length new) 1) "s" "")
  372. name
  373. (file-name-nondirectory file) headline)
  374. (run-hooks 'org-feed-after-adding-hook)
  375. (length new))))))
  376. ;;;###autoload
  377. (defun org-feed-goto-inbox (feed)
  378. "Go to the inbox that captures the feed named FEED."
  379. (interactive
  380. (list (if (= (length org-feed-alist) 1)
  381. (car org-feed-alist)
  382. (org-completing-read "Feed name: " org-feed-alist))))
  383. (if (stringp feed) (setq feed (assoc feed org-feed-alist)))
  384. (unless feed
  385. (error "No such feed in `org-feed-alist"))
  386. (org-feed-goto-inbox-internal (nth 2 feed) (nth 3 feed)))
  387. ;;;###autoload
  388. (defun org-feed-show-raw-feed (feed)
  389. "Show the raw feed buffer of a feed."
  390. (interactive
  391. (list (if (= (length org-feed-alist) 1)
  392. (car org-feed-alist)
  393. (org-completing-read "Feed name: " org-feed-alist))))
  394. (if (stringp feed) (setq feed (assoc feed org-feed-alist)))
  395. (unless feed
  396. (error "No such feed in `org-feed-alist"))
  397. (switch-to-buffer
  398. (org-feed-update feed 'retrieve-only))
  399. (goto-char (point-min)))
  400. (defun org-feed-goto-inbox-internal (file heading)
  401. "Find or create HEADING in FILE.
  402. Switch to that buffer, and return the position of that headline."
  403. (find-file file)
  404. (widen)
  405. (goto-char (point-min))
  406. (if (re-search-forward
  407. (concat "^\\*+[ \t]+" heading "[ \t]*\\(:.*?:[ \t]*\\)?$")
  408. nil t)
  409. (goto-char (match-beginning 0))
  410. (goto-char (point-max))
  411. (insert "\n\n* " heading "\n\n")
  412. (org-back-to-heading t))
  413. (point))
  414. (defun org-feed-read-previous-status (pos drawer)
  415. "Get the alist of old GUIDs from the entry at POS.
  416. This will find DRAWER and extract the alist."
  417. (save-excursion
  418. (goto-char pos)
  419. (let ((end (save-excursion (org-end-of-subtree t t))))
  420. (if (re-search-forward
  421. (concat "^[ \t]*:" drawer ":[ \t]*\n\\([^\000]*?\\)\n[ \t]*:END:")
  422. end t)
  423. (read (match-string 1))
  424. nil))))
  425. (defun org-feed-write-status (pos drawer status)
  426. "Write the feed STATUS to DRAWER in entry at POS."
  427. (save-excursion
  428. (goto-char pos)
  429. (let ((end (save-excursion (org-end-of-subtree t t)))
  430. guid)
  431. (if (re-search-forward (concat "^[ \t]*:" drawer ":[ \t]*\n")
  432. end t)
  433. (progn
  434. (goto-char (match-end 0))
  435. (delete-region (point)
  436. (save-excursion
  437. (and (re-search-forward "^[ \t]*:END:" nil t)
  438. (match-beginning 0)))))
  439. (outline-next-heading)
  440. (insert " :" drawer ":\n :END:\n")
  441. (beginning-of-line 0))
  442. (insert (pp-to-string status)))))
  443. (defun org-feed-add-items (pos entries)
  444. "Add the formatted items to the headline as POS."
  445. (let (entry level)
  446. (save-excursion
  447. (goto-char pos)
  448. (unless (looking-at org-complex-heading-regexp)
  449. (error "Wrong position"))
  450. (setq level (org-get-valid-level (length (match-string 1)) 1))
  451. (org-end-of-subtree t t)
  452. (skip-chars-backward " \t\n")
  453. (beginning-of-line 2)
  454. (setq pos (point))
  455. (while (setq entry (pop entries))
  456. (org-paste-subtree level entry 'yank))
  457. (org-mark-ring-push pos))))
  458. (defun org-feed-format-entry (entry template formatter)
  459. "Format ENTRY so that it can be inserted into an Org file.
  460. ENTRY is a property list. This function adds a `:formatted-for-org' property
  461. and returns the full property list.
  462. If that property is already present, nothing changes."
  463. (if formatter
  464. (funcall formatter entry)
  465. (let (dlines fmt tmp indent time name
  466. v-h v-t v-T v-u v-U v-a)
  467. (setq dlines (org-split-string (or (plist-get entry :description) "???")
  468. "\n")
  469. v-h (or (plist-get entry :title) (car dlines) "???")
  470. time (or (if (plist-get entry :pubDate)
  471. (org-read-date t t (plist-get entry :pubDate)))
  472. (current-time))
  473. v-t (format-time-string (org-time-stamp-format nil nil) time)
  474. v-T (format-time-string (org-time-stamp-format t nil) time)
  475. v-u (format-time-string (org-time-stamp-format nil t) time)
  476. v-U (format-time-string (org-time-stamp-format t t) time)
  477. v-a (if (setq tmp (or (and (plist-get entry :guid-permalink)
  478. (plist-get entry :guid))
  479. (plist-get entry :link)))
  480. (concat "[[" tmp "]]\n")
  481. ""))
  482. (with-temp-buffer
  483. (insert template)
  484. (goto-char (point-min))
  485. (while (re-search-forward "%\\([a-zA-Z]+\\)" nil t)
  486. (setq name (match-string 1))
  487. (cond
  488. ((member name '("h" "t" "T" "u" "U" "a"))
  489. (replace-match (symbol-value (intern (concat "v-" name))) t t))
  490. ((setq tmp (plist-get entry (intern (concat ":" name))))
  491. (save-excursion
  492. (save-match-data
  493. (beginning-of-line 1)
  494. (when (looking-at (concat "^\\([ \t]*\\)%" name "[ \t]*$"))
  495. (setq tmp (org-feed-make-indented-block
  496. tmp (org-get-indentation))))))
  497. (replace-match tmp t t))))
  498. (decode-coding-string
  499. (buffer-string) (detect-coding-region (point-min) (point-max) t))))))
  500. (defun org-feed-make-indented-block (s n)
  501. "Add indentation of N spaces to a multiline string S."
  502. (if (not (string-match "\n" s))
  503. s
  504. (mapconcat 'identity
  505. (org-split-string s "\n")
  506. (concat "\n" (make-string n ?\ )))))
  507. (defun org-feed-skip-http-headers (buffer)
  508. "Remove HTTP headers from BUFFER, and return it.
  509. Assumes headers are indeed present!"
  510. (with-current-buffer buffer
  511. (widen)
  512. (goto-char (point-min))
  513. (search-forward "\n\n")
  514. (delete-region (point-min) (point))
  515. buffer))
  516. (defun org-feed-get-feed (url)
  517. "Get the RSS feed file at URL and return the buffer."
  518. (cond
  519. ((eq org-feed-retrieve-method 'url-retrieve-synchronously)
  520. (org-feed-skip-http-headers (url-retrieve-synchronously url)))
  521. ((eq org-feed-retrieve-method 'curl)
  522. (ignore-errors (kill-buffer org-feed-buffer))
  523. (call-process "curl" nil org-feed-buffer nil "--silent" url)
  524. org-feed-buffer)
  525. ((eq org-feed-retrieve-method 'wget)
  526. (ignore-errors (kill-buffer org-feed-buffer))
  527. (call-process "wget" nil org-feed-buffer nil "-q" "-O" "-" url)
  528. org-feed-buffer)
  529. ((functionp org-feed-retrieve-method)
  530. (funcall org-feed-retrieve-method url))))
  531. (defun org-feed-parse-rss-feed (buffer)
  532. "Parse BUFFER for RSS feed entries.
  533. Returns a list of entries, with each entry a property list,
  534. containing the properties `:guid' and `:item-full-text'."
  535. (let ((case-fold-search t)
  536. entries beg end item guid entry)
  537. (with-current-buffer buffer
  538. (widen)
  539. (goto-char (point-min))
  540. (while (re-search-forward "<item\\>.*?>" nil t)
  541. (setq beg (point)
  542. end (and (re-search-forward "</item>" nil t)
  543. (match-beginning 0)))
  544. (setq item (buffer-substring beg end)
  545. guid (if (string-match "<guid\\>.*?>\\(.*?\\)</guid>" item)
  546. (org-match-string-no-properties 1 item)))
  547. (setq entry (list :guid guid :item-full-text item))
  548. (push entry entries)
  549. (widen)
  550. (goto-char end))
  551. (nreverse entries))))
  552. (defun org-feed-parse-rss-entry (entry)
  553. "Parse the `:item-full-text' field for xml tags and create new properties."
  554. (require 'xml)
  555. (with-temp-buffer
  556. (insert (plist-get entry :item-full-text))
  557. (goto-char (point-min))
  558. (while (re-search-forward "<\\([a-zA-Z]+\\>\\).*?>\\([^\000]*?\\)</\\1>"
  559. nil t)
  560. (setq entry (plist-put entry
  561. (intern (concat ":" (match-string 1)))
  562. (xml-substitute-special (match-string 2)))))
  563. (goto-char (point-min))
  564. (unless (re-search-forward "isPermaLink[ \t]*=[ \t]*\"false\"" nil t)
  565. (setq entry (plist-put entry :guid-permalink t))))
  566. entry)
  567. (defun org-feed-parse-atom-feed (buffer)
  568. "Parse BUFFER for Atom feed entries.
  569. Returns a list of entries, with each entry a property list,
  570. containing the properties `:guid' and `:item-full-text'.
  571. The `:item-full-text' property actually contains the sexp
  572. formatted as a string, not the original XML data."
  573. (require 'xml)
  574. (with-current-buffer buffer
  575. (widen)
  576. (let ((feed (car (xml-parse-region (point-min) (point-max)))))
  577. (mapcar
  578. (lambda (entry)
  579. (list
  580. :guid (car (xml-node-children (car (xml-get-children entry 'id))))
  581. :item-full-text (prin1-to-string entry)))
  582. (xml-get-children feed 'entry)))))
  583. (defun org-feed-parse-atom-entry (entry)
  584. "Parse the `:item-full-text' as a sexp and create new properties."
  585. (let ((xml (car (read-from-string (plist-get entry :item-full-text)))))
  586. ;; Get first <link href='foo'/>.
  587. (setq entry (plist-put entry :link
  588. (xml-get-attribute
  589. (car (xml-get-children xml 'link))
  590. 'href)))
  591. ;; Add <title/> as :title.
  592. (setq entry (plist-put entry :title
  593. (xml-substitute-special
  594. (car (xml-node-children
  595. (car (xml-get-children xml 'title)))))))
  596. (let* ((content (car (xml-get-children xml 'content)))
  597. (type (xml-get-attribute-or-nil content 'type)))
  598. (when content
  599. (cond
  600. ((string= type "text")
  601. ;; We like plain text.
  602. (setq entry (plist-put entry :description
  603. (xml-substitute-special
  604. (car (xml-node-children content))))))
  605. ((string= type "html")
  606. ;; TODO: convert HTML to Org markup.
  607. (setq entry (plist-put entry :description
  608. (xml-substitute-special
  609. (car (xml-node-children content))))))
  610. ((string= type "xhtml")
  611. ;; TODO: convert XHTML to Org markup.
  612. (setq entry (plist-put entry :description
  613. (prin1-to-string
  614. (xml-node-children content)))))
  615. (t
  616. (setq entry (plist-put entry :description
  617. (format "Unknown '%s' content." type)))))))
  618. entry))
  619. (provide 'org-feed)
  620. ;; arch-tag: 0929b557-9bc4-47f4-9633-30a12dbb5ae2
  621. ;;; org-feed.el ends here