org-notmuch.el 4.3 KB

123456789101112131415161718192021222324252627282930313233343536373839404142434445464748495051525354555657585960616263646566676869707172737475767778798081828384858687888990919293949596979899100101102103104105106107108109110111112113114115116117118119120121122123124125126127128129130131132133134135136
  1. ;;; org-notmuch.el --- Support for links to notmuch messages from within Org-mode
  2. ;; Copyright (C) 2010-2014 Matthieu Lemerre
  3. ;; Author: Matthieu Lemerre <racin@free.fr>
  4. ;; Keywords: outlines, hypermedia, calendar, wp
  5. ;; Homepage: https://orgmode.org
  6. ;; This file is not part of GNU Emacs.
  7. ;; This file is free software; you can redistribute it and/or modify
  8. ;; it under the terms of the GNU General Public License as published by
  9. ;; the Free Software Foundation; either version 2, or (at your option)
  10. ;; any later version.
  11. ;; This file is distributed in the hope that it will be useful,
  12. ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  13. ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  14. ;; GNU General Public License for more details.
  15. ;; You should have received a copy of the GNU General Public License
  16. ;; along with GNU Emacs. If not, see <http://www.gnu.org/licenses/>.
  17. ;;; Commentary:
  18. ;; This file implements links to notmuch messages and "searchs". A
  19. ;; search is a query to be performed by notmuch; it is the equivalent
  20. ;; to folders in other mail clients. Similarly, mails are refered to
  21. ;; by a query, so both a link can refer to several mails.
  22. ;; Links have one the following form
  23. ;; notmuch:<search terms>
  24. ;; notmuch-search:<search terms>.
  25. ;; The first form open the queries in notmuch-show mode, whereas the
  26. ;; second link open it in notmuch-search mode. Note that queries are
  27. ;; performed at the time the link is opened, and the result may be
  28. ;; different from whet the link was stored.
  29. ;;; Code:
  30. (require 'org)
  31. ;; customisable notmuch open functions
  32. (defcustom org-notmuch-open-function
  33. 'org-notmuch-follow-link
  34. "Function used to follow notmuch links.
  35. Should accept a notmuch search string as the sole argument."
  36. :group 'org-notmuch
  37. :version "24.4"
  38. :package-version '(Org . "8.0")
  39. :type 'function)
  40. (defcustom org-notmuch-search-open-function
  41. 'org-notmuch-search-follow-link
  42. "Function used to follow notmuch-search links.
  43. Should accept a notmuch search string as the sole argument."
  44. :group 'org-notmuch
  45. :version "24.4"
  46. :package-version '(Org . "8.0")
  47. :type 'function)
  48. ;; Install the link type
  49. (org-link-set-parameters "notmuch"
  50. :follow #'org-notmuch-open
  51. :store #'org-notmuch-store-link)
  52. (defun org-notmuch-store-link ()
  53. "Store a link to a notmuch search or message."
  54. (when (eq major-mode 'notmuch-show-mode)
  55. (let* ((message-id (notmuch-show-get-message-id t))
  56. (subject (notmuch-show-get-subject))
  57. (to (notmuch-show-get-to))
  58. (from (notmuch-show-get-from))
  59. (date (org-trim (notmuch-show-get-date)))
  60. desc link)
  61. (org-store-link-props :type "notmuch" :from from :to to :date date
  62. :subject subject :message-id message-id)
  63. (setq desc (org-email-link-description))
  64. (setq link (concat "notmuch:id:" message-id))
  65. (org-add-link-props :link link :description desc)
  66. link)))
  67. (defun org-notmuch-open (path)
  68. "Follow a notmuch message link specified by PATH."
  69. (funcall org-notmuch-open-function path))
  70. (defun org-notmuch-follow-link (search)
  71. "Follow a notmuch link to SEARCH.
  72. Can link to more than one message, if so all matching messages are shown."
  73. (require 'notmuch)
  74. (notmuch-show search))
  75. (org-link-set-parameters "notmuch-search"
  76. :follow #'org-notmuch-search-open
  77. :store #'org-notmuch-search-store-link)
  78. (defun org-notmuch-search-store-link ()
  79. "Store a link to a notmuch search or message."
  80. (when (eq major-mode 'notmuch-search-mode)
  81. (let ((link (concat "notmuch-search:"
  82. (org-link-escape notmuch-search-query-string)))
  83. (desc (concat "Notmuch search: " notmuch-search-query-string)))
  84. (org-store-link-props :type "notmuch-search"
  85. :link link
  86. :description desc)
  87. link)))
  88. (defun org-notmuch-search-open (path)
  89. "Follow a notmuch message link specified by PATH."
  90. (message "%s" path)
  91. (funcall org-notmuch-search-open-function path))
  92. (defun org-notmuch-search-follow-link (search)
  93. "Follow a notmuch link by displaying SEARCH in notmuch-search mode."
  94. (require 'notmuch)
  95. (notmuch-search (org-link-unescape search)))
  96. (defun org-notmuch-tree-follow-link (search)
  97. "Follow a notmuch link by displaying SEARCH in notmuch-tree mode."
  98. (require 'notmuch)
  99. (notmuch-tree (org-link-unescape search)))
  100. (provide 'org-notmuch)
  101. ;;; org-notmuch.el ends here