ob-R.el 11 KB

123456789101112131415161718192021222324252627282930313233343536373839404142434445464748495051525354555657585960616263646566676869707172737475767778798081828384858687888990919293949596979899100101102103104105106107108109110111112113114115116117118119120121122123124125126127128129130131132133134135136137138139140141142143144145146147148149150151152153154155156157158159160161162163164165166167168169170171172173174175176177178179180181182183184185186187188189190191192193194195196197198199200201202203204205206207208209210211212213214215216217218219220221222223224225226227228229230231232233234235236237238239240241242243244245246247248249250251252253254255256257258259260261262263264265266267268269270271272273274275276277278279280281282283284285286287288289290291292293294295296297298299300301302303304305306307308309310311
  1. ;;; ob-R.el --- org-babel functions for R code evaluation
  2. ;; Copyright (C) 2009, 2010 Free Software Foundation, Inc.
  3. ;; Author: Eric Schulte, Dan Davison
  4. ;; Keywords: literate programming, reproducible research, R, statistics
  5. ;; Homepage: http://orgmode.org
  6. ;; Version: 7.5
  7. ;; This file is part of GNU Emacs.
  8. ;; GNU Emacs is free software: you can redistribute it and/or modify
  9. ;; it under the terms of the GNU General Public License as published by
  10. ;; the Free Software Foundation, either version 3 of the License, or
  11. ;; (at your option) any later version.
  12. ;; GNU Emacs is distributed in the hope that it will be useful,
  13. ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  14. ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  15. ;; GNU General Public License for more details.
  16. ;; You should have received a copy of the GNU General Public License
  17. ;; along with GNU Emacs. If not, see <http://www.gnu.org/licenses/>.
  18. ;;; Commentary:
  19. ;; Org-Babel support for evaluating R code
  20. ;;; Code:
  21. (require 'ob)
  22. (require 'ob-ref)
  23. (require 'ob-comint)
  24. (require 'ob-eval)
  25. (eval-when-compile (require 'cl))
  26. (declare-function orgtbl-to-tsv "org-table" (table params))
  27. (declare-function R "ext:essd-r" (&optional start-args))
  28. (declare-function inferior-ess-send-input "ext:ess-inf" ())
  29. (declare-function ess-make-buffer-current "ext:ess-inf" ())
  30. (declare-function ess-eval-buffer "ext:ess-inf" (vis))
  31. (declare-function org-number-sequence "org-compat" (from &optional to inc))
  32. (defconst org-babel-header-arg-names:R
  33. '(width height bg units pointsize antialias quality compression
  34. res type family title fonts version paper encoding
  35. pagecentre colormodel useDingbats horizontal)
  36. "R-specific header arguments.")
  37. (defvar org-babel-default-header-args:R '())
  38. (defvar org-babel-R-command "R --slave --no-save"
  39. "Name of command to use for executing R code.")
  40. (defun org-babel-expand-body:R (body params &optional graphics-file)
  41. "Expand BODY according to PARAMS, return the expanded body."
  42. (let ((graphics-file
  43. (or graphics-file (org-babel-R-graphical-output-file params))))
  44. (mapconcat
  45. #'identity
  46. ((lambda (inside)
  47. (if graphics-file
  48. (append
  49. (list (org-babel-R-construct-graphics-device-call
  50. graphics-file params))
  51. inside
  52. (list "dev.off()"))
  53. inside))
  54. (append (org-babel-variable-assignments:R params)
  55. (list body))) "\n")))
  56. (defun org-babel-execute:R (body params)
  57. "Execute a block of R code.
  58. This function is called by `org-babel-execute-src-block'."
  59. (save-excursion
  60. (let* ((result-type (cdr (assoc :result-type params)))
  61. (session (org-babel-R-initiate-session
  62. (cdr (assoc :session params)) params))
  63. (colnames-p (cdr (assoc :colnames params)))
  64. (rownames-p (cdr (assoc :rownames params)))
  65. (graphics-file (org-babel-R-graphical-output-file params))
  66. (full-body (org-babel-expand-body:R body params graphics-file))
  67. (result
  68. (org-babel-R-evaluate
  69. session full-body result-type
  70. (or (equal "yes" colnames-p)
  71. (org-babel-pick-name
  72. (cdr (assoc :colname-names params)) colnames-p))
  73. (or (equal "yes" rownames-p)
  74. (org-babel-pick-name
  75. (cdr (assoc :rowname-names params)) rownames-p)))))
  76. (if graphics-file nil result))))
  77. (defun org-babel-prep-session:R (session params)
  78. "Prepare SESSION according to the header arguments specified in PARAMS."
  79. (let* ((session (org-babel-R-initiate-session session params))
  80. (var-lines (org-babel-variable-assignments:R params)))
  81. (org-babel-comint-in-buffer session
  82. (mapc (lambda (var)
  83. (end-of-line 1) (insert var) (comint-send-input nil t)
  84. (org-babel-comint-wait-for-output session)) var-lines))
  85. session))
  86. (defun org-babel-load-session:R (session body params)
  87. "Load BODY into SESSION."
  88. (save-window-excursion
  89. (let ((buffer (org-babel-prep-session:R session params)))
  90. (with-current-buffer buffer
  91. (goto-char (process-mark (get-buffer-process (current-buffer))))
  92. (insert (org-babel-chomp body)))
  93. buffer)))
  94. ;; helper functions
  95. (defun org-babel-variable-assignments:R (params)
  96. "Return list of R statements assigning the block's variables"
  97. (let ((vars (mapcar #'cdr (org-babel-get-header params :var))))
  98. (mapcar
  99. (lambda (pair)
  100. (org-babel-R-assign-elisp
  101. (car pair) (cdr pair)
  102. (equal "yes" (cdr (assoc :colnames params)))
  103. (equal "yes" (cdr (assoc :rownames params)))))
  104. (mapcar
  105. (lambda (i)
  106. (cons (car (nth i vars))
  107. (org-babel-reassemble-table
  108. (cdr (nth i vars))
  109. (cdr (nth i (cdr (assoc :colname-names params))))
  110. (cdr (nth i (cdr (assoc :rowname-names params)))))))
  111. (org-number-sequence 0 (1- (length vars)))))))
  112. (defun org-babel-R-quote-tsv-field (s)
  113. "Quote field S for export to R."
  114. (if (stringp s)
  115. (concat "\"" (mapconcat 'identity (split-string s "\"") "\"\"") "\"")
  116. (format "%S" s)))
  117. (defun org-babel-R-assign-elisp (name value colnames-p rownames-p)
  118. "Construct R code assigning the elisp VALUE to a variable named NAME."
  119. (if (listp value)
  120. (let ((transition-file (org-babel-temp-file "R-import-")))
  121. ;; ensure VALUE has an orgtbl structure (depth of at least 2)
  122. (unless (listp (car value)) (setq value (list value)))
  123. (with-temp-file transition-file
  124. (insert (orgtbl-to-tsv value '(:fmt org-babel-R-quote-tsv-field)))
  125. (insert "\n"))
  126. (format "%s <- read.table(\"%s\", header=%s, row.names=%s, sep=\"\\t\", as.is=TRUE)"
  127. name (org-babel-process-file-name transition-file 'noquote)
  128. (if (or (eq (nth 1 value) 'hline) colnames-p) "TRUE" "FALSE")
  129. (if rownames-p "1" "NULL")))
  130. (format "%s <- %s" name (org-babel-R-quote-tsv-field value))))
  131. (defvar ess-ask-for-ess-directory nil)
  132. (defun org-babel-R-initiate-session (session params)
  133. "If there is not a current R process then create one."
  134. (unless (string= session "none")
  135. (let ((session (or session "*R*"))
  136. (ess-ask-for-ess-directory
  137. (and ess-ask-for-ess-directory (not (cdr (assoc :dir params))))))
  138. (if (org-babel-comint-buffer-livep session)
  139. session
  140. (save-window-excursion
  141. (require 'ess) (R)
  142. (rename-buffer
  143. (if (bufferp session)
  144. (buffer-name session)
  145. (if (stringp session)
  146. session
  147. (buffer-name))))
  148. (current-buffer))))))
  149. (defvar ess-local-process-name nil)
  150. (defun org-babel-R-associate-session (session)
  151. "Associate R code buffer with an R session.
  152. Make SESSION be the inferior ESS process associated with the
  153. current code buffer."
  154. (setq ess-local-process-name
  155. (process-name (get-buffer-process session)))
  156. (ess-make-buffer-current))
  157. (defun org-babel-R-graphical-output-file (params)
  158. "Name of file to which R should send graphical output."
  159. (and (member "graphics" (cdr (assq :result-params params)))
  160. (cdr (assq :file params))))
  161. (defun org-babel-R-construct-graphics-device-call (out-file params)
  162. "Construct the call to the graphics device."
  163. (let ((devices
  164. '((:bmp . "bmp")
  165. (:jpg . "jpeg")
  166. (:jpeg . "jpeg")
  167. (:tiff . "tiff")
  168. (:png . "png")
  169. (:svg . "svg")
  170. (:pdf . "pdf")
  171. (:ps . "postscript")
  172. (:postscript . "postscript")))
  173. (allowed-args '(:width :height :bg :units :pointsize
  174. :antialias :quality :compression :res
  175. :type :family :title :fonts :version
  176. :paper :encoding :pagecentre :colormodel
  177. :useDingbats :horizontal))
  178. (device (and (string-match ".+\\.\\([^.]+\\)" out-file)
  179. (match-string 1 out-file)))
  180. (extra-args (cdr (assq :R-dev-args params))) filearg args)
  181. (setq device (or (and device (cdr (assq (intern (concat ":" device))
  182. devices))) "png"))
  183. (setq filearg
  184. (if (member device '("pdf" "postscript" "svg")) "file" "filename"))
  185. (setq args (mapconcat
  186. (lambda (pair)
  187. (if (member (car pair) allowed-args)
  188. (format ",%s=%s"
  189. (substring (symbol-name (car pair)) 1)
  190. (cdr pair)) ""))
  191. params ""))
  192. (format "%s(%s=\"%s\"%s%s%s)"
  193. device filearg out-file args
  194. (if extra-args "," "") (or extra-args ""))))
  195. (defvar org-babel-R-eoe-indicator "'org_babel_R_eoe'")
  196. (defvar org-babel-R-eoe-output "[1] \"org_babel_R_eoe\"")
  197. (defvar org-babel-R-write-object-command "{function(object, transfer.file) {object;invisible(if(inherits(try(write.table(object, file=transfer.file, sep=\"\\t\", na=\"nil\",row.names=%s, col.names=%s, quote=FALSE), silent=TRUE),\"try-error\")) {if(!file.exists(transfer.file)) file.create(transfer.file)})}}(object=%s, transfer.file=\"%s\")")
  198. (defun org-babel-R-evaluate
  199. (session body result-type column-names-p row-names-p)
  200. "Evaluate R code in BODY."
  201. (if session
  202. (org-babel-R-evaluate-session
  203. session body result-type column-names-p row-names-p)
  204. (org-babel-R-evaluate-external-process
  205. body result-type column-names-p row-names-p)))
  206. (defun org-babel-R-evaluate-external-process
  207. (body result-type column-names-p row-names-p)
  208. "Evaluate BODY in external R process.
  209. If RESULT-TYPE equals 'output then return standard output as a
  210. string. If RESULT-TYPE equals 'value then return the value of the
  211. last statement in BODY, as elisp."
  212. (case result-type
  213. (value
  214. (let ((tmp-file (org-babel-temp-file "R-")))
  215. (org-babel-eval org-babel-R-command
  216. (format org-babel-R-write-object-command
  217. (if row-names-p "TRUE" "FALSE")
  218. (if column-names-p
  219. (if row-names-p "NA" "TRUE")
  220. "FALSE")
  221. (format "{function ()\n{\n%s\n}}()" body)
  222. (org-babel-process-file-name tmp-file 'noquote)))
  223. (org-babel-R-process-value-result
  224. (org-babel-import-elisp-from-file tmp-file '(16)) column-names-p)))
  225. (output (org-babel-eval org-babel-R-command body))))
  226. (defun org-babel-R-evaluate-session
  227. (session body result-type column-names-p row-names-p)
  228. "Evaluate BODY in SESSION.
  229. If RESULT-TYPE equals 'output then return standard output as a
  230. string. If RESULT-TYPE equals 'value then return the value of the
  231. last statement in BODY, as elisp."
  232. (case result-type
  233. (value
  234. (with-temp-buffer
  235. (insert (org-babel-chomp body))
  236. (let ((ess-local-process-name
  237. (process-name (get-buffer-process session))))
  238. (ess-eval-buffer nil)))
  239. (let ((tmp-file (org-babel-temp-file "R-")))
  240. (org-babel-comint-eval-invisibly-and-wait-for-file
  241. session tmp-file
  242. (format org-babel-R-write-object-command
  243. (if row-names-p "TRUE" "FALSE")
  244. (if column-names-p
  245. (if row-names-p "NA" "TRUE")
  246. "FALSE")
  247. ".Last.value" (org-babel-process-file-name tmp-file 'noquote)))
  248. (org-babel-R-process-value-result
  249. (org-babel-import-elisp-from-file tmp-file '(16)) column-names-p)))
  250. (output
  251. (mapconcat
  252. #'org-babel-chomp
  253. (butlast
  254. (delq nil
  255. (mapcar
  256. (lambda (line) (when (> (length line) 0) line))
  257. (mapcar
  258. (lambda (line) ;; cleanup extra prompts left in output
  259. (if (string-match
  260. "^\\([ ]*[>+][ ]?\\)+\\([[0-9]+\\|[ ]\\)" line)
  261. (substring line (match-end 1))
  262. line))
  263. (org-babel-comint-with-output (session org-babel-R-eoe-output)
  264. (insert (mapconcat #'org-babel-chomp
  265. (list body org-babel-R-eoe-indicator)
  266. "\n"))
  267. (inferior-ess-send-input)))))) "\n"))))
  268. (defun org-babel-R-process-value-result (result column-names-p)
  269. "R-specific processing of return value.
  270. Insert hline if column names in output have been requested."
  271. (if column-names-p
  272. (cons (car result) (cons 'hline (cdr result)))
  273. result))
  274. (provide 'ob-R)
  275. ;; arch-tag: cd4c7298-503b-450f-a3c2-f3e74b630237
  276. ;;; ob-R.el ends here