org-gnus.el 11 KB

123456789101112131415161718192021222324252627282930313233343536373839404142434445464748495051525354555657585960616263646566676869707172737475767778798081828384858687888990919293949596979899100101102103104105106107108109110111112113114115116117118119120121122123124125126127128129130131132133134135136137138139140141142143144145146147148149150151152153154155156157158159160161162163164165166167168169170171172173174175176177178179180181182183184185186187188189190191192193194195196197198199200201202203204205206207208209210211212213214215216217218219220221222223224225226227228229230231232233234235236237238239240241242243244245246247248249250251252253254255256257258259260261262263264265266267268269270271272273274275276277278279280281282283284285286287288289290291292293294
  1. ;;; org-gnus.el --- Support for links to Gnus groups and messages from within Org-mode
  2. ;; Copyright (C) 2004-2012 Free Software Foundation, Inc.
  3. ;; Author: Carsten Dominik <carsten at orgmode dot org>
  4. ;; Tassilo Horn <tassilo at member dot fsf dot org>
  5. ;; Keywords: outlines, hypermedia, calendar, wp
  6. ;; Homepage: http://orgmode.org
  7. ;;
  8. ;; This file is part of GNU Emacs.
  9. ;;
  10. ;; GNU Emacs is free software: you can redistribute it and/or modify
  11. ;; it under the terms of the GNU General Public License as published by
  12. ;; the Free Software Foundation, either version 3 of the License, or
  13. ;; (at your option) any later version.
  14. ;; GNU Emacs is distributed in the hope that it will be useful,
  15. ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  16. ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  17. ;; GNU General Public License for more details.
  18. ;; You should have received a copy of the GNU General Public License
  19. ;; along with GNU Emacs. If not, see <http://www.gnu.org/licenses/>.
  20. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  21. ;;
  22. ;;; Commentary:
  23. ;; This file implements links to Gnus groups and messages from within Org-mode.
  24. ;; Org-mode loads this module by default - if this is not what you want,
  25. ;; configure the variable `org-modules'.
  26. ;;; Code:
  27. (require 'org)
  28. (eval-when-compile (require 'gnus-sum))
  29. ;; Declare external functions and variables
  30. (declare-function message-fetch-field "message" (header &optional not-all))
  31. (declare-function message-narrow-to-head-1 "message" nil)
  32. (declare-function nnimap-group-overview-filename "nnimap" (group server))
  33. ;; The following line suppresses a compiler warning stemming from gnus-sum.el
  34. (declare-function gnus-summary-last-subject "gnus-sum" nil)
  35. ;; Customization variables
  36. (when (fboundp 'defvaralias)
  37. (defvaralias 'org-usenet-links-prefer-google 'org-gnus-prefer-web-links))
  38. (defcustom org-gnus-prefer-web-links nil
  39. "If non-nil, `org-store-link' creates web links to Google groups or Gmane.
  40. When nil, Gnus will be used for such links.
  41. Using a prefix arg to the command \\[org-store-link] (`org-store-link')
  42. negates this setting for the duration of the command."
  43. :group 'org-link-store
  44. :type 'boolean)
  45. (defcustom org-gnus-nnimap-query-article-no-from-file nil
  46. "If non-nil, `org-gnus-follow-link' will try to translate
  47. Message-Ids to article numbers by querying the .overview file.
  48. Normally, this translation is done by querying the IMAP server,
  49. which is usually very fast. Unfortunately, some (maybe badly
  50. configured) IMAP servers don't support this operation quickly.
  51. So if following a link to a Gnus article takes ages, try setting
  52. this variable to `t'."
  53. :group 'org-link-store
  54. :type 'boolean)
  55. ;; Install the link type
  56. (org-add-link-type "gnus" 'org-gnus-open)
  57. (add-hook 'org-store-link-functions 'org-gnus-store-link)
  58. ;; Implementation
  59. (defun org-gnus-nnimap-cached-article-number (group server message-id)
  60. "Return cached article number (uid) of message in GROUP on SERVER.
  61. MESSAGE-ID is the message-id header field that identifies the
  62. message. If the uid is not cached, return nil."
  63. (with-temp-buffer
  64. (let ((nov (nnimap-group-overview-filename group server)))
  65. (when (file-exists-p nov)
  66. (mm-insert-file-contents nov)
  67. (set-buffer-modified-p nil)
  68. (goto-char (point-min))
  69. (catch 'found
  70. (while (search-forward message-id nil t)
  71. (let ((hdr (split-string (thing-at-point 'line) "\t")))
  72. (if (string= (nth 4 hdr) message-id)
  73. (throw 'found (nth 0 hdr))))))))))
  74. (defun org-gnus-group-link (group)
  75. "Create a link to the Gnus group GROUP.
  76. If GROUP is a newsgroup and `org-gnus-prefer-web-links' is
  77. non-nil, create a link to groups.google.com or gmane.org.
  78. Otherwise create a link to the group inside Gnus.
  79. If `org-store-link' was called with a prefix arg the meaning of
  80. `org-gnus-prefer-web-links' is reversed."
  81. (let ((unprefixed-group (replace-regexp-in-string "^[^:]+:" "" group)))
  82. (if (and (string-match "^nntp" group) ;; Only for nntp groups
  83. (org-xor current-prefix-arg
  84. org-gnus-prefer-web-links))
  85. (org-make-link (if (string-match "gmane" unprefixed-group)
  86. "http://news.gmane.org/"
  87. "http://groups.google.com/group/")
  88. unprefixed-group)
  89. (org-make-link "gnus:" group))))
  90. (defun org-gnus-article-link (group newsgroups message-id x-no-archive)
  91. "Create a link to a Gnus article.
  92. The article is specified by its MESSAGE-ID. Additional
  93. parameters are the Gnus GROUP, the NEWSGROUPS the article was
  94. posted to and the X-NO-ARCHIVE header value of that article.
  95. If GROUP is a newsgroup and `org-gnus-prefer-web-links' is
  96. non-nil, create a link to groups.google.com or gmane.org.
  97. Otherwise create a link to the article inside Gnus.
  98. If `org-store-link' was called with a prefix arg the meaning of
  99. `org-gnus-prefer-web-links' is reversed."
  100. (if (and (org-xor current-prefix-arg org-gnus-prefer-web-links)
  101. newsgroups ;; Make web links only for nntp groups
  102. (not x-no-archive)) ;; and if X-No-Archive isn't set.
  103. (format (if (string-match "gmane\\." newsgroups)
  104. "http://mid.gmane.org/%s"
  105. "http://groups.google.com/groups/search?as_umsgid=%s")
  106. (org-fixup-message-id-for-http message-id))
  107. (org-make-link "gnus:" group "#" message-id)))
  108. (defun org-gnus-store-link ()
  109. "Store a link to a Gnus folder or message."
  110. (cond
  111. ((eq major-mode 'gnus-group-mode)
  112. (let* ((group (cond ((fboundp 'gnus-group-group-name) ; depending on Gnus
  113. (gnus-group-group-name)) ; version
  114. ((fboundp 'gnus-group-name)
  115. (gnus-group-name))
  116. (t "???")))
  117. desc link)
  118. (when group
  119. (org-store-link-props :type "gnus" :group group)
  120. (setq desc (org-gnus-group-link group)
  121. link desc)
  122. (org-add-link-props :link link :description desc)
  123. link)))
  124. ((memq major-mode '(gnus-summary-mode gnus-article-mode))
  125. (let* ((group gnus-newsgroup-name)
  126. (header (with-current-buffer gnus-summary-buffer
  127. (gnus-summary-article-header)))
  128. (from (mail-header-from header))
  129. (message-id (org-remove-angle-brackets (mail-header-id header)))
  130. (date (org-trim (mail-header-date header)))
  131. (date-ts (and date
  132. (ignore-errors
  133. (format-time-string
  134. (org-time-stamp-format t)
  135. (date-to-time date)))))
  136. (date-ts-ia (and date
  137. (ignore-errors
  138. (format-time-string
  139. (org-time-stamp-format t t)
  140. (date-to-time date)))))
  141. (subject (copy-sequence (mail-header-subject header)))
  142. (to (cdr (assq 'To (mail-header-extra header))))
  143. newsgroups x-no-archive desc link)
  144. ;; Remove text properties of subject string to avoid Emacs bug
  145. ;; #3506
  146. (set-text-properties 0 (length subject) nil subject)
  147. ;; Fetching an article is an expensive operation; newsgroup and
  148. ;; x-no-archive are only needed for web links.
  149. (when (org-xor current-prefix-arg org-gnus-prefer-web-links)
  150. ;; Make sure the original article buffer is up-to-date
  151. (save-window-excursion (gnus-summary-select-article))
  152. (setq to (or to (gnus-fetch-original-field "To"))
  153. newsgroups (gnus-fetch-original-field "Newsgroups")
  154. x-no-archive (gnus-fetch-original-field "x-no-archive")))
  155. (org-store-link-props :type "gnus" :from from :subject subject
  156. :message-id message-id :group group :to to)
  157. (when date
  158. (org-add-link-props :date date :date-timestamp date-ts
  159. :date-timestamp-inactive date-ts-ia))
  160. (setq desc (org-email-link-description)
  161. link (org-gnus-article-link
  162. group newsgroups message-id x-no-archive))
  163. (org-add-link-props :link link :description desc)
  164. link))
  165. ((eq major-mode 'message-mode)
  166. (setq org-store-link-plist nil) ; reset
  167. (save-excursion
  168. (save-restriction
  169. (message-narrow-to-headers)
  170. (and (not (message-fetch-field "Message-ID"))
  171. (message-generate-headers '(Message-ID)))
  172. (goto-char (point-min))
  173. (re-search-forward "^Message-ID: *.*$" nil t)
  174. (put-text-property (match-beginning 0) (match-end 0) 'message-deletable nil)
  175. (let ((gcc (car (last
  176. (message-unquote-tokens
  177. (message-tokenize-header (mail-fetch-field "gcc" nil t) " ,")))))
  178. (id (org-remove-angle-brackets (mail-fetch-field "Message-ID")))
  179. (to (mail-fetch-field "To"))
  180. (from (mail-fetch-field "From"))
  181. (subject (mail-fetch-field "Subject"))
  182. desc link
  183. newsgroup xarchive) ; those are always nil for gcc
  184. (and (not gcc)
  185. (error "Can not create link: No Gcc header found."))
  186. (org-store-link-props :type "gnus" :from from :subject subject
  187. :message-id id :group gcc :to to)
  188. (setq desc (org-email-link-description)
  189. link (org-gnus-article-link
  190. gcc newsgroup id xarchive))
  191. (org-add-link-props :link link :description desc)
  192. link))))))
  193. (defun org-gnus-open-nntp (path)
  194. "Follow the nntp: link specified by PATH."
  195. (let* ((spec (split-string path "/"))
  196. (server (split-string (nth 2 spec) "@"))
  197. (group (nth 3 spec))
  198. (article (nth 4 spec)))
  199. (org-gnus-follow-link
  200. (format "nntp+%s:%s" (or (cdr server) (car server)) group)
  201. article)))
  202. (defun org-gnus-open (path)
  203. "Follow the Gnus message or folder link specified by PATH."
  204. (let (group article)
  205. (if (not (string-match "\\`\\([^#]+\\)\\(#\\(.*\\)\\)?" path))
  206. (error "Error in Gnus link"))
  207. (setq group (match-string 1 path)
  208. article (match-string 3 path))
  209. (when group
  210. (setq group (org-substring-no-properties group)))
  211. (when article
  212. (setq article (org-substring-no-properties article)))
  213. (org-gnus-follow-link group article)))
  214. (defun org-gnus-follow-link (&optional group article)
  215. "Follow a Gnus link to GROUP and ARTICLE."
  216. (require 'gnus)
  217. (funcall (cdr (assq 'gnus org-link-frame-setup)))
  218. (if gnus-other-frame-object (select-frame gnus-other-frame-object))
  219. (when group
  220. (setq group (org-substring-no-properties group)))
  221. (when article
  222. (setq article (org-substring-no-properties article)))
  223. (cond ((and group article)
  224. (gnus-activate-group group)
  225. (condition-case nil
  226. (let* ((method (gnus-find-method-for-group group))
  227. (backend (car method))
  228. (server (cadr method)))
  229. (cond
  230. ((eq backend 'nndoc)
  231. (if (gnus-group-read-group t nil group)
  232. (gnus-summary-goto-article article nil t)
  233. (message "Couldn't follow gnus link. %s"
  234. "The summary couldn't be opened.")))
  235. (t
  236. (let ((articles 1)
  237. group-opened)
  238. (when (and (eq backend 'nnimap)
  239. org-gnus-nnimap-query-article-no-from-file)
  240. (setq article
  241. (or (org-gnus-nnimap-cached-article-number
  242. (nth 1 (split-string group ":"))
  243. server (concat "<" article ">")) article)))
  244. (while (and (not group-opened)
  245. ;; stop on integer overflows
  246. (> articles 0))
  247. (setq group-opened (gnus-group-read-group
  248. articles nil group)
  249. articles (if (< articles 16)
  250. (1+ articles)
  251. (* articles 2))))
  252. (if group-opened
  253. (gnus-summary-goto-article article nil t)
  254. (message "Couldn't follow gnus link. %s"
  255. "The summary couldn't be opened."))))))
  256. (quit (message "Couldn't follow gnus link. %s"
  257. "The linked group is empty."))))
  258. (group (gnus-group-jump-to-group group))))
  259. (defun org-gnus-no-new-news ()
  260. "Like `M-x gnus' but doesn't check for new news."
  261. (if (not (gnus-alive-p)) (gnus)))
  262. (provide 'org-gnus)
  263. ;;; org-gnus.el ends here