ob-ref.el 8.9 KB

123456789101112131415161718192021222324252627282930313233343536373839404142434445464748495051525354555657585960616263646566676869707172737475767778798081828384858687888990919293949596979899100101102103104105106107108109110111112113114115116117118119120121122123124125126127128129130131132133134135136137138139140141142143144145146147148149150151152153154155156157158159160161162163164165166167168169170171172173174175176177178179180181182183184185186187188189190191192193194195196197198199200201202203204205206207208209210211212213214215216217218219220221222223224225226227228229230231232233
  1. ;;; ob-ref.el --- org-babel functions for referencing external data
  2. ;; Copyright (C) 2009, 2010 Free Software Foundation, Inc.
  3. ;; Author: Eric Schulte, Dan Davison
  4. ;; Keywords: literate programming, reproducible research
  5. ;; Homepage: http://orgmode.org
  6. ;; Version: 7.5
  7. ;; This file is part of GNU Emacs.
  8. ;; GNU Emacs is free software: you can redistribute it and/or modify
  9. ;; it under the terms of the GNU General Public License as published by
  10. ;; the Free Software Foundation, either version 3 of the License, or
  11. ;; (at your option) any later version.
  12. ;; GNU Emacs is distributed in the hope that it will be useful,
  13. ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  14. ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  15. ;; GNU General Public License for more details.
  16. ;; You should have received a copy of the GNU General Public License
  17. ;; along with GNU Emacs. If not, see <http://www.gnu.org/licenses/>.
  18. ;;; Commentary:
  19. ;; Functions for referencing data from the header arguments of a
  20. ;; org-babel block. The syntax of such a reference should be
  21. ;; #+VAR: variable-name=file:resource-id
  22. ;; - variable-name :: the name of the variable to which the value
  23. ;; will be assigned
  24. ;; - file :: path to the file containing the resource, or omitted if
  25. ;; resource is in the current file
  26. ;; - resource-id :: the id or name of the resource
  27. ;; So an example of a simple src block referencing table data in the
  28. ;; same file would be
  29. ;; #+TBLNAME: sandbox
  30. ;; | 1 | 2 | 3 |
  31. ;; | 4 | org-babel | 6 |
  32. ;;
  33. ;; #+begin_src emacs-lisp :var table=sandbox
  34. ;; (message table)
  35. ;; #+end_src
  36. ;;; Code:
  37. (require 'ob)
  38. (eval-when-compile
  39. (require 'cl))
  40. (declare-function org-remove-if-not "org" (predicate seq))
  41. (declare-function org-at-table-p "org" (&optional table-type))
  42. (declare-function org-count "org" (CL-ITEM CL-SEQ))
  43. (declare-function org-at-item-p "org-list" ())
  44. (defvar org-babel-ref-split-regexp
  45. "[ \f\t\n\r\v]*\\(.+?\\)[ \f\t\n\r\v]*=[ \f\t\n\r\v]*\\(.+\\)[ \f\t\n\r\v]*")
  46. (defun org-babel-ref-parse (assignment)
  47. "Parse a variable ASSIGNMENT in a header argument.
  48. If the right hand side of the assignment has a literal value
  49. return that value, otherwise interpret as a reference to an
  50. external resource and find it's value using
  51. `org-babel-ref-resolve'. Return a list with two elements. The
  52. first element of the list will be the name of the variable, and
  53. the second will be an emacs-lisp representation of the value of
  54. the variable."
  55. (when (string-match org-babel-ref-split-regexp assignment)
  56. (let ((var (match-string 1 assignment))
  57. (ref (match-string 2 assignment)))
  58. (cons (intern var)
  59. (let ((out (org-babel-read ref)))
  60. (if (equal out ref)
  61. (if (string-match "^\".*\"$" ref)
  62. (read ref)
  63. (org-babel-ref-resolve ref))
  64. out))))))
  65. (defvar org-babel-library-of-babel)
  66. (defun org-babel-ref-resolve (ref)
  67. "Resolve the reference REF and return its value."
  68. (save-window-excursion
  69. (save-excursion
  70. (let ((case-fold-search t)
  71. type args new-refere new-header-args new-referent result
  72. lob-info split-file split-ref index index-row index-col)
  73. ;; if ref is indexed grab the indices -- beware nested indices
  74. (when (and (string-match "\\[\\([^\\[]+\\)\\]$" ref)
  75. (let ((str (substring ref 0 (match-beginning 0))))
  76. (= (org-count ?( str) (org-count ?) str))))
  77. (setq index (match-string 1 ref))
  78. (setq ref (substring ref 0 (match-beginning 0))))
  79. ;; assign any arguments to pass to source block
  80. (when (string-match
  81. "^\\(.+?\\)\\(\\[\\(.*\\)\\]\\|\\(\\)\\)\(\\(.*\\)\)$" ref)
  82. (setq new-refere (match-string 1 ref))
  83. (setq new-header-args (match-string 3 ref))
  84. (setq new-referent (match-string 5 ref))
  85. (when (> (length new-refere) 0)
  86. (when (> (length new-referent) 0)
  87. (setq args (mapcar (lambda (ref) (cons :var ref))
  88. (org-babel-ref-split-args new-referent))))
  89. (when (> (length new-header-args) 0)
  90. (setq args (append (org-babel-parse-header-arguments new-header-args)
  91. args)))
  92. (setq ref new-refere)))
  93. (when (string-match "^\\(.+\\):\\(.+\\)$" ref)
  94. (setq split-file (match-string 1 ref))
  95. (setq split-ref (match-string 2 ref))
  96. (find-file split-file) (setq ref split-ref))
  97. (save-restriction
  98. (widen)
  99. (goto-char (point-min))
  100. (if (let ((result_regexp (concat "^[ \t]*#\\+\\(TBLNAME\\|RESNAME"
  101. "\\|RESULTS\\):[ \t]*"
  102. (regexp-quote ref) "[ \t]*$"))
  103. (regexp (concat org-babel-src-name-regexp
  104. (regexp-quote ref) "\\(\(.*\)\\)?" "[ \t]*$")))
  105. ;; goto ref in the current buffer
  106. (or (and (not args)
  107. (or (re-search-forward result_regexp nil t)
  108. (re-search-backward result_regexp nil t)))
  109. (re-search-forward regexp nil t)
  110. (re-search-backward regexp nil t)
  111. ;; check the Library of Babel
  112. (setq lob-info (cdr (assoc (intern ref)
  113. org-babel-library-of-babel)))))
  114. (unless lob-info (goto-char (match-beginning 0)))
  115. ;; ;; TODO: allow searching for names in other buffers
  116. ;; (setq id-loc (org-id-find ref 'marker)
  117. ;; buffer (marker-buffer id-loc)
  118. ;; loc (marker-position id-loc))
  119. ;; (move-marker id-loc nil)
  120. (error "reference '%s' not found in this buffer" ref))
  121. (if lob-info
  122. (setq type 'lob)
  123. (while (not (setq type (org-babel-ref-at-ref-p)))
  124. (forward-line 1)
  125. (beginning-of-line)
  126. (if (or (= (point) (point-min)) (= (point) (point-max)))
  127. (error "reference not found"))))
  128. (let ((params (append args '((:results . "silent")))))
  129. (setq result
  130. (case type
  131. ('results-line (org-babel-read-result))
  132. ('table (org-babel-read-table))
  133. ('list (org-babel-read-list))
  134. ('file (org-babel-read-link))
  135. ('source-block (org-babel-execute-src-block nil nil params))
  136. ('lob (org-babel-execute-src-block nil lob-info params)))))
  137. (if (symbolp result)
  138. (format "%S" result)
  139. (if (and index (listp result))
  140. (org-babel-ref-index-list index result)
  141. result)))))))
  142. (defun org-babel-ref-index-list (index lis)
  143. "Return the subset of LIS indexed by INDEX.
  144. Indices are 0 based and negative indices count from the end of
  145. LIS, so 0 references the first element of LIS and -1 references
  146. the last. If INDEX is separated by \",\"s then each \"portion\"
  147. is assumed to index into the next deepest nesting or dimension.
  148. A valid \"portion\" can consist of either an integer index, two
  149. integers separated by a \":\" in which case the entire range is
  150. returned, or an empty string or \"*\" both of which are
  151. interpreted to mean the entire range and as such are equivalent
  152. to \"0:-1\"."
  153. (if (and (> (length index) 0) (string-match "^\\([^,]*\\),?" index))
  154. (let ((ind-re "\\(\\([-[:digit:]]+\\):\\([-[:digit:]]+\\)\\|\*\\)")
  155. (length (length lis))
  156. (portion (match-string 1 index))
  157. (remainder (substring index (match-end 0))))
  158. (flet ((wrap (num) (if (< num 0) (+ length num) num))
  159. (open (ls) (if (and (listp ls) (= (length ls) 1)) (car ls) ls)))
  160. (open
  161. (mapcar
  162. (lambda (sub-lis)
  163. (if (listp sub-lis)
  164. (org-babel-ref-index-list remainder sub-lis)
  165. sub-lis))
  166. (if (or (= 0 (length portion)) (string-match ind-re portion))
  167. (mapcar
  168. (lambda (n) (nth n lis))
  169. (apply 'org-number-sequence
  170. (if (and (> (length portion) 0) (match-string 2 portion))
  171. (list
  172. (wrap (string-to-number (match-string 2 portion)))
  173. (wrap (string-to-number (match-string 3 portion))))
  174. (list (wrap 0) (wrap -1)))))
  175. (list (nth (wrap (string-to-number portion)) lis)))))))
  176. lis))
  177. (defun org-babel-ref-split-args (arg-string)
  178. "Split ARG-STRING into top-level arguments of balanced parenthesis."
  179. (let ((index 0) (depth 0) (buffer "") holder return)
  180. ;; crawl along string, splitting at any ","s which are on the top level
  181. (while (< index (length arg-string))
  182. (setq holder (substring arg-string index (+ 1 index)))
  183. (setq buffer (concat buffer holder))
  184. (setq index (+ 1 index))
  185. (cond
  186. ((string= holder ",")
  187. (when (= depth 0)
  188. (setq return (reverse (cons (substring buffer 0 -1) return)))
  189. (setq buffer "")))
  190. ((or (string= holder "(") (string= holder "[")) (setq depth (+ depth 1)))
  191. ((or (string= holder ")") (string= holder "]")) (setq depth (- depth 1)))))
  192. (mapcar #'org-babel-trim (reverse (cons buffer return)))))
  193. (defvar org-bracket-link-regexp)
  194. (defun org-babel-ref-at-ref-p ()
  195. "Return the type of reference located at point.
  196. Return nil if none of the supported reference types are found.
  197. Supported reference types are tables and source blocks."
  198. (cond ((org-at-table-p) 'table)
  199. ((org-at-item-p) 'list)
  200. ((looking-at "^[ \t]*#\\+BEGIN_SRC") 'source-block)
  201. ((looking-at org-bracket-link-regexp) 'file)
  202. ((looking-at org-babel-result-regexp) 'results-line)))
  203. (provide 'ob-ref)
  204. ;; arch-tag: ace4a4f4-ea38-4dac-8fe6-6f52fcc43b6d
  205. ;;; ob-ref.el ends here