ox-icalendar.el 35 KB

123456789101112131415161718192021222324252627282930313233343536373839404142434445464748495051525354555657585960616263646566676869707172737475767778798081828384858687888990919293949596979899100101102103104105106107108109110111112113114115116117118119120121122123124125126127128129130131132133134135136137138139140141142143144145146147148149150151152153154155156157158159160161162163164165166167168169170171172173174175176177178179180181182183184185186187188189190191192193194195196197198199200201202203204205206207208209210211212213214215216217218219220221222223224225226227228229230231232233234235236237238239240241242243244245246247248249250251252253254255256257258259260261262263264265266267268269270271272273274275276277278279280281282283284285286287288289290291292293294295296297298299300301302303304305306307308309310311312313314315316317318319320321322323324325326327328329330331332333334335336337338339340341342343344345346347348349350351352353354355356357358359360361362363364365366367368369370371372373374375376377378379380381382383384385386387388389390391392393394395396397398399400401402403404405406407408409410411412413414415416417418419420421422423424425426427428429430431432433434435436437438439440441442443444445446447448449450451452453454455456457458459460461462463464465466467468469470471472473474475476477478479480481482483484485486487488489490491492493494495496497498499500501502503504505506507508509510511512513514515516517518519520521522523524525526527528529530531532533534535536537538539540541542543544545546547548549550551552553554555556557558559560561562563564565566567568569570571572573574575576577578579580581582583584585586587588589590591592593594595596597598599600601602603604605606607608609610611612613614615616617618619620621622623624625626627628629630631632633634635636637638639640641642643644645646647648649650651652653654655656657658659660661662663664665666667668669670671672673674675676677678679680681682683684685686687688689690691692693694695696697698699700701702703704705706707708709710711712713714715716717718719720721722723724725726727728729730731732733734735736737738739740741742743744745746747748749750751752753754755756757758759760761762763764765766767768769770771772773774775776777778779780781782783784785786787788789790791792793794795796797798799800801802803804805806807808809810811812813814815816817818819820821822823824825826827828829830831832833834835836837838839840841842843844845846847848849850851852853854855856857858859860861862863864865866867868869870871872873874875876877878879880881882883884885886887888889890891892893894895896897898899900901902903904905906907908909910911912913914915916917918919920921922923924925926927928929930931932933934935936937938939940941942943944945946947948949950951952953954955956957958959960961
  1. ;;; ox-icalendar.el --- iCalendar Back-End for Org Export Engine -*- lexical-binding: t; -*-
  2. ;; Copyright (C) 2004-2016 Free Software Foundation, Inc.
  3. ;; Author: Carsten Dominik <carsten at orgmode dot org>
  4. ;; Nicolas Goaziou <n dot goaziou at gmail dot com>
  5. ;; Keywords: outlines, hypermedia, calendar, wp
  6. ;; Homepage: http://orgmode.org
  7. ;; This file is part of GNU Emacs.
  8. ;; GNU Emacs is free software: you can redistribute it and/or modify
  9. ;; it under the terms of the GNU General Public License as published by
  10. ;; the Free Software Foundation, either version 3 of the License, or
  11. ;; (at your option) any later version.
  12. ;; GNU Emacs is distributed in the hope that it will be useful,
  13. ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  14. ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  15. ;; GNU General Public License for more details.
  16. ;; You should have received a copy of the GNU General Public License
  17. ;; along with GNU Emacs. If not, see <http://www.gnu.org/licenses/>.
  18. ;;; Commentary:
  19. ;;
  20. ;; This library implements an iCalendar back-end for Org generic
  21. ;; exporter. See Org manual for more information.
  22. ;;
  23. ;; It is expected to conform to RFC 5545.
  24. ;;; Code:
  25. (require 'cl-lib)
  26. (require 'ox-ascii)
  27. (declare-function org-bbdb-anniv-export-ical "org-bbdb" nil)
  28. ;;; User-Configurable Variables
  29. (defgroup org-export-icalendar nil
  30. "Options specific for iCalendar export back-end."
  31. :tag "Org Export iCalendar"
  32. :group 'org-export)
  33. (defcustom org-icalendar-combined-agenda-file "~/org.ics"
  34. "The file name for the iCalendar file covering all agenda files.
  35. This file is created with the command `\\[org-icalendar-combine-agenda-files]'.
  36. The file name should be absolute. It will be overwritten without warning."
  37. :group 'org-export-icalendar
  38. :type 'file)
  39. (defcustom org-icalendar-alarm-time 0
  40. "Number of minutes for triggering an alarm for exported timed events.
  41. A zero value (the default) turns off the definition of an alarm trigger
  42. for timed events. If non-zero, alarms are created.
  43. - a single alarm per entry is defined
  44. - The alarm will go off N minutes before the event
  45. - only a DISPLAY action is defined."
  46. :group 'org-export-icalendar
  47. :version "24.1"
  48. :type 'integer)
  49. (defcustom org-icalendar-combined-name "OrgMode"
  50. "Calendar name for the combined iCalendar representing all agenda files."
  51. :group 'org-export-icalendar
  52. :type 'string)
  53. (defcustom org-icalendar-combined-description ""
  54. "Calendar description for the combined iCalendar (all agenda files)."
  55. :group 'org-export-icalendar
  56. :type 'string)
  57. (defcustom org-icalendar-exclude-tags nil
  58. "Tags that exclude a tree from export.
  59. This variable allows specifying different exclude tags from other
  60. back-ends. It can also be set with the ICALENDAR_EXCLUDE_TAGS
  61. keyword."
  62. :group 'org-export-icalendar
  63. :type '(repeat (string :tag "Tag")))
  64. (defcustom org-icalendar-use-deadline '(event-if-not-todo todo-due)
  65. "Contexts where iCalendar export should use a deadline time stamp.
  66. This is a list with possibly several symbols in it. Valid symbols are:
  67. `event-if-todo' Deadlines in TODO entries become calendar events.
  68. `event-if-not-todo' Deadlines in non-TODO entries become calendar events.
  69. `todo-due' Use deadlines in TODO entries as due-dates."
  70. :group 'org-export-icalendar
  71. :type '(set :greedy t
  72. (const :tag "Deadlines in non-TODO entries become events"
  73. event-if-not-todo)
  74. (const :tag "Deadline in TODO entries become events"
  75. event-if-todo)
  76. (const :tag "Deadlines in TODO entries become due-dates"
  77. todo-due)))
  78. (defcustom org-icalendar-use-scheduled '(todo-start)
  79. "Contexts where iCalendar export should use a scheduling time stamp.
  80. This is a list with possibly several symbols in it. Valid symbols are:
  81. `event-if-todo' Scheduling time stamps in TODO entries become an event.
  82. `event-if-not-todo' Scheduling time stamps in non-TODO entries become an event.
  83. `todo-start' Scheduling time stamps in TODO entries become start date.
  84. Some calendar applications show TODO entries only after
  85. that date."
  86. :group 'org-export-icalendar
  87. :type '(set :greedy t
  88. (const :tag
  89. "SCHEDULED timestamps in non-TODO entries become events"
  90. event-if-not-todo)
  91. (const :tag "SCHEDULED timestamps in TODO entries become events"
  92. event-if-todo)
  93. (const :tag "SCHEDULED in TODO entries become start date"
  94. todo-start)))
  95. (defcustom org-icalendar-categories '(local-tags category)
  96. "Items that should be entered into the \"categories\" field.
  97. This is a list of symbols, the following are valid:
  98. `category' The Org mode category of the current file or tree
  99. `todo-state' The todo state, if any
  100. `local-tags' The tags, defined in the current line
  101. `all-tags' All tags, including inherited ones."
  102. :group 'org-export-icalendar
  103. :type '(repeat
  104. (choice
  105. (const :tag "The file or tree category" category)
  106. (const :tag "The TODO state" todo-state)
  107. (const :tag "Tags defined in current line" local-tags)
  108. (const :tag "All tags, including inherited ones" all-tags))))
  109. (defcustom org-icalendar-with-timestamps 'active
  110. "Non-nil means make an event from plain time stamps.
  111. It can be set to `active', `inactive', t or nil, in order to make
  112. an event from, respectively, only active timestamps, only
  113. inactive ones, all of them or none.
  114. This variable has precedence over `org-export-with-timestamps'.
  115. It can also be set with the #+OPTIONS line, e.g. \"<:t\"."
  116. :group 'org-export-icalendar
  117. :type '(choice
  118. (const :tag "All timestamps" t)
  119. (const :tag "Only active timestamps" active)
  120. (const :tag "Only inactive timestamps" inactive)
  121. (const :tag "No timestamp" nil)))
  122. (defcustom org-icalendar-include-todo nil
  123. "Non-nil means create VTODO components from TODO items.
  124. Valid values are:
  125. nil don't include any task.
  126. t include tasks that are not in DONE state.
  127. `unblocked' include all TODO items that are not blocked.
  128. `all' include both done and not done items."
  129. :group 'org-export-icalendar
  130. :type '(choice
  131. (const :tag "None" nil)
  132. (const :tag "Unfinished" t)
  133. (const :tag "Unblocked" unblocked)
  134. (const :tag "All" all)
  135. (repeat :tag "Specific TODO keywords"
  136. (string :tag "Keyword"))))
  137. (defcustom org-icalendar-include-bbdb-anniversaries nil
  138. "Non-nil means a combined iCalendar file should include anniversaries.
  139. The anniversaries are defined in the BBDB database."
  140. :group 'org-export-icalendar
  141. :type 'boolean)
  142. (defcustom org-icalendar-include-sexps t
  143. "Non-nil means export to iCalendar files should also cover sexp entries.
  144. These are entries like in the diary, but directly in an Org file."
  145. :group 'org-export-icalendar
  146. :type 'boolean)
  147. (defcustom org-icalendar-include-body t
  148. "Amount of text below headline to be included in iCalendar export.
  149. This is a number of characters that should maximally be included.
  150. Properties, scheduling and clocking lines will always be removed.
  151. The text will be inserted into the DESCRIPTION field."
  152. :group 'org-export-icalendar
  153. :type '(choice
  154. (const :tag "Nothing" nil)
  155. (const :tag "Everything" t)
  156. (integer :tag "Max characters")))
  157. (defcustom org-icalendar-store-UID nil
  158. "Non-nil means store any created UIDs in properties.
  159. The iCalendar standard requires that all entries have a unique identifier.
  160. Org will create these identifiers as needed. When this variable is non-nil,
  161. the created UIDs will be stored in the ID property of the entry. Then the
  162. next time this entry is exported, it will be exported with the same UID,
  163. superseding the previous form of it. This is essential for
  164. synchronization services.
  165. This variable is not turned on by default because we want to avoid creating
  166. a property drawer in every entry if people are only playing with this feature,
  167. or if they are only using it locally."
  168. :group 'org-export-icalendar
  169. :type 'boolean)
  170. (defcustom org-icalendar-timezone (getenv "TZ")
  171. "The time zone string for iCalendar export.
  172. When nil or the empty string, use output
  173. from (current-time-zone)."
  174. :group 'org-export-icalendar
  175. :type '(choice
  176. (const :tag "Unspecified" nil)
  177. (string :tag "Time zone")))
  178. (defcustom org-icalendar-date-time-format ":%Y%m%dT%H%M%S"
  179. "Format-string for exporting icalendar DATE-TIME.
  180. See `format-time-string' for a full documentation. The only
  181. difference is that `org-icalendar-timezone' is used for %Z.
  182. Interesting value are:
  183. - \":%Y%m%dT%H%M%S\" for local time
  184. - \";TZID=%Z:%Y%m%dT%H%M%S\" for local time with explicit timezone
  185. - \":%Y%m%dT%H%M%SZ\" for time expressed in Universal Time"
  186. :group 'org-export-icalendar
  187. :version "24.1"
  188. :type '(choice
  189. (const :tag "Local time" ":%Y%m%dT%H%M%S")
  190. (const :tag "Explicit local time" ";TZID=%Z:%Y%m%dT%H%M%S")
  191. (const :tag "Universal time" ":%Y%m%dT%H%M%SZ")
  192. (string :tag "Explicit format")))
  193. (defvar org-icalendar-after-save-hook nil
  194. "Hook run after an iCalendar file has been saved.
  195. This hook is run with the name of the file as argument. A good
  196. way to use this is to tell a desktop calendar application to
  197. re-read the iCalendar file.")
  198. ;;; Define Back-End
  199. (org-export-define-derived-backend 'icalendar 'ascii
  200. :translate-alist '((clock . ignore)
  201. (footnote-definition . ignore)
  202. (footnote-reference . ignore)
  203. (headline . org-icalendar-entry)
  204. (inlinetask . ignore)
  205. (planning . ignore)
  206. (section . ignore)
  207. (inner-template . (lambda (c i) c))
  208. (template . org-icalendar-template))
  209. :options-alist
  210. '((:exclude-tags
  211. "ICALENDAR_EXCLUDE_TAGS" nil org-icalendar-exclude-tags split)
  212. (:with-timestamps nil "<" org-icalendar-with-timestamps)
  213. ;; Other variables.
  214. (:icalendar-alarm-time nil nil org-icalendar-alarm-time)
  215. (:icalendar-categories nil nil org-icalendar-categories)
  216. (:icalendar-date-time-format nil nil org-icalendar-date-time-format)
  217. (:icalendar-include-bbdb-anniversaries nil nil org-icalendar-include-bbdb-anniversaries)
  218. (:icalendar-include-body nil nil org-icalendar-include-body)
  219. (:icalendar-include-sexps nil nil org-icalendar-include-sexps)
  220. (:icalendar-include-todo nil nil org-icalendar-include-todo)
  221. (:icalendar-store-UID nil nil org-icalendar-store-UID)
  222. (:icalendar-timezone nil nil org-icalendar-timezone)
  223. (:icalendar-use-deadline nil nil org-icalendar-use-deadline)
  224. (:icalendar-use-scheduled nil nil org-icalendar-use-scheduled))
  225. :filters-alist
  226. '((:filter-headline . org-icalendar-clear-blank-lines))
  227. :menu-entry
  228. '(?c "Export to iCalendar"
  229. ((?f "Current file" org-icalendar-export-to-ics)
  230. (?a "All agenda files"
  231. (lambda (a s v b) (org-icalendar-export-agenda-files a)))
  232. (?c "Combine all agenda files"
  233. (lambda (a s v b) (org-icalendar-combine-agenda-files a))))))
  234. ;;; Internal Functions
  235. (defun org-icalendar-create-uid (file &optional bell)
  236. "Set ID property on headlines missing it in FILE.
  237. When optional argument BELL is non-nil, inform the user with
  238. a message if the file was modified."
  239. (let (modified-flag)
  240. (org-map-entries
  241. (lambda ()
  242. (let ((entry (org-element-at-point)))
  243. (unless (org-element-property :ID entry)
  244. (org-id-get-create)
  245. (setq modified-flag t)
  246. (forward-line))))
  247. nil nil 'comment)
  248. (when (and bell modified-flag)
  249. (message "ID properties created in file \"%s\"" file)
  250. (sit-for 2))))
  251. (defun org-icalendar-blocked-headline-p (headline info)
  252. "Non-nil when HEADLINE is considered to be blocked.
  253. INFO is a plist used as a communication channel.
  254. A headline is blocked when either
  255. - it has children which are not all in a completed state;
  256. - it has a parent with the property :ORDERED:, and there are
  257. siblings prior to it with incomplete status;
  258. - its parent is blocked because it has siblings that should be
  259. done first or is a child of a blocked grandparent entry."
  260. (or
  261. ;; Check if any child is not done.
  262. (org-element-map headline 'headline
  263. (lambda (hl) (eq (org-element-property :todo-type hl) 'todo))
  264. info 'first-match)
  265. ;; Check :ORDERED: node property.
  266. (catch 'blockedp
  267. (let ((current headline))
  268. (dolist (parent (org-element-lineage headline))
  269. (cond
  270. ((not (org-element-property :todo-keyword parent))
  271. (throw 'blockedp nil))
  272. ((org-not-nil (org-element-property :ORDERED parent))
  273. (let ((sibling current))
  274. (while (setq sibling (org-export-get-previous-element
  275. sibling info))
  276. (when (eq (org-element-property :todo-type sibling) 'todo)
  277. (throw 'blockedp t)))))
  278. (t (setq current parent))))))))
  279. (defun org-icalendar-use-UTC-date-time-p ()
  280. "Non-nil when `org-icalendar-date-time-format' requires UTC time."
  281. (char-equal (elt org-icalendar-date-time-format
  282. (1- (length org-icalendar-date-time-format))) ?Z))
  283. (defvar org-agenda-default-appointment-duration) ; From org-agenda.el.
  284. (defun org-icalendar-convert-timestamp (timestamp keyword &optional end utc)
  285. "Convert TIMESTAMP to iCalendar format.
  286. TIMESTAMP is a timestamp object. KEYWORD is added in front of
  287. it, in order to make a complete line (e.g. \"DTSTART\").
  288. When optional argument END is non-nil, use end of time range.
  289. Also increase the hour by two (if time string contains a time),
  290. or the day by one (if it does not contain a time) when no
  291. explicit ending time is specified.
  292. When optional argument UTC is non-nil, time will be expressed in
  293. Universal Time, ignoring `org-icalendar-date-time-format'."
  294. (let* ((year-start (org-element-property :year-start timestamp))
  295. (year-end (org-element-property :year-end timestamp))
  296. (month-start (org-element-property :month-start timestamp))
  297. (month-end (org-element-property :month-end timestamp))
  298. (day-start (org-element-property :day-start timestamp))
  299. (day-end (org-element-property :day-end timestamp))
  300. (hour-start (org-element-property :hour-start timestamp))
  301. (hour-end (org-element-property :hour-end timestamp))
  302. (minute-start (org-element-property :minute-start timestamp))
  303. (minute-end (org-element-property :minute-end timestamp))
  304. (with-time-p minute-start)
  305. (equal-bounds-p
  306. (equal (list year-start month-start day-start hour-start minute-start)
  307. (list year-end month-end day-end hour-end minute-end)))
  308. (mi (cond ((not with-time-p) 0)
  309. ((not end) minute-start)
  310. ((and org-agenda-default-appointment-duration equal-bounds-p)
  311. (+ minute-end org-agenda-default-appointment-duration))
  312. (t minute-end)))
  313. (h (cond ((not with-time-p) 0)
  314. ((not end) hour-start)
  315. ((or (not equal-bounds-p)
  316. org-agenda-default-appointment-duration)
  317. hour-end)
  318. (t (+ hour-end 2))))
  319. (d (cond ((not end) day-start)
  320. ((not with-time-p) (1+ day-end))
  321. (t day-end)))
  322. (m (if end month-end month-start))
  323. (y (if end year-end year-start)))
  324. (concat
  325. keyword
  326. (format-time-string
  327. (cond (utc ":%Y%m%dT%H%M%SZ")
  328. ((not with-time-p) ";VALUE=DATE:%Y%m%d")
  329. (t (replace-regexp-in-string "%Z"
  330. org-icalendar-timezone
  331. org-icalendar-date-time-format
  332. t)))
  333. ;; Convert timestamp into internal time in order to use
  334. ;; `format-time-string' and fix any mistake (i.e. MI >= 60).
  335. (encode-time 0 mi h d m y)
  336. (and (or utc (and with-time-p (org-icalendar-use-UTC-date-time-p)))
  337. t)))))
  338. (defun org-icalendar-dtstamp ()
  339. "Return DTSTAMP property, as a string."
  340. (format-time-string "DTSTAMP:%Y%m%dT%H%M%SZ" nil t))
  341. (defun org-icalendar-get-categories (entry info)
  342. "Return categories according to `org-icalendar-categories'.
  343. ENTRY is a headline or an inlinetask element. INFO is a plist
  344. used as a communication channel."
  345. (mapconcat
  346. #'identity
  347. (org-uniquify
  348. (let (categories)
  349. (dolist (type org-icalendar-categories (nreverse categories))
  350. (cl-case type
  351. (category
  352. (push (org-export-get-category entry info) categories))
  353. (todo-state
  354. (let ((todo (org-element-property :todo-keyword entry)))
  355. (and todo (push todo categories))))
  356. (local-tags
  357. (setq categories
  358. (append (nreverse (org-export-get-tags entry info))
  359. categories)))
  360. (all-tags
  361. (setq categories
  362. (append (nreverse (org-export-get-tags entry info nil t))
  363. categories)))))))
  364. ","))
  365. (defun org-icalendar-transcode-diary-sexp (sexp uid summary)
  366. "Transcode a diary sexp into iCalendar format.
  367. SEXP is the diary sexp being transcoded, as a string. UID is the
  368. unique identifier for the entry. SUMMARY defines a short summary
  369. or subject for the event."
  370. (when (require 'icalendar nil t)
  371. (org-element-normalize-string
  372. (with-temp-buffer
  373. (let ((sexp (if (not (string-match "\\`<%%" sexp)) sexp
  374. (concat (substring sexp 1 -1) " " summary))))
  375. (put-text-property 0 1 'uid uid sexp)
  376. (insert sexp "\n"))
  377. (org-diary-to-ical-string (current-buffer))))))
  378. (defun org-icalendar-cleanup-string (s)
  379. "Cleanup string S according to RFC 5545."
  380. (when s
  381. ;; Protect "\", "," and ";" characters. and replace newline
  382. ;; characters with literal \n.
  383. (replace-regexp-in-string
  384. "[ \t]*\n" "\\n"
  385. (replace-regexp-in-string "[\\,;]" "\\\\\\&" s)
  386. nil t)))
  387. (defun org-icalendar-fold-string (s)
  388. "Fold string S according to RFC 5545."
  389. (org-element-normalize-string
  390. (mapconcat
  391. (lambda (line)
  392. ;; Limit each line to a maximum of 75 characters. If it is
  393. ;; longer, fold it by using "\n " as a continuation marker.
  394. (let ((len (length line)))
  395. (if (<= len 75) line
  396. (let ((folded-line (substring line 0 75))
  397. (chunk-start 75)
  398. chunk-end)
  399. ;; Since continuation marker takes up one character on the
  400. ;; line, real contents must be split at 74 chars.
  401. (while (< (setq chunk-end (+ chunk-start 74)) len)
  402. (setq folded-line
  403. (concat folded-line "\n "
  404. (substring line chunk-start chunk-end))
  405. chunk-start chunk-end))
  406. (concat folded-line "\n " (substring line chunk-start))))))
  407. (org-split-string s "\n") "\n")))
  408. ;;; Filters
  409. (defun org-icalendar-clear-blank-lines (headline _back-end _info)
  410. "Remove blank lines in HEADLINE export.
  411. HEADLINE is a string representing a transcoded headline.
  412. BACK-END and INFO are ignored."
  413. (replace-regexp-in-string "^\\(?:[ \t]*\n\\)+" "" headline))
  414. ;;; Transcode Functions
  415. ;;;; Headline and Inlinetasks
  416. ;; The main function is `org-icalendar-entry', which extracts
  417. ;; information from a headline or an inlinetask (summary,
  418. ;; description...) and then delegates code generation to
  419. ;; `org-icalendar--vtodo' and `org-icalendar--vevent', depending
  420. ;; on the component needed.
  421. ;; Obviously, `org-icalendar--valarm' handles alarms, which can
  422. ;; happen within a VTODO component.
  423. (defun org-icalendar-entry (entry contents info)
  424. "Transcode ENTRY element into iCalendar format.
  425. ENTRY is either a headline or an inlinetask. CONTENTS is
  426. ignored. INFO is a plist used as a communication channel.
  427. This function is called on every headline, the section below
  428. it (minus inlinetasks) being its contents. It tries to create
  429. VEVENT and VTODO components out of scheduled date, deadline date,
  430. plain timestamps, diary sexps. It also calls itself on every
  431. inlinetask within the section."
  432. (unless (org-element-property :footnote-section-p entry)
  433. (let* ((type (org-element-type entry))
  434. ;; Determine contents really associated to the entry. For
  435. ;; a headline, limit them to section, if any. For an
  436. ;; inlinetask, this is every element within the task.
  437. (inside
  438. (if (eq type 'inlinetask)
  439. (cons 'org-data (cons nil (org-element-contents entry)))
  440. (let ((first (car (org-element-contents entry))))
  441. (and (eq (org-element-type first) 'section)
  442. (cons 'org-data
  443. (cons nil (org-element-contents first))))))))
  444. (concat
  445. (let ((todo-type (org-element-property :todo-type entry))
  446. (uid (or (org-element-property :ID entry) (org-id-new)))
  447. (summary (org-icalendar-cleanup-string
  448. (or (org-element-property :SUMMARY entry)
  449. (org-export-data
  450. (org-element-property :title entry) info))))
  451. (loc (org-icalendar-cleanup-string
  452. (org-element-property :LOCATION entry)))
  453. ;; Build description of the entry from associated section
  454. ;; (headline) or contents (inlinetask).
  455. (desc
  456. (org-icalendar-cleanup-string
  457. (or (org-element-property :DESCRIPTION entry)
  458. (let ((contents (org-export-data inside info)))
  459. (cond
  460. ((not (org-string-nw-p contents)) nil)
  461. ((wholenump org-icalendar-include-body)
  462. (let ((contents (org-trim contents)))
  463. (substring
  464. contents 0 (min (length contents)
  465. org-icalendar-include-body))))
  466. (org-icalendar-include-body (org-trim contents)))))))
  467. (cat (org-icalendar-get-categories entry info)))
  468. (concat
  469. ;; Events: Delegate to `org-icalendar--vevent' to generate
  470. ;; "VEVENT" component from scheduled, deadline, or any
  471. ;; timestamp in the entry.
  472. (let ((deadline (org-element-property :deadline entry)))
  473. (and deadline
  474. (memq (if todo-type 'event-if-todo 'event-if-not-todo)
  475. org-icalendar-use-deadline)
  476. (org-icalendar--vevent
  477. entry deadline (concat "DL-" uid)
  478. (concat "DL: " summary) loc desc cat)))
  479. (let ((scheduled (org-element-property :scheduled entry)))
  480. (and scheduled
  481. (memq (if todo-type 'event-if-todo 'event-if-not-todo)
  482. org-icalendar-use-scheduled)
  483. (org-icalendar--vevent
  484. entry scheduled (concat "SC-" uid)
  485. (concat "S: " summary) loc desc cat)))
  486. ;; When collecting plain timestamps from a headline and its
  487. ;; title, skip inlinetasks since collection will happen once
  488. ;; ENTRY is one of them.
  489. (let ((counter 0))
  490. (mapconcat
  491. #'identity
  492. (org-element-map (cons (org-element-property :title entry)
  493. (org-element-contents inside))
  494. 'timestamp
  495. (lambda (ts)
  496. (when (let ((type (org-element-property :type ts)))
  497. (cl-case (plist-get info :with-timestamps)
  498. (active (memq type '(active active-range)))
  499. (inactive (memq type '(inactive inactive-range)))
  500. ((t) t)))
  501. (let ((uid (format "TS%d-%s" (cl-incf counter) uid)))
  502. (org-icalendar--vevent
  503. entry ts uid summary loc desc cat))))
  504. info nil (and (eq type 'headline) 'inlinetask))
  505. ""))
  506. ;; Task: First check if it is appropriate to export it. If
  507. ;; so, call `org-icalendar--vtodo' to transcode it into
  508. ;; a "VTODO" component.
  509. (when (and todo-type
  510. (cl-case (plist-get info :icalendar-include-todo)
  511. (all t)
  512. (unblocked
  513. (and (eq type 'headline)
  514. (not (org-icalendar-blocked-headline-p
  515. entry info))))
  516. ((t) (eq todo-type 'todo))))
  517. (org-icalendar--vtodo entry uid summary loc desc cat))
  518. ;; Diary-sexp: Collect every diary-sexp element within ENTRY
  519. ;; and its title, and transcode them. If ENTRY is
  520. ;; a headline, skip inlinetasks: they will be handled
  521. ;; separately.
  522. (when org-icalendar-include-sexps
  523. (let ((counter 0))
  524. (mapconcat #'identity
  525. (org-element-map
  526. (cons (org-element-property :title entry)
  527. (org-element-contents inside))
  528. 'diary-sexp
  529. (lambda (sexp)
  530. (org-icalendar-transcode-diary-sexp
  531. (org-element-property :value sexp)
  532. (format "DS%d-%s" (cl-incf counter) uid)
  533. summary))
  534. info nil (and (eq type 'headline) 'inlinetask))
  535. "")))))
  536. ;; If ENTRY is a headline, call current function on every
  537. ;; inlinetask within it. In agenda export, this is independent
  538. ;; from the mark (or lack thereof) on the entry.
  539. (when (eq type 'headline)
  540. (mapconcat #'identity
  541. (org-element-map inside 'inlinetask
  542. (lambda (task) (org-icalendar-entry task nil info))
  543. info) ""))
  544. ;; Don't forget components from inner entries.
  545. contents))))
  546. (defun org-icalendar--vevent
  547. (entry timestamp uid summary location description categories)
  548. "Create a VEVENT component.
  549. ENTRY is either a headline or an inlinetask element. TIMESTAMP
  550. is a timestamp object defining the date-time of the event. UID
  551. is the unique identifier for the event. SUMMARY defines a short
  552. summary or subject for the event. LOCATION defines the intended
  553. venue for the event. DESCRIPTION provides the complete
  554. description of the event. CATEGORIES defines the categories the
  555. event belongs to.
  556. Return VEVENT component as a string."
  557. (org-icalendar-fold-string
  558. (if (eq (org-element-property :type timestamp) 'diary)
  559. (org-icalendar-transcode-diary-sexp
  560. (org-element-property :raw-value timestamp) uid summary)
  561. (concat "BEGIN:VEVENT\n"
  562. (org-icalendar-dtstamp) "\n"
  563. "UID:" uid "\n"
  564. (org-icalendar-convert-timestamp timestamp "DTSTART") "\n"
  565. (org-icalendar-convert-timestamp timestamp "DTEND" t) "\n"
  566. ;; RRULE.
  567. (when (org-element-property :repeater-type timestamp)
  568. (format "RRULE:FREQ=%s;INTERVAL=%d\n"
  569. (cl-case (org-element-property :repeater-unit timestamp)
  570. (hour "HOURLY") (day "DAILY") (week "WEEKLY")
  571. (month "MONTHLY") (year "YEARLY"))
  572. (org-element-property :repeater-value timestamp)))
  573. "SUMMARY:" summary "\n"
  574. (and (org-string-nw-p location) (format "LOCATION:%s\n" location))
  575. (and (org-string-nw-p description)
  576. (format "DESCRIPTION:%s\n" description))
  577. "CATEGORIES:" categories "\n"
  578. ;; VALARM.
  579. (org-icalendar--valarm entry timestamp summary)
  580. "END:VEVENT"))))
  581. (defun org-icalendar--vtodo
  582. (entry uid summary location description categories)
  583. "Create a VTODO component.
  584. ENTRY is either a headline or an inlinetask element. UID is the
  585. unique identifier for the task. SUMMARY defines a short summary
  586. or subject for the task. LOCATION defines the intended venue for
  587. the task. DESCRIPTION provides the complete description of the
  588. task. CATEGORIES defines the categories the task belongs to.
  589. Return VTODO component as a string."
  590. (let ((start (or (and (memq 'todo-start org-icalendar-use-scheduled)
  591. (org-element-property :scheduled entry))
  592. ;; If we can't use a scheduled time for some
  593. ;; reason, start task now.
  594. (let ((now (decode-time)))
  595. (list 'timestamp
  596. (list :type 'active
  597. :minute-start (nth 1 now)
  598. :hour-start (nth 2 now)
  599. :day-start (nth 3 now)
  600. :month-start (nth 4 now)
  601. :year-start (nth 5 now)))))))
  602. (org-icalendar-fold-string
  603. (concat "BEGIN:VTODO\n"
  604. "UID:TODO-" uid "\n"
  605. (org-icalendar-dtstamp) "\n"
  606. (org-icalendar-convert-timestamp start "DTSTART") "\n"
  607. (and (memq 'todo-due org-icalendar-use-deadline)
  608. (org-element-property :deadline entry)
  609. (concat (org-icalendar-convert-timestamp
  610. (org-element-property :deadline entry) "DUE")
  611. "\n"))
  612. "SUMMARY:" summary "\n"
  613. (and (org-string-nw-p location) (format "LOCATION:%s\n" location))
  614. (and (org-string-nw-p description)
  615. (format "DESCRIPTION:%s\n" description))
  616. "CATEGORIES:" categories "\n"
  617. "SEQUENCE:1\n"
  618. (format "PRIORITY:%d\n"
  619. (let ((pri (or (org-element-property :priority entry)
  620. org-default-priority)))
  621. (floor (- 9 (* 8. (/ (float (- org-lowest-priority pri))
  622. (- org-lowest-priority
  623. org-highest-priority)))))))
  624. (format "STATUS:%s\n"
  625. (if (eq (org-element-property :todo-type entry) 'todo)
  626. "NEEDS-ACTION"
  627. "COMPLETED"))
  628. "END:VTODO"))))
  629. (defun org-icalendar--valarm (entry timestamp summary)
  630. "Create a VALARM component.
  631. ENTRY is the calendar entry triggering the alarm. TIMESTAMP is
  632. the start date-time of the entry. SUMMARY defines a short
  633. summary or subject for the task.
  634. Return VALARM component as a string, or nil if it isn't allowed."
  635. ;; Create a VALARM entry if the entry is timed. This is not very
  636. ;; general in that:
  637. ;; (a) only one alarm per entry is defined,
  638. ;; (b) only minutes are allowed for the trigger period ahead of the
  639. ;; start time,
  640. ;; (c) only a DISPLAY action is defined. [ESF]
  641. (let ((alarm-time
  642. (let ((warntime
  643. (org-element-property :APPT_WARNTIME entry)))
  644. (if warntime (string-to-number warntime) 0))))
  645. (and (or (> alarm-time 0) (> org-icalendar-alarm-time 0))
  646. (org-element-property :hour-start timestamp)
  647. (format "BEGIN:VALARM
  648. ACTION:DISPLAY
  649. DESCRIPTION:%s
  650. TRIGGER:-P0DT0H%dM0S
  651. END:VALARM\n"
  652. summary
  653. (if (zerop alarm-time) org-icalendar-alarm-time alarm-time)))))
  654. ;;;; Template
  655. (defun org-icalendar-template (contents info)
  656. "Return complete document string after iCalendar conversion.
  657. CONTENTS is the transcoded contents string. INFO is a plist used
  658. as a communication channel."
  659. (org-icalendar--vcalendar
  660. ;; Name.
  661. (if (not (plist-get info :input-file)) (buffer-name (buffer-base-buffer))
  662. (file-name-nondirectory
  663. (file-name-sans-extension (plist-get info :input-file))))
  664. ;; Owner.
  665. (if (not (plist-get info :with-author)) ""
  666. (org-export-data (plist-get info :author) info))
  667. ;; Timezone.
  668. (if (org-string-nw-p org-icalendar-timezone) org-icalendar-timezone
  669. (cadr (current-time-zone)))
  670. ;; Description.
  671. (org-export-data (plist-get info :title) info)
  672. contents))
  673. (defun org-icalendar--vcalendar (name owner tz description contents)
  674. "Create a VCALENDAR component.
  675. NAME, OWNER, TZ, DESCRIPTION and CONTENTS are all strings giving,
  676. respectively, the name of the calendar, its owner, the timezone
  677. used, a short description and the other components included."
  678. (concat (format "BEGIN:VCALENDAR
  679. VERSION:2.0
  680. X-WR-CALNAME:%s
  681. PRODID:-//%s//Emacs with Org mode//EN
  682. X-WR-TIMEZONE:%s
  683. X-WR-CALDESC:%s
  684. CALSCALE:GREGORIAN\n"
  685. (org-icalendar-cleanup-string name)
  686. (org-icalendar-cleanup-string owner)
  687. (org-icalendar-cleanup-string tz)
  688. (org-icalendar-cleanup-string description))
  689. contents
  690. "END:VCALENDAR\n"))
  691. ;;; Interactive Functions
  692. ;;;###autoload
  693. (defun org-icalendar-export-to-ics
  694. (&optional async subtreep visible-only body-only)
  695. "Export current buffer to an iCalendar file.
  696. If narrowing is active in the current buffer, only export its
  697. narrowed part.
  698. If a region is active, export that region.
  699. A non-nil optional argument ASYNC means the process should happen
  700. asynchronously. The resulting file should be accessible through
  701. the `org-export-stack' interface.
  702. When optional argument SUBTREEP is non-nil, export the sub-tree
  703. at point, extracting information from the headline properties
  704. first.
  705. When optional argument VISIBLE-ONLY is non-nil, don't export
  706. contents of hidden elements.
  707. When optional argument BODY-ONLY is non-nil, only write code
  708. between \"BEGIN:VCALENDAR\" and \"END:VCALENDAR\".
  709. Return ICS file name."
  710. (interactive)
  711. (let ((file (buffer-file-name (buffer-base-buffer))))
  712. (when (and file org-icalendar-store-UID)
  713. (org-icalendar-create-uid file 'warn-user)))
  714. ;; Export part. Since this back-end is backed up by `ascii', ensure
  715. ;; links will not be collected at the end of sections.
  716. (let ((outfile (org-export-output-file-name ".ics" subtreep)))
  717. (org-export-to-file 'icalendar outfile
  718. async subtreep visible-only body-only
  719. '(:ascii-charset utf-8 :ascii-links-to-notes nil)
  720. (lambda (file)
  721. (run-hook-with-args 'org-icalendar-after-save-hook file) nil))))
  722. ;;;###autoload
  723. (defun org-icalendar-export-agenda-files (&optional async)
  724. "Export all agenda files to iCalendar files.
  725. When optional argument ASYNC is non-nil, export happens in an
  726. external process."
  727. (interactive)
  728. (if async
  729. ;; Asynchronous export is not interactive, so we will not call
  730. ;; `org-check-agenda-file'. Instead we remove any non-existent
  731. ;; agenda file from the list.
  732. (let ((files (cl-remove-if-not #'file-exists-p (org-agenda-files t))))
  733. (org-export-async-start
  734. (lambda (results)
  735. (dolist (f results) (org-export-add-to-stack f 'icalendar)))
  736. `(let (output-files)
  737. (dolist (file ',files outputfiles)
  738. (with-current-buffer (org-get-agenda-file-buffer file)
  739. (push (expand-file-name (org-icalendar-export-to-ics))
  740. output-files))))))
  741. (let ((files (org-agenda-files t)))
  742. (org-agenda-prepare-buffers files)
  743. (unwind-protect
  744. (dolist (file files)
  745. (catch 'nextfile
  746. (org-check-agenda-file file)
  747. (with-current-buffer (org-get-agenda-file-buffer file)
  748. (org-icalendar-export-to-ics))))
  749. (org-release-buffers org-agenda-new-buffers)))))
  750. ;;;###autoload
  751. (defun org-icalendar-combine-agenda-files (&optional async)
  752. "Combine all agenda files into a single iCalendar file.
  753. A non-nil optional argument ASYNC means the process should happen
  754. asynchronously. The resulting file should be accessible through
  755. the `org-export-stack' interface.
  756. The file is stored under the name chosen in
  757. `org-icalendar-combined-agenda-file'."
  758. (interactive)
  759. (if async
  760. (let ((files (cl-remove-if-not #'file-exists-p (org-agenda-files t))))
  761. (org-export-async-start
  762. (lambda (_)
  763. (org-export-add-to-stack
  764. (expand-file-name org-icalendar-combined-agenda-file)
  765. 'icalendar))
  766. `(apply #'org-icalendar--combine-files ',files)))
  767. (apply #'org-icalendar--combine-files (org-agenda-files t))))
  768. (defun org-icalendar-export-current-agenda (file)
  769. "Export current agenda view to an iCalendar FILE.
  770. This function assumes major mode for current buffer is
  771. `org-agenda-mode'."
  772. (let* ((org-export-babel-evaluate) ; Don't evaluate Babel block.
  773. (contents
  774. (org-export-string-as
  775. (with-output-to-string
  776. (save-excursion
  777. (let ((p (point-min)))
  778. (while (setq p (next-single-property-change p 'org-hd-marker))
  779. (let ((m (get-text-property p 'org-hd-marker)))
  780. (when m
  781. (with-current-buffer (marker-buffer m)
  782. (org-with-wide-buffer
  783. (goto-char (marker-position m))
  784. (princ
  785. (org-element-normalize-string
  786. (buffer-substring
  787. (point) (progn (outline-next-heading) (point)))))))))
  788. (forward-line)))))
  789. 'icalendar t
  790. '(:ascii-charset utf-8 :ascii-links-to-notes nil
  791. :icalendar-include-todo all))))
  792. (with-temp-file file
  793. (insert
  794. (org-icalendar--vcalendar
  795. org-icalendar-combined-name
  796. user-full-name
  797. (or (org-string-nw-p org-icalendar-timezone) (cadr (current-time-zone)))
  798. org-icalendar-combined-description
  799. contents)))
  800. (run-hook-with-args 'org-icalendar-after-save-hook file)))
  801. (defun org-icalendar--combine-files (&rest files)
  802. "Combine entries from multiple files into an iCalendar file.
  803. FILES is a list of files to build the calendar from."
  804. (org-agenda-prepare-buffers files)
  805. (unwind-protect
  806. (progn
  807. (with-temp-file org-icalendar-combined-agenda-file
  808. (insert
  809. (org-icalendar--vcalendar
  810. ;; Name.
  811. org-icalendar-combined-name
  812. ;; Owner.
  813. user-full-name
  814. ;; Timezone.
  815. (or (org-string-nw-p org-icalendar-timezone)
  816. (cadr (current-time-zone)))
  817. ;; Description.
  818. org-icalendar-combined-description
  819. ;; Contents.
  820. (concat
  821. ;; Agenda contents.
  822. (mapconcat
  823. (lambda (file)
  824. (catch 'nextfile
  825. (org-check-agenda-file file)
  826. (with-current-buffer (org-get-agenda-file-buffer file)
  827. ;; Create ID if necessary.
  828. (when org-icalendar-store-UID
  829. (org-icalendar-create-uid file t))
  830. (org-export-as
  831. 'icalendar nil nil t
  832. '(:ascii-charset utf-8 :ascii-links-to-notes nil)))))
  833. files "")
  834. ;; BBDB anniversaries.
  835. (when (and org-icalendar-include-bbdb-anniversaries
  836. (require 'org-bbdb nil t))
  837. (with-output-to-string (org-bbdb-anniv-export-ical)))))))
  838. (run-hook-with-args 'org-icalendar-after-save-hook
  839. org-icalendar-combined-agenda-file))
  840. (org-release-buffers org-agenda-new-buffers)))
  841. (provide 'ox-icalendar)
  842. ;; Local variables:
  843. ;; generated-autoload-file: "org-loaddefs.el"
  844. ;; End:
  845. ;;; ox-icalendar.el ends here