ob-C.el 8.3 KB

123456789101112131415161718192021222324252627282930313233343536373839404142434445464748495051525354555657585960616263646566676869707172737475767778798081828384858687888990919293949596979899100101102103104105106107108109110111112113114115116117118119120121122123124125126127128129130131132133134135136137138139140141142143144145146147148149150151152153154155156157158159160161162163164165166167168169170171172173174175176177178179180181182183184185186187188189190191192193194195196197198199200201202203204205206207208209210211212213214215216217218219220221222223224225226227228229230231232233234235236237238239240241242243244
  1. ;;; ob-C.el --- org-babel functions for C and similar languages
  2. ;; Copyright (C) 2010-2013 Free Software Foundation, Inc.
  3. ;; Author: Eric Schulte
  4. ;; Keywords: literate programming, reproducible research
  5. ;; Homepage: http://orgmode.org
  6. ;; This file is part of GNU Emacs.
  7. ;; GNU Emacs is free software: you can redistribute it and/or modify
  8. ;; it under the terms of the GNU General Public License as published by
  9. ;; the Free Software Foundation, either version 3 of the License, or
  10. ;; (at your option) any later version.
  11. ;; GNU Emacs is distributed in the hope that it will be useful,
  12. ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  13. ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  14. ;; GNU General Public License for more details.
  15. ;; You should have received a copy of the GNU General Public License
  16. ;; along with GNU Emacs. If not, see <http://www.gnu.org/licenses/>.
  17. ;;; Commentary:
  18. ;; Org-Babel support for evaluating C code.
  19. ;;
  20. ;; very limited implementation:
  21. ;; - currently only support :results output
  22. ;; - not much in the way of error feedback
  23. ;;; Code:
  24. (require 'ob)
  25. (require 'cc-mode)
  26. (declare-function org-entry-get "org"
  27. (pom property &optional inherit literal-nil))
  28. (defvar org-babel-tangle-lang-exts)
  29. (add-to-list 'org-babel-tangle-lang-exts '("C++" . "cpp"))
  30. (defvar org-babel-default-header-args:C '())
  31. (defvar org-babel-C-compiler "gcc"
  32. "Command used to compile a C source code file into an
  33. executable.")
  34. (defvar org-babel-C++-compiler "g++"
  35. "Command used to compile a C++ source code file into an
  36. executable.")
  37. (defvar org-babel-c-variant nil
  38. "Internal variable used to hold which type of C (e.g. C or C++)
  39. is currently being evaluated.")
  40. (defun org-babel-execute:cpp (body params)
  41. "Execute BODY according to PARAMS.
  42. This function calls `org-babel-execute:C++'."
  43. (org-babel-execute:C++ body params))
  44. (defun org-babel-execute:C++ (body params)
  45. "Execute a block of C++ code with org-babel.
  46. This function is called by `org-babel-execute-src-block'."
  47. (let ((org-babel-c-variant 'cpp)) (org-babel-C-execute body params)))
  48. (defun org-babel-expand-body:C++ (body params)
  49. "Expand a block of C++ code with org-babel according to it's
  50. header arguments (calls `org-babel-C-expand')."
  51. (let ((org-babel-c-variant 'cpp)) (org-babel-C-expand body params)))
  52. (defun org-babel-execute:C (body params)
  53. "Execute a block of C code with org-babel.
  54. This function is called by `org-babel-execute-src-block'."
  55. (let ((org-babel-c-variant 'c)) (org-babel-C-execute body params)))
  56. (defun org-babel-expand-body:c (body params)
  57. "Expand a block of C code with org-babel according to it's
  58. header arguments (calls `org-babel-C-expand')."
  59. (let ((org-babel-c-variant 'c)) (org-babel-C-expand body params)))
  60. (defun org-babel-C-execute (body params)
  61. "This function should only be called by `org-babel-execute:C'
  62. or `org-babel-execute:C++'."
  63. (let* ((tmp-src-file (org-babel-temp-file
  64. "C-src-"
  65. (cond
  66. ((equal org-babel-c-variant 'c) ".c")
  67. ((equal org-babel-c-variant 'cpp) ".cpp"))))
  68. (tmp-bin-file (org-babel-temp-file "C-bin-" org-babel-exeext))
  69. (cmdline (cdr (assoc :cmdline params)))
  70. (flags (cdr (assoc :flags params)))
  71. (full-body (org-babel-C-expand body params))
  72. (compile
  73. (progn
  74. (with-temp-file tmp-src-file (insert full-body))
  75. (org-babel-eval
  76. (format "%s -o %s %s %s"
  77. (cond
  78. ((equal org-babel-c-variant 'c) org-babel-C-compiler)
  79. ((equal org-babel-c-variant 'cpp) org-babel-C++-compiler))
  80. (org-babel-process-file-name tmp-bin-file)
  81. (mapconcat 'identity
  82. (if (listp flags) flags (list flags)) " ")
  83. (org-babel-process-file-name tmp-src-file)) ""))))
  84. (let ((results
  85. (org-babel-trim
  86. (org-babel-eval
  87. (concat tmp-bin-file (if cmdline (concat " " cmdline) "")) ""))))
  88. (org-babel-reassemble-table
  89. (org-babel-result-cond (cdr (assoc :result-params params))
  90. (org-babel-read results)
  91. (let ((tmp-file (org-babel-temp-file "c-")))
  92. (with-temp-file tmp-file (insert results))
  93. (org-babel-import-elisp-from-file tmp-file)))
  94. (org-babel-pick-name
  95. (cdr (assoc :colname-names params)) (cdr (assoc :colnames params)))
  96. (org-babel-pick-name
  97. (cdr (assoc :rowname-names params)) (cdr (assoc :rownames params)))))
  98. ))
  99. (defun org-babel-C-expand (body params)
  100. "Expand a block of C or C++ code with org-babel according to
  101. it's header arguments."
  102. (let ((vars (mapcar #'cdr (org-babel-get-header params :var)))
  103. (main-p (not (string= (cdr (assoc :main params)) "no")))
  104. (includes (or (cdr (assoc :includes params))
  105. (org-babel-read (org-entry-get nil "includes" t))))
  106. (defines (org-babel-read
  107. (or (cdr (assoc :defines params))
  108. (org-babel-read (org-entry-get nil "defines" t))))))
  109. (mapconcat 'identity
  110. (list
  111. ;; includes
  112. (mapconcat
  113. (lambda (inc) (format "#include %s" inc))
  114. (if (listp includes) includes (list includes)) "\n")
  115. ;; defines
  116. (mapconcat
  117. (lambda (inc) (format "#define %s" inc))
  118. (if (listp defines) defines (list defines)) "\n")
  119. ;; variables
  120. (mapconcat 'org-babel-C-var-to-C vars "\n")
  121. ;; body
  122. (if main-p
  123. (org-babel-C-ensure-main-wrap body)
  124. body) "\n") "\n")))
  125. (defun org-babel-C-ensure-main-wrap (body)
  126. "Wrap BODY in a \"main\" function call if none exists."
  127. (if (string-match "^[ \t]*[intvod]+[ \t\n\r]*main[ \t]*(.*)" body)
  128. body
  129. (format "int main() {\n%s\nreturn 0;\n}\n" body)))
  130. (defun org-babel-prep-session:C (session params)
  131. "This function does nothing as C is a compiled language with no
  132. support for sessions"
  133. (error "C is a compiled languages -- no support for sessions"))
  134. (defun org-babel-load-session:C (session body params)
  135. "This function does nothing as C is a compiled language with no
  136. support for sessions"
  137. (error "C is a compiled languages -- no support for sessions"))
  138. ;; helper functions
  139. (defun org-babel-C-format-val (type val)
  140. "Handle the FORMAT part of TYPE with the data from VAL."
  141. (let ((format-data (cadr type)))
  142. (if (stringp format-data)
  143. (cons "" (format format-data val))
  144. (funcall format-data val))))
  145. (defun org-babel-C-val-to-C-type (val)
  146. "Determine the type of VAL.
  147. Return a list (TYPE-NAME FORMAT). TYPE-NAME should be the name of the type.
  148. FORMAT can be either a format string or a function which is called with VAL."
  149. (cond
  150. ((integerp val) '("int" "%d"))
  151. ((floatp val) '("double" "%f"))
  152. ((or (listp val) (vectorp val))
  153. (lexical-let ((type (org-babel-C-val-to-C-list-type val)))
  154. (list (car type)
  155. (lambda (val)
  156. (cons
  157. (format "[%d]%s"
  158. (length val)
  159. (car (org-babel-C-format-val type (elt val 0))))
  160. (concat "{ "
  161. (mapconcat (lambda (v)
  162. (cdr (org-babel-C-format-val type v)))
  163. val
  164. ", ")
  165. " }"))))))
  166. (t ;; treat unknown types as string
  167. '("char" (lambda (val)
  168. (let ((s (format "%s" val))) ;; convert to string for unknown types
  169. (cons (format "[%d]" (1+ (length s)))
  170. (concat "\"" s "\""))))))))
  171. (defun org-babel-C-val-to-C-list-type (val)
  172. "Determine the C array type of a VAL."
  173. (let (type)
  174. (mapc
  175. #'(lambda (i)
  176. (let* ((tmp-type (org-babel-C-val-to-C-type i))
  177. (type-name (car type))
  178. (tmp-type-name (car tmp-type)))
  179. (when (and type (not (string= type-name tmp-type-name)))
  180. (if (and (member type-name '("int" "double" "int32_t"))
  181. (member tmp-type-name '("int" "double" "int32_t")))
  182. (setq tmp-type '("double" "" "%f"))
  183. (error "Only homogeneous lists are supported by C. You can not mix %s and %s"
  184. type-name
  185. tmp-type-name)))
  186. (setq type tmp-type)))
  187. val)
  188. type))
  189. (defun org-babel-C-var-to-C (pair)
  190. "Convert an elisp val into a string of C code specifying a var
  191. of the same value."
  192. ;; TODO list support
  193. (let ((var (car pair))
  194. (val (cdr pair)))
  195. (when (symbolp val)
  196. (setq val (symbol-name val))
  197. (when (= (length val) 1)
  198. (setq val (string-to-char val))))
  199. (let* ((type-data (org-babel-C-val-to-C-type val))
  200. (type (car type-data))
  201. (formated (org-babel-C-format-val type-data val))
  202. (suffix (car formated))
  203. (data (cdr formated)))
  204. (format "%s %s%s = %s;"
  205. type
  206. var
  207. suffix
  208. data))))
  209. (provide 'ob-C)
  210. ;;; ob-C.el ends here