ob-lob.el 4.2 KB

123456789101112131415161718192021222324252627282930313233343536373839404142434445464748495051525354555657585960616263646566676869707172737475767778798081828384858687888990919293949596979899100101102103104105106107108109110111112113114115116117118119120121122123124125
  1. ;;; ob-lob.el --- functions supporting the Library of Babel
  2. ;; Copyright (C) 2009, 2010 Free Software Foundation, Inc.
  3. ;; Author: Eric Schulte, Dan Davison
  4. ;; Keywords: literate programming, reproducible research
  5. ;; Homepage: http://orgmode.org
  6. ;; Version: 7.5
  7. ;; This file is part of GNU Emacs.
  8. ;; GNU Emacs is free software: you can redistribute it and/or modify
  9. ;; it under the terms of the GNU General Public License as published by
  10. ;; the Free Software Foundation, either version 3 of the License, or
  11. ;; (at your option) any later version.
  12. ;; GNU Emacs is distributed in the hope that it will be useful,
  13. ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  14. ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  15. ;; GNU General Public License for more details.
  16. ;; You should have received a copy of the GNU General Public License
  17. ;; along with GNU Emacs. If not, see <http://www.gnu.org/licenses/>.
  18. ;;; Commentary:
  19. ;; See the online documentation for more information
  20. ;;
  21. ;; http://orgmode.org/worg/org-contrib/babel/
  22. ;;; Code:
  23. (require 'ob)
  24. (require 'ob-table)
  25. (defvar org-babel-library-of-babel nil
  26. "Library of source-code blocks.
  27. This is an association list. Populate the library by adding
  28. files to `org-babel-lob-files'.")
  29. (defcustom org-babel-lob-files '()
  30. "Files used to populate the `org-babel-library-of-babel'.
  31. To add files to this list use the `org-babel-lob-ingest' command."
  32. :group 'org-babel
  33. :type 'list)
  34. ;;;###autoload
  35. (defun org-babel-lob-ingest (&optional file)
  36. "Add all named source-blocks defined in FILE to
  37. `org-babel-library-of-babel'."
  38. (interactive "fFile: ")
  39. (let ((lob-ingest-count 0))
  40. (org-babel-map-src-blocks file
  41. (let* ((info (org-babel-get-src-block-info 'light))
  42. (source-name (nth 4 info)))
  43. (when source-name
  44. (setq source-name (intern source-name)
  45. org-babel-library-of-babel
  46. (cons (cons source-name info)
  47. (assq-delete-all source-name org-babel-library-of-babel))
  48. lob-ingest-count (1+ lob-ingest-count)))))
  49. (message "%d src block%s added to Library of Babel"
  50. lob-ingest-count (if (> lob-ingest-count 1) "s" ""))
  51. lob-ingest-count))
  52. (defconst org-babel-lob-call-aliases '("lob" "call")
  53. "Aliases to call a source block function.
  54. If you change the value of this variable then your files may
  55. become unusable by other org-babel users, and vice versa.")
  56. (defconst org-babel-lob-one-liner-regexp
  57. (concat
  58. "^\\([ \t]*\\)#\\+\\(?:"
  59. (mapconcat #'regexp-quote org-babel-lob-call-aliases "\\|")
  60. "\\):[ \t]+\\([^\(\)\n]+?\\)\\(\\[\\(.*\\)\\]\\|\\(\\)\\)"
  61. "\(\\([^\n]*\\)\)\\(\\[.+\\]\\|\\)[ \t]*\\([^\n]*\\)")
  62. "Regexp to match calls to predefined source block functions.")
  63. ;; functions for executing lob one-liners
  64. ;;;###autoload
  65. (defun org-babel-lob-execute-maybe ()
  66. "Execute a Library of Babel source block, if appropriate.
  67. Detect if this is context for a Library Of Babel source block and
  68. if so then run the appropriate source block from the Library."
  69. (interactive)
  70. (let ((info (org-babel-lob-get-info)))
  71. (if (nth 0 info) (progn (org-babel-lob-execute info) t) nil)))
  72. ;;;###autoload
  73. (defun org-babel-lob-get-info ()
  74. "Return a Library of Babel function call as a string."
  75. (let ((case-fold-search t))
  76. (save-excursion
  77. (beginning-of-line 1)
  78. (if (looking-at org-babel-lob-one-liner-regexp)
  79. (append
  80. (mapcar #'org-babel-clean-text-properties
  81. (list
  82. (format "%s%s(%s)%s"
  83. (match-string 2)
  84. (if (match-string 4)
  85. (concat "[" (match-string 4) "]") "")
  86. (or (match-string 6) "") (match-string 7))
  87. (match-string 8)))
  88. (list (length (match-string 1))))))))
  89. (defun org-babel-lob-execute (info)
  90. "Execute the lob call specified by INFO."
  91. (let ((params (org-babel-process-params
  92. (org-babel-merge-params
  93. org-babel-default-header-args
  94. (org-babel-params-from-buffer)
  95. (org-babel-params-from-properties)
  96. (org-babel-parse-header-arguments
  97. (org-babel-clean-text-properties
  98. (concat ":var results="
  99. (mapconcat #'identity (butlast info) " "))))))))
  100. (org-babel-execute-src-block
  101. nil (list "emacs-lisp" "results" params nil nil (nth 2 info)))))
  102. (provide 'ob-lob)
  103. ;; arch-tag: ce0712c9-2147-4019-ba3f-42341b8b474b
  104. ;;; ob-lob.el ends here